meson.build

   1 project('libevdev', 'c',
   2         version: '1.9.1', # change autotools version too
   3         license: 'MIT/Expat',
   4         default_options: [ 'c_std=gnu99', 'warning_level=2' ],
   5         meson_version: '>= 0.47.0')
   6
   7 libevdev_version = meson.project_version().split('.')
   8
   9 dir_src         = join_paths(meson.source_root(), 'libevdev')
  10 dir_src_test    = join_paths(meson.source_root(), 'test')
  11
  12 # Include directories
  13 includes_include = include_directories('include')
  14
  15 # DO NOT MODIFY THIS
  16 # Use symbol versioning instead.
  17 libevdev_lt_c=5
  18 libevdev_lt_r=0
  19 libevdev_lt_a=3
  20
  21 # convert to soname
  22 libevdev_so_version = '@0@.@1@.@2@'.format((libevdev_lt_c - libevdev_lt_a),
  23                                            libevdev_lt_a, libevdev_lt_r)
  24
  25
  26 # Compiler setup
  27 cc = meson.get_compiler('c')
  28 cppflags = ['-Wno-unused-parameter', '-fvisibility=hidden']
  29 cflags = cppflags + ['-Wmissing-prototypes', '-Wstrict-prototypes']
  30 add_project_arguments(cflags, language: 'c')
  31 add_project_arguments(cppflags, language: 'cpp')
  32
  33 # config.h
  34 config_h = configuration_data()
  35 config_h.set('_GNU_SOURCE', '1')
  36
  37 # Dependencies
  38 pkgconfig = import('pkgconfig')
  39 dep_lm = cc.find_library('m')
  40
  41 input_h = join_paths(meson.source_root(), 'include', 'linux', host_machine.system(), 'input.h')
  42 uinput_h = join_paths(meson.source_root(), 'include', 'linux', host_machine.system(), 'uinput.h')
  43 input_event_codes_h = join_paths(meson.source_root(), 'include', 'linux', host_machine.system(), 'input-event-codes.h')
  44
  45 # event-names.h
  46 make_event_names = find_program('libevdev/make-event-names.py')
  47 event_names_h = configure_file(input: 'libevdev/libevdev.h',
  48                                output: 'event-names.h',
  49                                command: [make_event_names, input_h, input_event_codes_h],
  50                                capture: true)
  51
  52
  53 # libevdev.so
  54 install_headers('libevdev/libevdev.h',
  55                 'libevdev/libevdev-uinput.h',
  56                 subdir: 'libevdev-1.0/libevdev')
  57 src_libevdev = [
  58         event_names_h,
  59         'libevdev/libevdev.h',
  60         'libevdev/libevdev-int.h',
  61         'libevdev/libevdev-util.h',
  62         'libevdev/libevdev-uinput.c',
  63         'libevdev/libevdev-uinput.h',
  64         'libevdev/libevdev-uinput-int.h',
  65         'libevdev/libevdev.c',
  66         'libevdev/libevdev-names.c',
  67         'include/linux/input.h',
  68         'include/linux/uinput.h',
  69         input_event_codes_h,
  70         input_h,
  71         uinput_h
  72 ]
  73
  74 mapfile = join_paths(dir_src, 'libevdev.sym')
  75 version_flag = '-Wl,--version-script,@0@'.format(mapfile)
  76 lib_libevdev = library('evdev',
  77         src_libevdev,
  78         include_directories: [includes_include],
  79         dependencies: [],
  80         version: libevdev_so_version,
  81         link_args: version_flag,
  82         link_depends: mapfile,
  83         install: true
  84 )
  85
  86 dep_libevdev = declare_dependency(link_with: lib_libevdev)
  87
  88 pkgconfig.generate(
  89         filebase: 'libevdev',
  90         name: 'libevdev',
  91         description: 'Handler library for evdev events',
  92         version: meson.project_version(),
  93         libraries: lib_libevdev,
  94         subdirs: 'libevdev-1.0',
  95 )
  96
  97 man_config = configuration_data()
  98 man_config.set('PACKAGE_VERSION', meson.project_version())
  99 manpage = configure_file(input: 'doc/libevdev.man.in',
 100                          output: 'libevdev.3',
 101                          configuration: man_config)
 102 install_man(manpage)
 103
 104
 105 # tools
 106 executable('libevdev-events',
 107            sources: ['tools/libevdev-events.c'],
 108            include_directories: [includes_include],
 109            dependencies: dep_libevdev,
 110            install: false)
 111 executable('touchpad-edge-detector',
 112            sources: ['tools/touchpad-edge-detector.c'],
 113            include_directories: [includes_include],
 114            dependencies: [dep_libevdev, dep_lm],
 115            install: true)
 116 executable('mouse-dpi-tool',
 117            sources: ['tools/mouse-dpi-tool.c'],
 118            include_directories: [includes_include],
 119            dependencies: dep_libevdev,
 120            install: true)
 121 executable('libevdev-tweak-device',
 122            sources: ['tools/libevdev-tweak-device.c'],
 123            include_directories: [includes_include],
 124            dependencies: dep_libevdev,
 125            install: true)
 126
 127
 128 # tests
 129 dep_check = dependency('check', version: '>= 0.9.9',
 130                        required: get_option('tests'))
 131 if dep_check.found()
 132         executable('test-link',
 133                    sources: ['test/test-link.c'],
 134                    include_directories: [includes_include],
 135                    dependencies: dep_libevdev,
 136                    install: false)
 137         executable('test-compile-pedantic',
 138                    sources: ['test/test-compile-pedantic.c'],
 139                    c_args: ['-pedantic', '-Werror', '-std=c89'],
 140                    include_directories: [includes_include],
 141                    dependencies: dep_libevdev,
 142                    install: false)
 143
 144         src_common = [
 145                 'test/test-common-uinput.c',
 146                 'test/test-common-uinput.h',
 147                 'test/test-common.c',
 148                 'test/test-common.h',
 149                 'test/test-main.c',
 150         ]
 151         test_event_codes = executable('test-event-codes',
 152                                       sources: src_common + [
 153                                         'test/test-event-codes.c',
 154                                         'test/test-event-names.c',
 155                                         'test/test-context.c',
 156                                       ],
 157                                       include_directories: [includes_include],
 158                                       dependencies: [dep_libevdev, dep_check],
 159                                       install: false)
 160         test('test-event-codes', test_event_codes, suite: 'library')
 161
 162         test_internals = executable('test-internals',
 163                                     sources: src_common + [
 164                                         'test/test-int-queue.c',
 165                                     ],
 166                                     include_directories: [includes_include],
 167                                     dependencies: [dep_libevdev, dep_check],
 168                                     install: false)
 169         test('test-internals', test_internals, suite: 'library')
 170
 171         test_uinput = executable('test-uinput',
 172                                  sources: src_common + [
 173                                         'test/test-uinput.c',
 174                                  ],
 175                                  include_directories: [includes_include],
 176                                  dependencies: [dep_libevdev, dep_check],
 177                                  install: false)
 178         test('test-uinput', test_uinput, suite: 'library')
 179
 180         test_libevdev = executable('test-libevdev',
 181                                    sources: src_common + [
 182                                         'test/test-libevdev-init.c',
 183                                         'test/test-libevdev-has-event.c',
 184                                         'test/test-libevdev-events.c',
 185                                    ],
 186                                    include_directories: [includes_include],
 187                                    dependencies: [dep_libevdev, dep_check],
 188                                    install: false)
 189         test('test-libevdev', test_libevdev, suite: 'library')
 190
 191         test_kernel = executable('test-kernel',
 192                                  sources: src_common + [
 193                                         'test/test-kernel.c',
 194                                  ],
 195                                  include_directories: [includes_include],
 196                                  dependencies: [dep_libevdev, dep_check],
 197                                  install: false)
 198         test('test-kernel', test_kernel, suite: 'kernel')
 199
 200
 201         valgrind = find_program('valgrind', required: false)
 202         if valgrind.found()
 203                 valgrind_env = environment()
 204                 valgrind_env.set('CK_TIMEOUT_MULTIPLIER', '10')
 205                 valgrind_env.set('CK_FORK', 'no')
 206                 valgrind_env.set('RUNNING_ON_VALGRIND', '1')
 207                 valgrind_suppressions_file = join_paths(dir_src_test, 'valgrind.suppressions')
 208                 add_test_setup('valgrind',
 209                                 exe_wrapper: [ valgrind,
 210                                                 '--leak-check=full',
 211                                                 '--gen-suppressions=all',
 212                                                 '--error-exitcode=3',
 213                                                 '--suppressions=' + valgrind_suppressions_file ],
 214                                 env:  valgrind_env,
 215                                 timeout_multiplier: 100)
 216         else
 217                 message('valgrind not found, disabling valgrind test suite')
 218         endif
 219
 220         test_static_link = find_program('test/test-static-symbols-leak.sh')
 221         test('static-symbols-leak', test_static_link,
 222              args: [meson.current_build_dir()],
 223              suite: 'static')
 224 endif
 225
 226 doxygen = find_program('doxygen', required: get_option('documentation'))
 227 if doxygen.found()
 228         doxygen = find_program('doxygen')
 229
 230         src_doxygen = files(
 231                 # source files
 232                 join_paths(dir_src, 'libevdev.h'),
 233                 join_paths(dir_src, 'libevdev-uinput.h'),
 234                 # style files
 235                 'doc/style/bootstrap.css',
 236                 'doc/style/customdoxygen.css',
 237                 'doc/style/doxy-boot.js',
 238                 'doc/style/dynsections.js',
 239                 'doc/style/footer.html',
 240                 'doc/style/header.html',
 241                 'doc/style/layout.xml',
 242                 'doc/style/libevdevdoxygen.css',
 243                 'doc/style/LICENSE',
 244                 'doc/style/README.md',
 245                 'doc/style/style.css',
 246         )
 247         doxyfiles = []
 248         foreach f: src_doxygen
 249                 df = configure_file(input: f,
 250                                     output: '@PLAINNAME@',
 251                                     copy: true)
 252                 doxyfiles += [df]
 253         endforeach
 254
 255         doc_config = configuration_data()
 256         doc_config.set('PACKAGE_NAME', meson.project_name())
 257         doc_config.set('PACKAGE_VERSION', meson.project_version())
 258         doc_config.set('builddir', meson.current_build_dir())
 259         doc_config.set('top_srcdir', meson.source_root())
 260         doc_config.set('srcdir', join_paths(meson.source_root(), 'doc'))
 261
 262         doxyfile = configure_file(input: 'doc/libevdev.doxygen.in',
 263                                   output: 'libevdev.doxygen',
 264                                   configuration: doc_config)
 265         custom_target('doxygen',
 266                       input: [doxyfiles, doxyfile] + src_doxygen,
 267                       output: ['.'],
 268                       command: [doxygen, doxyfile],
 269                       install: false,
 270                       build_by_default: true)
 271 endif
 272
 273 # Coverity breaks because it doesn't define _Float128 correctly, you'll end
 274 # up with a bunch of messages in the form:
 275 # "/usr/include/stdlib.h", line 133: error #20: identifier "_Float128" is
 276 #           undefined
 277 #   extern _Float128 strtof128 (const char *__restrict __nptr,
 278 #          ^
 279 # We don't use float128 ourselves, it gets pulled in from math.h or
 280 # something, so let's just define it as uint128 and move on.
 281 # Unfortunately we can't detect the coverity build at meson configure
 282 # time, we only know it fails at runtime. So make this an option instead, to
 283 # be removed when coverity fixes this again.
 284 if get_option('coverity')
 285         config_h.set('_Float128', '__uint128_t')
 286         config_h.set('_Float32', 'int')
 287         config_h.set('_Float32x', 'int')
 288         config_h.set('_Float64', 'long')
 289         config_h.set('_Float64x', 'long')
 290 endif
 291
 292 ############ output files ############
 293 configure_file(output: 'config.h', configuration: config_h)