meson.build

   1 # Copyright © 2017-2019 Intel Corporation
   2
   3 # Permission is hereby granted, free of charge, to any person obtaining a copy
   4 # of this software and associated documentation files (the "Software"), to deal
   5 # in the Software without restriction, including without limitation the rights
   6 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   7 # copies of the Software, and to permit persons to whom the Software is
   8 # furnished to do so, subject to the following conditions:
   9
  10 # The above copyright notice and this permission notice shall be included in
  11 # all copies or substantial portions of the Software.
  12
  13 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  14 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  15 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  16 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  17 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  18 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  19 # SOFTWARE.
  20
  21 project(
  22   'mesa',
  23   ['c', 'cpp'],
  24   version : run_command(
  25     [find_program('python', 'python3'), 'bin/meson_get_version.py']
  26   ).stdout(),
  27   license : 'MIT',
  28   meson_version : '>= 0.46',
  29   default_options : ['buildtype=debugoptimized', 'b_ndebug=if-release', 'c_std=c99', 'cpp_std=c++14']
  30 )
  31
  32 cc = meson.get_compiler('c')
  33 cpp = meson.get_compiler('cpp')
  34
  35 null_dep = dependency('', required : false)
  36
  37 if get_option('layout') != 'mirror'
  38   error('`mirror` is the only build directory layout supported')
  39 endif
  40
  41 # Arguments for the preprocessor, put these in a separate array from the C and
  42 # C++ (cpp in meson terminology) arguments since they need to be added to the
  43 # default arguments for both C and C++.
  44 pre_args = [
  45   '-D__STDC_CONSTANT_MACROS',
  46   '-D__STDC_FORMAT_MACROS',
  47   '-D__STDC_LIMIT_MACROS',
  48   '-DPACKAGE_VERSION="@0@"'.format(meson.project_version()),
  49   '-DPACKAGE_BUGREPORT="https://gitlab.freedesktop.org/mesa/mesa/issues"',
  50 ]
  51
  52 with_vulkan_icd_dir = get_option('vulkan-icd-dir')
  53 with_tests = get_option('build-tests')
  54 with_valgrind = get_option('valgrind')
  55 with_libunwind = get_option('libunwind')
  56 with_glx_read_only_text = get_option('glx-read-only-text')
  57 with_glx_direct = get_option('glx-direct')
  58 with_osmesa = get_option('osmesa')
  59 with_swr_arches = get_option('swr-arches')
  60 with_vulkan_overlay_layer = get_option('vulkan-overlay-layer')
  61 with_tools = get_option('tools')
  62 if with_tools.contains('all')
  63   with_tools = [
  64     'drm-shim',
  65     'etnaviv',
  66     'freedreno',
  67     'glsl',
  68     'intel',
  69     'intel-ui',
  70     'lima',
  71     'nir',
  72     'nouveau',
  73     'xvmc',
  74   ]
  75 endif
  76
  77 with_intel_tools = with_tools.contains('intel') or with_tools.contains('intel-ui')
  78 with_imgui = with_intel_tools or with_vulkan_overlay_layer
  79
  80 dri_drivers_path = get_option('dri-drivers-path')
  81 if dri_drivers_path == ''
  82   dri_drivers_path = join_paths(get_option('prefix'), get_option('libdir'), 'dri')
  83 endif
  84 dri_search_path = get_option('dri-search-path')
  85 if dri_search_path == ''
  86   dri_search_path = dri_drivers_path
  87 endif
  88
  89 with_gles1 = get_option('gles1')
  90 with_gles2 = get_option('gles2')
  91 if host_machine.system() == 'windows'
  92   if with_gles1 == 'auto'
  93     with_gles1 = 'false'
  94   endif
  95   if with_gles2 == 'auto'
  96     with_gles2 = 'false'
  97   endif
  98 endif
  99 with_opengl = get_option('opengl')
 100
 101 # Default shared glapi off for windows, on elsewhere.
 102 _sg = get_option('shared-glapi')
 103 if _sg == 'auto'
 104   with_shared_glapi = host_machine.system() != 'windows'
 105 else
 106   with_shared_glapi = _sg == 'true'
 107 endif
 108
 109 # shared-glapi is required if at least two OpenGL APIs are being built
 110 if not with_shared_glapi
 111   if ((with_gles1 == 'true' and with_gles2 == 'true') or
 112       (with_gles1 == 'true' and with_opengl) or
 113       (with_gles2 == 'true' and with_opengl))
 114     error('shared-glapi required for building two or more of OpenGL, OpenGL ES 1.x, OpenGL ES 2.x')
 115   endif
 116   with_gles1 = 'false'
 117   with_gles2 = 'false'
 118 endif
 119
 120 # We require OpenGL for OpenGL ES
 121 if not with_opengl
 122   if (with_gles1 == 'true' or with_gles2 == 'true') and not with_opengl
 123     error('building OpenGL ES without OpenGL is not supported.')
 124   endif
 125   with_gles1 = 'false'
 126   with_gles2 = 'false'
 127 endif
 128
 129 with_gles1 = with_gles1 != 'false'
 130 with_gles2 = with_gles2 != 'false'
 131 with_any_opengl = with_opengl or with_gles1 or with_gles2
 132 # Only build shared_glapi if at least one OpenGL API is enabled
 133 with_shared_glapi = with_shared_glapi and with_any_opengl
 134
 135 system_has_kms_drm = ['openbsd', 'netbsd', 'freebsd', 'gnu/kfreebsd', 'dragonfly', 'linux', 'sunos'].contains(host_machine.system())
 136
 137 dri_drivers = get_option('dri-drivers')
 138 if dri_drivers.contains('auto')
 139   if system_has_kms_drm
 140     # TODO: PPC, Sparc
 141     if ['x86', 'x86_64'].contains(host_machine.cpu_family())
 142       dri_drivers = ['i915', 'i965', 'r100', 'r200', 'nouveau']
 143     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 144       dri_drivers = []
 145     else
 146       error('Unknown architecture @0@. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 147             host_machine.cpu_family()))
 148     endif
 149   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 150     # only swrast would make sense here, but gallium swrast is a much better default
 151     dri_drivers = []
 152   else
 153     error('Unknown OS @0@. Please pass -Ddri-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 154           host_machine.system()))
 155   endif
 156 endif
 157
 158 with_dri_i915 = dri_drivers.contains('i915')
 159 with_dri_i965 = dri_drivers.contains('i965')
 160 with_dri_r100 = dri_drivers.contains('r100')
 161 with_dri_r200 = dri_drivers.contains('r200')
 162 with_dri_nouveau = dri_drivers.contains('nouveau')
 163 with_dri_swrast = dri_drivers.contains('swrast')
 164
 165 with_dri = dri_drivers.length() != 0 and dri_drivers != ['']
 166
 167 gallium_drivers = get_option('gallium-drivers')
 168 if gallium_drivers.contains('auto')
 169   if system_has_kms_drm
 170     # TODO: PPC, Sparc
 171     if ['x86', 'x86_64'].contains(host_machine.cpu_family())
 172       gallium_drivers = [
 173         'r300', 'r600', 'radeonsi', 'nouveau', 'virgl', 'svga', 'swrast',
 174         'iris'
 175       ]
 176     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 177       gallium_drivers = [
 178         'kmsro', 'v3d', 'vc4', 'freedreno', 'etnaviv', 'nouveau',
 179         'tegra', 'virgl', 'lima', 'panfrost', 'swrast'
 180       ]
 181     else
 182       error('Unknown architecture @0@. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 183             host_machine.cpu_family()))
 184     endif
 185   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 186     gallium_drivers = ['swrast']
 187   else
 188     error('Unknown OS @0@. Please pass -Dgallium-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 189           host_machine.system()))
 190   endif
 191 endif
 192 with_gallium_kmsro = gallium_drivers.contains('kmsro')
 193 with_gallium_radeonsi = gallium_drivers.contains('radeonsi')
 194 with_gallium_r300 = gallium_drivers.contains('r300')
 195 with_gallium_r600 = gallium_drivers.contains('r600')
 196 with_gallium_nouveau = gallium_drivers.contains('nouveau')
 197 with_gallium_freedreno = gallium_drivers.contains('freedreno')
 198 with_gallium_softpipe = gallium_drivers.contains('swrast')
 199 with_gallium_vc4 = gallium_drivers.contains('vc4')
 200 with_gallium_v3d = gallium_drivers.contains('v3d')
 201 with_gallium_panfrost = gallium_drivers.contains('panfrost')
 202 with_gallium_etnaviv = gallium_drivers.contains('etnaviv')
 203 with_gallium_tegra = gallium_drivers.contains('tegra')
 204 with_gallium_iris = gallium_drivers.contains('iris')
 205 with_gallium_i915 = gallium_drivers.contains('i915')
 206 with_gallium_svga = gallium_drivers.contains('svga')
 207 with_gallium_virgl = gallium_drivers.contains('virgl')
 208 with_gallium_swr = gallium_drivers.contains('swr')
 209 with_gallium_lima = gallium_drivers.contains('lima')
 210 with_gallium_zink = gallium_drivers.contains('zink')
 211
 212 if cc.get_id().startswith('intel') and meson.version().version_compare('< 0.49.1')
 213   error('Meson does not have sufficient support of ICC before 0.49.1 to compile mesa')
 214 endif
 215
 216 with_gallium = gallium_drivers.length() != 0 and gallium_drivers != ['']
 217
 218 if with_gallium and system_has_kms_drm
 219   _glx = get_option('glx')
 220   _egl = get_option('egl')
 221   if _glx == 'dri' or _egl == 'true' or (_glx == 'disabled' and _egl != 'false')
 222     with_dri = true
 223   endif
 224 endif
 225
 226 _vulkan_drivers = get_option('vulkan-drivers')
 227 if _vulkan_drivers.contains('auto')
 228   if system_has_kms_drm
 229     if host_machine.cpu_family().startswith('x86')
 230       _vulkan_drivers = ['amd', 'intel']
 231     elif ['arm', 'aarch64'].contains(host_machine.cpu_family())
 232       _vulkan_drivers = []
 233     else
 234       error('Unknown architecture @0@. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 235             host_machine.cpu_family()))
 236     endif
 237   elif ['darwin', 'windows', 'cygwin', 'haiku'].contains(host_machine.system())
 238     # No vulkan driver supports windows or macOS currently
 239     _vulkan_drivers = []
 240   else
 241     error('Unknown OS @0@. Please pass -Dvulkan-drivers to set driver options. Patches gladly accepted to fix this.'.format(
 242           host_machine.system()))
 243   endif
 244 endif
 245
 246 with_intel_vk = _vulkan_drivers.contains('intel')
 247 with_amd_vk = _vulkan_drivers.contains('amd')
 248 with_freedreno_vk = _vulkan_drivers.contains('freedreno')
 249 with_any_vk = _vulkan_drivers.length() != 0 and _vulkan_drivers != ['']
 250
 251 if with_dri_swrast and (with_gallium_softpipe or with_gallium_swr)
 252   error('Only one swrast provider can be built')
 253 endif
 254 if with_dri_i915 and with_gallium_i915
 255   error('Only one i915 provider can be built')
 256 endif
 257 if with_gallium_kmsro and not (with_gallium_v3d or with_gallium_vc4 or with_gallium_etnaviv or with_gallium_freedreno or with_gallium_panfrost or with_gallium_lima)
 258   error('kmsro driver requires one or more renderonly drivers (vc4, etnaviv, freedreno, panfrost, lima)')
 259 endif
 260 if with_gallium_tegra and not with_gallium_nouveau
 261   error('tegra driver requires nouveau driver')
 262 endif
 263
 264 if host_machine.system() == 'darwin'
 265   with_dri_platform = 'apple'
 266   pre_args += '-DBUILDING_MESA'
 267 elif ['windows', 'cygwin'].contains(host_machine.system())
 268   with_dri_platform = 'windows'
 269 elif system_has_kms_drm
 270   with_dri_platform = 'drm'
 271 else
 272   # FIXME: haiku doesn't use dri, and xlib doesn't use dri, probably should
 273   # assert here that one of those cases has been met.
 274   # FIXME: illumos ends up here as well
 275   with_dri_platform = 'none'
 276 endif
 277
 278 _platforms = get_option('platforms')
 279 if _platforms.contains('auto')
 280   if system_has_kms_drm
 281     _platforms = ['x11', 'wayland', 'drm', 'surfaceless']
 282   elif ['darwin', 'cygwin'].contains(host_machine.system())
 283     _platforms = ['x11', 'surfaceless']
 284   elif ['haiku'].contains(host_machine.system())
 285     _platforms = ['haiku']
 286   elif host_machine.system() == 'windows'
 287     _platforms = ['windows']
 288   else
 289     error('Unknown OS @0@. Please pass -Dplatforms to set platforms. Patches gladly accepted to fix this.'.format(
 290           host_machine.system()))
 291   endif
 292 endif
 293
 294 with_platform_android = _platforms.contains('android')
 295 with_platform_x11 = _platforms.contains('x11')
 296 with_platform_wayland = _platforms.contains('wayland')
 297 with_platform_drm = _platforms.contains('drm')
 298 with_platform_haiku = _platforms.contains('haiku')
 299 with_platform_surfaceless = _platforms.contains('surfaceless')
 300 with_platform_windows = _platforms.contains('windows')
 301
 302 with_platforms = false
 303 if _platforms.length() != 0 and _platforms != ['']
 304   # sanity check that list contains no empty strings
 305   if _platforms.contains('')
 306     error('Invalid argument list given to -Dplatforms, please fix.')
 307   endif
 308   with_platforms = true
 309   egl_native_platform = _platforms[0]
 310 endif
 311
 312 _xlib_lease = get_option('xlib-lease')
 313 if _xlib_lease == 'auto'
 314   with_xlib_lease = with_platform_x11 and with_platform_drm
 315 else
 316   with_xlib_lease = _xlib_lease == 'true'
 317 endif
 318
 319 with_glx = get_option('glx')
 320 if with_glx == 'auto'
 321   if with_dri
 322     with_glx = 'dri'
 323   elif with_platform_haiku
 324     with_glx = 'disabled'
 325   elif host_machine.system() == 'windows'
 326     with_glx = 'disabled'
 327   elif with_gallium
 328     # Even when building just gallium drivers the user probably wants dri
 329     with_glx = 'dri'
 330   elif with_platform_x11 and with_any_opengl and not with_any_vk
 331     # The automatic behavior should not be to turn on xlib based glx when
 332     # building only vulkan drivers
 333     with_glx = 'xlib'
 334   else
 335     with_glx = 'disabled'
 336   endif
 337 endif
 338 if with_glx == 'dri'
 339    if with_gallium
 340       with_dri = true
 341    endif
 342 endif
 343
 344 if not (with_dri or with_gallium or with_glx != 'disabled')
 345   with_gles1 = false
 346   with_gles2 = false
 347   with_opengl = false
 348   with_any_opengl = false
 349   with_shared_glapi = false
 350 endif
 351
 352 _gbm = get_option('gbm')
 353 if _gbm == 'auto'
 354   with_gbm = system_has_kms_drm and with_dri
 355 else
 356   with_gbm = _gbm == 'true'
 357 endif
 358 if with_gbm and not system_has_kms_drm
 359   error('GBM only supports DRM/KMS platforms')
 360 endif
 361
 362 _egl = get_option('egl')
 363 if _egl == 'auto'
 364   with_egl = (
 365     not ['darwin', 'windows'].contains(host_machine.system()) and
 366     with_dri and with_shared_glapi and with_platforms
 367   )
 368 elif _egl == 'true'
 369   if not with_dri
 370     error('EGL requires dri')
 371   elif not with_shared_glapi
 372     error('EGL requires shared-glapi')
 373   elif not with_platforms
 374     error('No platforms specified, consider -Dplatforms=drm,x11,surfaceless at least')
 375   elif not ['disabled', 'dri'].contains(with_glx)
 376     error('EGL requires dri, but a GLX is being built without dri')
 377   elif ['darwin', 'windows'].contains(host_machine.system())
 378     error('EGL is not available on Windows or MacOS')
 379   endif
 380   with_egl = true
 381 else
 382   with_egl = false
 383 endif
 384
 385 if with_egl and not (with_platform_drm or with_platform_surfaceless or with_platform_android)
 386   if with_gallium_radeonsi
 387     error('RadeonSI requires the drm, surfaceless or android platform when using EGL')
 388   endif
 389   if with_gallium_virgl
 390     error('Virgl requires the drm, surfaceless or android platform when using EGL')
 391   endif
 392 endif
 393
 394 # Android uses emutls for versions <= P/28. For USE_ELF_TLS we need ELF TLS.
 395 if host_machine.system() != 'windows' and (not with_platform_android or get_option('platform-sdk-version') >= 29)
 396   pre_args += '-DUSE_ELF_TLS'
 397 endif
 398
 399 if with_glx != 'disabled'
 400   if not (with_platform_x11 and with_any_opengl)
 401     error('Cannot build GLX support without X11 platform support and at least one OpenGL API')
 402   elif with_glx == 'gallium-xlib'
 403     if not with_gallium
 404       error('Gallium-xlib based GLX requires at least one gallium driver')
 405     elif not with_gallium_softpipe
 406       error('Gallium-xlib based GLX requires softpipe or llvmpipe.')
 407     elif with_dri
 408       error('gallium-xlib conflicts with any dri driver')
 409     endif
 410   elif with_glx == 'xlib'
 411     if with_dri
 412       error('xlib conflicts with any dri driver')
 413     endif
 414   elif with_glx == 'dri'
 415     if not with_shared_glapi
 416       error('dri based GLX requires shared-glapi')
 417     endif
 418   endif
 419 endif
 420
 421 with_glvnd = get_option('glvnd')
 422 if with_glvnd
 423   if with_platform_windows
 424     error('glvnd cannot be used on Windows')
 425   elif with_glx == 'xlib' or with_glx == 'gallium-xlib'
 426     error('Cannot build glvnd support for GLX that is not DRI based.')
 427   elif with_glx == 'disabled' and not with_egl
 428     error('glvnd requires DRI based GLX and/or EGL')
 429   endif
 430   if get_option('egl-lib-suffix') != ''
 431     error('''EGL lib suffix can't be used with libglvnd''')
 432   endif
 433 endif
 434
 435 if with_vulkan_icd_dir == ''
 436   with_vulkan_icd_dir = join_paths(get_option('datadir'), 'vulkan/icd.d')
 437 endif
 438
 439 # GNU/Hurd includes egl_dri2, without drm.
 440 with_dri2 = (with_dri or with_any_vk) and (with_dri_platform == 'drm' or
 441   host_machine.system() == 'gnu')
 442 _dri3 = get_option('dri3')
 443 if _dri3 == 'auto'
 444   with_dri3 = system_has_kms_drm and with_dri2
 445 else
 446   with_dri3 = _dri3 == 'true'
 447 endif
 448
 449 if with_any_vk and (with_platform_x11 and not with_dri3)
 450   error('Vulkan drivers require dri3 for X11 support')
 451 endif
 452 if with_dri
 453   if with_glx == 'disabled' and not with_egl and not with_gbm and with_osmesa != 'classic'
 454     error('building dri drivers require at least one windowing system or classic osmesa')
 455   endif
 456 endif
 457
 458 prog_pkgconfig = find_program('pkg-config')
 459
 460 _vdpau = get_option('gallium-vdpau')
 461 if not system_has_kms_drm
 462   if _vdpau == 'true'
 463     error('VDPAU state tracker can only be build on unix-like OSes.')
 464   else
 465     _vdpau = 'false'
 466   endif
 467 elif not with_platform_x11
 468   if _vdpau == 'true'
 469     error('VDPAU state tracker requires X11 support.')
 470   else
 471     _vdpau = 'false'
 472   endif
 473 elif not (with_gallium_r300 or with_gallium_r600 or with_gallium_radeonsi or
 474           with_gallium_nouveau)
 475   if _vdpau == 'true'
 476     error('VDPAU state tracker requires at least one of the following gallium drivers: r300, r600, radeonsi, nouveau.')
 477   else
 478     _vdpau = 'false'
 479   endif
 480 endif
 481 dep_vdpau = null_dep
 482 with_gallium_vdpau = false
 483 if _vdpau != 'false'
 484   dep_vdpau = dependency('vdpau', version : '>= 1.1', required : _vdpau == 'true')
 485   if dep_vdpau.found()
 486     dep_vdpau = declare_dependency(
 487       compile_args : run_command(prog_pkgconfig, ['vdpau', '--cflags']).stdout().split()
 488     )
 489     with_gallium_vdpau = true
 490   endif
 491 endif
 492
 493 if with_gallium_vdpau
 494   pre_args += '-DHAVE_ST_VDPAU'
 495 endif
 496 vdpau_drivers_path = get_option('vdpau-libs-path')
 497 if vdpau_drivers_path == ''
 498   vdpau_drivers_path = join_paths(get_option('libdir'), 'vdpau')
 499 endif
 500
 501 if with_gallium_zink
 502   dep_vulkan = dependency('vulkan')
 503 endif
 504
 505 _xvmc = get_option('gallium-xvmc')
 506 if not system_has_kms_drm
 507   if _xvmc == 'true'
 508     error('XVMC state tracker can only be build on unix-like OSes.')
 509   else
 510     _xvmc = 'false'
 511   endif
 512 elif not with_platform_x11
 513   if _xvmc == 'true'
 514     error('XVMC state tracker requires X11 support.')
 515   else
 516     _xvmc = 'false'
 517   endif
 518 elif not (with_gallium_r600 or with_gallium_nouveau)
 519   if _xvmc == 'true'
 520     error('XVMC state tracker requires at least one of the following gallium drivers: r600, nouveau.')
 521   else
 522     _xvmc = 'false'
 523   endif
 524 endif
 525 dep_xvmc = null_dep
 526 dep_xv = null_dep
 527 with_gallium_xvmc = false
 528 if _xvmc != 'false'
 529   dep_xvmc = dependency('xvmc', version : '>= 1.0.6', required : _xvmc == 'true')
 530   dep_xv = dependency('xv', required : _xvmc == 'true')
 531   with_gallium_xvmc = dep_xvmc.found() and dep_xv.found()
 532 endif
 533
 534 xvmc_drivers_path = get_option('xvmc-libs-path')
 535 if xvmc_drivers_path == ''
 536   xvmc_drivers_path = get_option('libdir')
 537 endif
 538
 539 _omx = get_option('gallium-omx')
 540 if not system_has_kms_drm
 541   if ['auto', 'disabled'].contains(_omx)
 542     _omx = 'disabled'
 543   else
 544     error('OMX state tracker can only be built on unix-like OSes.')
 545   endif
 546 elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
 547   if ['auto', 'disabled'].contains(_omx)
 548     _omx = 'disabled'
 549   else
 550     error('OMX state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
 551   endif
 552 endif
 553 with_gallium_omx = _omx
 554 dep_omx = null_dep
 555 dep_omx_other = []
 556 if ['auto', 'bellagio'].contains(_omx)
 557   dep_omx = dependency(
 558     'libomxil-bellagio', required : _omx == 'bellagio'
 559   )
 560   if dep_omx.found()
 561     with_gallium_omx = 'bellagio'
 562   endif
 563 endif
 564 if ['auto', 'tizonia'].contains(_omx)
 565   if with_dri and with_egl
 566     dep_omx = dependency(
 567       'libtizonia', version : '>= 0.10.0',
 568       required : _omx == 'tizonia',
 569     )
 570     dep_omx_other = [
 571       dependency('libtizplatform', required : _omx == 'tizonia'),
 572       dependency('tizilheaders', required : _omx == 'tizonia'),
 573     ]
 574     if dep_omx.found() and dep_omx_other[0].found() and dep_omx_other[1].found()
 575       with_gallium_omx = 'tizonia'
 576     endif
 577   elif _omx == 'tizonia'
 578     error('OMX-Tizonia state tracker requires dri and egl')
 579   endif
 580 endif
 581 if _omx == 'auto'
 582   with_gallium_omx = 'disabled'
 583 else
 584   with_gallium_omx = _omx
 585 endif
 586
 587 pre_args += [
 588   '-DENABLE_ST_OMX_BELLAGIO=' + (with_gallium_omx == 'bellagio' ? '1' : '0'),
 589   '-DENABLE_ST_OMX_TIZONIA=' + (with_gallium_omx == 'tizonia' ? '1' : '0'),
 590 ]
 591
 592
 593 omx_drivers_path = get_option('omx-libs-path')
 594
 595 if with_gallium_omx != 'disabled'
 596   # Figure out where to put the omx driver.
 597   # FIXME: this could all be vastly simplified by adding a 'defined_variable'
 598   # argument to meson's get_pkgconfig_variable method.
 599   if omx_drivers_path == ''
 600     _omx_libdir = dep_omx.get_pkgconfig_variable('libdir')
 601     _omx_drivers_dir = dep_omx.get_pkgconfig_variable('pluginsdir')
 602     if _omx_libdir == get_option('libdir')
 603       omx_drivers_path = _omx_drivers_dir
 604     else
 605       _omx_base_dir = []
 606       # This will fail on windows. Does OMX run on windows?
 607       _omx_libdir = _omx_libdir.split('/')
 608       _omx_drivers_dir = _omx_drivers_dir.split('/')
 609       foreach o : _omx_drivers_dir
 610         if not _omx_libdir.contains(o)
 611           _omx_base_dir += o
 612         endif
 613       endforeach
 614       omx_drivers_path = join_paths(get_option('libdir'), _omx_base_dir)
 615     endif
 616   endif
 617 endif
 618
 619 _va = get_option('gallium-va')
 620 if not system_has_kms_drm
 621   if _va == 'true'
 622     error('VA state tracker can only be built on unix-like OSes.')
 623   else
 624     _va = 'false'
 625   endif
 626 elif not (with_gallium_r600 or with_gallium_radeonsi or with_gallium_nouveau)
 627   if _va == 'true'
 628     error('VA state tracker requires at least one of the following gallium drivers: r600, radeonsi, nouveau.')
 629   else
 630     _va = 'false'
 631   endif
 632 endif
 633 with_gallium_va = false
 634 dep_va = null_dep
 635 if _va != 'false'
 636   dep_va = dependency('libva', version : '>= 0.38.0', required : _va == 'true')
 637   if dep_va.found()
 638     dep_va_headers = declare_dependency(
 639       compile_args : run_command(prog_pkgconfig, ['libva', '--cflags']).stdout().split()
 640     )
 641     with_gallium_va = true
 642   endif
 643 endif
 644
 645 va_drivers_path = get_option('va-libs-path')
 646 if va_drivers_path == ''
 647   va_drivers_path = join_paths(get_option('libdir'), 'dri')
 648 endif
 649
 650 _xa = get_option('gallium-xa')
 651 if not system_has_kms_drm
 652   if _xa == 'true'
 653     error('XA state tracker can only be built on unix-like OSes.')
 654   else
 655     _xa = 'false'
 656   endif
 657 elif not (with_gallium_nouveau or with_gallium_freedreno or with_gallium_i915
 658           or with_gallium_svga)
 659   if _xa == 'true'
 660     error('XA state tracker requires at least one of the following gallium drivers: nouveau, freedreno, i915, svga.')
 661   else
 662     _xa = 'false'
 663   endif
 664 endif
 665 with_gallium_xa = _xa != 'false'
 666
 667 d3d_drivers_path = get_option('d3d-drivers-path')
 668 if d3d_drivers_path == ''
 669   d3d_drivers_path = join_paths(get_option('prefix'), get_option('libdir'), 'd3d')
 670 endif
 671
 672 with_gallium_st_nine =  get_option('gallium-nine')
 673 if with_gallium_st_nine
 674   if not with_gallium_softpipe
 675     error('The nine state tracker requires gallium softpipe/llvmpipe.')
 676   elif not (with_gallium_radeonsi or with_gallium_nouveau or with_gallium_r600
 677             or with_gallium_r300 or with_gallium_svga or with_gallium_i915
 678             or with_gallium_iris)
 679     error('The nine state tracker requires at least one non-swrast gallium driver.')
 680   endif
 681   if not with_dri3
 682     error('Using nine with wine requires dri3')
 683   endif
 684 endif
 685
 686 if get_option('power8') != 'false'
 687   # on old versions of meson the cpu family would return as ppc64le on little
 688   # endian power8, this was changed in 0.48 such that the family would always
 689   # be ppc64 regardless of endianness, and then the machine.endian() value
 690   # should be checked. Since we support versions < 0.48 we need to use
 691   # startswith.
 692   if host_machine.cpu_family().startswith('ppc64') and host_machine.endian() == 'little'
 693     if cc.get_id() == 'gcc' and cc.version().version_compare('< 4.8')
 694       error('Altivec is not supported with gcc version < 4.8.')
 695     endif
 696     if cc.compiles('''
 697         #include <altivec.h>
 698         int main() {
 699           vector unsigned char r;
 700           vector unsigned int v = vec_splat_u32 (1);
 701           r = __builtin_vec_vgbbd ((vector unsigned char) v);
 702           return 0;
 703         }''',
 704         args : '-mpower8-vector',
 705         name : 'POWER8 intrinsics')
 706       pre_args += ['-D_ARCH_PWR8', '-mpower8-vector']
 707     elif get_option('power8') == 'true'
 708       error('POWER8 intrinsic support required but not found.')
 709     endif
 710   endif
 711 endif
 712
 713 _opencl = get_option('gallium-opencl')
 714 clover_cpp_std = []
 715 if _opencl != 'disabled'
 716   if not with_gallium
 717     error('OpenCL Clover implementation requires at least one gallium driver.')
 718   endif
 719
 720   dep_clc = dependency('libclc')
 721   with_gallium_opencl = true
 722   with_opencl_icd = _opencl == 'icd'
 723
 724   with_opencl_spirv = get_option('opencl-spirv')
 725   if with_opencl_spirv
 726     dep_spirv_tools = dependency('SPIRV-Tools', required : true, version : '>= 2018.0')
 727     # LLVMSPIRVLib is available at https://github.com/KhronosGroup/SPIRV-LLVM-Translator
 728     dep_llvmspirvlib = dependency('LLVMSPIRVLib', required : true, version : '>= 0.2.1')
 729   else
 730     dep_spirv_tools = null_dep
 731     dep_llvmspirvlib = null_dep
 732   endif
 733
 734   if host_machine.cpu_family().startswith('ppc') and cpp.compiles('''
 735       #if !defined(__VEC__) || !defined(__ALTIVEC__)
 736       #error "AltiVec not enabled"
 737       #endif''',
 738       name : 'Altivec')
 739     clover_cpp_std += ['cpp_std=gnu++11']
 740   endif
 741 else
 742   dep_clc = null_dep
 743   dep_spirv_tools = null_dep
 744   dep_llvmspirvlib = null_dep
 745   with_gallium_opencl = false
 746   with_opencl_icd = false
 747   with_opencl_spirv = false
 748 endif
 749
 750 gl_pkgconfig_c_flags = []
 751 if with_platform_x11
 752   if with_any_vk or with_egl or (with_glx == 'dri' and with_dri_platform == 'drm')
 753     pre_args += '-DHAVE_X11_PLATFORM'
 754   endif
 755   if with_glx == 'xlib' or with_glx == 'gallium-xlib'
 756     pre_args += '-DUSE_XSHM'
 757   else
 758     pre_args += '-DGLX_INDIRECT_RENDERING'
 759     if with_glx_direct
 760       pre_args += '-DGLX_DIRECT_RENDERING'
 761     endif
 762     if with_dri_platform == 'drm'
 763       pre_args += '-DGLX_USE_DRM'
 764     elif with_dri_platform == 'apple'
 765       pre_args += '-DGLX_USE_APPLEGL'
 766     elif with_dri_platform == 'windows'
 767       pre_args += '-DGLX_USE_WINDOWSGL'
 768     endif
 769   endif
 770 else
 771   pre_args += '-DEGL_NO_X11'
 772   gl_pkgconfig_c_flags += '-DEGL_NO_X11'
 773 endif
 774 if with_platform_drm
 775   if with_egl and not with_gbm
 776     error('EGL drm platform requires gbm')
 777   endif
 778   pre_args += '-DHAVE_DRM_PLATFORM'
 779 endif
 780 if with_platform_surfaceless
 781   pre_args += '-DHAVE_SURFACELESS_PLATFORM'
 782 endif
 783 if with_platform_android
 784   dep_android = [
 785     dependency('cutils'),
 786     dependency('hardware'),
 787     dependency('sync'),
 788   ]
 789   if get_option('platform-sdk-version') >= 26
 790     dep_android += dependency('nativewindow')
 791   endif
 792   pre_args += '-DHAVE_ANDROID_PLATFORM'
 793 endif
 794 if with_platform_haiku
 795   pre_args += '-DHAVE_HAIKU_PLATFORM'
 796 endif
 797
 798 if meson.version().version_compare('>=0.50')
 799   prog_python = import('python').find_installation('python3')
 800 else
 801   prog_python = import('python3').find_python()
 802 endif
 803 has_mako = run_command(
 804   prog_python, '-c',
 805   '''
 806 from distutils.version import StrictVersion
 807 import mako
 808 assert StrictVersion(mako.__version__) > StrictVersion("0.8.0")
 809   ''')
 810 if has_mako.returncode() != 0
 811   error('Python (3.x) mako module >= 0.8.0 required to build mesa.')
 812 endif
 813
 814 if cc.get_id() == 'gcc' and cc.version().version_compare('< 4.4.6')
 815   error('When using GCC, version 4.4.6 or later is required.')
 816 endif
 817
 818 # Support systems without ETIME (e.g. FreeBSD)
 819 if cc.get_define('ETIME', prefix : '#include <errno.h>') == ''
 820   pre_args += '-DETIME=ETIMEDOUT'
 821 endif
 822
 823 # Define DEBUG for debug builds only (debugoptimized is not included on this one)
 824 if get_option('buildtype') == 'debug'
 825   pre_args += '-DDEBUG'
 826 endif
 827
 828 with_shader_cache = false
 829 _shader_cache = get_option('shader-cache')
 830 if _shader_cache != 'false'
 831   if host_machine.system() == 'windows'
 832     if _shader_cache == 'true'
 833       error('Shader Cache does not currently work on Windows')
 834     endif
 835   else
 836     pre_args += '-DENABLE_SHADER_CACHE'
 837     with_shader_cache = true
 838   endif
 839 endif
 840 if with_amd_vk and not with_shader_cache
 841   error('Radv requires shader cache support')
 842 endif
 843
 844 # Check for GCC style builtins
 845 foreach b : ['bswap32', 'bswap64', 'clz', 'clzll', 'ctz', 'expect', 'ffs',
 846              'ffsll', 'popcount', 'popcountll', 'unreachable']
 847   if cc.has_function(b)
 848     pre_args += '-DHAVE___BUILTIN_@0@'.format(b.to_upper())
 849   endif
 850 endforeach
 851
 852 # check for GCC __attribute__
 853 foreach a : ['const', 'flatten', 'malloc', 'pure', 'unused',
 854              'warn_unused_result', 'weak',]
 855   if cc.compiles('int foo(void) __attribute__((@0@));'.format(a),
 856                  name : '__attribute__((@0@))'.format(a))
 857     pre_args += '-DHAVE_FUNC_ATTRIBUTE_@0@'.format(a.to_upper())
 858   endif
 859 endforeach
 860 if cc.compiles('int foo(const char *p, ...) __attribute__((format(printf, 1, 2)));',
 861                name : '__attribute__((format(...)))')
 862   pre_args += '-DHAVE_FUNC_ATTRIBUTE_FORMAT'
 863 endif
 864 if cc.compiles('struct __attribute__((packed)) foo { int bar; };',
 865                name : '__attribute__((packed))')
 866   pre_args += '-DHAVE_FUNC_ATTRIBUTE_PACKED'
 867 endif
 868 if cc.compiles('int *foo(void) __attribute__((returns_nonnull));',
 869                name : '__attribute__((returns_nonnull))')
 870   pre_args += '-DHAVE_FUNC_ATTRIBUTE_RETURNS_NONNULL'
 871 endif
 872 if cc.compiles('''int foo_def(void) __attribute__((visibility("default")));
 873                   int foo_hid(void) __attribute__((visibility("hidden")));
 874                   int foo_int(void) __attribute__((visibility("internal")));
 875                   int foo_pro(void) __attribute__((visibility("protected")));''',
 876                name : '__attribute__((visibility(...)))')
 877   pre_args += '-DHAVE_FUNC_ATTRIBUTE_VISIBILITY'
 878 endif
 879 if cc.compiles('int foo(void) { return 0; } int bar(void) __attribute__((alias("foo")));',
 880                name : '__attribute__((alias(...)))')
 881   pre_args += '-DHAVE_FUNC_ATTRIBUTE_ALIAS'
 882 endif
 883 if cc.compiles('int foo(void) __attribute__((__noreturn__));',
 884                name : '__attribute__((__noreturn__))')
 885   pre_args += '-DHAVE_FUNC_ATTRIBUTE_NORETURN'
 886 endif
 887 if cc.compiles('__uint128_t foo(void) { return 0; }',
 888                name : '__uint128_t')
 889   pre_args += '-DHAVE_UINT128'
 890 endif
 891
 892 # TODO: this is very incomplete
 893 if ['linux', 'cygwin', 'gnu', 'freebsd', 'gnu/kfreebsd'].contains(host_machine.system())
 894   pre_args += '-D_GNU_SOURCE'
 895 elif host_machine.system() == 'sunos'
 896   pre_args += '-D__EXTENSIONS__'
 897 elif host_machine.system() == 'windows'
 898   pre_args += [
 899     '-D_WINDOWS', '-D_WIN32_WINNT=0x0601', '-D_WINVER=0x0601',
 900     '-DPIPE_SUBSYSTEM_WINDOWS_USER',
 901     '-D_USE_MATH_DEFINES',  # XXX: scons doesn't use this for mingw
 902   ]
 903   if cc.get_id() == 'msvc'
 904     pre_args += [
 905       '-DVC_EXTRALEAN',
 906       '-D_CRT_SECURE_NO_WARNINGS',
 907       '-D_CRT_SECURE_NO_DEPRECATE',
 908       '-D_SCL_SECURE_NO_WARNINGS',
 909       '-D_SCL_SECURE_NO_DEPRECATE',
 910       '-D_ALLOW_KEYWORD_MACROS',
 911       '-D_HAS_EXCEPTIONS=0', # Tell C++ STL to not use exceptions
 912     ]
 913   else
 914     pre_args += ['-D__MSVCRT_VERSION__=0x0700']
 915   endif
 916 endif
 917
 918 # Check for generic C arguments
 919 c_args = []
 920 c_vis_args = []
 921 c_msvc_compat_args = []
 922 no_override_init_args = []
 923 cpp_args = []
 924 cpp_vis_args = []
 925 cpp_msvc_compat_args = []
 926 if cc.get_id() == 'msvc'
 927   foreach a : ['/wd4018',  # signed/unsigned mismatch
 928                '/wd4056',  # overflow in floating-point constant arithmetic
 929                '/wd4244',  # conversion from 'type1' to 'type2', possible loss of data
 930                '/wd4267',  # 'var' : conversion from 'size_t' to 'type', possible loss of data
 931                '/wd4305',  # trancation from 'type1' to 'type2'
 932                '/wd4351',  # new behavior: elements of array 'array' will be default initialized
 933                '/wd4756',  # overflow in constant arithmetic
 934                '/wd4800',  # forcing value to bool 'true' or 'false' (performance warning)
 935                '/wd4996',  # disabled deprecated POSIX name warnings
 936                '/wd4291']  # no matching operator delete found
 937     if cc.has_argument(a)
 938       c_args += a
 939     endif
 940     if cpp.has_argument(a)
 941       cpp_args += a
 942     endif
 943   endforeach
 944   if cc.has_argument('-Wmicrosoft-enum-value')  # Clang
 945     c_args += '-Wno-microsoft-enum-value'
 946     cpp_args += '-Wno-microsoft-enum-value'
 947   endif
 948 else
 949   _trial = [
 950     '-Werror=implicit-function-declaration',
 951     '-Werror=missing-prototypes',
 952     '-Werror=return-type',
 953     '-Werror=empty-body',
 954     '-Werror=incompatible-pointer-types',
 955     '-Werror=int-conversion',
 956     '-Wno-missing-field-initializers',
 957     '-Wno-format-truncation',
 958     '-fno-math-errno',
 959     '-fno-trapping-math',
 960     '-Qunused-arguments',
 961   ]
 962   # MinGW chokes on format specifiers and I can't get it all working
 963   if not (cc.get_id() == 'gcc' and host_machine.system() == 'windows')
 964     _trial += ['-Werror=format', '-Wformat-security']
 965   endif
 966   foreach a : _trial
 967     if cc.has_argument(a)
 968       c_args += a
 969     endif
 970   endforeach
 971
 972   _trial = [
 973     '-Werror=return-type',
 974     '-Werror=empty-body',
 975     '-Wno-non-virtual-dtor',
 976     '-Wno-missing-field-initializers',
 977     '-Wno-format-truncation',
 978     '-fno-math-errno',
 979     '-fno-trapping-math',
 980     '-Qunused-arguments',
 981   ]
 982   # MinGW chokes on format specifiers and I can't get it all working
 983   if not (cc.get_id() == 'gcc' and host_machine.system() == 'windows')
 984     _trial += ['-Werror=format', '-Wformat-security']
 985   endif
 986   foreach a : _trial
 987     if cpp.has_argument(a)
 988       cpp_args += a
 989     endif
 990   endforeach
 991
 992   foreach a : ['-Wno-override-init', '-Wno-initializer-overrides']
 993     if cc.has_argument(a)
 994       no_override_init_args += a
 995     endif
 996   endforeach
 997
 998   if cc.has_argument('-fvisibility=hidden')
 999     c_vis_args += '-fvisibility=hidden'
1000   endif
1001
1002   # Check for C and C++ arguments for MSVC compatibility. These are only used
1003   # in parts of the mesa code base that need to compile with MSVC, mainly
1004   # common code
1005   foreach a : ['-Werror=pointer-arith', '-Werror=vla', '-Werror=gnu-empty-initializer']
1006     if cc.has_argument(a)
1007       c_msvc_compat_args += a
1008     endif
1009     if cpp.has_argument(a)
1010       cpp_msvc_compat_args += a
1011     endif
1012   endforeach
1013
1014   if cpp.has_argument('-fvisibility=hidden')
1015     cpp_vis_args += '-fvisibility=hidden'
1016   endif
1017
1018 endif
1019
1020 # set linker arguments
1021 if host_machine.system() == 'windows'
1022   if cc.get_id() == 'msvc'
1023     add_project_link_arguments(
1024       '/fixed:no',
1025       '/incremental:no',
1026       '/dynamicbase',
1027       '/nxcompat',
1028       language : ['c', 'cpp'],
1029     )
1030   else
1031     add_project_link_arguments(
1032       '-Wl,--nxcompat',
1033       '-Wl,--dynamicbase',
1034       '-static-libgcc',
1035       '-static-libstdc++',
1036       language : ['c', 'cpp'],
1037     )
1038   endif
1039 endif
1040
1041 if host_machine.cpu_family().startswith('x86') and cc.get_id() != 'msvc'
1042   pre_args += '-DUSE_SSE41'
1043   with_sse41 = true
1044   sse41_args = ['-msse4.1']
1045
1046   # GCC on x86 (not x86_64) with -msse* assumes a 16 byte aligned stack, but
1047   # that's not guaranteed
1048   if host_machine.cpu_family() == 'x86'
1049     sse41_args += '-mstackrealign'
1050   endif
1051 else
1052   with_sse41 = false
1053   sse41_args = []
1054 endif
1055
1056 # Check for GCC style atomics
1057 dep_atomic = null_dep
1058
1059 if cc.compiles('''#include <stdint.h>
1060                   int main() {
1061                     struct {
1062                       uint64_t *v;
1063                     } x;
1064                     return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
1065                            (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
1066
1067                   }''',
1068                name : 'GCC atomic builtins')
1069   pre_args += '-DUSE_GCC_ATOMIC_BUILTINS'
1070
1071   # Not all atomic calls can be turned into lock-free instructions, in which
1072   # GCC will make calls into the libatomic library. Check whether we need to
1073   # link with -latomic.
1074   #
1075   # This can happen for 64-bit atomic operations on 32-bit architectures such
1076   # as ARM.
1077   if not cc.links('''#include <stdint.h>
1078                      int main() {
1079                        struct {
1080                          uint64_t *v;
1081                        } x;
1082                        return (int)__atomic_load_n(x.v, __ATOMIC_ACQUIRE) &
1083                               (int)__atomic_add_fetch(x.v, (uint64_t)1, __ATOMIC_ACQ_REL);
1084                      }''',
1085                   name : 'GCC atomic builtins required -latomic')
1086     dep_atomic = cc.find_library('atomic')
1087   endif
1088 endif
1089 if not cc.links('''#include <stdint.h>
1090                    uint64_t v;
1091                    int main() {
1092                      return __sync_add_and_fetch(&v, (uint64_t)1);
1093                    }''',
1094                 dependencies : dep_atomic,
1095                 name : 'GCC 64bit atomics')
1096   pre_args += '-DMISSING_64BIT_ATOMICS'
1097 endif
1098
1099 dep_ws2_32 = cc.find_library('ws2_32', required : with_platform_windows)
1100
1101 # TODO: shared/static? Is this even worth doing?
1102
1103 with_asm_arch = ''
1104 if host_machine.cpu_family() == 'x86'
1105   if system_has_kms_drm or host_machine.system() == 'gnu'
1106     with_asm_arch = 'x86'
1107     pre_args += ['-DUSE_X86_ASM', '-DUSE_MMX_ASM', '-DUSE_3DNOW_ASM',
1108                  '-DUSE_SSE_ASM']
1109
1110     if with_glx_read_only_text
1111       pre_args += ['-DGLX_X86_READONLY_TEXT']
1112     endif
1113   endif
1114 elif host_machine.cpu_family() == 'x86_64'
1115   if system_has_kms_drm
1116     with_asm_arch = 'x86_64'
1117     pre_args += ['-DUSE_X86_64_ASM']
1118   endif
1119 elif host_machine.cpu_family() == 'arm'
1120   if system_has_kms_drm
1121     with_asm_arch = 'arm'
1122     pre_args += ['-DUSE_ARM_ASM']
1123   endif
1124 elif host_machine.cpu_family() == 'aarch64'
1125   if system_has_kms_drm
1126     with_asm_arch = 'aarch64'
1127     pre_args += ['-DUSE_AARCH64_ASM']
1128   endif
1129 elif host_machine.cpu_family() == 'sparc64'
1130   if system_has_kms_drm
1131     with_asm_arch = 'sparc'
1132     pre_args += ['-DUSE_SPARC_ASM']
1133   endif
1134 elif host_machine.cpu_family().startswith('ppc64') and host_machine.endian() == 'little'
1135   if system_has_kms_drm
1136     with_asm_arch = 'ppc64le'
1137     pre_args += ['-DUSE_PPC64LE_ASM']
1138   endif
1139 endif
1140
1141 # Check for standard headers and functions
1142 if (cc.has_header_symbol('sys/sysmacros.h', 'major') and
1143   cc.has_header_symbol('sys/sysmacros.h', 'minor') and
1144   cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
1145   pre_args += '-DMAJOR_IN_SYSMACROS'
1146 endif
1147 if (cc.has_header_symbol('sys/mkdev.h', 'major') and
1148   cc.has_header_symbol('sys/mkdev.h', 'minor') and
1149   cc.has_header_symbol('sys/mkdev.h', 'makedev'))
1150   pre_args += '-DMAJOR_IN_MKDEV'
1151 endif
1152
1153 foreach h : ['xlocale.h', 'sys/sysctl.h', 'linux/futex.h', 'endian.h', 'dlfcn.h', 'execinfo.h', 'sys/shm.h', 'cet.h']
1154   if cc.compiles('#include <@0@>'.format(h), name : '@0@'.format(h))
1155     pre_args += '-DHAVE_@0@'.format(h.to_upper().underscorify())
1156   endif
1157 endforeach
1158
1159 foreach f : ['strtof', 'mkostemp', 'timespec_get', 'memfd_create', 'random_r', 'flock', 'strtok_r']
1160   if cc.has_function(f)
1161     pre_args += '-DHAVE_@0@'.format(f.to_upper())
1162   endif
1163 endforeach
1164
1165 if cc.has_header_symbol('errno.h', 'program_invocation_name',
1166                         args : '-D_GNU_SOURCE')
1167    pre_args += '-DHAVE_PROGRAM_INVOCATION_NAME'
1168 elif with_tools.contains('intel')
1169   error('Intel tools require the program_invocation_name variable')
1170 endif
1171
1172 # MinGW provides a __builtin_posix_memalign function, but not a posix_memalign.
1173 # This means that this check will succeed, but then compilation will later
1174 # fail. MSVC doesn't have this function at all, so only check for it on
1175 # non-windows platforms.
1176 if host_machine.system() != 'windows'
1177   if cc.has_function('posix_memalign')
1178     pre_args += '-DHAVE_POSIX_MEMALIGN'
1179   endif
1180 endif
1181
1182 if cc.has_member('struct dirent', 'd_type', prefix: '''#include <sys/types.h>
1183    #include <dirent.h>''')
1184    pre_args += '-DHAVE_DIRENT_D_TYPE'
1185 endif
1186
1187 # strtod locale support
1188 if cc.links('''
1189     #define _GNU_SOURCE
1190     #include <stdlib.h>
1191     #include <locale.h>
1192     #ifdef HAVE_XLOCALE_H
1193     #include <xlocale.h>
1194     #endif
1195     int main() {
1196       locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
1197       const char *s = "1.0";
1198       char *end;
1199       double d = strtod_l(s, end, loc);
1200       float f = strtof_l(s, end, loc);
1201       freelocale(loc);
1202       return 0;
1203     }''',
1204     args : pre_args,
1205     name : 'strtod has locale support')
1206   pre_args += '-DHAVE_STRTOD_L'
1207 endif
1208
1209 # Check for some linker flags
1210 ld_args_bsymbolic = []
1211 if cc.links('int main() { return 0; }', args : '-Wl,-Bsymbolic', name : 'Bsymbolic')
1212   ld_args_bsymbolic += '-Wl,-Bsymbolic'
1213 endif
1214 ld_args_gc_sections = []
1215 if cc.links('static char unused() { return 5; } int main() { return 0; }',
1216             args : '-Wl,--gc-sections', name : 'gc-sections')
1217   ld_args_gc_sections += '-Wl,--gc-sections'
1218 endif
1219 with_ld_version_script = false
1220 if cc.links('int main() { return 0; }',
1221             args : '-Wl,--version-script=@0@'.format(
1222               join_paths(meson.source_root(), 'build-support/conftest.map')),
1223             name : 'version-script')
1224   with_ld_version_script = true
1225 endif
1226 with_ld_dynamic_list = false
1227 if cc.links('int main() { return 0; }',
1228             args : '-Wl,--dynamic-list=@0@'.format(
1229               join_paths(meson.source_root(), 'build-support/conftest.dyn')),
1230             name : 'dynamic-list')
1231   with_ld_dynamic_list = true
1232 endif
1233
1234 ld_args_build_id = cc.get_supported_link_arguments('-Wl,--build-id=sha1')
1235
1236 # check for dl support
1237 dep_dl = null_dep
1238 if not cc.has_function('dlopen')
1239   dep_dl = cc.find_library('dl', required : host_machine.system() != 'windows')
1240 endif
1241 if cc.has_function('dladdr', dependencies : dep_dl)
1242   # This is really only required for megadrivers
1243   pre_args += '-DHAVE_DLADDR'
1244 endif
1245
1246 if cc.has_function('dl_iterate_phdr')
1247   pre_args += '-DHAVE_DL_ITERATE_PHDR'
1248 elif with_intel_vk
1249   error('Intel "Anvil" Vulkan driver requires the dl_iterate_phdr function')
1250 elif with_dri_i965 and with_shader_cache
1251   error('Intel i965 GL driver requires dl_iterate_phdr when built with shader caching.')
1252 endif
1253
1254 # Determine whether or not the rt library is needed for time functions
1255 if host_machine.system() == 'windows' or cc.has_function('clock_gettime')
1256   dep_clock = null_dep
1257 else
1258   dep_clock = cc.find_library('rt')
1259 endif
1260
1261 # TODO: some of these may be conditional
1262 dep_zlib = dependency('zlib', version : '>= 1.2.3', fallback : ['zlib', 'zlib_dep'])
1263 pre_args += '-DHAVE_ZLIB'
1264
1265 _zstd = get_option('zstd')
1266 if _zstd != 'false'
1267   dep_zstd = dependency('libzstd', required : _zstd == 'true')
1268   if dep_zstd.found()
1269     pre_args += '-DHAVE_ZSTD'
1270   endif
1271 else
1272   dep_zstd = null_dep
1273 endif
1274
1275 dep_thread = dependency('threads')
1276 if dep_thread.found() and host_machine.system() != 'windows'
1277   pre_args += '-DHAVE_PTHREAD'
1278   if cc.has_function(
1279       'pthread_setaffinity_np',
1280       dependencies : dep_thread,
1281       prefix : '#include <pthread.h>',
1282       args : '-D_GNU_SOURCE')
1283     pre_args += '-DHAVE_PTHREAD_SETAFFINITY'
1284   endif
1285   if cc.has_function(
1286       'pthread_setaffinity_np',
1287       dependencies : dep_thread,
1288       prefix : '#include <pthread_np.h>')
1289     pre_args += '-DPTHREAD_SETAFFINITY_IN_NP_HEADER'
1290   endif
1291 endif
1292 if host_machine.system() != 'windows'
1293   dep_expat = dependency('expat', fallback : ['expat', 'expat_dep'])
1294 else
1295   dep_expat = null_dep
1296 endif
1297 # this only exists on linux so either this is linux and it will be found, or
1298 # it's not linux and wont
1299 dep_m = cc.find_library('m', required : false)
1300
1301 # Check for libdrm. Various drivers have different libdrm version requirements,
1302 # but we always want to use the same version for all libdrm modules. That means
1303 # even if driver foo requires 2.4.0 and driver bar requires 2.4.3, if foo and
1304 # bar are both on use 2.4.3 for both of them
1305 dep_libdrm_amdgpu = null_dep
1306 dep_libdrm_radeon = null_dep
1307 dep_libdrm_nouveau = null_dep
1308 dep_libdrm_intel = null_dep
1309
1310 _drm_amdgpu_ver = '2.4.100'
1311 _drm_radeon_ver = '2.4.71'
1312 _drm_nouveau_ver = '2.4.66'
1313 _drm_intel_ver = '2.4.75'
1314 _drm_ver = '2.4.81'
1315
1316 _libdrm_checks = [
1317   ['intel', with_dri_i915 or with_gallium_i915],
1318   ['amdgpu', with_amd_vk or with_gallium_radeonsi],
1319   ['radeon', (with_gallium_radeonsi or with_dri_r100 or with_dri_r200 or
1320               with_gallium_r300 or with_gallium_r600)],
1321   ['nouveau', (with_gallium_nouveau or with_dri_nouveau)],
1322 ]
1323
1324 # VC4 only needs core libdrm support of this version, not a libdrm_vc4
1325 # library.
1326 if with_gallium_vc4
1327   _drm_ver = '2.4.89'
1328 endif
1329
1330 # etnaviv only needs core libdrm
1331 if with_gallium_etnaviv
1332   _drm_ver = '2.4.89'
1333 endif
1334
1335 # Loop over the enables versions and get the highest libdrm requirement for all
1336 # active drivers.
1337 _drm_blame = ''
1338 foreach d : _libdrm_checks
1339   ver = get_variable('_drm_@0@_ver'.format(d[0]))
1340   if d[1] and ver.version_compare('>' + _drm_ver)
1341     _drm_ver = ver
1342     _drm_blame = d[0]
1343   endif
1344 endforeach
1345 if _drm_blame != ''
1346   message('libdrm @0@ needed because @1@ has the highest requirement'.format(_drm_ver, _drm_blame))
1347 endif
1348
1349 # Then get each libdrm module
1350 foreach d : _libdrm_checks
1351   if d[1]
1352     set_variable(
1353       'dep_libdrm_' + d[0],
1354       dependency('libdrm_' + d[0], version : '>=' + _drm_ver)
1355     )
1356   endif
1357 endforeach
1358
1359 with_gallium_drisw_kms = false
1360 dep_libdrm = dependency(
1361   'libdrm', version : '>=' + _drm_ver,
1362   # GNU/Hurd includes egl_dri2, without drm.
1363   required : (with_dri2 and host_machine.system() != 'gnu') or with_dri3
1364 )
1365 if dep_libdrm.found()
1366   pre_args += '-DHAVE_LIBDRM'
1367   if with_dri_platform == 'drm' and with_dri
1368     with_gallium_drisw_kms = true
1369   endif
1370 endif
1371
1372 llvm_modules = ['bitwriter', 'engine', 'mcdisassembler', 'mcjit', 'core', 'executionengine', 'scalaropts', 'transformutils', 'instcombine']
1373 llvm_optional_modules = ['coroutines']
1374 if with_amd_vk or with_gallium_radeonsi or with_gallium_r600
1375   llvm_modules += ['amdgpu', 'native', 'bitreader', 'ipo']
1376   if with_gallium_r600
1377     llvm_modules += 'asmparser'
1378   endif
1379 endif
1380 if with_gallium_opencl
1381   llvm_modules += [
1382     'all-targets', 'linker', 'coverage', 'instrumentation', 'ipo', 'irreader',
1383     'lto', 'option', 'objcarcopts', 'profiledata',
1384   ]
1385 endif
1386
1387 if with_amd_vk or with_gallium_radeonsi
1388   _llvm_version = '>= 8.0.0'
1389 elif with_gallium_swr
1390   _llvm_version = '>= 6.0.0'
1391 else
1392   _llvm_version = '>= 3.9.0'
1393 endif
1394
1395 _shared_llvm = get_option('shared-llvm')
1396 _llvm = get_option('llvm')
1397
1398 # The cmake method will never find libllvm.so|dylib; this is fine for windows
1399 # because llvm doesn't support libllvm.dll
1400 _llvm_method = 'config-tool'
1401 if (meson.version().version_compare('>= 0.51.0') and
1402     host_machine.system() == 'windows')
1403   _llvm_method = 'cmake'
1404 endif
1405
1406 dep_llvm = null_dep
1407 with_llvm = false
1408 if _llvm != 'false'
1409   dep_llvm = dependency(
1410     'llvm',
1411     version : _llvm_version,
1412     modules : llvm_modules,
1413     optional_modules : llvm_optional_modules,
1414     required : (
1415       with_amd_vk or with_gallium_radeonsi or with_gallium_swr or
1416       with_gallium_opencl or _llvm == 'true'
1417     ),
1418     static : not _shared_llvm,
1419     method : _llvm_method,
1420     fallback : ['llvm', 'dep_llvm'],
1421   )
1422   with_llvm = dep_llvm.found()
1423 endif
1424 if with_llvm
1425   pre_args += '-DLLVM_AVAILABLE'
1426   pre_args += '-DMESA_LLVM_VERSION_STRING="@0@"'.format(dep_llvm.version())
1427
1428   # LLVM can be built without rtti, turning off rtti changes the ABI of C++
1429   # programs, so we need to build all C++ code in mesa without rtti as well to
1430   # ensure that linking works.
1431   #
1432   # In meson 0.51.0 we can use cmake to find LLVM in addittion to meson's
1433   # builtin llvm-config based finder. A new generic variable getter method
1434   # has also been added, so we'll use that if we can, to cover the cmake case.
1435   if dep_llvm.type_name() == 'internal'
1436     _rtti = subproject('llvm').get_variable('has_rtti', true)
1437   elif meson.version().version_compare('>=0.51')
1438     # The CMake finder will return 'ON', the llvm-config will return 'YES'
1439     _rtti = ['ON', 'YES'].contains(dep_llvm.get_variable(cmake : 'LLVM_ENABLE_RTTI', configtool: 'has-rtti'))
1440   else
1441     _rtti = dep_llvm.get_configtool_variable('has-rtti') == 'YES'
1442   endif
1443   if not _rtti
1444     if with_gallium_nouveau
1445       error('The Nouveau driver requires rtti. You either need to turn off nouveau or use an LLVM built with LLVM_ENABLE_RTTI.')
1446     elif with_gallium_opencl
1447       error('The Clover OpenCL state tracker requires rtti, you need to turn off clover or use an LLVM built with LLVM_ENABLE_RTTI.')
1448     endif
1449     if cc.get_id() == 'msvc'
1450       cpp_args += '/GR-'
1451     else
1452       cpp_args += '-fno-rtti'
1453     endif
1454   endif
1455 elif with_amd_vk or with_gallium_radeonsi or with_gallium_swr
1456   error('The following drivers require LLVM: Radv, RadeonSI, SWR. One of these is enabled, but LLVM is disabled.')
1457 elif with_gallium_opencl
1458   error('The OpenCL "Clover" state tracker requires LLVM, but LLVM is disabled.')
1459 endif
1460
1461 if (with_amd_vk or with_gallium_radeonsi or with_gallium_opencl or
1462     (with_gallium_r600 and with_llvm))
1463   dep_elf = dependency('libelf', required : false)
1464   if not dep_elf.found()
1465     dep_elf = cc.find_library('elf')
1466   endif
1467 else
1468   dep_elf = null_dep
1469 endif
1470
1471 dep_glvnd = null_dep
1472 if with_glvnd
1473   dep_glvnd = dependency('libglvnd', version : '>= 1.2.0')
1474   pre_args += '-DUSE_LIBGLVND=1'
1475 endif
1476
1477 if with_valgrind != 'false'
1478   dep_valgrind = dependency('valgrind', required : with_valgrind == 'true')
1479   if dep_valgrind.found()
1480     pre_args += '-DHAVE_VALGRIND'
1481   endif
1482 else
1483   dep_valgrind = null_dep
1484 endif
1485
1486 # pthread stubs. Lets not and say we didn't
1487
1488 if host_machine.system() == 'windows'
1489   # Prefer the winflexbison versions, they're much easier to install and have
1490   # better windows support.
1491
1492   prog_flex = find_program('win_flex', required : false)
1493   if prog_flex.found()
1494     # windows compatibility (uses <io.h> instead of <unistd.h> and _isatty,
1495     # _fileno functions)
1496     prog_flex = [prog_flex, '--wincompat']
1497   else
1498     prog_flex = [find_program('lex', 'flex', required : with_any_opengl)]
1499   endif
1500   # Force flex to use const keyword in prototypes, as relies on __cplusplus or
1501   # __STDC__ macro to determine whether it's safe to use const keyword, but
1502   # MSVC never defines __STDC__ unless we disable all MSVC extensions.
1503   prog_flex += '-DYY_USE_CONST='
1504
1505   prog_bison = find_program('win_bison', required : false)
1506   if not prog_bison.found()
1507     prog_bison = find_program('yacc', 'bison', required : with_any_opengl)
1508   endif
1509 else
1510   prog_bison = find_program('bison', required : with_any_opengl)
1511
1512   # Disable deprecated keyword warnings, since we have to use them for
1513   # old-bison compat.  See discussion in
1514   # https://gitlab.freedesktop.org/mesa/mesa/merge_requests/2161
1515   prog_bison = [prog_bison, '-Wno-deprecated']
1516
1517   prog_flex = find_program('flex', required : with_any_opengl)
1518 endif
1519
1520 dep_selinux = null_dep
1521 if get_option('selinux')
1522   dep_selinux = dependency('libselinux')
1523   pre_args += '-DMESA_SELINUX'
1524 endif
1525
1526 if with_libunwind != 'false'
1527   dep_unwind = dependency('libunwind', required : with_libunwind == 'true')
1528   if dep_unwind.found()
1529     pre_args += '-DHAVE_LIBUNWIND'
1530   endif
1531 else
1532   dep_unwind = null_dep
1533 endif
1534
1535 if with_osmesa != 'none'
1536   if with_osmesa == 'gallium' and not with_gallium_softpipe
1537     error('OSMesa gallium requires gallium softpipe or llvmpipe.')
1538   endif
1539   if host_machine.system() == 'windows'
1540     osmesa_lib_name = 'osmesa'
1541   else
1542     osmesa_lib_name = 'OSMesa'
1543   endif
1544   osmesa_bits = get_option('osmesa-bits')
1545   if osmesa_bits != '8'
1546     if with_dri or with_glx != 'disabled'
1547       error('OSMesa bits must be 8 if building glx or dir based drivers')
1548     endif
1549     osmesa_lib_name = osmesa_lib_name + osmesa_bits
1550     pre_args += [
1551       '-DCHAN_BITS=@0@'.format(osmesa_bits), '-DDEFAULT_SOFTWARE_DEPTH_BITS=31'
1552     ]
1553   endif
1554 endif
1555
1556 # TODO: symbol mangling
1557
1558 if with_platform_wayland
1559   dep_wl_scanner = dependency('wayland-scanner', native: true)
1560   prog_wl_scanner = find_program(dep_wl_scanner.get_pkgconfig_variable('wayland_scanner'))
1561   if dep_wl_scanner.version().version_compare('>= 1.15')
1562     wl_scanner_arg = 'private-code'
1563   else
1564     wl_scanner_arg = 'code'
1565   endif
1566   dep_wl_protocols = dependency('wayland-protocols', version : '>= 1.8')
1567   dep_wayland_client = dependency('wayland-client', version : '>=1.11')
1568   dep_wayland_server = dependency('wayland-server', version : '>=1.11')
1569   if with_egl
1570     dep_wayland_egl = dependency('wayland-egl-backend', version : '>= 3')
1571     dep_wayland_egl_headers = declare_dependency(
1572       compile_args : run_command(prog_pkgconfig, ['wayland-egl-backend', '--cflags']).stdout().split())
1573   endif
1574   wayland_dmabuf_xml = join_paths(
1575     dep_wl_protocols.get_pkgconfig_variable('pkgdatadir'), 'unstable',
1576     'linux-dmabuf', 'linux-dmabuf-unstable-v1.xml'
1577   )
1578   pre_args += ['-DHAVE_WAYLAND_PLATFORM', '-DWL_HIDE_DEPRECATED']
1579 endif
1580
1581 dep_x11 = null_dep
1582 dep_xext = null_dep
1583 dep_xdamage = null_dep
1584 dep_xfixes = null_dep
1585 dep_x11_xcb = null_dep
1586 dep_xcb = null_dep
1587 dep_xcb_glx = null_dep
1588 dep_xcb_dri2 = null_dep
1589 dep_xcb_dri3 = null_dep
1590 dep_dri2proto = null_dep
1591 dep_glproto = null_dep
1592 dep_xxf86vm = null_dep
1593 dep_xcb_dri3 = null_dep
1594 dep_xcb_present = null_dep
1595 dep_xcb_sync = null_dep
1596 dep_xcb_xfixes = null_dep
1597 dep_xshmfence = null_dep
1598 dep_xcb_xrandr = null_dep
1599 dep_xlib_xrandr = null_dep
1600 if with_platform_x11
1601   if with_glx == 'xlib' or with_glx == 'gallium-xlib'
1602     dep_x11 = dependency('x11')
1603     dep_xext = dependency('xext')
1604     dep_xcb = dependency('xcb')
1605   elif with_glx == 'dri'
1606     dep_x11 = dependency('x11')
1607     dep_xext = dependency('xext')
1608     dep_xdamage = dependency('xdamage', version : '>= 1.1')
1609     dep_xfixes = dependency('xfixes')
1610     dep_xcb_glx = dependency('xcb-glx', version : '>= 1.8.1')
1611   endif
1612   if (with_any_vk or with_glx == 'dri' or with_egl or
1613        (with_gallium_vdpau or with_gallium_xvmc or with_gallium_va or
1614         with_gallium_omx != 'disabled'))
1615     dep_xcb = dependency('xcb')
1616     dep_x11_xcb = dependency('x11-xcb')
1617     if with_dri_platform == 'drm' and not dep_libdrm.found()
1618       error('libdrm required for gallium video statetrackers when using x11')
1619     endif
1620   endif
1621   if with_any_vk or with_egl or (with_glx == 'dri' and with_dri_platform == 'drm')
1622     dep_xcb_dri2 = dependency('xcb-dri2', version : '>= 1.8')
1623
1624     if with_dri3
1625       pre_args += '-DHAVE_DRI3'
1626       dep_xcb_dri3 = dependency('xcb-dri3')
1627       dep_xcb_present = dependency('xcb-present')
1628       # until xcb-dri3 has been around long enough to make a hard-dependency:
1629       if (dep_xcb_dri3.version().version_compare('>= 1.13') and
1630           dep_xcb_present.version().version_compare('>= 1.13'))
1631         pre_args += '-DHAVE_DRI3_MODIFIERS'
1632       endif
1633       dep_xcb_sync = dependency('xcb-sync')
1634       dep_xshmfence = dependency('xshmfence', version : '>= 1.1')
1635     endif
1636   endif
1637   if with_glx == 'dri' or with_glx == 'gallium-xlib'
1638     dep_glproto = dependency('glproto', version : '>= 1.4.14')
1639   endif
1640   if with_glx == 'dri'
1641     if with_dri_platform == 'drm'
1642       dep_dri2proto = dependency('dri2proto', version : '>= 2.8')
1643       dep_xxf86vm = dependency('xxf86vm')
1644     endif
1645   endif
1646   if (with_egl or (
1647       with_gallium_vdpau or with_gallium_xvmc or with_gallium_xa or
1648       with_gallium_omx != 'disabled'))
1649     dep_xcb_xfixes = dependency('xcb-xfixes')
1650   endif
1651   if with_xlib_lease
1652     dep_xcb_xrandr = dependency('xcb-randr')
1653     dep_xlib_xrandr = dependency('xrandr', version : '>= 1.3')
1654   endif
1655 endif
1656
1657 if get_option('gallium-extra-hud')
1658   pre_args += '-DHAVE_GALLIUM_EXTRA_HUD=1'
1659 endif
1660
1661 _sensors = get_option('lmsensors')
1662 if _sensors != 'false'
1663   dep_lmsensors = cc.find_library('sensors', required : _sensors == 'true')
1664   if dep_lmsensors.found()
1665     pre_args += '-DHAVE_LIBSENSORS=1'
1666   endif
1667 else
1668   dep_lmsensors = null_dep
1669 endif
1670
1671 foreach a : pre_args
1672   add_project_arguments(a, language : ['c', 'cpp'])
1673 endforeach
1674 foreach a : c_args
1675   add_project_arguments(a, language : ['c'])
1676 endforeach
1677 foreach a : cpp_args
1678   add_project_arguments(a, language : ['cpp'])
1679 endforeach
1680
1681 gl_priv_reqs = []
1682
1683 if with_glx == 'xlib' or with_glx == 'gallium-xlib'
1684   gl_priv_reqs += ['x11', 'xext', 'xcb']
1685 elif with_glx == 'dri'
1686   gl_priv_reqs += [
1687     'x11', 'xext', 'xdamage >= 1.1', 'xfixes', 'x11-xcb', 'xcb',
1688     'xcb-glx >= 1.8.1']
1689   if with_dri_platform == 'drm'
1690     gl_priv_reqs += 'xcb-dri2 >= 1.8'
1691     gl_priv_reqs += 'xxf86vm'
1692   endif
1693 endif
1694 if dep_libdrm.found()
1695   gl_priv_reqs += 'libdrm >= 2.4.75'
1696 endif
1697
1698 gl_priv_libs = []
1699 if dep_thread.found()
1700   gl_priv_libs += ['-lpthread', '-pthread']
1701 endif
1702 if dep_m.found()
1703   gl_priv_libs += '-lm'
1704 endif
1705 if dep_dl.found()
1706   gl_priv_libs += '-ldl'
1707 endif
1708
1709 pkg = import('pkgconfig')
1710
1711 if host_machine.system() == 'windows'
1712   prog_dumpbin = find_program('dumpbin', required : false)
1713   with_symbols_check = prog_dumpbin.found() and with_tests
1714   symbols_check_args = ['--dumpbin', prog_dumpbin.path()]
1715 else
1716   prog_nm = find_program('nm')
1717   with_symbols_check = with_tests
1718   symbols_check_args = ['--nm', prog_nm.path()]
1719 endif
1720
1721 # This quirk needs to be applied to sources with functions defined in assembly
1722 # as GCC LTO drops them. See: https://bugs.freedesktop.org/show_bug.cgi?id=109391
1723 gcc_lto_quirk = (cc.get_id() == 'gcc') ? ['-fno-lto'] : []
1724
1725 subdir('include')
1726 subdir('bin')
1727 subdir('src')
1728
1729 # Meson 0.49 and earlier seems to have a bug that fails to evaluate the string-
1730 # formatting below unless the first argument is passed as a variable. This has
1731 # been fixed in Meson 0.50 and beyond, but we need to keep it like this for now
1732 # for backwards compatibility.
1733 _with_opengl_string = with_opengl ? 'yes' : 'no'
1734
1735 lines = ['',
1736   'prefix:          ' + get_option('prefix'),
1737   'libdir:          ' + get_option('libdir'),
1738   'includedir:      ' + get_option('includedir'),
1739   '',
1740   'OpenGL:          @0@ (ES1: @1@ ES2: @2@)'.format(_with_opengl_string,
1741                                                     with_gles1 ? 'yes' : 'no',
1742                                                     with_gles2 ? 'yes' : 'no'),
1743 ]
1744
1745 if with_osmesa != 'none'
1746   lines += ''
1747   suffix = ''
1748   if with_osmesa == 'gallium'
1749     suffix = '(Gallium)'
1750   endif
1751   lines += 'OSMesa:          lib' + osmesa_lib_name + suffix
1752 else
1753   lines += 'OSMesa:          no'
1754 endif
1755
1756 if with_dri
1757   lines += ''
1758   lines += 'DRI platform:    ' + with_dri_platform
1759   if dri_drivers.length() != 0 and dri_drivers != ['']
1760     lines += 'DRI drivers:     ' + ' '.join(dri_drivers)
1761   else
1762     lines += 'DRI drivers:     no'
1763   endif
1764   lines += 'DRI driver dir:  ' + dri_drivers_path
1765 endif
1766
1767 if with_glx != 'disabled'
1768   lines += ''
1769   if with_glx == 'dri'
1770     lines += 'GLX:             DRI-based'
1771   elif with_glx == 'xlib'
1772     lines += 'GLX:             Xlib-based'
1773   elif with_glx == 'gallium-xlib'
1774     lines += 'GLX:             Xlib-based (Gallium)'
1775   else
1776     lines += 'GLX:             ' + with_glx
1777   endif
1778 endif
1779
1780 lines += ''
1781 lines += 'EGL:             ' + (with_egl ? 'yes' : 'no')
1782 if with_egl
1783   egl_drivers = []
1784   if with_dri
1785     egl_drivers += 'builtin:egl_dri2'
1786   endif
1787   if with_dri3
1788     egl_drivers += 'builtin:egl_dri3'
1789   endif
1790   lines += 'EGL drivers:     ' + ' '.join(egl_drivers)
1791 endif
1792 lines += 'GBM:             ' + (with_gbm ? 'yes' : 'no')
1793 if with_platforms
1794   lines += 'EGL/Vulkan/VL platforms:   ' + ' '.join(_platforms)
1795 endif
1796
1797 lines += ''
1798 if with_any_vk
1799   lines += 'Vulkan drivers:  ' + ' '.join(_vulkan_drivers)
1800   lines += 'Vulkan ICD dir:  ' + with_vulkan_icd_dir
1801 else
1802   lines += 'Vulkan drivers:  no'
1803 endif
1804
1805 lines += ''
1806 if with_llvm
1807   lines += 'llvm:            yes'
1808   lines += 'llvm-version:    ' + dep_llvm.version()
1809 else
1810   lines += 'llvm:            no'
1811 endif
1812
1813 lines += ''
1814 if with_gallium
1815   lines += 'Gallium drivers: ' + ' '.join(gallium_drivers)
1816   gallium_st = ['mesa']
1817   if with_gallium_xa
1818     gallium_st += 'xa'
1819   endif
1820   if with_gallium_xvmc
1821     gallium_st += 'xvmc'
1822   endif
1823   if with_gallium_xvmc
1824     gallium_st += 'xvmc'
1825   endif
1826   if with_gallium_vdpau
1827     gallium_st += 'vdpau'
1828   endif
1829   if with_gallium_omx != 'disabled'
1830     gallium_st += 'omx' + with_gallium_omx
1831   endif
1832   if with_gallium_va
1833     gallium_st += 'va'
1834   endif
1835   if with_gallium_st_nine
1836     gallium_st += 'nine'
1837   endif
1838   if with_gallium_opencl
1839     gallium_st += 'clover'
1840   endif
1841   lines += 'Gallium st:      ' + ' '.join(gallium_st)
1842 else
1843   lines += 'Gallium:         no'
1844 endif
1845
1846 lines += 'HUD lmsensors:   ' + (dep_lmsensors.found() ? 'yes' : 'no')
1847
1848 lines += ''
1849 lines += 'Shared-glapi:    ' + (with_shared_glapi ? 'yes' : 'no')
1850
1851
1852 indent = '        '
1853 summary = indent + ('\n' + indent).join(lines)
1854 message('Configuration summary:\n@0@\n'.format(summary))