meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 33
  23
  24 apiversion = '1.0'
  25 soversion = 0
  26 # FIXME: this doesn't actually do what we want it to
  27 # maintaining compatibility with the previous libtool versioning
  28 # current = minor * 100 + micro
  29 libversion = '@0@.@1@.0'.format(soversion, pa_version_minor.to_int() * 100 + pa_version_micro.to_int())
  30
  31 # A simplified, synchronous, ABI-stable interface for client applications.
  32 # For the version x:y:z always will hold y=z.
  33 libpulse_simple_version = '1.1.1'
  34
  35 # The ABI-stable GLib adapter for client applications.
  36 # For the version x:y:z always will hold y=z.
  37 libpulse_mainloop_glib_version = '0.5.0'
  38
  39 # Paths
  40
  41 prefix = get_option('prefix')
  42 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  43
  44 bindir = join_paths(prefix, get_option('bindir'))
  45 libdir = join_paths(prefix, get_option('libdir'))
  46 libexecdir = join_paths(prefix, get_option('libexecdir'))
  47 mandir = join_paths(prefix, get_option('mandir'))
  48 datadir = join_paths(prefix, get_option('datadir'))
  49 localstatedir = join_paths(prefix, get_option('localstatedir'))
  50 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  51 privlibdir = join_paths(get_option('libdir'), 'pulseaudio')
  52 alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  53
  54 pulselibexecdir = join_paths(libexecdir, 'pulse')
  55 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  56
  57 modlibexecdir = get_option('modlibexecdir')
  58 if modlibexecdir == ''
  59   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  60 endif
  61
  62 pulsedspdir = get_option('pulsedspdir')
  63 if pulsedspdir == ''
  64   join_paths(libdir, 'pulseaudio')
  65 endif
  66
  67 bashcompletiondir = get_option('bashcompletiondir')
  68 if bashcompletiondir == ''
  69   bash_completion_dep = dependency('bash-completion', required : false)
  70   if bash_completion_dep.found()
  71     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
  72   else
  73     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
  74   endif
  75 endif
  76
  77 zshcompletiondir = get_option('zshcompletiondir')
  78 if zshcompletiondir == ''
  79   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
  80 endif
  81
  82 # Configuration data
  83
  84 cc = meson.get_compiler('c')
  85
  86 cdata = configuration_data()
  87 cdata.set_quoted('PACKAGE', 'pulseaudio')
  88 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
  89 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
  90 cdata.set_quoted('CANONICAL_HOST', host_machine.cpu())
  91 cdata.set('PA_MAJOR', pa_version_major)
  92 cdata.set('PA_MINOR', pa_version_minor)
  93 cdata.set('PA_API_VERSION', pa_api_version)
  94 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
  95 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
  96 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
  97 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
  98 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
  99 cdata.set_quoted('PA_SOEXT', '.so')
 100 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 101 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 102 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 103 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 104 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 105 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 106 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 107 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 108 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 109 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 110 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 111 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 112 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 113
 114 # Platform specifics
 115 # First some defaults to keep config file generation happy
 116 cdata.set('HAVE_COREAUDIO', 0)
 117 cdata.set('HAVE_WAVEOUT', 0)
 118 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 119 # rather than ending up in the config.h file?
 120 if host_machine.system() == 'darwin'
 121   cdata.set('OS_IS_DARWIN', 1)
 122   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 123 elif host_machine.system() == 'windows'
 124   cdata.set('OS_IS_WIN32', 1)
 125   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 126 #elif host_machine.system() == 'solaris'
 127 #  # Apparently meson has no solaris support?
 128 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 129 #  cdata.set('_XOPEN_SOURCE', 600)
 130 #  cdata.set('__EXTENSIONS__', 1)
 131 endif
 132
 133 # Headers
 134
 135 check_headers = [
 136   'arpa/inet.h',
 137   'cpuid.h',
 138   'execinfo.h',
 139   'grp.h',
 140   'langinfo.h',
 141   'locale.h',
 142   'netdb.h',
 143   'netinet/in.h',
 144   'netinet/in_systm.h',
 145   'netinet/ip.h',
 146   'netinet/tcp.h',
 147   'pcreposix.h',
 148   'poll.h',
 149   'pwd.h',
 150   'regex.h',
 151   'sched.h',
 152   'sys/capability.h',
 153   'sys/eventfd.h',
 154   'sys/ioctl.h',
 155   'sys/mman.h',
 156   'sys/prctl.h',
 157   'sys/resource.h',
 158   'sys/select.h',
 159   'sys/socket.h',
 160   'sys/un.h',
 161   'sys/wait.h',
 162   'valgrind/memcheck.h',
 163   'xlocale.h',
 164 ]
 165
 166 foreach h : check_headers
 167   if cc.has_header(h)
 168     define = 'HAVE_' + h.underscorify().to_upper()
 169     cdata.set(define, 1)
 170   endif
 171 endforeach
 172
 173 # FIXME: move this to the above set
 174 if cc.has_header('pthread.h')
 175   cdata.set('HAVE_PTHREAD', 1)
 176 endif
 177
 178 # Functions
 179
 180 check_functions = [
 181   'accept4',
 182   'clock_gettime',
 183   'fchmod',
 184   'fchown',
 185   'fork',
 186   'fstat',
 187   'getaddrinfo',
 188   'getgrgid_r',
 189   'getpwnam_r',
 190   'gettimeofday',
 191   'getuid',
 192   'lstat',
 193   'memfd_create',
 194   'mkfifo',
 195   'mlock',
 196   'nanosleep',
 197   'paccept',
 198   'pipe',
 199   'pipe2',
 200   'posix_madvise',
 201   'readlink',
 202   'setegid',
 203   'seteuid',
 204   'setregid',
 205   'setreuid',
 206   'setresgid',
 207   'setresuid',
 208   'setsid',
 209   'sig2str',
 210   'sigaction',
 211   'strtod_l',
 212   'symlink',
 213   'sysconf',
 214   'uname',
 215 ]
 216
 217 foreach f : check_functions
 218   if cc.has_function(f)
 219     define = 'HAVE_' + f.underscorify().to_upper()
 220     cdata.set(define, 1)
 221   endif
 222 endforeach
 223
 224 if cc.has_function('SYS_memfd_create', prefix : '#include <sys/syscall.h>')
 225   cdata.set('HAVE_MEMFD', 1)
 226 endif
 227
 228 # Symbols
 229
 230 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 231   cdata.set('HAVE_SIGXCPU', 1)
 232 endif
 233
 234 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 235   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 236     # Define INADDR_NONE if not found (Solaris)
 237     cdata.set('INADDR_NONE', '0xffffffff')
 238   endif
 239 endif
 240
 241 # Types
 242
 243 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 244 cdata.set('GETGROUPS_T', 'gid_t')
 245
 246 # Include paths
 247
 248 configinc = include_directories('.')
 249 topinc = include_directories('src')
 250
 251 # CFLAGS
 252
 253 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 254 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 255 cdata.set('MESON_BUILD', 1)
 256
 257 # Core Dependencies
 258
 259 libm_dep = cc.find_library('m', required : true)
 260 thread_dep = dependency('threads')
 261 cap_dep = cc.find_library('cap', required : false)
 262
 263 shm_dep = cc.find_library('rt', required : false)
 264 if shm_dep.found()
 265   cdata.set('HAVE_SHM_OPEN', 1)
 266 endif
 267
 268 atomictest = '''void func() {
 269   volatile int atomic = 2;
 270   __sync_bool_compare_and_swap (&atomic, 2, 3);
 271 }
 272 '''
 273 if cc.compiles(atomictest)
 274   cdata.set('HAVE_ATOMIC_BUILTINS', true)
 275 else
 276   # FIXME: check if we need libatomic_ops
 277 endif
 278
 279 # FIXME: make sure it's >= 2.2
 280 ltdl_dep = cc.find_library('ltdl', required : true)
 281 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 282 #        and do we still want to support this at all?
 283 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 284
 285 if get_option('database') == 'tdb'
 286   database_dep = dependency('tdb')
 287 elif get_option('database') == 'gdbm'
 288   database_dep = cc.find_library('gdbm', required : true)
 289 else
 290   database_dep = dependency('', required: false)
 291 endif
 292
 293 if get_option('ipv6')
 294   cdata.set('HAVE_IPV6', 1)
 295 endif
 296
 297 if get_option('legacy-database-entry-format')
 298   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 299 endif
 300
 301 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 302 if alsa_dep.found()
 303   cdata.set('HAVE_ALSA', 1)
 304   cdata.set('HAVE_ALSA_UCM', 1)
 305 endif
 306
 307 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 308 if asyncns_dep.found()
 309   cdata.set('HAVE_LIBASYNCNS', 1)
 310 endif
 311
 312 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 313 if dbus_dep.found()
 314   cdata.set('HAVE_DBUS', 1)
 315 endif
 316
 317 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 318 if gio_dep.found()
 319   cdata.set('HAVE_GSETTINGS', 1)
 320 endif
 321
 322 glib_dep = dependency('glib-2.0', version : '>= 2.4.0', required: get_option('glib'))
 323 if glib_dep.found()
 324   cdata.set('HAVE_GLIB', 1)
 325 endif
 326
 327 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 328 if gtk_dep.found()
 329   cdata.set('HAVE_GTK', 1)
 330 endif
 331
 332 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 333 if samplerate_dep.found()
 334   cdata.set('HAVE_LIBSAMPLERATE', 1)
 335 endif
 336
 337 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 338
 339 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 340 if soxr_dep.found()
 341   cdata.set('HAVE_SOXR', 1)
 342 endif
 343
 344 systemd_dep = dependency('libsystemd', required : get_option('systemd'))
 345 if systemd_dep.found()
 346   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 347   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 348   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 349 endif
 350
 351 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 352 if x11_dep.found()
 353   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 354   ice_dep  = dependency('ice',  required : true)
 355   sm_dep   = dependency('sm',   required : true)
 356   xtst_dep = dependency('xtst', required : true)
 357   cdata.set('HAVE_X11', 1)
 358 endif
 359
 360 # FIXME: support ORC
 361 cdata.set('DISABLE_ORC', 1)
 362
 363 # Module dependencies
 364
 365 if cc.has_header('sys/soundcard.h')
 366   cdata.set('HAVE_OSS_OUTPUT', 1)
 367   cdata.set('HAVE_OSS_WRAPPER', 1)
 368   cdata.set_quoted('PULSEDSP_LOCATION', pulsedspdir)
 369 endif
 370
 371 if get_option('hal-compat')
 372   cdata.set('HAVE_HAL_COMPAT', 1)
 373 endif
 374
 375 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 376 if avahi_dep.found()
 377   cdata.set('HAVE_AVAHI', 1)
 378 endif
 379
 380 bluez_dep = dependency('bluez', version : '>= 5.0', required : get_option('bluez5'))
 381 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 382 if bluez_dep.found()
 383   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 384   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 385   cdata.set('HAVE_SBC', 1)
 386   cdata.set('HAVE_BLUEZ', 1)
 387   cdata.set('HAVE_BLUEZ_5', 1)
 388   if get_option('bluez5-native-headset')
 389     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 390   endif
 391   if get_option('bluez5-ofono-headset')
 392     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 393   endif
 394 endif
 395
 396 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 397 if fftw_dep.found()
 398   cdata.set('HAVE_FFTW', 1)
 399 endif
 400
 401 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 402 if jack_dep.found()
 403   cdata.set('HAVE_JACK', 1)
 404 endif
 405
 406 lirc_dep = dependency('lirc', required : get_option('lirc'))
 407 if lirc_dep.found()
 408   cdata.set('HAVE_LIRC', 1)
 409 endif
 410
 411 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 412 if openssl_dep.found()
 413   cdata.set('HAVE_OPENSSL', 1)
 414 endif
 415
 416 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 417 if speex_dep.found()
 418   cdata.set('HAVE_SPEEX', 1)
 419 endif
 420
 421 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 422 if udev_dep.found()
 423   cdata.set('HAVE_UDEV', 1)
 424 endif
 425
 426 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 427 if webrtc_dep.found()
 428   cdata.set('HAVE_WEBRTC', 1)
 429 endif
 430
 431 # Test dependencies
 432
 433 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 434
 435 # Now generate config.h from everything above
 436 configure_file(output : 'config.h', configuration : cdata)
 437
 438 if get_option('man')
 439   subdir('man')
 440 endif
 441 subdir('shell-completion/bash')
 442 subdir('shell-completion/zsh')
 443 subdir('src')
 444
 445 ############################################################
 446
 447 # Final summary
 448
 449 summary = [
 450   '',
 451   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 452   '',
 453   'prefix:                        @0@'.format(prefix),
 454   'bindir:                        @0@'.format(bindir),
 455   'libdir:                        @0@'.format(libdir),
 456   'libexecdir:                    @0@'.format(libexecdir),
 457   'mandir:                        @0@'.format(mandir),
 458   'datadir:                       @0@'.format(datadir),
 459   'sysconfdir:                    @0@'.format(sysconfdir),
 460   'localstatedir:                 @0@'.format(localstatedir),
 461   'modlibexecdir:                 @0@'.format(modlibexecdir),
 462   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 463   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 464   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 465   'Bash completions directory:    @0@'.format(bashcompletiondir),
 466   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 467   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 468 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 469 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 470 #  'LIBS:                          @0@'.format(${LIBS}),
 471   '',
 472   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 473   'Enable X11:                    @0@'.format(x11_dep.found()),
 474 #  'Enable OSS Output:             @0@'.format(${ENABLE_OSS_OUTPUT}),
 475 #  'Enable OSS Wrapper:            @0@'.format(${ENABLE_OSS_WRAPPER}),
 476 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 477   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 478 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 479 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 480 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 481   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 482 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 483   'Enable GSettings:              @0@'.format(gio_dep.found()),
 484   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 485   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 486   'Enable Jack:                   @0@'.format(jack_dep.found()),
 487   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 488   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 489   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 490   '  Enable BlueZ 5:              @0@'.format(bluez_dep.found()),
 491   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 492   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 493   'Enable udev:                   @0@'.format(udev_dep.found()),
 494   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 495   'Enable systemd:                @0@'.format(systemd_dep.found()),
 496 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 497   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 498   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 499   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 500   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 501 #  'Enable orc:                    @0@'.format(${ENABLE_ORC}),
 502   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 503   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 504   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 505   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 506 #  'Enable gcov coverage:          @0@'.format(${ENABLE_GCOV}),
 507   'Enable man pages:              @0@'.format(get_option('man')),
 508   'Enable unit tests:             @0@'.format(get_option('tests')),
 509   '',
 510   'Database:                      @0@'.format(get_option('database')),
 511   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 512   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 513   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 514   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 515 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 516 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 517 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 518 ]
 519
 520 message('\n    '.join(summary))
 521
 522 # Sanity checks
 523
 524 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 525   error('At least one echo canceller implementation must be available!')
 526 endif
 527
 528 if samplerate_dep.found()
 529   warning('Support for libsamplerate is DEPRECATED')
 530 endif
 531
 532 if host_machine.system() != 'windows'
 533   if not dbus_dep.found()
 534     message = [
 535       'You do not have D-Bus support enabled. It is strongly recommended',
 536       'that you enable D-Bus support if your platform supports it.',
 537       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 538       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 539       'support and even a native control protocol for communicating and',
 540       'controlling the PulseAudio daemon itself.',
 541     ]
 542     warning('\n' + '\n'.join(message))
 543   endif
 544   if not udev_dep.found()
 545     message = [
 546       'You do not have udev support enabled. It is strongly recommended',
 547       'that you enable udev support if your platform supports it as it is',
 548       'the primary method used to detect hardware audio devices (on Linux)',
 549       'and is thus a critical part of PulseAudio on that platform.',
 550     ]
 551     warning('\n' + '\n'.join(message))
 552   endif
 553   if not speex_dep.found()
 554     message = [
 555       'You do not have speex support enabled. It is strongly recommended',
 556       'that you enable speex support if your platform supports it as it is',
 557       'the primary method used for audio resampling and is thus a critical',
 558       'part of PulseAudio on that platform.',
 559     ]
 560     warning('\n' + '\n'.join(message))
 561   endif
 562 endif