meson.build

   1 project('libevdev', 'c',
   2         version: '1.9.0', # change autotools version too
   3         license: 'MIT/Expat',
   4         default_options: [ 'c_std=gnu99', 'warning_level=2' ],
   5         meson_version: '>= 0.47.0')
   6
   7 libevdev_version = meson.project_version().split('.')
   8
   9 dir_src         = join_paths(meson.source_root(), 'libevdev')
  10 dir_src_test    = join_paths(meson.source_root(), 'test')
  11
  12 # Include directories
  13 includes_include = include_directories('include')
  14
  15 # DO NOT MODIFY THIS
  16 # Use symbol versioning instead.
  17 libevdev_lt_c=5
  18 libevdev_lt_r=0
  19 libevdev_lt_a=3
  20
  21 # convert to soname
  22 libevdev_so_version = '@0@.@1@.@2@'.format((libevdev_lt_c - libevdev_lt_a),
  23                                            libevdev_lt_a, libevdev_lt_r)
  24
  25
  26 # Compiler setup
  27 cc = meson.get_compiler('c')
  28 cppflags = ['-Wno-unused-parameter', '-fvisibility=hidden']
  29 cflags = cppflags + ['-Wmissing-prototypes', '-Wstrict-prototypes']
  30 add_project_arguments(cflags, language: 'c')
  31 add_project_arguments(cppflags, language: 'cpp')
  32
  33 # config.h
  34 config_h = configuration_data()
  35 config_h.set('_GNU_SOURCE', '1')
  36
  37 # Dependencies
  38 pkgconfig = import('pkgconfig')
  39 dep_lm = cc.find_library('m')
  40
  41 # event-names.h
  42 input_h = join_paths(meson.source_root(), 'include', 'linux', 'input.h')
  43 input_event_codes_h = join_paths(meson.source_root(), 'include', 'linux', 'input-event-codes.h')
  44
  45 make_event_names = find_program('libevdev/make-event-names.py')
  46 event_names_h = configure_file(input: 'libevdev/libevdev.h',
  47                                output: 'event-names.h',
  48                                command: [make_event_names, input_h, input_event_codes_h],
  49                                capture: true)
  50
  51
  52 # libevdev.so
  53 install_headers('libevdev/libevdev.h',
  54                 'libevdev/libevdev-uinput.h',
  55                 subdir: 'libevdev-1.0/libevdev')
  56 src_libevdev = [
  57         event_names_h,
  58         'libevdev/libevdev.h',
  59         'libevdev/libevdev-int.h',
  60         'libevdev/libevdev-util.h',
  61         'libevdev/libevdev-uinput.c',
  62         'libevdev/libevdev-uinput.h',
  63         'libevdev/libevdev-uinput-int.h',
  64         'libevdev/libevdev.c',
  65         'libevdev/libevdev-names.c',
  66         'include/linux/input-event-codes.h',
  67         'include/linux/input.h',
  68         'include/linux/uinput.h'
  69 ]
  70
  71 mapfile = join_paths(dir_src, 'libevdev.sym')
  72 version_flag = '-Wl,--version-script,@0@'.format(mapfile)
  73 lib_libevdev = library('evdev',
  74         src_libevdev,
  75         include_directories: [includes_include],
  76         dependencies: [],
  77         version: libevdev_so_version,
  78         link_args: version_flag,
  79         link_depends: mapfile,
  80         install: true
  81 )
  82
  83 dep_libevdev = declare_dependency(link_with: lib_libevdev)
  84
  85 pkgconfig.generate(
  86         filebase: 'libevdev',
  87         name: 'libevdev',
  88         description: 'Handler library for evdev events',
  89         version: meson.project_version(),
  90         libraries: lib_libevdev,
  91         subdirs: 'libevdev-1.0',
  92 )
  93
  94 man_config = configuration_data()
  95 man_config.set('PACKAGE_VERSION', meson.project_version())
  96 manpage = configure_file(input: 'doc/libevdev.man.in',
  97                          output: 'libevdev.3',
  98                          configuration: man_config)
  99 install_man(manpage)
 100
 101
 102 # tools
 103 executable('libevdev-events',
 104            sources: ['tools/libevdev-events.c'],
 105            include_directories: [includes_include],
 106            dependencies: dep_libevdev,
 107            install: false)
 108 executable('touchpad-edge-detector',
 109            sources: ['tools/touchpad-edge-detector.c'],
 110            include_directories: [includes_include],
 111            dependencies: [dep_libevdev, dep_lm],
 112            install: true)
 113 executable('mouse-dpi-tool',
 114            sources: ['tools/mouse-dpi-tool.c'],
 115            include_directories: [includes_include],
 116            dependencies: dep_libevdev,
 117            install: true)
 118 executable('libevdev-tweak-device',
 119            sources: ['tools/libevdev-tweak-device.c'],
 120            include_directories: [includes_include],
 121            dependencies: dep_libevdev,
 122            install: true)
 123
 124
 125 # tests
 126 dep_check = dependency('check', version: '>= 0.9.9',
 127                        required: get_option('tests'))
 128 if dep_check.found()
 129         executable('test-link',
 130                    sources: ['test/test-link.c'],
 131                    dependencies: dep_libevdev,
 132                    install: false)
 133         executable('test-compile-pedantic',
 134                    sources: ['test/test-compile-pedantic.c'],
 135                    c_args: ['-pedantic', '-Werror', '-std=c89'],
 136                    dependencies: dep_libevdev,
 137                    install: false)
 138
 139         src_common = [
 140                 'test/test-common-uinput.c',
 141                 'test/test-common-uinput.h',
 142                 'test/test-common.c',
 143                 'test/test-common.h',
 144                 'test/test-main.c',
 145         ]
 146         test_event_codes = executable('test-event-codes',
 147                                       sources: src_common + [
 148                                         'test/test-event-codes.c',
 149                                         'test/test-event-names.c',
 150                                         'test/test-context.c',
 151                                       ],
 152                                       dependencies: [dep_libevdev, dep_check],
 153                                       install: false)
 154         test('test-event-codes', test_event_codes, suite: 'library')
 155
 156         test_internals = executable('test-internals',
 157                                     sources: src_common + [
 158                                         'test/test-int-queue.c',
 159                                     ],
 160                                     dependencies: [dep_libevdev, dep_check],
 161                                     install: false)
 162         test('test-internals', test_internals, suite: 'library')
 163
 164         test_uinput = executable('test-uinput',
 165                                  sources: src_common + [
 166                                         'test/test-uinput.c',
 167                                  ],
 168                                  dependencies: [dep_libevdev, dep_check],
 169                                  install: false)
 170         test('test-uinput', test_uinput, suite: 'library')
 171
 172         test_libevdev = executable('test-libevdev',
 173                                    sources: src_common + [
 174                                         'test/test-libevdev-init.c',
 175                                         'test/test-libevdev-has-event.c',
 176                                         'test/test-libevdev-events.c',
 177                                    ],
 178                                    dependencies: [dep_libevdev, dep_check],
 179                                    install: false)
 180         test('test-libevdev', test_libevdev, suite: 'library')
 181
 182         test_kernel = executable('test-kernel',
 183                                  sources: src_common + [
 184                                         'test/test-kernel.c',
 185                                  ],
 186                                  dependencies: [dep_libevdev, dep_check],
 187                                  install: false)
 188         test('test-kernel', test_kernel, suite: 'kernel')
 189
 190
 191         valgrind = find_program('valgrind', required: false)
 192         if valgrind.found()
 193                 valgrind_env = environment()
 194                 valgrind_env.set('CK_TIMEOUT_MULTIPLIER', '10')
 195                 valgrind_env.set('CK_FORK', 'no')
 196                 valgrind_env.set('RUNNING_ON_VALGRIND', '1')
 197                 valgrind_suppressions_file = join_paths(dir_src_test, 'valgrind.suppressions')
 198                 add_test_setup('valgrind',
 199                                 exe_wrapper: [ valgrind,
 200                                                 '--leak-check=full',
 201                                                 '--gen-suppressions=all',
 202                                                 '--error-exitcode=3',
 203                                                 '--suppressions=' + valgrind_suppressions_file ],
 204                                 env:  valgrind_env,
 205                                 timeout_multiplier: 100)
 206         else
 207                 message('valgrind not found, disabling valgrind test suite')
 208         endif
 209
 210         test_static_link = find_program('test/test-static-symbols-leak.sh')
 211         test('static-symbols-leak', test_static_link,
 212              args: [meson.current_build_dir()],
 213              suite: 'static')
 214 endif
 215
 216 doxygen = find_program('doxygen', required: get_option('documentation'))
 217 if doxygen.found()
 218         doxygen = find_program('doxygen')
 219
 220         src_doxygen = files(
 221                 # source files
 222                 join_paths(dir_src, 'libevdev.h'),
 223                 join_paths(dir_src, 'libevdev-uinput.h'),
 224                 # style files
 225                 'doc/style/bootstrap.css',
 226                 'doc/style/customdoxygen.css',
 227                 'doc/style/doxy-boot.js',
 228                 'doc/style/dynsections.js',
 229                 'doc/style/footer.html',
 230                 'doc/style/header.html',
 231                 'doc/style/layout.xml',
 232                 'doc/style/libevdevdoxygen.css',
 233                 'doc/style/LICENSE',
 234                 'doc/style/README.md',
 235                 'doc/style/style.css',
 236         )
 237         doxyfiles = []
 238         foreach f: src_doxygen
 239                 df = configure_file(input: f,
 240                                     output: '@PLAINNAME@',
 241                                     copy: true)
 242                 doxyfiles += [df]
 243         endforeach
 244
 245         doc_config = configuration_data()
 246         doc_config.set('PACKAGE_NAME', meson.project_name())
 247         doc_config.set('PACKAGE_VERSION', meson.project_version())
 248         doc_config.set('builddir', meson.current_build_dir())
 249         doc_config.set('top_srcdir', meson.source_root())
 250         doc_config.set('srcdir', join_paths(meson.source_root(), 'doc'))
 251
 252         doxyfile = configure_file(input: 'doc/libevdev.doxygen.in',
 253                                   output: 'libevdev.doxygen',
 254                                   configuration: doc_config)
 255         custom_target('doxygen',
 256                       input: [doxyfiles, doxyfile] + src_doxygen,
 257                       output: ['.'],
 258                       command: [doxygen, doxyfile],
 259                       install: false,
 260                       build_by_default: true)
 261 endif
 262
 263 # Coverity breaks because it doesn't define _Float128 correctly, you'll end
 264 # up with a bunch of messages in the form:
 265 # "/usr/include/stdlib.h", line 133: error #20: identifier "_Float128" is
 266 #           undefined
 267 #   extern _Float128 strtof128 (const char *__restrict __nptr,
 268 #          ^
 269 # We don't use float128 ourselves, it gets pulled in from math.h or
 270 # something, so let's just define it as uint128 and move on.
 271 # Unfortunately we can't detect the coverity build at meson configure
 272 # time, we only know it fails at runtime. So make this an option instead, to
 273 # be removed when coverity fixes this again.
 274 if get_option('coverity')
 275         config_h.set('_Float128', '__uint128_t')
 276         config_h.set('_Float32', 'int')
 277         config_h.set('_Float32x', 'int')
 278         config_h.set('_Float64', 'long')
 279         config_h.set('_Float64x', 'long')
 280 endif
 281
 282 ############ output files ############
 283 configure_file(output: 'config.h', configuration: config_h)