meson.build

   1 project('nntrainer', 'c', 'cpp',
   2   version: '0.3.0',
   3   license: ['apache-2.0'],
   4   meson_version: '>=0.50.0',
   5   default_options: [
   6     'werror=true',
   7     'warning_level=1',
   8     'c_std=gnu89',
   9     'cpp_std=c++17',
  10     'buildtype=release'
  11   ]
  12 )
  13 add_project_arguments('-DMIN_CPP_VERSION=201703L', language:['c','cpp'])
  14
  15 cc = meson.get_compiler('c')
  16 cxx = meson.get_compiler('cpp')
  17
  18 if get_option('platform') == 'tizen'
  19   # Pass __TIZEN__ to the compiler
  20   add_project_arguments('-D__TIZEN__=1', language:['c','cpp'])
  21
  22   if get_option('enable-tizen-feature-check')
  23     add_project_arguments('-D__FEATURE_CHECK_SUPPORT__', language: ['c', 'cpp'])
  24   endif
  25 endif
  26
  27 warning_flags = [
  28   '-Wredundant-decls',
  29   '-Wwrite-strings',
  30   '-Wformat',
  31   '-Wformat-nonliteral',
  32   '-Wformat-security',
  33   '-Winit-self',
  34   '-Waddress',
  35   '-Wno-multichar',
  36   '-Wvla',
  37   '-Wpointer-arith',
  38   '-Wno-error=varargs',
  39   '-Wdefaulted-function-deleted',
  40   '-ftree-vectorize'
  41 ]
  42
  43 warning_c_flags = [
  44   '-Wmissing-declarations',
  45   '-Wmissing-include-dirs',
  46   '-Wmissing-prototypes',
  47   '-Wnested-externs',
  48   '-Waggregate-return',
  49   '-Wold-style-definition',
  50   '-Wdeclaration-after-statement',
  51   '-Wno-error=varargs'
  52 ]
  53
  54 foreach extra_arg : warning_flags
  55   if cc.has_argument (extra_arg)
  56     add_project_arguments([extra_arg], language: 'c')
  57   endif
  58   if cxx.has_argument (extra_arg)
  59     add_project_arguments([extra_arg], language: 'cpp')
  60   endif
  61 endforeach
  62
  63 foreach extra_arg : warning_c_flags
  64   if cc.has_argument (extra_arg)
  65     add_project_arguments([extra_arg], language: 'c')
  66   endif
  67 endforeach
  68
  69 # Set install path
  70 nntrainer_prefix = get_option('prefix')
  71 nntrainer_libdir = nntrainer_prefix / get_option('libdir')
  72 nntrainer_bindir = nntrainer_prefix / get_option('bindir')
  73 nntrainer_includedir = nntrainer_prefix / get_option('includedir')
  74 nntrainer_confdir = get_option('sysconfdir')
  75 application_install_dir = nntrainer_bindir / 'applications'
  76
  77 # handle resources
  78 nntrainer_resdir = meson.build_root() / 'res'
  79 run_command('mkdir', '-p', nntrainer_resdir)
  80
  81 if get_option('install-app')
  82 # add a script to install resources from installs to application_install_dir
  83 meson.add_install_script(
  84   'sh', '-c', 'cp -r @0@ ${DESTDIR}@1@'.format(nntrainer_resdir, application_install_dir)
  85 )
  86 endif
  87
  88 # Set default configuration
  89 nntrainer_conf = configuration_data()
  90 nntrainer_conf.set('VERSION', meson.project_version())
  91 nntrainer_conf.set('PREFIX', nntrainer_prefix)
  92 nntrainer_conf.set('EXEC_PREFIX', nntrainer_bindir)
  93 nntrainer_conf.set('LIB_INSTALL_DIR', nntrainer_libdir)
  94 nntrainer_conf.set('PLUGIN_INSTALL_PREFIX', nntrainer_libdir / 'nntrainer')
  95 nntrainer_conf.set('INCLUDE_INSTALL_DIR', nntrainer_includedir)
  96 nntrainer_conf.set('CAPI_ML_COMMON_DEP', get_option('capi-ml-common-actual'))
  97
  98 dummy_dep = dependency('', required: false)
  99
 100 blas_dep = dummy_dep
 101 # Dependencies
 102 if get_option('enable-cublas')
 103    add_project_arguments('-DUSE_CUBLAS=1', language:['c','cpp'])
 104 endif
 105
 106 if get_option('enable-blas')
 107   add_project_arguments('-DUSE_BLAS=1', language:['c','cpp'])
 108   if get_option('platform') == 'tizen' or get_option('platform') == 'yocto'
 109     blas_dep = dependency('openblas')
 110   else
 111     blas_dep = dependency('blas-openblas', required:false)
 112     # for Ubuntu 20.04
 113     if not blas_dep.found()
 114       blas_dep = dependency('openblas')
 115     endif
 116   endif
 117 endif
 118
 119 if get_option('enable-profile')
 120   add_project_arguments('-DPROFILE=1', language:['c', 'cpp'])
 121 endif
 122
 123 if get_option('use_gym')
 124    add_project_arguments('-DUSE_GYM=1', language:['c','cpp'])
 125 endif
 126
 127 if get_option('enable-logging')
 128    add_project_arguments('-D__LOGGING__=1', language:['c','cpp'])
 129 endif
 130
 131 if get_option('enable-test')
 132   add_project_arguments('-DENABLE_TEST=1', language:['c','cpp'])
 133 endif
 134
 135 if get_option('reduce-tolerance')
 136   add_project_arguments('-DREDUCE_TOLERANCE=1', language:['c', 'cpp'])
 137 endif
 138
 139 libm_dep = cxx.find_library('m') # cmath library
 140 libdl_dep = cxx.find_library('dl') # DL library
 141 thread_dep = dependency('threads') # pthread for tensorflow-lite
 142
 143 iniparser_dep = dependency('iniparser', required : false, version : '>=4.1') # iniparser
 144 if not iniparser_dep.found()
 145   message('falling back to find libiniparser library and header files')
 146   libiniparser_dep = cxx.find_library('iniparser')
 147   sysroot = run_command(
 148     cxx.cmd_array() + ['-print-sysroot']
 149     ).stdout().split('\n')[0]
 150
 151   if sysroot.startswith('/')
 152     sysroot_inc_cflags_template = '-I@0@/usr/include@1@'
 153     sysroot_inc = sysroot_inc_cflags_template.format(sysroot, '')
 154     add_project_arguments(sysroot_inc, language: ['c', 'cpp'])
 155     sysroot_inc_cflags_iniparser = sysroot_inc_cflags_template.format(sysroot,
 156       '/iniparser')
 157   else
 158     sysroot_inc_cflags_iniparser = '-I/usr/include/iniparser'
 159   endif
 160
 161   if libiniparser_dep.found() and cxx.has_header('iniparser.h', \
 162         args : sysroot_inc_cflags_iniparser)
 163     iniparser_dep = declare_dependency (dependencies : libiniparser_dep,
 164       compile_args : sysroot_inc_cflags_iniparser)
 165   else
 166     error('Failed to resolve dependency on iniparser')
 167   endif
 168 endif
 169
 170 nnstreamer_capi_dep = dependency(get_option('capi-ml-inference-actual'), required:false)
 171 if nnstreamer_capi_dep.found()
 172   add_project_arguments('-DNNSTREAMER_AVAILABLE=1', language:['c','cpp'])
 173   # accessing this variable when dep_.not_found() remains hard error on purpose
 174   supported_nnstreamer_capi = nnstreamer_capi_dep.version().version_compare('>=1.7.0')
 175   if not supported_nnstreamer_capi
 176     add_project_arguments('-DUNSUPPORTED_NNSTREAMER=1', language:['c','cpp'])
 177     warning('capi-nnstreamer version is too old, we do not know if it works with older nnstreamer version')
 178   endif
 179 endif
 180
 181 ml_api_common_dep = dependency(get_option('capi-ml-common-actual'), required: true)
 182
 183 if get_option('enable-nnstreamer-backbone')
 184   add_project_arguments('-DENABLE_NNSTREAMER_BACKBONE=1', language:['c','cpp'])
 185 endif
 186
 187 tflite_dep = dependency('tensorflow2-lite', required: false)
 188 if get_option('enable-tflite-backbone')
 189   add_project_arguments('-DENABLE_TFLITE_BACKBONE=1', language:['c','cpp'])
 190 endif
 191
 192 gtest_dep = dependency('gtest', static: true, main: false, required: false)
 193 gtest_main_dep = dependency('gtest', static: true, main: true, required: false)
 194
 195 opencv_dep = dependency('opencv', required: false)
 196 if not opencv_dep.found()
 197   opencv_dep = dependency('opencv4', required: false)
 198   if not opencv_dep.found()
 199     opencv_dep = dependency('opencv3', required: false)
 200   endif
 201 endif
 202 if opencv_dep.found()
 203   add_project_arguments('-DENABLE_DATA_AUGMENTATION_OPENCV=1', language:['c','cpp'])
 204 endif
 205 flatc_prog = find_program('flatc', required: false)
 206
 207 # Install .pc
 208 configure_file(input: 'nntrainer.pc.in', output: 'nntrainer.pc',
 209   install_dir: nntrainer_libdir / 'pkgconfig',
 210   configuration: nntrainer_conf
 211 )
 212
 213 # Install conf
 214 configure_file(
 215   input: 'nntrainer.ini.in',
 216   output: 'nntrainer.ini',
 217   install_dir: nntrainer_confdir,
 218   configuration: nntrainer_conf
 219 )
 220 nntrainer_conf_abs_path = get_option('prefix') / nntrainer_confdir / 'nntrainer.ini'
 221 message('NNTRAINER_CONF_PATH=@0@'.format(nntrainer_conf_abs_path))
 222
 223 add_project_arguments(
 224   '-DNNTRAINER_CONF_PATH="@0@"'.format(nntrainer_conf_abs_path),
 225   language: ['c', 'cpp']
 226 )
 227
 228 # Build nntrainer
 229 subdir('nntrainer')
 230
 231 # Build api
 232 subdir('api')
 233
 234 if get_option('enable-test')
 235   if gtest_dep.found()
 236     subdir('test')
 237   else
 238     error('test enabled but gtest not found')
 239   endif
 240 endif
 241
 242 if get_option('enable-app')
 243   jsoncpp_dep = dependency('jsoncpp') # jsoncpp
 244   libcurl_dep = dependency('libcurl')
 245   if not tflite_dep.found()
 246     error('Tensorflow-Lite dependency not found')
 247   endif
 248   subdir('Applications')
 249 endif
 250
 251 if get_option('enable-nnstreamer-tensor-filter')
 252   nnstreamer_dep = dependency('nnstreamer', required: true)
 253   subdir('nnstreamer/tensor_filter')
 254 endif
 255
 256 if get_option('enable-android')
 257
 258   ndk_build = find_program('ndk-build', required : true)
 259   jni_root = meson.current_source_dir() / 'jni'
 260   jni_build_root = meson.current_build_dir() / 'jni'
 261
 262   ndk_args = {
 263     'NDK_PROJECT_PATH': jni_root,
 264     'APP_BUILD_SCRIPT': jni_root / 'Android.mk',
 265     'NDK_APPLICATION_MK': jni_root / 'Application.mk',
 266     'NDK_LIBS_OUT': jni_build_root / 'libs',
 267     'NDK_OUT': jni_build_root / 'objs',
 268     'ENABLE_PROFILE': get_option('enable-profile') ? 1 : 0,
 269     'ENABLE_BLAS': get_option('enable-blas') ? 1 : 0,
 270   }
 271
 272   num_threads = run_command('grep', '-c', '^processor', '/proc/cpuinfo').stdout().strip()
 273   message('num processor are: ' + num_threads)
 274
 275   thread_opt_flag = '-j' + num_threads
 276
 277   ndk_additional_flags = [thread_opt_flag]
 278
 279   ndk_build_command = [ndk_build]
 280   foreach key, val : ndk_args
 281     ndk_build_command += '@0@=@1@'.format(key, val)
 282   endforeach
 283   ndk_build_command += ndk_additional_flags
 284
 285   android_build_target = custom_target('android',
 286     output: 'jni',
 287     build_by_default: true,
 288     command: ndk_build_command
 289   )
 290
 291 endif