meson.build

   1 project('nntrainer', 'c', 'cpp',
   2   version: '0.0.1',
   3   license: ['apache-2.0'],
   4   meson_version: '>=0.50.0',
   5   default_options: [
   6     'werror=true',
   7     'warning_level=1',
   8     'c_std=gnu89',
   9     'cpp_std=c++14',
  10     'buildtype=release'
  11   ]
  12 )
  13 add_project_arguments('-DMIN_CPP_VERSION=201402', language:['c','cpp'])
  14
  15 cc = meson.get_compiler('c')
  16 cxx = meson.get_compiler('cpp')
  17 build_platform = ''
  18
  19 if get_option('enable-tizen')
  20   # Pass __TIZEN__ to the compiler
  21   build_platform = 'tizen'
  22   add_project_arguments('-D__TIZEN__=1', language:['c','cpp'])
  23
  24   if get_option('enable-tizen-feature-check')
  25     add_project_arguments('-D__FEATURE_CHECK_SUPPORT__', language: ['c', 'cpp'])
  26   endif
  27 endif
  28
  29 warning_flags = [
  30   '-Wredundant-decls',
  31   '-Wwrite-strings',
  32   '-Wformat',
  33   '-Wformat-nonliteral',
  34   '-Wformat-security',
  35   '-Winit-self',
  36   '-Waddress',
  37   '-Wno-multichar',
  38   '-Wvla',
  39   '-Wpointer-arith',
  40   '-Wno-error=varargs',
  41   '-Wdefaulted-function-deleted',
  42   '-ftree-vectorize'
  43 ]
  44
  45 warning_c_flags = [
  46   '-Wmissing-declarations',
  47   '-Wmissing-include-dirs',
  48   '-Wmissing-prototypes',
  49   '-Wnested-externs',
  50   '-Waggregate-return',
  51   '-Wold-style-definition',
  52   '-Wdeclaration-after-statement',
  53   '-Wno-error=varargs'
  54 ]
  55
  56 foreach extra_arg : warning_flags
  57   if cc.has_argument (extra_arg)
  58     add_project_arguments([extra_arg], language: 'c')
  59   endif
  60   if cxx.has_argument (extra_arg)
  61     add_project_arguments([extra_arg], language: 'cpp')
  62   endif
  63 endforeach
  64
  65 foreach extra_arg : warning_c_flags
  66   if cc.has_argument (extra_arg)
  67     add_project_arguments([extra_arg], language: 'c')
  68   endif
  69 endforeach
  70
  71 # Set install path
  72 nntrainer_prefix = get_option('prefix')
  73 nntrainer_libdir = nntrainer_prefix / get_option('libdir')
  74 nntrainer_bindir = nntrainer_prefix / get_option('bindir')
  75 nntrainer_includedir = nntrainer_prefix / get_option('includedir')
  76 nntrainer_confdir = get_option('sysconfdir')
  77 application_install_dir = nntrainer_bindir / 'applications'
  78
  79 # handle resources
  80 nntrainer_resdir = meson.build_root() / 'res'
  81 run_command('mkdir', '-p', nntrainer_resdir)
  82
  83 if get_option('install-app')
  84 # add a script to install resources from installs to application_install_dir
  85 meson.add_install_script(
  86   'sh', '-c', 'cp -r @0@ ${DESTDIR}@1@'.format(nntrainer_resdir, application_install_dir)
  87 )
  88 endif
  89
  90 # Set default configuration
  91 nntrainer_conf = configuration_data()
  92 nntrainer_conf.set('VERSION', meson.project_version())
  93 nntrainer_conf.set('PREFIX', nntrainer_prefix)
  94 nntrainer_conf.set('EXEC_PREFIX', nntrainer_bindir)
  95 nntrainer_conf.set('LIB_INSTALL_DIR', nntrainer_libdir)
  96 nntrainer_conf.set('PLUGIN_INSTALL_PREFIX', nntrainer_libdir / 'nntrainer')
  97 nntrainer_conf.set('INCLUDE_INSTALL_DIR', nntrainer_includedir)
  98
  99 dummy_dep = dependency('', required: false)
 100
 101 blas_dep = dummy_dep
 102 # Dependencies
 103 if get_option('enable-cublas')
 104    add_project_arguments('-DUSE_CUBLAS=1', language:['c','cpp'])
 105 endif
 106
 107 if get_option('enable-blas')
 108   add_project_arguments('-DUSE_BLAS=1', language:['c','cpp'])
 109   if build_platform == 'tizen'
 110     blas_dep = dependency('openblas')
 111   else
 112     blas_dep = dependency('blas-openblas', required:false)
 113     # for Ubuntu 20.04
 114     if not blas_dep.found()
 115       blas_dep = dependency('openblas')
 116     endif
 117   endif
 118 endif
 119
 120 if get_option('enable-profile')
 121   add_project_arguments('-DPROFILE=1', language:['c', 'cpp'])
 122 endif
 123
 124 if get_option('use_gym')
 125    add_project_arguments('-DUSE_GYM=1', language:['c','cpp'])
 126 endif
 127
 128 if get_option('enable-logging')
 129    add_project_arguments('-D__LOGGING__=1', language:['c','cpp'])
 130 endif
 131
 132 if get_option('enable-test')
 133   add_project_arguments('-DENABLE_TEST=1', language:['c','cpp'])
 134 endif
 135
 136 if get_option('reduce-tolerance')
 137   add_project_arguments('-DREDUCE_TOLERANCE=1', language:['c', 'cpp'])
 138 endif
 139
 140 libm_dep = cxx.find_library('m') # cmath library
 141 libdl_dep = cxx.find_library('dl') # DL library
 142 thread_dep = dependency('threads') # pthread for tensorflow-lite
 143 iniparser_dep = dependency('iniparser', required : false, version : '>=4.1') # iniparser
 144 if not iniparser_dep.found()
 145   message('falling back to find libiniparser library and header files')
 146   libiniparser_dep = cxx.find_library('iniparser')
 147   if libiniparser_dep.found() and cxx.has_header('iniparser.h', \
 148         args : '-I/usr/include/iniparser')
 149     iniparser_dep = declare_dependency (dependencies : libiniparser_dep,
 150       compile_args : '-I/usr/include/iniparser')
 151   endif
 152 endif
 153
 154 nnstreamer_capi_dep = dependency(get_option('capi-ml-inference-actual'), required:false)
 155 if nnstreamer_capi_dep.found()
 156   add_project_arguments('-DNNSTREAMER_AVAILABLE=1', language:['c','cpp'])
 157   # accessing this variable when dep_.not_found() remains hard error on purpose
 158   supported_nnstreamer_capi = nnstreamer_capi_dep.version().version_compare('>=1.7.0')
 159   if not supported_nnstreamer_capi
 160     add_project_arguments('-DUNSUPPORTED_NNSTREAMER=1', language:['c','cpp'])
 161     warning('capi-nnstreamer version is too old, we do not know if it works with older nnstreamer version')
 162   endif
 163 endif
 164
 165 ml_api_common_dep = dependency(get_option('capi-ml-common-actual'), required:true)
 166
 167 if get_option('enable-nnstreamer-backbone')
 168   add_project_arguments('-DENABLE_NNSTREAMER_BACKBONE=1', language:['c','cpp'])
 169 endif
 170
 171 tflite_dep = dependency('tensorflow2-lite', required: false)
 172 if get_option('enable-tflite-backbone')
 173   add_project_arguments('-DENABLE_TFLITE_BACKBONE=1', language:['c','cpp'])
 174 endif
 175
 176 gtest_dep = dependency('gtest', static: true, main: false, required: false)
 177 gtest_main_dep = dependency('gtest', static: true, main: true, required: false)
 178
 179 opencv_dep = dependency('opencv', required: false)
 180 if not opencv_dep.found()
 181   opencv_dep = dependency('opencv4', required: false)
 182   if not opencv_dep.found()
 183     opencv_dep = dependency('opencv3', required: false)
 184   endif
 185 endif
 186 if opencv_dep.found()
 187   add_project_arguments('-DENABLE_DATA_AUGMENTATION_OPENCV=1', language:['c','cpp'])
 188 endif
 189
 190 # Install .pc
 191 configure_file(input: 'nntrainer.pc.in', output: 'nntrainer.pc',
 192   install_dir: nntrainer_libdir / 'pkgconfig',
 193   configuration: nntrainer_conf
 194 )
 195
 196 # Install conf
 197 configure_file(
 198   input: 'nntrainer.ini.in',
 199   output: 'nntrainer.ini',
 200   install_dir: nntrainer_confdir,
 201   configuration: nntrainer_conf
 202 )
 203 nntrainer_conf_abs_path = get_option('prefix') / nntrainer_confdir / 'nntrainer.ini'
 204 message('NNTRAINER_CONF_PATH=@0@'.format(nntrainer_conf_abs_path))
 205
 206 add_project_arguments(
 207   '-DNNTRAINER_CONF_PATH="@0@"'.format(nntrainer_conf_abs_path),
 208   language: ['c', 'cpp']
 209 )
 210
 211 # Build nntrainer
 212 subdir('nntrainer')
 213
 214 # Build api
 215 subdir('api')
 216
 217 if get_option('enable-test')
 218   if gtest_dep.found()
 219     subdir('test')
 220   else
 221     error('test enabled but gtest not found')
 222   endif
 223 endif
 224
 225 if get_option('enable-app')
 226   jsoncpp_dep = dependency('jsoncpp') # jsoncpp
 227   libcurl_dep = dependency('libcurl')
 228   if not tflite_dep.found()
 229     error('Tensorflow-Lite dependency not found')
 230   endif
 231   subdir('Applications')
 232 endif
 233
 234 if get_option('enable-nnstreamer-tensor-filter')
 235   nnstreamer_dep = dependency('nnstreamer', required: true)
 236   subdir('nnstreamer/tensor_filter')
 237 endif
 238
 239 if get_option('enable-android')
 240
 241   ndk_build = find_program('ndk-build', required : true)
 242   jni_root = meson.current_source_dir() / 'jni'
 243   jni_build_root = meson.current_build_dir() / 'jni'
 244
 245   ndk_args = {
 246     'NDK_PROJECT_PATH': jni_root,
 247     'APP_BUILD_SCRIPT': jni_root / 'Android.mk',
 248     'NDK_APPLICATION_MK': jni_root / 'Application.mk',
 249     'NDK_LIBS_OUT': jni_build_root / 'libs',
 250     'NDK_OUT': jni_build_root / 'objs',
 251     'ENABLE_PROFILE': get_option('enable-profile') ? 1 : 0,
 252     'ENABLE_BLAS': get_option('enable-blas') ? 1 : 0,
 253   }
 254
 255   num_threads = run_command('grep', '-c', '^processor', '/proc/cpuinfo').stdout().strip()
 256   message('num processor are: ' + num_threads)
 257
 258   thread_opt_flag = '-j' + num_threads
 259
 260   ndk_additional_flags = [thread_opt_flag]
 261
 262   ndk_build_command = [ndk_build]
 263   foreach key, val : ndk_args
 264     ndk_build_command += '@0@=@1@'.format(key, val)
 265   endforeach
 266   ndk_build_command += ndk_additional_flags
 267
 268   android_build_target = custom_target('android',
 269     output: 'jni',
 270     build_by_default: true,
 271     command: ndk_build_command
 272   )
 273
 274 endif