meson.build

   1 project('pulseaudio', 'c', 'cpp',
   2         version : run_command(find_program('git-version-gen'), join_paths(meson.current_source_dir(), '.tarball-version')).stdout().strip(),
   3         meson_version : '>= 0.50.0',
   4         default_options : [ 'c_std=gnu11', 'cpp_std=c++11' ]
   5         )
   6
   7 pa_version_str = meson.project_version()
   8 # For tarballs, the first split will do nothing, but for builds in git, we
   9 # split out suffixes when there are commits since the last tag
  10 # (e.g.: v11.99.1-3-gad14bdb24 -> v11.99.1)
  11 version_split = pa_version_str.split('-')[0].split('.')
  12 pa_version_major = version_split[0].split('v')[0]
  13 pa_version_minor = version_split[1]
  14 if version_split.length() > 2
  15   pa_version_micro = version_split[2]
  16 else
  17   pa_version_micro = '0'
  18 endif
  19 pa_version_major_minor = pa_version_major + '.' + pa_version_minor
  20
  21 pa_api_version = 12
  22 pa_protocol_version = 35
  23
  24 # The stable ABI for client applications, for the version info x:y:z
  25 # always will hold x=z
  26 libpulse_version_info = [23, 0, 23]
  27
  28 # A simplified, synchronous, ABI-stable interface for client
  29 # applications, for the version info x:y:z always will hold x=z
  30 libpulse_simple_version_info = [1, 1, 1]
  31
  32 # The ABI-stable GLib adapter for client applications, for the version
  33 # info x:y:z always will hold x=z
  34 libpulse_mainloop_glib_version_info = [0, 6, 0]
  35
  36 libpulse_version = '@0@.@1@.@2@'.format(
  37   libpulse_version_info[0] - libpulse_version_info[2],
  38   libpulse_version_info[0],
  39   libpulse_version_info[1],
  40 )
  41
  42 libpulse_simple_version = '@0@.@1@.@2@'.format(
  43   libpulse_simple_version_info[0] - libpulse_simple_version_info[2],
  44   libpulse_simple_version_info[0],
  45   libpulse_simple_version_info[1],
  46 )
  47
  48 libpulse_mainloop_glib_version = '@0@.@1@.@2@'.format(
  49   libpulse_mainloop_glib_version_info[0] - libpulse_mainloop_glib_version_info[2],
  50   libpulse_mainloop_glib_version_info[0],
  51   libpulse_mainloop_glib_version_info[1],
  52 )
  53
  54 # Paths
  55
  56 prefix = get_option('prefix')
  57 assert(prefix.startswith('/'), 'Prefix is not absolute: "@0@"'.format(prefix))
  58
  59 bindir = join_paths(prefix, get_option('bindir'))
  60 includedir = join_paths(prefix, get_option('includedir'))
  61 libdir = join_paths(prefix, get_option('libdir'))
  62 libexecdir = join_paths(prefix, get_option('libexecdir'))
  63 mandir = join_paths(prefix, get_option('mandir'))
  64 datadir = join_paths(prefix, get_option('datadir'))
  65 localedir = join_paths(prefix, get_option('localedir'))
  66 localstatedir = join_paths(prefix, get_option('localstatedir'))
  67 sysconfdir = join_paths(prefix, get_option('sysconfdir'))
  68 privlibdir = join_paths(libdir, 'pulseaudio')
  69
  70 alsadatadir = get_option('alsadatadir')
  71 if alsadatadir == ''
  72   alsadatadir = join_paths(datadir, 'pulseaudio', 'alsa-mixer')
  73 endif
  74
  75 pkgconfigdir = join_paths(libdir, 'pkgconfig')
  76 pulselibexecdir = join_paths(libexecdir, 'pulse')
  77 pulsesysconfdir = join_paths(sysconfdir, 'pulse')
  78
  79 modlibexecdir = get_option('modlibexecdir')
  80 if modlibexecdir == ''
  81   modlibexecdir = join_paths(libdir, 'pulse-' + pa_version_major_minor, 'modules')
  82 endif
  83
  84 padsplibdir = get_option('padsplibdir')
  85 if padsplibdir == ''
  86   padsplibdir = privlibdir
  87 endif
  88
  89 pulsedsp_location = get_option('pulsedsp-location')
  90 if pulsedsp_location == ''
  91   pulsedsp_location = join_paths(prefix, padsplibdir)
  92 endif
  93
  94 systemduserunitdir = get_option('systemduserunitdir')
  95 # the default value is set below
  96
  97 udevrulesdir = get_option('udevrulesdir')
  98 if udevrulesdir == ''
  99   # absolute path, otherwise meson prepends the prefix
 100   udevrulesdir = '/lib/udev/rules.d'
 101 endif
 102
 103 vapidir = join_paths(datadir, 'vala', 'vapi')
 104
 105 bashcompletiondir = get_option('bashcompletiondir')
 106 if bashcompletiondir == ''
 107   bash_completion_dep = dependency('bash-completion', required : false)
 108   if bash_completion_dep.found()
 109     bashcompletiondir = bash_completion_dep.get_pkgconfig_variable('completionsdir')
 110   else
 111     bashcompletiondir = join_paths(datadir, 'bash-completion', 'completions')
 112   endif
 113 endif
 114
 115 zshcompletiondir = get_option('zshcompletiondir')
 116 if zshcompletiondir == ''
 117   zshcompletiondir = join_paths(datadir, 'zsh', 'site-functions')
 118 endif
 119
 120 # Configuration data
 121
 122 cc = meson.get_compiler('c')
 123
 124 cdata = configuration_data()
 125 cdata.set_quoted('PACKAGE', 'pulseaudio')
 126 cdata.set_quoted('PACKAGE_NAME', 'pulseaudio')
 127 cdata.set_quoted('PACKAGE_VERSION', pa_version_str)
 128 cdata.set_quoted('CANONICAL_HOST', target_machine.cpu_family())
 129 cdata.set('PA_MAJOR', pa_version_major)
 130 cdata.set('PA_MINOR', pa_version_minor)
 131 cdata.set('PA_API_VERSION', pa_api_version)
 132 cdata.set('PA_PROTOCOL_VERSION', pa_protocol_version)
 133 cdata.set_quoted('PA_MACHINE_ID', join_paths(sysconfdir, 'machine-id'))
 134 cdata.set_quoted('PA_MACHINE_ID_FALLBACK', join_paths(localstatedir, 'lib', 'dbus', 'machine-id'))
 135 cdata.set_quoted('PA_SRCDIR', join_paths(meson.current_source_dir(), 'src'))
 136 cdata.set_quoted('PA_BUILDDIR', meson.current_build_dir())
 137 cdata.set_quoted('PA_SOEXT', '.so')
 138 cdata.set_quoted('PA_DEFAULT_CONFIG_DIR', pulsesysconfdir)
 139 cdata.set('PA_DEFAULT_CONFIG_DIR_UNQUOTED', pulsesysconfdir)
 140 cdata.set_quoted('PA_BINARY', join_paths(bindir, 'pulseaudio'))
 141 cdata.set_quoted('PA_SYSTEM_RUNTIME_PATH', join_paths(localstatedir, 'run', 'pulse'))
 142 cdata.set_quoted('PA_SYSTEM_CONFIG_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 143 cdata.set_quoted('PA_SYSTEM_STATE_PATH', join_paths(localstatedir, 'lib', 'pulse'))
 144 cdata.set_quoted('PA_DLSEARCHPATH', modlibexecdir)
 145 cdata.set_quoted('PA_SYSTEM_USER', get_option('system_user'))
 146 cdata.set_quoted('PA_SYSTEM_GROUP', get_option('system_group'))
 147 cdata.set_quoted('PA_ACCESS_GROUP', get_option('access_group'))
 148 cdata.set_quoted('PA_CFLAGS', 'Not yet supported on meson')
 149 cdata.set_quoted('PA_ALSA_PATHS_DIR', join_paths(alsadatadir, 'paths'))
 150 cdata.set_quoted('PA_ALSA_PROFILE_SETS_DIR', join_paths(alsadatadir, 'profile-sets'))
 151 cdata.set_quoted('DESKTOPFILEDIR', join_paths(datadir, 'applications'))
 152 cdata.set_quoted('PULSE_LOCALEDIR', localedir)
 153 cdata.set_quoted('GETTEXT_PACKAGE', 'pulseaudio')
 154 cdata.set('ENABLE_NLS', 1)
 155 cdata.set('top_srcdir', meson.source_root())
 156
 157 # Platform specifics
 158 # First some defaults to keep config file generation happy
 159 cdata.set('HAVE_COREAUDIO', 0)
 160 cdata.set('HAVE_WAVEOUT', 0)
 161
 162 platform_socket_dep = []
 163 platform_dep = []
 164
 165 # FIXME: This was not tested. Maybe some flags should better be CFLAGS,
 166 # rather than ending up in the config.h file?
 167 if host_machine.system() == 'darwin'
 168   cdata.set('OS_IS_DARWIN', 1)
 169   cdata.set('_DARWIN_C_SOURCE', '200112L') # Needed to get NSIG on Mac OS
 170 elif host_machine.system() == 'windows'
 171   cdata.set('OS_IS_WIN32', 1)
 172   cdata.set('HAVE_WINDOWS_H', 1)
 173   cdata.set('HAVE_WAVEOUT', 1)
 174   cdata.set('HAVE_WINSOCK2_H', 1)
 175   cdata.set('HAVE_WS2TCPIP_H', 1)
 176   cdata.set('WIN32_LEAN_AND_MEAN', 1) # Needed to avoid including unnecessary headers on Windows
 177   cdata.set('gid_t', 'int')
 178   cdata.set('uid_t', 'int')
 179   ws2_32_dep = meson.get_compiler('c').find_library('ws2_32')
 180   winsock_dep = meson.get_compiler('c').find_library('wsock32')
 181   ole32_dep = meson.get_compiler('c').find_library('ole32')
 182   ssp_dep = meson.get_compiler('c').find_library('ssp')
 183   pcreposix_dep = meson.get_compiler('c').find_library('pcreposix')
 184   platform_socket_dep = [ws2_32_dep, winsock_dep]
 185   platform_dep = [ole32_dep, ssp_dep, pcreposix_dep]
 186 #elif host_machine.system() == 'solaris'
 187 #  # Apparently meson has no solaris support?
 188 #  # Needed to get declarations for msg_control and msg_controllen on Solaris
 189 #  cdata.set('_XOPEN_SOURCE', 600)
 190 #  cdata.set('__EXTENSIONS__', 1)
 191 endif
 192
 193 if cc.has_type('_Bool')
 194   cdata.set('HAVE_STD_BOOL', 1)
 195 endif
 196
 197 if host_machine.cpu_family() == 'x86_64' or cc.sizeof('void *') >= 8
 198   cdata.set('HAVE_FAST_64BIT_OPERATIONS', 1)
 199 endif
 200
 201 # Headers
 202
 203 check_headers = [
 204   'arpa/inet.h',
 205   'byteswap.h',
 206   'cpuid.h',
 207   'dlfcn.h',
 208   'execinfo.h',
 209   'grp.h',
 210   'langinfo.h',
 211   'linux/sockios.h',
 212   'locale.h',
 213   'netdb.h',
 214   'netinet/in.h',
 215   'netinet/in_systm.h',
 216   'netinet/ip.h',
 217   'netinet/tcp.h',
 218   'pcreposix.h',
 219   'poll.h',
 220   'pwd.h',
 221   'regex.h',
 222   'sched.h',
 223   'stdint.h',
 224   'sys/atomic.h',
 225   'sys/capability.h',
 226   'sys/conf.h',
 227   'sys/dl.h',
 228   'sys/eventfd.h',
 229   'sys/filio.h',
 230   'sys/ioctl.h',
 231   'sys/mman.h',
 232   'sys/prctl.h',
 233   'sys/resource.h',
 234   'sys/select.h',
 235   'sys/socket.h',
 236   'sys/syscall.h',
 237   'sys/uio.h',
 238   'sys/un.h',
 239   'sys/wait.h',
 240   'syslog.h',
 241   'xlocale.h',
 242 ]
 243
 244 foreach h : check_headers
 245   if cc.has_header(h)
 246     define = 'HAVE_' + h.underscorify().to_upper()
 247     cdata.set(define, 1)
 248   endif
 249 endforeach
 250
 251 if cc.has_header('valgrind/memcheck.h', required: get_option('valgrind'))
 252   cdata.set('HAVE_VALGRIND_MEMCHECK_H', 1)
 253 endif
 254
 255 # FIXME: move this to the above set
 256 if host_machine.system() != 'windows'
 257   if cc.has_header('pthread.h')
 258     cdata.set('HAVE_PTHREAD', 1)
 259   endif
 260 endif
 261
 262 if cc.has_header_symbol('pthread.h', 'PTHREAD_PRIO_INHERIT')
 263   cdata.set('HAVE_PTHREAD_PRIO_INHERIT', 1)
 264 endif
 265
 266 # Functions
 267
 268 check_functions = [
 269   'accept4',
 270   'clock_gettime',
 271   'ctime_r',
 272   'fchmod',
 273   'fchown',
 274   'fork',
 275   'fstat',
 276   'getaddrinfo',
 277   'getgrgid_r',
 278   'getgrnam_r',
 279   'getpwnam_r',
 280   'getpwuid_r',
 281   'gettimeofday',
 282   'getuid',
 283   'lrintf',
 284   'lstat',
 285   'memfd_create',
 286   'mkfifo',
 287   'mlock',
 288   'nanosleep',
 289   'open64',
 290   'paccept',
 291   'pipe',
 292   'pipe2',
 293   'posix_fadvise',
 294   'posix_madvise',
 295   'posix_memalign',
 296   'ppoll',
 297   'readlink',
 298   'setegid',
 299   'seteuid',
 300   'setpgid',
 301   'setregid',
 302   'setresgid',
 303   'setresuid',
 304   'setreuid',
 305   'setsid',
 306   'sig2str',
 307   'sigaction',
 308   'strerror_r',
 309   'strtod_l',
 310   'strtof',
 311   'symlink',
 312   'sysconf',
 313   'uname',
 314 ]
 315
 316 foreach f : check_functions
 317   if cc.has_function(f)
 318     define = 'HAVE_' + f.underscorify().to_upper()
 319
 320     if f == 'posix_memalign' and host_machine.system() == 'windows'
 321       message('Win32/mingw32 does not properly define posix_memalign.')
 322     elif f == 'fork' and host_machine.system() == 'windows'
 323       # __builtin_fork is defined and compiles properly, but calling __builtin_fork() does not.
 324       # This causes Meson to think that Windows has a fork() which causes a link error...
 325       message('Win32/mingw32 does not properly define fork.')
 326     else
 327       cdata.set(define, 1)
 328     endif
 329   endif
 330 endforeach
 331
 332 if cc.has_header_symbol('sys/syscall.h', 'SYS_memfd_create')
 333   cdata.set('HAVE_MEMFD', 1)
 334 endif
 335
 336 if cc.has_function('dgettext')
 337   if host_machine.system() != 'windows'
 338     libintl_dep = []
 339   else
 340     libintl_dep = cc.find_library('intl')
 341   endif
 342 else
 343   libintl_dep = cc.find_library('intl')
 344 endif
 345
 346 # Symbols
 347
 348 if cc.has_header_symbol('signal.h', 'SIGXCPU')
 349   cdata.set('HAVE_SIGXCPU', 1)
 350 endif
 351
 352 if not cc.has_header_symbol('netinet/in.h', 'INADDR_NONE')
 353   if not cc.has_header_symbol('winsock2.h', 'INADDR_NONE')
 354     # Define INADDR_NONE if not found (Solaris)
 355     cdata.set('INADDR_NONE', '0xffffffff')
 356   endif
 357 endif
 358
 359 check_decls = [
 360   [ 'environ', 'unistd.h', '#define _GNU_SOURCE' ],
 361   [ 'SOUND_PCM_READ_RATE', 'sys/soundcard.h', '' ],
 362   [ 'SOUND_PCM_READ_CHANNELS', 'sys/soundcard.h', '' ],
 363   [ 'SOUND_PCM_READ_BITS', 'sys/soundcard.h', '' ],
 364 ]
 365
 366 foreach s : check_decls
 367   if cc.has_header_symbol(s[1], s[0], prefix : s[2])
 368     define = 'HAVE_DECL_' + s[0].to_upper()
 369     cdata.set(define, 1)
 370   endif
 371 endforeach
 372
 373 # Types
 374
 375 # FIXME: do we ever care about gid_t not being defined / smaller than an int?
 376 cdata.set('GETGROUPS_T', 'gid_t')
 377
 378 # Include paths
 379
 380 configinc = include_directories('.')
 381 topinc = include_directories('src')
 382
 383 # CFLAGS/LDFLAGS
 384
 385 pa_c_args = ['-DHAVE_CONFIG_H', '-D_GNU_SOURCE']
 386 server_c_args = ['-D__INCLUDED_FROM_PULSE_AUDIO']
 387 cdata.set('MESON_BUILD', 1)
 388
 389 # On ELF systems we don't want the libraries to be unloaded since we don't clean them up properly,
 390 # so we request the nodelete flag to be enabled.
 391 # On other systems, we don't really know how to do that, but it's welcome if somebody can tell.
 392 # Windows doesn't support this flag.
 393 if host_machine.system() != 'windows'
 394   nodelete_link_args = ['-Wl,-z,nodelete']
 395 else
 396   nodelete_link_args = []
 397 endif
 398
 399 # Code coverage
 400
 401 if get_option('gcov')
 402   add_project_arguments('--coverage', language: ['c', 'cpp'])
 403   add_project_link_arguments('--coverage', language: ['c', 'cpp'])
 404 endif
 405
 406 # Core Dependencies
 407
 408 libm_dep = cc.find_library('m', required : true)
 409
 410 thread_dep = dependency('threads')
 411 foreach f : [
 412   'pthread_getname_np',
 413   'pthread_setaffinity_np',
 414   'pthread_setname_np',
 415 ]
 416   if cc.has_function(f, dependencies : thread_dep)
 417     define = 'HAVE_' + f.underscorify().to_upper()
 418     cdata.set(define, 1)
 419   endif
 420 endforeach
 421
 422 cap_dep = cc.find_library('cap', required : false)
 423
 424 shm_dep = cc.find_library('rt', required : false)
 425 if shm_dep.found()
 426   cdata.set('HAVE_SHM_OPEN', 1)
 427 endif
 428
 429 dl_dep = cc.find_library('dl', required : false)
 430 if dl_dep.found()
 431   cdata.set('HAVE_DLADDR', 1)
 432 endif
 433
 434 have_iconv = false
 435 if cc.has_function('iconv_open')
 436   iconv_dep = dependency('', required : false)
 437   have_iconv = true
 438 else
 439   iconv_dep = cc.find_library('iconv', required : false)
 440   have_iconv = iconv_dep.found()
 441 endif
 442 if have_iconv
 443   cdata.set('HAVE_ICONV', 1)
 444   iconvconsttest = '''#include <iconv.h>
 445 size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);
 446 '''
 447   if cc.compiles(iconvconsttest, dependencies : iconv_dep)
 448     cdata.set('ICONV_CONST', '')
 449   else
 450     cdata.set('ICONV_CONST', 'const')
 451   endif
 452 endif
 453
 454 # Atomic operations
 455
 456 if get_option('atomic-arm-memory-barrier')
 457     cdata.set('ATOMIC_ARM_MEMORY_BARRIER_ENABLED', 1)
 458 endif
 459
 460 need_libatomic_ops = false
 461
 462 atomictest = '''void func() {
 463   volatile int atomic = 2;
 464   __sync_bool_compare_and_swap (&atomic, 2, 3);
 465 }
 466 '''
 467
 468 if cc.compiles(atomictest)
 469   cdata.set('HAVE_ATOMIC_BUILTINS', 1)
 470
 471   newatomictest = '''void func() {
 472     int c = 0;
 473     __atomic_store_n(&c, 4, __ATOMIC_SEQ_CST);
 474   }
 475   '''
 476
 477   if(cc.compiles(newatomictest))
 478     cdata.set('HAVE_ATOMIC_BUILTINS_MEMORY_MODEL', 1)
 479   endif
 480
 481 elif host_machine.cpu_family() == 'arm'
 482   if host_machine.system() == 'linux' and get_option('atomic-arm-linux-helpers')
 483     cdata.set('ATOMIC_ARM_LINUX_HELPERS', 1)
 484   else
 485     armatomictest = '''int func() {
 486       volatile int a=0;
 487       int o=0, n=1, r;
 488       asm volatile (
 489               "ldrex    %0, [%1]\n"
 490               "subs  %0, %0, %2\n"
 491               "strexeq %0, %3, [%1]\n"
 492               : "=&r" (r)
 493               : "r" (&a), "Ir" (o), "r" (n)
 494       : "cc");
 495       return (a==1 ? 0 : -1);
 496     }
 497     '''
 498
 499     if cc.compiles(armatomictest)
 500       cdata.set('ATOMIC_ARM_INLINE_ASM', 1)
 501     else
 502       need_libatomic_ops = true
 503     endif
 504   endif # arm && !linux
 505
 506 elif not ['freebsd', 'netbsd'].contains(host_machine.system())
 507   need_libatomic_ops = true
 508 endif # !atomic helpers && !arm
 509
 510 if need_libatomic_ops
 511   assert(cc.has_header('atomic_ops.h'), 'Need libatomic_ops')
 512
 513   cdata.set('AO_REQUIRE_CAS', 1)
 514
 515   if host_machine.system() != 'windows'
 516     libatomic_ops_dep = cc.find_library('atomic_ops', required : true)
 517   else
 518     libatomic_ops_dep = dependency('', required: false)
 519   endif
 520 else
 521   libatomic_ops_dep = dependency('', required: false)
 522 endif
 523
 524 # ARM checks
 525 # ARMV6 instructions we need
 526 if host_machine.cpu_family() == 'arm'
 527   armv6test = '''int func() {
 528     volatile int a = -60000, b = 0xaaaabbbb, c = 0xccccdddd;
 529     asm volatile ("ldr r0, %2 \n"
 530                   "ldr r2, %3 \n"
 531                   "ldr r3, %4 \n"
 532                   "ssat r1, #8, r0 \n"
 533                   "str r1, %0 \n"
 534                   "pkhbt r1, r3, r2, LSL #8 \n"
 535                   "str r1, %1 \n"
 536                   : "=m" (a), "=m" (b)
 537                   : "m" (a), "m" (b), "m" (c)
 538                   : "r0", "r1", "r2", "r3", "cc");
 539     return (a == -128 && b == 0xaabbdddd) ? 0 : -1;
 540   }
 541   '''
 542
 543   if cc.compiles(armv6test)
 544     cdata.set('HAVE_ARMV6', 1)
 545   endif
 546 endif
 547 # NEON checks are automatically done by the unstable-simd module
 548
 549 # FIXME: make sure it's >= 2.2
 550 ltdl_dep = cc.find_library('ltdl', required : true)
 551 # FIXME: can meson support libtool -dlopen/-dlpreopen things?
 552 #        and do we still want to support this at all?
 553 cdata.set('DISABLE_LIBTOOL_PRELOAD', 1)
 554
 555 if get_option('database') == 'tdb'
 556   database_dep = dependency('tdb')
 557 elif get_option('database') == 'gdbm'
 558   database_dep = cc.find_library('gdbm', required : true)
 559 else
 560   database_dep = dependency('', required: false)
 561 endif
 562
 563 if get_option('ipv6')
 564   cdata.set('HAVE_IPV6', 1)
 565 endif
 566
 567 if get_option('legacy-database-entry-format')
 568   cdata.set('ENABLE_LEGACY_DATABASE_ENTRY_FORMAT', 1)
 569 endif
 570
 571 if get_option('stream-restore-clear-old-devices')
 572   cdata.set('STREAM_RESTORE_CLEAR_OLD_DEVICES', 1)
 573 endif
 574
 575 if get_option('running-from-build-tree')
 576   cdata.set('HAVE_RUNNING_FROM_BUILD_TREE', 1)
 577 endif
 578
 579 alsa_dep = dependency('alsa', version : '>= 1.0.24', required : get_option('alsa'))
 580 if alsa_dep.found()
 581   cdata.set('HAVE_ALSA', 1)
 582   cdata.set('HAVE_ALSA_UCM', 1)
 583 endif
 584
 585 asyncns_dep = dependency('libasyncns', version : '>= 0.1', required : get_option('asyncns'))
 586 if asyncns_dep.found()
 587   cdata.set('HAVE_LIBASYNCNS', 1)
 588 endif
 589
 590 dbus_dep = dependency('dbus-1', version : '>= 1.4.12', required : get_option('dbus'))
 591 if dbus_dep.found()
 592   cdata.set('HAVE_DBUS', 1)
 593 endif
 594
 595 gio_dep = dependency('gio-2.0', version : '>= 2.26.0', required : get_option('gsettings'))
 596 if gio_dep.found()
 597   cdata.set('HAVE_GSETTINGS', 1)
 598 endif
 599
 600 glib_dep = dependency('glib-2.0', version : '>= 2.28.0', required: get_option('glib'))
 601 if glib_dep.found()
 602   cdata.set('HAVE_GLIB', 1)
 603 endif
 604
 605 gtk_dep = dependency('gtk+-3.0', required : get_option('gtk'))
 606 if gtk_dep.found()
 607   cdata.set('HAVE_GTK', 1)
 608 endif
 609
 610 have_orcc = false
 611 orcc_args = []
 612 orc_dep = dependency('orc-0.4', version : '>= 0.4.11', required : get_option('orc'))
 613 orcc = find_program('orcc', required : get_option('orc'))
 614 if orc_dep.found() and orcc.found()
 615   have_orcc = true
 616   orcc_args = [orcc]
 617   #orcc_args = [orcc, '--include', 'glib.h']
 618   cdata.set('HAVE_ORC', 1)
 619 else
 620   cdata.set('DISABLE_ORC', 1)
 621 endif
 622
 623 samplerate_dep = dependency('samplerate', version : '>= 0.1.0', required : get_option('samplerate'))
 624 if samplerate_dep.found()
 625   cdata.set('HAVE_LIBSAMPLERATE', 1)
 626 endif
 627
 628 sndfile_dep = dependency('sndfile', version : '>= 1.0.20')
 629
 630 soxr_dep = dependency('soxr', version : '>= 0.1.1', required : get_option('soxr'))
 631 if soxr_dep.found()
 632   cdata.set('HAVE_SOXR', 1)
 633 endif
 634
 635 libsystemd_dep = dependency('libsystemd', required : get_option('systemd'))
 636 if libsystemd_dep.found()
 637   cdata.set('HAVE_SYSTEMD_DAEMON', 1)
 638   cdata.set('HAVE_SYSTEMD_LOGIN', 1)
 639   cdata.set('HAVE_SYSTEMD_JOURNAL', 1)
 640 endif
 641 systemd_dep = dependency('systemd', required : get_option('systemd'))
 642 if systemd_dep.found() and systemduserunitdir == ''
 643   systemduserunitdir = systemd_dep.get_pkgconfig_variable('systemduserunitdir')
 644 endif
 645
 646 x11_dep = dependency('x11-xcb', required : get_option('x11'))
 647 if x11_dep.found()
 648   xcb_dep  = dependency('xcb',  required : true, version : '>= 1.6')
 649   ice_dep  = dependency('ice',  required : true)
 650   sm_dep   = dependency('sm',   required : true)
 651   xtst_dep = dependency('xtst', required : true)
 652   cdata.set('HAVE_X11', 1)
 653 endif
 654
 655 # Module dependencies
 656 if cc.has_header('sys/soundcard.h', required: get_option('oss-output'))
 657   cdata.set('HAVE_OSS_OUTPUT', 1)
 658   cdata.set('HAVE_OSS_WRAPPER', 1)
 659   cdata.set('PULSEDSP_LOCATION', pulsedsp_location)
 660 endif
 661
 662 if get_option('hal-compat')
 663   cdata.set('HAVE_HAL_COMPAT', 1)
 664 endif
 665
 666 avahi_dep = dependency('avahi-client', version : '>= 0.6.0', required : get_option('avahi'), disabler : true)
 667 if avahi_dep.found()
 668   cdata.set('HAVE_AVAHI', 1)
 669 endif
 670
 671 sbc_dep = dependency('sbc', version : '>= 1.0', required : false)
 672 if get_option('bluez5')
 673   assert(dbus_dep.found(), 'BlueZ requires D-Bus support')
 674   assert(sbc_dep.found(), 'BlueZ requires SBC support')
 675   cdata.set('HAVE_SBC', 1)
 676   cdata.set('HAVE_BLUEZ', 1)
 677   cdata.set('HAVE_BLUEZ_5', 1)
 678   if get_option('bluez5-native-headset')
 679     cdata.set('HAVE_BLUEZ_5_NATIVE_HEADSET', 1)
 680   endif
 681   if get_option('bluez5-ofono-headset')
 682     cdata.set('HAVE_BLUEZ_5_OFONO_HEADSET', 1)
 683   endif
 684 endif
 685
 686 fftw_dep = dependency('fftw3f', required : get_option('fftw'))
 687 if fftw_dep.found()
 688   cdata.set('HAVE_FFTW', 1)
 689 endif
 690
 691 jack_dep = dependency('jack', version : '>= 0.117.0', required : get_option('jack'))
 692 if jack_dep.found()
 693   cdata.set('HAVE_JACK', 1)
 694 endif
 695
 696 lirc_dep = dependency('lirc', required : get_option('lirc'))
 697 if lirc_dep.found()
 698   cdata.set('HAVE_LIRC', 1)
 699 endif
 700
 701 openssl_dep = dependency('openssl', version : '>= 0.9', required : get_option('openssl'))
 702 if openssl_dep.found()
 703   cdata.set('HAVE_OPENSSL', 1)
 704 endif
 705
 706 speex_dep = dependency('speexdsp', version : '>= 1.2', required : get_option('speex'))
 707 if speex_dep.found()
 708   cdata.set('HAVE_SPEEX', 1)
 709 endif
 710
 711 udev_dep = dependency('libudev', version : '>= 143', required : get_option('udev'))
 712 if udev_dep.found()
 713   cdata.set('HAVE_UDEV', 1)
 714 endif
 715
 716 webrtc_dep = dependency('webrtc-audio-processing', version : '>= 0.2', required : get_option('webrtc-aec'))
 717 if webrtc_dep.found()
 718   cdata.set('HAVE_WEBRTC', 1)
 719 endif
 720
 721 gst_dep = dependency('gstreamer-1.0', version : '>= 1.14', required : get_option('gstreamer'))
 722 gstapp_dep = dependency('gstreamer-app-1.0', required : get_option('gstreamer'))
 723 gstrtp_dep = dependency('gstreamer-rtp-1.0', required : get_option('gstreamer'))
 724
 725 have_gstreamer = false
 726 if gst_dep.found() and gstapp_dep.found() and gstrtp_dep.found()
 727   have_gstreamer = true
 728 endif
 729
 730 # These are required for the CMake file generation
 731 cdata.set('PA_LIBDIR', libdir)
 732 cdata.set('PA_INCDIR', includedir)
 733 if glib_dep.found()
 734   cdata.set('HAVE_GLIB20', 1) # to match the AM_CONDITIONAL for CMake file generation
 735 endif
 736
 737 # Test dependencies
 738
 739 check_dep = dependency('check', version : '>= 0.9.10', required : get_option('tests'))
 740
 741 # Subdirs
 742
 743 subdir('doxygen')
 744 subdir('po')
 745 if get_option('man')
 746   subdir('man')
 747 endif
 748 subdir('shell-completion/bash')
 749 subdir('shell-completion/zsh')
 750 subdir('src')
 751 subdir('vala')
 752
 753 # Now generate config.h from everything above
 754 configure_file(output : 'config.h', configuration : cdata)
 755
 756 # pkg-config files
 757
 758 pc_cdata = configuration_data()
 759
 760 pc_cdata.set('prefix', prefix)
 761 pc_cdata.set('exec_prefix', prefix)
 762 pc_cdata.set('libdir', libdir)
 763 pc_cdata.set('includedir', includedir)
 764 pc_cdata.set('modlibexecdir', modlibexecdir)
 765 pc_cdata.set('PACKAGE_VERSION', pa_version_str)
 766 pc_cdata.set('PA_MAJORMINOR', pa_version_major_minor)
 767 # FIXME: the line below is wrong. Currently the meson thread dep lacks documentation,
 768 # and doesn't allow introspection, ie. none of get_pkgconfig_variable() or
 769 # get_configtool_variable() work with it, so we have no way to get this flag right,
 770 # unless we do all the work ourselves. See current work in glib, also meson #553.
 771 pc_cdata.set('PTHREAD_LIBS', '-pthread')
 772
 773 pc_files = [
 774   'libpulse.pc',
 775   'libpulse-simple.pc',
 776 ]
 777
 778 if glib_dep.found()
 779   pc_files += 'libpulse-mainloop-glib.pc'
 780 endif
 781
 782 foreach file : pc_files
 783   configure_file(
 784     input : file + '.in',
 785     output : file,
 786     configuration : pc_cdata,
 787     install_dir : pkgconfigdir)
 788 endforeach
 789
 790 # CMake files
 791
 792 m4 = find_program('m4', required: true)
 793
 794 cmakedir = join_paths(libdir, 'cmake', 'PulseAudio')
 795
 796 cmake_template_file = configure_file(
 797   input : 'PulseAudioConfig.cmake.in',
 798   output : 'PulseAudioConfig.cmake.tmp',
 799   configuration: cdata,
 800 )
 801
 802 custom_target('PulseAudioConfig.cmake',
 803   input : cmake_template_file,
 804   output : 'PulseAudioConfig.cmake',
 805   capture : true,
 806   command : [m4, '@INPUT@'],
 807   build_by_default : true,
 808   install : true,
 809   install_dir : cmakedir,
 810 )
 811
 812 configure_file(
 813   input : 'PulseAudioConfigVersion.cmake.in',
 814   output : 'PulseAudioConfigVersion.cmake',
 815   configuration: cdata,
 816   install : true,
 817   install_dir : cmakedir,
 818 )
 819
 820 ############################################################
 821
 822 # Final summary
 823
 824 summary = [
 825   '',
 826   '---{ @0@ @1@ }---'.format(meson.project_name(), meson.project_version()),
 827   '',
 828   'prefix:                        @0@'.format(prefix),
 829   'bindir:                        @0@'.format(bindir),
 830   'libdir:                        @0@'.format(libdir),
 831   'libexecdir:                    @0@'.format(libexecdir),
 832   'mandir:                        @0@'.format(mandir),
 833   'datadir:                       @0@'.format(datadir),
 834   'sysconfdir:                    @0@'.format(sysconfdir),
 835   'localstatedir:                 @0@'.format(localstatedir),
 836   'modlibexecdir:                 @0@'.format(modlibexecdir),
 837   'alsadatadir:                   @0@'.format(alsadatadir),
 838   'System Runtime Path:           @0@'.format(cdata.get_unquoted('PA_SYSTEM_RUNTIME_PATH')),
 839   'System State Path:             @0@'.format(cdata.get_unquoted('PA_SYSTEM_STATE_PATH')),
 840   'System Config Path:            @0@'.format(cdata.get_unquoted('PA_SYSTEM_CONFIG_PATH')),
 841   'Bash completions directory:    @0@'.format(bashcompletiondir),
 842   'Zsh completions directory:     @0@'.format(zshcompletiondir),
 843   'Compiler:                      @0@ @1@'.format(cc.get_id(), cc.version()),
 844 #  'CFLAGS:                        @0@'.format(${CFLAGS}),
 845 #  'CPPFLAGS:                      @0@'.format(${CPPFLAGS}),
 846 #  'LIBS:                          @0@'.format(${LIBS}),
 847   '',
 848   'Enable memfd shared memory:    @0@'.format(cdata.has('HAVE_MEMFD')),
 849   'Enable X11:                    @0@'.format(x11_dep.found()),
 850   'Enable OSS Output:             @0@'.format(cdata.has('HAVE_OSS_OUTPUT')),
 851   'Enable OSS Wrapper:            @0@'.format(cdata.has('HAVE_OSS_WRAPPER')),
 852 #  'Enable EsounD:                 @0@'.format(${ENABLE_ESOUND}),
 853   'Enable Alsa:                   @0@'.format(alsa_dep.found()),
 854 #  'Enable CoreAudio:              @0@'.format(${ENABLE_COREAUDIO}),
 855 #  'Enable Solaris:                @0@'.format(${ENABLE_SOLARIS}),
 856 #  'Enable WaveOut:                @0@'.format(${ENABLE_WAVEOUT}),
 857   'Enable GLib 2:                 @0@'.format(glib_dep.found()),
 858 #  'Enable GConf:                  @0@'.format(${ENABLE_GCONF}),
 859   'Enable GSettings:              @0@'.format(gio_dep.found()),
 860   'Enable Gtk+ 3:                 @0@'.format(gtk_dep.found()),
 861   'Enable Avahi:                  @0@'.format(avahi_dep.found()),
 862   'Enable Jack:                   @0@'.format(jack_dep.found()),
 863   'Enable Async DNS:              @0@'.format(asyncns_dep.found()),
 864   'Enable LIRC:                   @0@'.format(lirc_dep.found()),
 865   'Enable D-Bus:                  @0@'.format(dbus_dep.found()),
 866   '  Enable BlueZ 5:              @0@'.format(get_option('bluez5')),
 867   '    Enable native headsets:    @0@'.format(get_option('bluez5-native-headset')),
 868   '    Enable  ofono headsets:    @0@'.format(get_option('bluez5-ofono-headset')),
 869   'Enable udev:                   @0@'.format(udev_dep.found()),
 870   '  Enable HAL->udev compat:     @0@'.format(get_option('hal-compat')),
 871   'Enable systemd:                @0@'.format(libsystemd_dep.found()),
 872 #  'Enable TCP Wrappers:           @0@'.format(${ENABLE_TCPWRAP}),
 873   'Enable libsamplerate:          @0@'.format(samplerate_dep.found()),
 874   'Enable IPv6:                   @0@'.format(get_option('ipv6')),
 875   'Enable OpenSSL (for Airtunes): @0@'.format(openssl_dep.found()),
 876   'Enable FFTW:                   @0@'.format(fftw_dep.found()),
 877   'Enable ORC:                    @0@'.format(have_orcc),
 878   'Enable GStreamer:              @0@'.format(have_gstreamer),
 879   'Enable Adrian echo canceller:  @0@'.format(get_option('adrian-aec')),
 880   'Enable Speex (resampler, AEC): @0@'.format(speex_dep.found()),
 881   'Enable SoXR (resampler):       @0@'.format(soxr_dep.found()),
 882   'Enable WebRTC echo canceller:  @0@'.format(webrtc_dep.found()),
 883   'Enable Gcov coverage:          @0@'.format(get_option('gcov')),
 884   'Enable Valgrind:               @0@'.format(cdata.has('HAVE_VALGRIND_MEMCHECK_H')),
 885   'Enable man pages:              @0@'.format(get_option('man')),
 886   'Enable unit tests:             @0@'.format(get_option('tests')),
 887   '',
 888   'Database:                      @0@'.format(get_option('database')),
 889   'Legacy Database Entry Support: @0@'.format(get_option('legacy-database-entry-format')),
 890   'module-stream-restore:',
 891   '  Clear old devices:           @0@'.format(get_option('stream-restore-clear-old-devices')),
 892   'Running from build tree:       @0@'.format(get_option('running-from-build-tree')),
 893   'System User:                   @0@'.format(cdata.get_unquoted('PA_SYSTEM_USER')),
 894   'System Group:                  @0@'.format(cdata.get_unquoted('PA_SYSTEM_GROUP')),
 895   'Access Group:                  @0@'.format(cdata.get_unquoted('PA_ACCESS_GROUP')),
 896 #  'Enable per-user EsounD socket: @0@'.format(${ENABLE_PER_USER_ESOUND_SOCKET}),
 897 #  'Force preopen:                 @0@'.format(${FORCE_PREOPEN}),
 898 #  'Preopened modules:             @0@'.format(${PREOPEN_MODS}),
 899 ]
 900
 901 message('\n    '.join(summary))
 902
 903 # Sanity checks
 904
 905 if not speex_dep.found() and not webrtc_dep.found() and not get_option('adrian-aec')
 906   error('At least one echo canceller implementation must be available!')
 907 endif
 908
 909 if samplerate_dep.found()
 910   warning('Support for libsamplerate is DEPRECATED')
 911 endif
 912
 913 if host_machine.system() != 'windows'
 914   if not dbus_dep.found()
 915     message = [
 916       'You do not have D-Bus support enabled. It is strongly recommended',
 917       'that you enable D-Bus support if your platform supports it.',
 918       'Many parts of PulseAudio use D-Bus, from ConsoleKit interaction',
 919       'to the Device Reservation Protocol to speak to JACK, Bluetooth',
 920       'support and even a native control protocol for communicating and',
 921       'controlling the PulseAudio daemon itself.',
 922     ]
 923     warning('\n' + '\n'.join(message))
 924   endif
 925   if not udev_dep.found()
 926     message = [
 927       'You do not have udev support enabled. It is strongly recommended',
 928       'that you enable udev support if your platform supports it as it is',
 929       'the primary method used to detect hardware audio devices (on Linux)',
 930       'and is thus a critical part of PulseAudio on that platform.',
 931     ]
 932     warning('\n' + '\n'.join(message))
 933   endif
 934   if not speex_dep.found()
 935     message = [
 936       'You do not have speex support enabled. It is strongly recommended',
 937       'that you enable speex support if your platform supports it as it is',
 938       'the primary method used for audio resampling and is thus a critical',
 939       'part of PulseAudio on that platform.',
 940     ]
 941     warning('\n' + '\n'.join(message))
 942   endif
 943 endif