meson.build

   1 project(
   2   'glib-networking', 'c',
   3   version: '2.60.1',
   4   license: 'LGPL2.1+',
   5   meson_version: '>= 0.47.0',
   6   default_options: ['c_std=c11']
   7 )
   8
   9 prefix = get_option('prefix')
  10 datadir = join_paths(prefix, get_option('datadir'))
  11 libdir = join_paths(prefix, get_option('libdir'))
  12 libexecdir = join_paths(prefix, get_option('libexecdir'))
  13 localedir = join_paths(prefix, get_option('localedir'))
  14
  15 installed_tests_metadir = join_paths(datadir, 'installed-tests', meson.project_name())
  16 installed_tests_execdir = join_paths(libexecdir, 'installed-tests', meson.project_name())
  17
  18 cc = meson.get_compiler('c')
  19 host_system = host_machine.system()
  20
  21 config_h = configuration_data()
  22
  23 config_h.set_quoted('GETTEXT_PACKAGE', meson.project_name())
  24
  25 # Update default CA file
  26 if get_option('default_ca_file') != ''
  27   config_h.set_quoted('TIZEN_DEFAULT_CA_FILE', get_option('default_ca_file'))
  28 endif
  29
  30 # TIZEN extension
  31 if get_option('tizen_ext')
  32   config_h.set('TIZEN_EXT', get_option('tizen_ext'))
  33 endif
  34
  35 # compiler flags
  36 common_flags = [
  37   '-DHAVE_CONFIG_H',
  38   '-DG_LOG_DOMAIN="GLib-Net"',
  39   '-DLOCALE_DIR="@0@"'.format(localedir),
  40   '-DG_DISABLE_DEPRECATED',
  41   '-DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_46'
  42 ]
  43
  44 add_project_arguments(common_flags, language: 'c')
  45
  46 symbol_map = join_paths(meson.current_source_dir(), meson.project_name() + '.map')
  47
  48 module_ldflags = []
  49
  50 if host_system.contains('linux')
  51   test_ldflag = '-Wl,--version-script,' + symbol_map
  52   module_ldflags += cc.get_supported_link_arguments(test_ldflag)
  53 endif
  54
  55 # *** Check GLib GIO        ***
  56 glib_dep = dependency('glib-2.0', version: '>= 2.46.0',
  57   fallback: ['glib', 'libglib_dep'])
  58 gio_dep = dependency('gio-2.0',
  59   fallback: ['glib', 'libgio_dep'])
  60 gobject_dep = dependency('gio-2.0',
  61   fallback: ['glib', 'libgobject_dep'])
  62 gmodule_dep = dependency('gmodule-2.0',
  63   fallback: ['glib', 'libgmodule_dep'])
  64
  65 if glib_dep.type_name() == 'internal'
  66   glib_proj = subproject('glib')
  67   gio_module_dir = glib_proj.get_variable('glib_giomodulesdir')
  68 else
  69   gio_module_dir = gio_dep.get_pkgconfig_variable('giomoduledir',
  70                                                   define_variable: ['libdir', join_paths(prefix, libdir)])
  71 endif
  72
  73 assert(gio_module_dir.startswith(prefix), 'GIO_MODULE_DIR is missing from gio-2.0.pc')
  74
  75 # *** Checks for LibProxy   ***
  76 libproxy_dep = dependency('libproxy-1.0', version: '>= 0.3.1', required: get_option('libproxy'))
  77
  78 # *** Checks for GNOME      ***
  79 gsettings_desktop_schemas_dep = dependency('gsettings-desktop-schemas', required: get_option('gnome_proxy'))
  80
  81 backends = []
  82
  83 # *** Checks for GnuTLS     ***
  84 gnutls_dep = dependency('gnutls', version: '>= 3.4.6', required: get_option('gnutls'))
  85
  86 if gnutls_dep.found()
  87   backends += ['gnutls']
  88 endif
  89
  90 # *** Checks for OpenSSL    ***
  91 openssl_option = get_option('openssl')
  92 if openssl_option.disabled()
  93   openssl_dep = []
  94 else
  95   # XXX: https://github.com/mesonbuild/meson/issues/2945
  96   openssl_dep = dependency('openssl1.1', required: openssl_option.enabled() and cc.get_id() != 'msvc')
  97   if openssl_dep.found()
  98     backends += ['openssl']
  99   elif cc.get_id() == 'msvc' and not openssl_option.disabled()
 100     # MSVC builds of OpenSSL does not generate pkg-config files,
 101     # so we check for it manually here in this case, if we can't find those files
 102     # Based on the CMake check for OpenSSL in CURL's CMakeLists.txt,
 103     # on which headers we should check for
 104     have_openssl = true
 105     foreach h : ['crypto.h', 'engine.h', 'err.h', 'pem.h',
 106                  'rsa.h', 'ssl.h', 'x509.h', 'rand.h', 'tls1.h']
 107       header = 'openssl/' + h
 108       if not cc.has_header(header)
 109         have_openssl = false
 110         if openssl_option.enabled()
 111           error('openssl module is enabled and @0@ not found'.format(header))
 112         endif
 113       endif
 114     endforeach
 115
 116     # OpenSSL 1.1.x and 1.0.x (or earlier) have different .lib names,
 117     # so we need to look for the correct pair
 118
 119     # Find either libcrypto.lib (1.1.x) or libeay32.lib (1.0.x or earlier) first
 120     libcrypto_dep = cc.find_library('libcrypto', required: false)
 121     if libcrypto_dep.found()
 122       libssl = 'libssl'
 123     else
 124       libcrypto_dep = cc.find_library('libeay32', required: openssl_option)
 125       libssl = 'ssleay32'
 126     endif
 127
 128     if libcrypto_dep.found()
 129       # Find the corresponding SSL library depending on which crypto .lib we found
 130       libssl_dep = cc.find_library(libssl, required: openssl_option)
 131     endif
 132
 133     if libcrypto_dep.found() and have_openssl
 134       openssl_dep = [libcrypto_dep, libssl_dep]
 135       backends += ['openssl']
 136     endif
 137   endif
 138 endif
 139
 140 if backends.length() == 0
 141   error('No TLS backends enabled. Please enable at least one TLS backend')
 142 endif
 143
 144 configure_file(
 145   output: 'config.h',
 146   configuration: config_h
 147 )
 148
 149 gnome = import('gnome')
 150 i18n = import('i18n')
 151 pkg = import('pkgconfig')
 152
 153 po_dir = join_paths(meson.source_root(), 'po')
 154
 155 top_inc = include_directories('.')
 156 tls_inc = include_directories('tls')
 157
 158 subdir('po')
 159
 160 enable_installed_tests = get_option('installed_tests')
 161 test_template = files('template.test.in')
 162
 163 module_suffix = []
 164 # Keep the autotools convention for shared module suffix because GModule
 165 # depends on it: https://gitlab.gnome.org/GNOME/glib/issues/520
 166 if ['darwin', 'ios'].contains(host_system)
 167   module_suffix = 'so'
 168 endif
 169
 170 if libproxy_dep.found() or gsettings_desktop_schemas_dep.found()
 171   proxy_test_programs = []
 172
 173   if libproxy_dep.found()
 174     subdir('proxy/libproxy')
 175   endif
 176
 177   if gsettings_desktop_schemas_dep.found()
 178     subdir('proxy/gnome')
 179   endif
 180
 181   subdir('proxy/tests')
 182 endif
 183
 184 subdir('tls/base')
 185
 186 if gnutls_dep.found()
 187   subdir('tls/gnutls')
 188 endif
 189
 190 if backends.contains('openssl')
 191   subdir('tls/openssl')
 192 endif
 193
 194 subdir('tls/tests')
 195
 196 # Will automatically pick it up from the cross file if defined
 197 gio_querymodules = find_program('gio-querymodules', required : false)
 198 if gio_querymodules.found()
 199   meson.add_install_script('meson_post_install.py', gio_querymodules.path(), gio_module_dir)
 200 endif
 201
 202 output = '\n\n'
 203 output += '  gnutls support:      ' + backends.contains('gnutls').to_string() + '\n'
 204 output += '  openssl support:     ' + backends.contains('openssl').to_string() + '\n'
 205 output += '  libproxy support:    ' + libproxy_dep.found().to_string() + '\n'
 206 output += '  GNOME proxy support: ' + gsettings_desktop_schemas_dep.found().to_string() + '\n'
 207 output += '  TIZEN default CA file: ' + get_option('default_ca_file') + '\n'
 208 output += '  TIZEN extension:     ' + get_option('tizen_ext').to_string() + '\n'
 209 message(output)