meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 meson.add_dist_script('scripts/save-tarball-version.sh', meson.project_version())
   8
   9 pa_version_str = meson.project_version()
  10 # For tarballs, the first split will do nothing, but for builds in git, we
  11 # split out suffixes when there are commits since the last tag
  12 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  13 version_split = pa_version_str.split('-')[0].split('.')
  14 pa_version_major = version_split[0].split('v')[0]
  15 pa_version_minor = version_split[1]
  16 if version_split.length() > 2
  17   pa_version_micro = version_split[2]
  18 else
  19   pa_version_micro = '0'
  20 endif
  21 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  22
  23 pa_api_version = 12
  24 pa_protocol_version = 35
  25
  26 # The stable ABI for client applications, for the version info x:y:z
  27 # always will hold x=z
  28 libpulse_version_info = [24, 0, 24]
  29
  30 # A simplified, synchronous, ABI-stable interface for client
  31 # applications, for the version info x:y:z always will hold x=z
  32 libpulse_simple_version_info = [1, 1, 1]
  33
  34 # The ABI-stable GLib adapter for client applications, for the version
  35 # info x:y:z always will hold x=z
  36 libpulse_mainloop_glib_version_info = [0, 6, 0]
  37
  38 libpulse_version = '@0@.@1@.@2@'.format(
  39   libpulse_version_info[0] - libpulse_version_info[2],
  40   libpulse_version_info[0],
  41   libpulse_version_info[1],
  42 )
  43
  44 libpulse_simple_version = '@0@.@1@.@2@'.format(
  45   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  46   libpulse_simple_version_info[0],
  47   libpulse_simple_version_info[1],
  48 )
  49
  50 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  51   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  52   libpulse_mainloop_glib_version_info[0],
  53   libpulse_mainloop_glib_version_info[1],
  54 )
  55
  56 # Paths
  57
  58 prefix = get_option('prefix')
  59 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  60
  61 bindir = join_paths(prefix, get_option('bindir'))
  62 includedir = join_paths(prefix, get_option('includedir'))
  63 libdir = join_paths(prefix, get_option('libdir'))
  64 libexecdir = join_paths(prefix, get_option('libexecdir'))
  65 mandir = join_paths(prefix, get_option('mandir'))
  66 datadir = join_paths(prefix, get_option('datadir'))
  67 localedir = join_paths(prefix, get_option('localedir'))
  68 localstatedir = join_paths(prefix, get_option('localstatedir'))
  69 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  70 privlibdir = join_paths(libdir, 'pulseaudio')
  71
  72 if host_machine.system() == 'windows'
  73   # Windows only supports loading libraries from the same dir as the executable
  74   privlibdir = bindir
  75 endif
  76
  77 alsadatadir = get_option('alsadatadir')
  78 if alsadatadir == ''
  79   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  80 endif
  81
  82 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  83 pulselibexecdir = join_paths(libexecdir, 'pulse')
  84 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  85
  86 modlibexecdir = get_option('modlibexecdir')
  87 if modlibexecdir == ''
  88   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  89 endif
  90
  91 padsplibdir = get_option('padsplibdir')
  92 if padsplibdir == ''
  93   padsplibdir = privlibdir
  94 endif
  95
  96 pulsedsp_location = get_option('pulsedsp-location')
  97 if pulsedsp_location == ''
  98   pulsedsp_location = join_paths(prefix, padsplibdir)
  99 endif
 100
 101 systemduserunitdir = get_option('systemduserunitdir')
 102 # the default value is set below
 103
 104 udevrulesdir = get_option('udevrulesdir')
 105 if udevrulesdir == ''
 106   # absolute path, otherwise meson prepends the prefix
 107   udevrulesdir = '/lib/udev/rules.d'
 108 endif
 109
 110 vapidir = join_paths(datadir, 'vala', 'vapi')
 111
 112 bashcompletiondir = get_option('bashcompletiondir')
 113 if bashcompletiondir == ''
 114   bash_completion_dep = dependency('bash-completion', required : false)
 115   if bash_completion_dep.found()
 116     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 117   else
 118     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 119   endif
 120 endif
 121
 122 zshcompletiondir = get_option('zshcompletiondir')
 123 if zshcompletiondir == ''
 124   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 125 endif
 126
 127 # Configuration data
 128
 129 cc = meson.get_compiler('c')
 130
 131 cdata = configuration_data()
 132 cdata.set_quoted('PACKAGE', 'pulseaudio')
 133 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 134 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 135 cdata.set('PA_MAJOR', pa_version_major)
 136 cdata.set('PA_MINOR', pa_version_minor)
 137 cdata.set('PA_API_VERSION', pa_api_version)
 138 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 139 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 140 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 141 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 142 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 143 cdata.set_quoted('PA_SOEXT', '.so')
 144 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 145 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 146 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 147 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 148 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 149 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 150 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 151 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 152 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 153 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 154 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 155 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 156 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 157 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 158 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 159 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 160 cdata.set('ENABLE_NLS', 1)
 161 cdata.set('top_srcdir', meson.source_root())
 162
 163 # Platform specifics
 164 # First some defaults to keep config file generation happy
 165 cdata.set('HAVE_COREAUDIO', 0)
 166 cdata.set('HAVE_WAVEOUT', 0)
 167 cdata.set('OS_IS_FREEBSD', 0)
 168
 169 platform_socket_dep = []
 170 platform_dep = []
 171
 172 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 173 # rather than ending up in the config.h file?
 174 if host_machine.system() == 'darwin'
 175   cdata.set('OS_IS_DARWIN', 1)
 176   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 177 elif host_machine.system() == 'windows'
 178   cdata.set('OS_IS_WIN32', 1)
 179   cdata.set('HAVE_WINDOWS_H', 1)
 180   cdata.set('HAVE_WAVEOUT', 1)
 181   cdata.set('HAVE_WINSOCK2_H', 1)
 182   cdata.set('HAVE_WS2TCPIP_H', 1)
 183   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 184   cdata.set('gid_t', 'int')
 185   cdata.set('uid_t', 'int')
 186   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 187   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 188   ole32_dep = meson.get_compiler('c').find_library('ole32')
 189   ssp_dep = meson.get_compiler('c').find_library('ssp')
 190   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 191   platform_socket_dep = [ws2_32_dep, winsock_dep]
 192   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 193 elif host_machine.system() == 'freebsd'
 194   cdata.set('OS_IS_FREEBSD', 1)
 195 #elif host_machine.system() == 'solaris'
 196 #  # Apparently meson has no solaris support?
 197 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 198 #  cdata.set('_XOPEN_SOURCE', 600)
 199 #  cdata.set('__EXTENSIONS__', 1)
 200 endif
 201
 202 if cc.has_type('_Bool')
 203   cdata.set('HAVE_STD_BOOL', 1)
 204 endif
 205
 206 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 207   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 208 endif
 209
 210 # Headers
 211
 212 check_headers = [
 213   'arpa/inet.h',
 214   'byteswap.h',
 215   'cpuid.h',
 216   'dlfcn.h',
 217   'execinfo.h',
 218   'grp.h',
 219   'langinfo.h',
 220   'linux/sockios.h',
 221   'locale.h',
 222   'netdb.h',
 223   'netinet/in.h',
 224   'netinet/in_systm.h',
 225   'netinet/ip.h',
 226   'netinet/tcp.h',
 227   'pcreposix.h',
 228   'poll.h',
 229   'pwd.h',
 230   'regex.h',
 231   'sched.h',
 232   'stdint.h',
 233   'sys/atomic.h',
 234   'sys/capability.h',
 235   'sys/conf.h',
 236   'sys/dl.h',
 237   'sys/eventfd.h',
 238   'sys/filio.h',
 239   'sys/ioctl.h',
 240   'sys/mman.h',
 241   'sys/prctl.h',
 242   'sys/resource.h',
 243   'sys/select.h',
 244   'sys/socket.h',
 245   'sys/syscall.h',
 246   'sys/uio.h',
 247   'sys/un.h',
 248   'sys/wait.h',
 249   'syslog.h',
 250   'xlocale.h',
 251 ]
 252
 253 foreach h : check_headers
 254   if cc.has_header(h)
 255     define = 'HAVE_' + h.underscorify().to_upper()
 256     cdata.set(define, 1)
 257   endif
 258 endforeach
 259
 260 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 261   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 262 endif
 263
 264 # FIXME: move this to the above set
 265 if host_machine.system() != 'windows'
 266   if cc.has_header('pthread.h')
 267     cdata.set('HAVE_PTHREAD', 1)
 268   endif
 269 endif
 270
 271 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 272   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 273 endif
 274
 275 # Functions
 276
 277 check_functions = [
 278   'accept4',
 279   'clock_gettime',
 280   'ctime_r',
 281   'fchmod',
 282   'fchown',
 283   'fork',
 284   'fstat',
 285   'getaddrinfo',
 286   'getgrgid_r',
 287   'getgrnam_r',
 288   'getpwnam_r',
 289   'getpwuid_r',
 290   'gettimeofday',
 291   'getuid',
 292   'lrintf',
 293   'lstat',
 294   'memfd_create',
 295   'mkfifo',
 296   'mlock',
 297   'nanosleep',
 298   'open64',
 299   'paccept',
 300   'pipe',
 301   'pipe2',
 302   'posix_fadvise',
 303   'posix_madvise',
 304   'posix_memalign',
 305   'ppoll',
 306   'readlink',
 307   'setegid',
 308   'seteuid',
 309   'setpgid',
 310   'setregid',
 311   'setresgid',
 312   'setresuid',
 313   'setreuid',
 314   'setsid',
 315   'sig2str',
 316   'sigaction',
 317   'strerror_r',
 318   'strtod_l',
 319   'strtof',
 320   'symlink',
 321   'sysconf',
 322   'uname',
 323 ]
 324
 325 foreach f : check_functions
 326   if cc.has_function(f)
 327     define = 'HAVE_' + f.underscorify().to_upper()
 328
 329     if f == 'posix_memalign' and host_machine.system() == 'windows'
 330       message('Win32/mingw32 does not properly define posix_memalign.')
 331     elif f == 'fork' and host_machine.system() == 'windows'
 332       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 333       # This causes Meson to think that Windows has a fork() which causes a link error...
 334       message('Win32/mingw32 does not properly define fork.')
 335     else
 336       cdata.set(define, 1)
 337     endif
 338   endif
 339 endforeach
 340
 341 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create') \
 342   or cc.has_function('memfd_create')
 343   cdata.set('HAVE_MEMFD', 1)
 344 endif
 345
 346 if cc.has_function('dgettext')
 347   if host_machine.system() != 'windows'
 348     libintl_dep = []
 349   else
 350     libintl_dep = cc.find_library('intl')
 351   endif
 352 else
 353   libintl_dep = cc.find_library('intl')
 354 endif
 355
 356 # Symbols
 357
 358 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 359   cdata.set('HAVE_SIGXCPU', 1)
 360 endif
 361
 362 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 363   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 364     # Define INADDR_NONE if not found (Solaris)
 365     cdata.set('INADDR_NONE', '0xffffffff')
 366   endif
 367 endif
 368
 369 check_decls = [
 370   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 371   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 372   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 373   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 374 ]
 375
 376 foreach s : check_decls
 377   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 378     define = 'HAVE_DECL_' + s[0].to_upper()
 379     cdata.set(define, 1)
 380   endif
 381 endforeach
 382
 383 # Types
 384
 385 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 386 cdata.set('GETGROUPS_T', 'gid_t')
 387
 388 # Include paths
 389
 390 configinc = include_directories('.')
 391 topinc = include_directories('src')
 392
 393 # CFLAGS/LDFLAGS
 394
 395 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 396 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 397 cdata.set('MESON_BUILD', 1)
 398
 399 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 400 # so we request the nodelete flag to be enabled.
 401 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 402 # Windows doesn't support this flag.
 403 if host_machine.system() != 'windows'
 404   nodelete_link_args = ['-Wl,-z,nodelete']
 405 else
 406   nodelete_link_args = []
 407 endif
 408
 409 # Code coverage
 410
 411 if get_option('gcov')
 412   add_project_arguments('--coverage', language: ['c', 'cpp'])
 413   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 414 endif
 415
 416 # Core Dependencies
 417
 418 libm_dep = cc.find_library('m', required : true)
 419
 420 thread_dep = dependency('threads')
 421 foreach f : [
 422   'pthread_getname_np',
 423   'pthread_setaffinity_np',
 424   'pthread_setname_np',
 425 ]
 426   if cc.has_function(f, dependencies : thread_dep)
 427     define = 'HAVE_' + f.underscorify().to_upper()
 428     cdata.set(define, 1)
 429   endif
 430 endforeach
 431
 432 cap_dep = cc.find_library('cap', required : false)
 433
 434 shm_dep = cc.find_library('rt', required : false)
 435 if cc.has_function('shm_open', dependencies : shm_dep)
 436   cdata.set('HAVE_SHM_OPEN', 1)
 437 endif
 438
 439 dl_dep = cc.find_library('dl', required : false)
 440 if cc.has_function('dladdr', dependencies : dl_dep)
 441   cdata.set('HAVE_DLADDR', 1)
 442 endif
 443
 444 have_iconv = false
 445 if cc.has_function('iconv_open')
 446   iconv_dep = dependency('', required : false)
 447   have_iconv = true
 448   # tell the libiconv header to pretend to be libc iconv
 449   cdata.set('LIBICONV_PLUG', 1)
 450 else
 451   iconv_dep = cc.find_library('iconv', required : false)
 452   have_iconv = iconv_dep.found()
 453 endif
 454 if have_iconv
 455   cdata.set('HAVE_ICONV', 1)
 456   iconvconsttest = '''#include <iconv.h>
 457 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 458 '''
 459   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 460     cdata.set('ICONV_CONST', '')
 461   else
 462     cdata.set('ICONV_CONST', 'const')
 463   endif
 464 endif
 465
 466 # Used for backtraces on BSD
 467 execinfo_dep = cc.find_library('execinfo', required : false)
 468
 469 # Atomic operations
 470
 471 if get_option('atomic-arm-memory-barrier')
 472     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 473 endif
 474
 475 need_libatomic_ops = false
 476
 477 atomictest = '''void func() {
 478   volatile int atomic = 2;
 479   __sync_bool_compare_and_swap (&atomic, 2, 3);
 480 }
 481 '''
 482
 483 if cc.compiles(atomictest)
 484   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 485
 486   newatomictest = '''void func() {
 487     int c = 0;
 488     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 489   }
 490   '''
 491
 492   if(cc.compiles(newatomictest))
 493     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 494   endif
 495
 496 elif host_machine.cpu_family() == 'arm'
 497   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 498     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 499   else
 500     armatomictest = '''int func() {
 501       volatile int a=0;
 502       int o=0, n=1, r;
 503       asm volatile (
 504               "ldrex    %0, [%1]\n"
 505               "subs  %0, %0, %2\n"
 506               "strexeq %0, %3, [%1]\n"
 507               : "=&r" (r)
 508               : "r" (&a), "Ir" (o), "r" (n)
 509       : "cc");
 510       return (a==1 ? 0 : -1);
 511     }
 512     '''
 513
 514     if cc.compiles(armatomictest)
 515       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 516     else
 517       need_libatomic_ops = true
 518     endif
 519   endif # arm && !linux
 520
 521 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 522   need_libatomic_ops = true
 523 endif # !atomic helpers && !arm
 524
 525 if need_libatomic_ops
 526   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 527
 528   cdata.set('AO_REQUIRE_CAS', 1)
 529
 530   if host_machine.system() != 'windows'
 531     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 532   else
 533     libatomic_ops_dep = dependency('', required: false)
 534   endif
 535 else
 536   libatomic_ops_dep = dependency('', required: false)
 537 endif
 538
 539 # ARM checks
 540 # ARMV6 instructions we need
 541 if host_machine.cpu_family() == 'arm'
 542   armv6test = '''int func() {
 543     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 544     asm volatile ("ldr r0, %2 \n"
 545                   "ldr r2, %3 \n"
 546                   "ldr r3, %4 \n"
 547                   "ssat r1, #8, r0 \n"
 548                   "str r1, %0 \n"
 549                   "pkhbt r1, r3, r2, LSL #8 \n"
 550                   "str r1, %1 \n"
 551                   : "=m" (a), "=m" (b)
 552                   : "m" (a), "m" (b), "m" (c)
 553                   : "r0", "r1", "r2", "r3", "cc");
 554     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 555   }
 556   '''
 557
 558   if cc.compiles(armv6test)
 559     cdata.set('HAVE_ARMV6', 1)
 560   endif
 561 endif
 562 # NEON checks are automatically done by the unstable-simd module
 563
 564 # FIXME: make sure it's >= 2.2
 565 ltdl_dep = cc.find_library('ltdl', required : true)
 566 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 567 #        and do we still want to support this at all?
 568 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 569
 570 if get_option('database') == 'tdb'
 571   database_dep = dependency('tdb')
 572 elif get_option('database') == 'gdbm'
 573   database_dep = cc.find_library('gdbm', required : true)
 574 else
 575   database_dep = dependency('', required: false)
 576 endif
 577
 578 if get_option('ipv6')
 579   cdata.set('HAVE_IPV6', 1)
 580 endif
 581
 582 if get_option('legacy-database-entry-format')
 583   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 584 endif
 585
 586 if get_option('stream-restore-clear-old-devices')
 587   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 588 endif
 589
 590 if get_option('running-from-build-tree')
 591   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 592 endif
 593
 594 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 595 if alsa_dep.found()
 596   cdata.set('HAVE_ALSA', 1)
 597   cdata.set('HAVE_ALSA_UCM', 1)
 598 endif
 599
 600 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 601 if asyncns_dep.found()
 602   cdata.set('HAVE_LIBASYNCNS', 1)
 603 endif
 604
 605 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 606 if dbus_dep.found()
 607   cdata.set('HAVE_DBUS', 1)
 608 endif
 609
 610 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 611 if gio_dep.found()
 612   cdata.set('HAVE_GSETTINGS', 1)
 613 endif
 614
 615 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 616 if glib_dep.found()
 617   cdata.set('HAVE_GLIB', 1)
 618 endif
 619
 620 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 621 if gtk_dep.found()
 622   cdata.set('HAVE_GTK', 1)
 623 endif
 624
 625 have_orcc = false
 626 orcc_args = []
 627 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 628 orcc = find_program('orcc', required : get_option('orc'))
 629 if orc_dep.found() and orcc.found()
 630   have_orcc = true
 631   orcc_args = [orcc]
 632   #orcc_args = [orcc, '--include', 'glib.h']
 633   cdata.set('HAVE_ORC', 1)
 634 else
 635   cdata.set('DISABLE_ORC', 1)
 636 endif
 637
 638 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 639 if samplerate_dep.found()
 640   cdata.set('HAVE_LIBSAMPLERATE', 1)
 641 endif
 642
 643 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 644
 645 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 646 if soxr_dep.found()
 647   cdata.set('HAVE_SOXR', 1)
 648 endif
 649
 650 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 651 if libsystemd_dep.found()
 652   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 653   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 654   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 655 endif
 656 systemd_dep = dependency('systemd', required : get_option('systemd'))
 657 if systemd_dep.found() and systemduserunitdir == ''
 658   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 659 endif
 660
 661 libelogind_dep = dependency('libelogind', required : get_option('elogind'))
 662 if libelogind_dep.found()
 663   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 664 endif
 665
 666 tcpwrap_dep = cc.find_library('wrap', required: get_option('tcpwrap'))
 667 if cc.has_header('tcpd.h') and cc.has_function('hosts_access', dependencies : tcpwrap_dep)
 668   cdata.set('HAVE_LIBWRAP', 1)
 669 endif
 670
 671 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 672 if x11_dep.found()
 673   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 674   ice_dep  = dependency('ice',  required : true)
 675   sm_dep   = dependency('sm',   required : true)
 676   xtst_dep = dependency('xtst', required : true)
 677   cdata.set('HAVE_X11', 1)
 678   if cc.has_function('XSetIOErrorExitHandler', dependencies: x11_dep)
 679     cdata.set('HAVE_XSETIOERROREXITHANDLER', 1)
 680   endif
 681 endif
 682
 683 # Module dependencies
 684 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 685   cdata.set('HAVE_OSS_OUTPUT', 1)
 686   cdata.set('HAVE_OSS_WRAPPER', 1)
 687   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 688 endif
 689
 690 if get_option('hal-compat')
 691   cdata.set('HAVE_HAL_COMPAT', 1)
 692 endif
 693
 694 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 695 if avahi_dep.found()
 696   cdata.set('HAVE_AVAHI', 1)
 697 endif
 698
 699 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 700
 701 if get_option('bluez5')
 702   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 703   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 704   cdata.set('HAVE_SBC', 1)
 705   cdata.set('HAVE_BLUEZ', 1)
 706   cdata.set('HAVE_BLUEZ_5', 1)
 707   if get_option('bluez5-native-headset')
 708     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 709   endif
 710   if get_option('bluez5-ofono-headset')
 711     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 712   endif
 713 endif
 714
 715 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 716 if fftw_dep.found()
 717   cdata.set('HAVE_FFTW', 1)
 718 endif
 719
 720 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 721 if jack_dep.found()
 722   cdata.set('HAVE_JACK', 1)
 723 endif
 724
 725 lirc_dep = dependency('lirc', required : get_option('lirc'))
 726 if lirc_dep.found()
 727   cdata.set('HAVE_LIRC', 1)
 728 endif
 729
 730 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 731 if openssl_dep.found()
 732   cdata.set('HAVE_OPENSSL', 1)
 733 endif
 734
 735 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 736 if speex_dep.found()
 737   cdata.set('HAVE_SPEEX', 1)
 738 endif
 739
 740 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 741 if udev_dep.found()
 742   cdata.set('HAVE_UDEV', 1)
 743 endif
 744
 745 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 746 if webrtc_dep.found()
 747   cdata.set('HAVE_WEBRTC', 1)
 748 endif
 749
 750 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 751 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 752 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 753
 754 have_gstreamer = false
 755 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 756   have_gstreamer = true
 757 endif
 758
 759 bluez5_gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('bluez5-gstreamer'))
 760 bluez5_gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('bluez5-gstreamer'))
 761 have_bluez5_gstreamer = false
 762 if bluez5_gst_dep.found() and bluez5_gstapp_dep.found()
 763   have_bluez5_gstreamer = true
 764   cdata.set('HAVE_GSTLDAC', 1)
 765   cdata.set('HAVE_GSTAPTX', 1)
 766 endif
 767
 768 # These are required for the CMake file generation
 769 cdata.set('PA_LIBDIR', libdir)
 770 cdata.set('PA_INCDIR', includedir)
 771 if glib_dep.found()
 772   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 773 endif
 774
 775 # Test dependencies
 776
 777 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 778
 779 # Subdirs
 780
 781 subdir('doxygen')
 782 subdir('po')
 783 if get_option('man')
 784   subdir('man')
 785 endif
 786 subdir('shell-completion/bash')
 787 subdir('shell-completion/zsh')
 788 subdir('src')
 789 subdir('vala')
 790
 791 # Now generate config.h from everything above
 792 configure_file(output : 'config.h', configuration : cdata)
 793
 794 # pkg-config files
 795
 796 pc_cdata = configuration_data()
 797
 798 pc_cdata.set('prefix', prefix)
 799 pc_cdata.set('exec_prefix', prefix)
 800 pc_cdata.set('libdir', libdir)
 801 pc_cdata.set('includedir', includedir)
 802 pc_cdata.set('modlibexecdir', modlibexecdir)
 803 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 804 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 805 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 806 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 807 # get_configtool_variable() work with it, so we have no way to get this flag right,
 808 # unless we do all the work ourselves. See current work in glib, also meson #553.
 809 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 810
 811 pc_files = [
 812   'libpulse.pc',
 813   'libpulse-simple.pc',
 814 ]
 815
 816 if glib_dep.found()
 817   pc_files += 'libpulse-mainloop-glib.pc'
 818 endif
 819
 820 foreach file : pc_files
 821   configure_file(
 822     input : file + '.in',
 823     output : file,
 824     configuration : pc_cdata,
 825     install_dir : pkgconfigdir)
 826 endforeach
 827
 828 # CMake files
 829
 830 m4 = find_program('m4', required: true)
 831
 832 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 833
 834 cmake_template_file = configure_file(
 835   input : 'PulseAudioConfig.cmake.in',
 836   output : 'PulseAudioConfig.cmake.tmp',
 837   configuration: cdata,
 838 )
 839
 840 custom_target('PulseAudioConfig.cmake',
 841   input : cmake_template_file,
 842   output : 'PulseAudioConfig.cmake',
 843   capture : true,
 844   command : [m4, '@INPUT@'],
 845   build_by_default : true,
 846   install : true,
 847   install_dir : cmakedir,
 848 )
 849
 850 configure_file(
 851   input : 'PulseAudioConfigVersion.cmake.in',
 852   output : 'PulseAudioConfigVersion.cmake',
 853   configuration: cdata,
 854   install : true,
 855   install_dir : cmakedir,
 856 )
 857
 858 ############################################################
 859
 860 # Final summary
 861
 862 summary = [
 863   '',
 864   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 865   '',
 866   'prefix:                        @0@'.format(prefix),
 867   'bindir:                        @0@'.format(bindir),
 868   'libdir:                        @0@'.format(libdir),
 869   'libexecdir:                    @0@'.format(libexecdir),
 870   'mandir:                        @0@'.format(mandir),
 871   'datadir:                       @0@'.format(datadir),
 872   'sysconfdir:                    @0@'.format(sysconfdir),
 873   'localstatedir:                 @0@'.format(localstatedir),
 874   'modlibexecdir:                 @0@'.format(modlibexecdir),
 875   'alsadatadir:                   @0@'.format(alsadatadir),
 876   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 877   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 878   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 879   'Bash completions directory:    @0@'.format(bashcompletiondir),
 880   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 881   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 882 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 883 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 884 #  'LIBS:                          @0@'.format(${LIBS}),
 885   '',
 886   'Enable pulseaudio daemon:      @0@'.format(get_option('daemon')),
 887   '',
 888   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 889   'Enable X11:                    @0@'.format(x11_dep.found()),
 890   '  Safe X11 I/O errors:         @0@'.format(cdata.has('HAVE_XSETIOERROREXITHANDLER')),
 891   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 892   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 893 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 894   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 895 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 896 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 897 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 898   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 899   'Enable GSettings:              @0@'.format(gio_dep.found()),
 900   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 901   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 902   'Enable Jack:                   @0@'.format(jack_dep.found()),
 903   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 904   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 905   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 906   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 907   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 908   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 909   '    Enable GStreamer based codecs: @0@'.format(have_bluez5_gstreamer),
 910   'Enable udev:                   @0@'.format(udev_dep.found()),
 911   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 912   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 913   'Enable elogind:                @0@'.format(libelogind_dep.found()),
 914   'Enable TCP Wrappers:           @0@'.format(tcpwrap_dep.found()),
 915   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 916   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 917   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 918   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 919   'Enable ORC:                    @0@'.format(have_orcc),
 920   'Enable GStreamer:              @0@'.format(have_gstreamer),
 921   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 922   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 923   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 924   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 925   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 926   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 927   'Enable man pages:              @0@'.format(get_option('man')),
 928   'Enable unit tests:             @0@'.format(get_option('tests')),
 929   '',
 930   'Database:                      @0@'.format(get_option('database')),
 931   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 932   'module-stream-restore:',
 933   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 934   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 935   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 936   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 937   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 938 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 939 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 940 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 941 ]
 942
 943 message('\n    '.join(summary))
 944
 945 # Sanity checks
 946
 947 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 948   error('At least one echo canceller implementation must be available!')
 949 endif
 950
 951 if samplerate_dep.found()
 952   warning('Support for libsamplerate is DEPRECATED')
 953 endif
 954
 955 if host_machine.system() != 'windows'
 956   if not dbus_dep.found()
 957     message = [
 958       'You do not have D-Bus support enabled. It is strongly recommended',
 959       'that you enable D-Bus support if your platform supports it.',
 960       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 961       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 962       'support and even a native control protocol for communicating and',
 963       'controlling the PulseAudio daemon itself.',
 964     ]
 965     warning('\n' + '\n'.join(message))
 966   endif
 967   if host_machine.system() == 'linux' and not udev_dep.found()
 968     message = [
 969       'You do not have udev support enabled. It is strongly recommended',
 970       'that you enable udev support if your platform supports it as it is',
 971       'the primary method used to detect hardware audio devices (on Linux)',
 972       'and is thus a critical part of PulseAudio on that platform.',
 973     ]
 974     warning('\n' + '\n'.join(message))
 975   endif
 976   if not speex_dep.found()
 977     message = [
 978       'You do not have speex support enabled. It is strongly recommended',
 979       'that you enable speex support if your platform supports it as it is',
 980       'the primary method used for audio resampling and is thus a critical',
 981       'part of PulseAudio on that platform.',
 982     ]
 983     warning('\n' + '\n'.join(message))
 984   endif
 985 endif