meson.build

   1 project('nntrainer', 'c', 'cpp',
   2   version: '0.3.0',
   3   license: ['apache-2.0'],
   4   meson_version: '>=0.50.0',
   5   default_options: [
   6     'werror=true',
   7     'warning_level=1',
   8     'c_std=gnu89',
   9     'cpp_std=c++17',
  10     'buildtype=release'
  11   ]
  12 )
  13 add_project_arguments('-DMIN_CPP_VERSION=201703L', language:['c','cpp'])
  14
  15 cc = meson.get_compiler('c')
  16 cxx = meson.get_compiler('cpp')
  17
  18 if get_option('platform') == 'tizen'
  19   # Pass __TIZEN__ to the compiler
  20   add_project_arguments('-D__TIZEN__=1', language:['c','cpp'])
  21
  22   if get_option('enable-tizen-feature-check')
  23     add_project_arguments('-D__FEATURE_CHECK_SUPPORT__', language: ['c', 'cpp'])
  24   endif
  25 endif
  26
  27 warning_flags = [
  28   '-Wredundant-decls',
  29   '-Wwrite-strings',
  30   '-Wformat',
  31   '-Wformat-nonliteral',
  32   '-Wformat-security',
  33   '-Winit-self',
  34   '-Waddress',
  35   '-Wno-multichar',
  36   '-Wvla',
  37   '-Wpointer-arith',
  38   '-Wno-error=varargs',
  39   '-Wdefaulted-function-deleted',
  40   '-ftree-vectorize'
  41 ]
  42
  43 warning_c_flags = [
  44   '-Wmissing-declarations',
  45   '-Wmissing-include-dirs',
  46   '-Wmissing-prototypes',
  47   '-Wnested-externs',
  48   '-Waggregate-return',
  49   '-Wold-style-definition',
  50   '-Wdeclaration-after-statement',
  51   '-Wno-error=varargs'
  52 ]
  53
  54 foreach extra_arg : warning_flags
  55   if cc.has_argument (extra_arg)
  56     add_project_arguments([extra_arg], language: 'c')
  57   endif
  58   if cxx.has_argument (extra_arg)
  59     add_project_arguments([extra_arg], language: 'cpp')
  60   endif
  61 endforeach
  62
  63 foreach extra_arg : warning_c_flags
  64   if cc.has_argument (extra_arg)
  65     add_project_arguments([extra_arg], language: 'c')
  66   endif
  67 endforeach
  68
  69 # Set install path
  70 nntrainer_prefix = get_option('prefix')
  71 nntrainer_libdir = nntrainer_prefix / get_option('libdir')
  72 nntrainer_bindir = nntrainer_prefix / get_option('bindir')
  73 nntrainer_includedir = nntrainer_prefix / get_option('includedir')
  74 nntrainer_confdir = get_option('sysconfdir')
  75 application_install_dir = nntrainer_bindir / 'applications'
  76
  77 # handle resources
  78 nntrainer_resdir = meson.build_root() / 'res'
  79 run_command('mkdir', '-p', nntrainer_resdir)
  80
  81 if get_option('install-app')
  82 # add a script to install resources from installs to application_install_dir
  83 meson.add_install_script(
  84   'sh', '-c', 'cp -r @0@ ${DESTDIR}@1@'.format(nntrainer_resdir, application_install_dir)
  85 )
  86 endif
  87
  88 # Set default configuration
  89 nntrainer_conf = configuration_data()
  90 nntrainer_conf.set('VERSION', meson.project_version())
  91 nntrainer_conf.set('PREFIX', nntrainer_prefix)
  92 nntrainer_conf.set('EXEC_PREFIX', nntrainer_bindir)
  93 nntrainer_conf.set('LIB_INSTALL_DIR', nntrainer_libdir)
  94 nntrainer_conf.set('PLUGIN_INSTALL_PREFIX', nntrainer_libdir / 'nntrainer')
  95 nntrainer_conf.set('INCLUDE_INSTALL_DIR', nntrainer_includedir)
  96 nntrainer_conf.set('CAPI_ML_COMMON_DEP', get_option('capi-ml-common-actual'))
  97
  98 dummy_dep = dependency('', required: false)
  99 found_dummy_dep = declare_dependency() # dummy dep to use if found
 100
 101 blas_dep = dummy_dep
 102 # Dependencies
 103 if get_option('enable-cublas')
 104    add_project_arguments('-DUSE_CUBLAS=1', language:['c','cpp'])
 105 endif
 106
 107 if get_option('enable-blas')
 108   add_project_arguments('-DUSE_BLAS=1', language:['c','cpp'])
 109   if get_option('platform') == 'tizen' or get_option('platform') == 'yocto'
 110     blas_dep = dependency('openblas')
 111   elif get_option('platform') == 'android'
 112     message('preparing blas')
 113     run_command(meson.source_root() / 'jni' / 'prepare_openblas.sh', meson.build_root(), check: true)
 114     blas_dep = found_dummy_dep
 115   else
 116     blas_dep = dependency('blas-openblas', required:false)
 117     # for Ubuntu 20.04
 118     if not blas_dep.found()
 119       blas_dep = dependency('openblas')
 120     endif
 121   endif
 122 endif
 123
 124 openmp_dep = dummy_dep
 125 if get_option('enable-openmp')
 126   openmp_dep = dependency('openmp')
 127 endif
 128
 129 if get_option('enable-profile')
 130   add_project_arguments('-DPROFILE=1', language:['c', 'cpp'])
 131 endif
 132
 133 if get_option('enable-debug')
 134   add_project_arguments('-DDEBUG=1', language:['c', 'cpp'])
 135 endif
 136
 137 if get_option('use_gym')
 138    add_project_arguments('-DUSE_GYM=1', language:['c','cpp'])
 139 endif
 140
 141 if get_option('enable-logging')
 142    add_project_arguments('-D__LOGGING__=1', language:['c','cpp'])
 143 endif
 144
 145 if get_option('enable-test')
 146   add_project_arguments('-DENABLE_TEST=1', language:['c','cpp'])
 147 endif
 148
 149 if get_option('reduce-tolerance')
 150   add_project_arguments('-DREDUCE_TOLERANCE=1', language:['c', 'cpp'])
 151 endif
 152
 153 libm_dep = cxx.find_library('m') # cmath library
 154 libdl_dep = cxx.find_library('dl') # DL library
 155 thread_dep = dependency('threads') # pthread for tensorflow-lite
 156
 157 iniparser_dep = dependency('iniparser', required : false, version : '>=4.1') # iniparser
 158 if get_option('platform') == 'android'
 159   message('preparing iniparser')
 160   run_command(meson.source_root() / 'jni' / 'prepare_iniparser.sh', meson.build_root(), check: true)
 161   iniparser_dep = found_dummy_dep
 162 endif
 163
 164 if not iniparser_dep.found()
 165   message('falling back to find libiniparser library and header files')
 166   libiniparser_dep = cxx.find_library('iniparser')
 167   sysroot = run_command(
 168     cxx.cmd_array() + ['-print-sysroot']
 169     ).stdout().split('\n')[0]
 170
 171   if sysroot.startswith('/')
 172     sysroot_inc_cflags_template = '-I@0@/usr/include@1@'
 173     sysroot_inc = sysroot_inc_cflags_template.format(sysroot, '')
 174     add_project_arguments(sysroot_inc, language: ['c', 'cpp'])
 175     sysroot_inc_cflags_iniparser = sysroot_inc_cflags_template.format(sysroot,
 176       '/iniparser')
 177   else
 178     sysroot_inc_cflags_iniparser = '-I/usr/include/iniparser'
 179   endif
 180
 181   if libiniparser_dep.found() and cxx.has_header('iniparser.h', \
 182         args : sysroot_inc_cflags_iniparser)
 183     iniparser_dep = declare_dependency (dependencies : libiniparser_dep,
 184       compile_args : sysroot_inc_cflags_iniparser)
 185   else
 186     error('Failed to resolve dependency on iniparser')
 187   endif
 188 endif
 189
 190 nnstreamer_capi_dep = dependency(get_option('capi-ml-inference-actual'), required:false)
 191 if nnstreamer_capi_dep.found()
 192   add_project_arguments('-DNNSTREAMER_AVAILABLE=1', language:['c','cpp'])
 193   # accessing this variable when dep_.not_found() remains hard error on purpose
 194   supported_nnstreamer_capi = nnstreamer_capi_dep.version().version_compare('>=1.7.0')
 195   if not supported_nnstreamer_capi
 196     add_project_arguments('-DUNSUPPORTED_NNSTREAMER=1', language:['c','cpp'])
 197     warning('capi-nnstreamer version is too old, we do not know if it works with older nnstreamer version')
 198   endif
 199 endif
 200
 201 ml_api_common_dep = dummy_dep
 202
 203 if get_option('platform') != 'android'
 204   ml_api_common_dep = dependency(get_option('capi-ml-common-actual'), required: true)
 205 else
 206   message('preparing ml api')
 207   run_command(meson.source_root() / 'jni' / 'prepare_ml-api.sh', meson.build_root(), check: true)
 208   ml_api_common_dep = found_dummy_dep
 209 endif
 210
 211 if get_option('enable-nnstreamer-backbone')
 212   add_project_arguments('-DENABLE_NNSTREAMER_BACKBONE=1', language:['c','cpp'])
 213 endif
 214
 215 tflite_dep = dummy_dep
 216
 217 if get_option('platform') != 'android'
 218   tflite_dep = dependency('tensorflow2-lite', required: false)
 219 else
 220   message('preparing tflite')
 221   run_command(meson.source_root() / 'jni' / 'prepare_tflite.sh', '2.3.0', meson.build_root(), check: true)
 222   tflite_dep = found_dummy_dep
 223 endif
 224
 225 if get_option('enable-tflite-backbone')
 226   add_project_arguments('-DENABLE_TFLITE_BACKBONE=1', language:['c','cpp'])
 227 endif
 228
 229 gtest_dep = dependency('gtest', static: true, main: false, required: false)
 230 gtest_main_dep = dependency('gtest', static: true, main: true, required: false)
 231
 232 opencv_dep = dependency('opencv', required: false)
 233 if not opencv_dep.found()
 234   opencv_dep = dependency('opencv4', required: false)
 235   if not opencv_dep.found()
 236     opencv_dep = dependency('opencv3', required: false)
 237   endif
 238 endif
 239 if opencv_dep.found()
 240   add_project_arguments('-DENABLE_DATA_AUGMENTATION_OPENCV=1', language:['c','cpp'])
 241 endif
 242 flatc_prog = find_program('flatc', required: false)
 243
 244 # Install .pc
 245 configure_file(input: 'nntrainer.pc.in', output: 'nntrainer.pc',
 246   install_dir: nntrainer_libdir / 'pkgconfig',
 247   configuration: nntrainer_conf
 248 )
 249
 250 # Install conf
 251 configure_file(
 252   input: 'nntrainer.ini.in',
 253   output: 'nntrainer.ini',
 254   install_dir: nntrainer_confdir,
 255   configuration: nntrainer_conf
 256 )
 257 nntrainer_conf_abs_path = get_option('prefix') / nntrainer_confdir / 'nntrainer.ini'
 258 message('NNTRAINER_CONF_PATH=@0@'.format(nntrainer_conf_abs_path))
 259
 260 add_project_arguments(
 261   '-DNNTRAINER_CONF_PATH="@0@"'.format(nntrainer_conf_abs_path),
 262   language: ['c', 'cpp']
 263 )
 264
 265 # Build nntrainer
 266 subdir('nntrainer')
 267
 268 # Build api
 269 subdir('api')
 270
 271 if get_option('enable-test')
 272   if get_option('platform') == 'android'
 273     warning('test is not supported in android build, test skipped')
 274   else
 275     if gtest_dep.found()
 276       subdir('test')
 277     else
 278       error('test enabled but gtest not found')
 279     endif
 280   endif
 281 endif
 282
 283 if get_option('enable-app')
 284   if get_option('platform') == 'android'
 285     warning('android app is not supported for now, building app skipped')
 286   else
 287     jsoncpp_dep = dependency('jsoncpp') # jsoncpp
 288     libcurl_dep = dependency('libcurl')
 289     if not tflite_dep.found()
 290       error('Tensorflow-Lite dependency not found')
 291     endif
 292     subdir('Applications')
 293   endif
 294 endif
 295
 296 if get_option('enable-nnstreamer-tensor-filter')
 297   if get_option('platform') == 'android'
 298     warning('android nnstreamer-filter is not yet supported, building nnstreamer-filter skipped')
 299   else
 300     nnstreamer_dep = dependency('nnstreamer', required: true)
 301     subdir('nnstreamer/tensor_filter')
 302   endif
 303 endif
 304
 305 if get_option('enable-android')
 306
 307   ndk_build = find_program('ndk-build', required : true)
 308   jni_root = meson.current_source_dir() / 'jni'
 309   jni_build_root = meson.current_build_dir() / 'jni'
 310
 311   ndk_args = {
 312     'NDK_PROJECT_PATH': jni_root,
 313     'APP_BUILD_SCRIPT': jni_root / 'Android.mk',
 314     'NDK_APPLICATION_MK': jni_root / 'Application.mk',
 315     'NDK_LIBS_OUT': jni_build_root / 'libs',
 316     'NDK_OUT': jni_build_root / 'objs',
 317     'ENABLE_PROFILE': get_option('enable-profile') ? 1 : 0,
 318     'ENABLE_BLAS': get_option('enable-blas') ? 1 : 0,
 319   }
 320
 321   num_threads = run_command('grep', '-c', '^processor', '/proc/cpuinfo').stdout().strip()
 322   message('num processor are: ' + num_threads)
 323
 324   thread_opt_flag = '-j' + num_threads
 325
 326   ndk_additional_flags = [thread_opt_flag]
 327
 328   ndk_build_command = [ndk_build]
 329   foreach key, val : ndk_args
 330     ndk_build_command += '@0@=@1@'.format(key, val)
 331   endforeach
 332   ndk_build_command += ndk_additional_flags
 333
 334   android_build_target = custom_target('android',
 335     output: 'jni',
 336     build_by_default: true,
 337     command: ndk_build_command
 338   )
 339
 340 endif
 341
 342 if get_option('platform') == 'android'
 343   subdir('jni')
 344 endif
 345
 346 if get_option('platform') != 'none'
 347   message('building for ' + get_option('platform'))
 348 endif