meson.build

   1 project('gstreamer', 'c', 'cpp',
   2   version : '1.9.90',
   3   meson_version : '>= 0.35.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 prefix = get_option('prefix')
  25 libtype = get_option('library_format')
  26
  27 libexecdir = get_option('libexecdir')
  28 helpers_install_dir = libexecdir + '/gstreamer-1.0/'
  29
  30 cc = meson.get_compiler('c')
  31
  32 # Ignore several spurious warnings for things gstreamer does very commonly
  33 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  34 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  35 # NOTE: Only add warnings here if you are sure they're spurious
  36 if cc.get_id() == 'msvc'
  37   add_global_arguments('/wd4018', '/wd4244', '/wd4996', language : 'c')
  38 endif
  39
  40 cdata = configuration_data()
  41 cdata.set('GST_VERSION_MAJOR', gst_version_major)
  42 cdata.set('GST_VERSION_MINOR', gst_version_minor)
  43 cdata.set('GST_VERSION_MICRO', gst_version_micro)
  44 cdata.set('GST_VERSION_NANO', gst_version_nano)
  45 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  46 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  47 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  48 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  49 cdata.set('GST_API_VERSION', '"1.0"')
  50 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  51 cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  52 cdata.set('GST_LICENSE', '"LGPL"')
  53 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  54 cdata.set('GST_PACKAGE_NAME', '"GStreamer source release"')
  55 cdata.set('PACKAGE', '"gstreamer"')
  56 cdata.set('PACKAGE_NAME', '"GStreamer"')
  57 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  58 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  59 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  60 cdata.set('PACKAGE_URL', '""')
  61 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  62 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  63 cdata.set('VERSION', '"@0@"'.format(gst_version))
  64 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  65 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  66 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  67 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  68
  69 # These are only needed/used by the ABI tests
  70 host_defines = [
  71   [ 'x86', 'HAVE_CPU_I386' ],
  72   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  73   [ 'arm', 'HAVE_CPU_ARM' ],
  74   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
  75   [ 'mips', 'HAVE_CPU_MIPS' ],
  76   [ 'powerpc', 'HAVE_CPU_PPC' ],
  77   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
  78   [ 'alpha', 'HAVE_CPU_ALPHA' ],
  79   [ 'sparc', 'HAVE_CPU_SPARC' ],
  80   [ 'ia64', 'HAVE_CPU_IA64' ],
  81   [ 'hppa', 'HAVE_CPU_HPPA' ],
  82   [ 'm68k', 'HAVE_CPU_M68K' ],
  83   [ 's390', 'HAVE_CPU_S390' ],
  84 ]
  85 foreach h : host_defines
  86   if h.get(0) == host_machine.cpu()
  87     cdata.set(h.get(1), 1)
  88   endif
  89 endforeach
  90 # FIXME: should really be called HOST_CPU or such
  91 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
  92
  93 check_headers = [['dlfcn.h','HAVE_DLFCN_H'],
  94   ['inttypes.h', 'HAVE_INTTYPES_H'],
  95   ['memory.h', 'HAVE_MEMORY_H'],
  96   ['poll.h', 'HAVE_POLL_H'],
  97   ['stdint.h', 'HAVE_STDINT_H'],
  98   ['stdio_ext.h', 'HAVE_STDIO_EXT_H'],
  99   ['strings.h', 'HAVE_STRINGS_H'],
 100   ['string.h', 'HAVE_STRING_H'],
 101   ['sys/param.h', 'HAVE_SYS_PARAM_H'],
 102   ['sys/poll.h', 'HAVE_SYS_POLL_H'],
 103   ['sys/prctl.h', 'HAVE_SYS_PRCTL_H'],
 104   ['sys/socket.h', 'HAVE_SYS_SOCKET_H'],
 105   ['sys/stat.h', 'HAVE_SYS_STAT_H'],
 106   ['sys/times.h', 'HAVE_SYS_TIMES_H'],
 107   ['sys/time.h', 'HAVE_SYS_TIME_H'],
 108   ['sys/types.h', 'HAVE_SYS_TYPES_H'],
 109   ['sys/utsname.h', 'HAVE_SYS_UTSNAME_H'],
 110   ['sys/wait.h', 'HAVE_SYS_WAIT_H'],
 111   ['ucontext.h', 'HAVE_UCONTEXT_H'],
 112   ['unistd.h', 'HAVE_UNISTD_H'],
 113   ['valgrind/valgrind.h', 'HAVE_VALGRIND_VALGRIND_H'],
 114   ['sys/resource.h', 'HAVE_SYS_RESOURCE_H'],
 115 ]
 116
 117 if host_machine.system() == 'windows'
 118   check_headers += [ ['winsock2.h', 'HAVE_WINSOCK2_H'] ]
 119 endif
 120
 121 foreach h : check_headers
 122   if cc.has_header(h.get(0))
 123     cdata.set(h.get(1), 1)
 124   endif
 125 endforeach
 126
 127 gmtoff_src = '''#include <time.h>
 128 int main(void) {
 129   struct tm t;
 130   t.tm_gmtoff = 0;
 131   return 0;
 132 }
 133 '''
 134
 135 if cc.compiles(gmtoff_src, name : 'tm_gmtoff from time.h')
 136   cdata.set('HAVE_TM_GMTOFF', 1)
 137 endif
 138
 139 if cc.has_function('gmtime_r', prefix : '#include<time.h>')
 140   cdata.set('HAVE_GMTIME_R', 1)
 141 endif
 142 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 143   cdata.set('HAVE_LOCALTIME_R', 1)
 144 endif
 145 if cc.has_function('sigaction', prefix : '#include<signal.h>')
 146   cdata.set('HAVE_SIGACTION', 1)
 147 endif
 148 have_getrusage = cc.has_function('getrusage', prefix : '#include <sys/time.h>\n#include <sys/resource.h>')
 149 if have_getrusage
 150   cdata.set('HAVE_GETRUSAGE', 1)
 151 endif
 152
 153 if cc.has_function('fseeko', prefix : '#include<stdio.h>')
 154   cdata.set('HAVE_FSEEKO', 1)
 155 endif
 156 if cc.has_function('ftello', prefix : '#include<stdio.h>')
 157   cdata.set('HAVE_FTELLO', 1)
 158 endif
 159 if cc.has_function('fsetpos', prefix : '#include<stdio.h>')
 160   cdata.set('HAVE_FSETPOS', 1)
 161 endif
 162 if cc.has_function('fgetpos', prefix : '#include<stdio.h>')
 163   cdata.set('HAVE_FGETPOS', 1)
 164 endif
 165 if cc.has_function('poll', prefix : '#include<poll.h>')
 166   cdata.set('HAVE_POLL', 1)
 167 endif
 168 if cc.has_function('pselect', prefix : '#include<sys/select.h>')
 169   cdata.set('HAVE_PSELECT', 1)
 170 endif
 171 cdata.set('HAVE_MMAP', 1)
 172
 173 if cc.has_function('posix_memalign', prefix : '#include<stdlib.h>')
 174   cdata.set('HAVE_POSIX_MEMALIGN', 1)
 175 endif
 176 if cc.has_function('getpagesize', prefix : '#include<unistd.h>')
 177   cdata.set('HAVE_GETPAGESIZE', 1)
 178 endif
 179
 180 # With XCode 8, clock_gettime will be incorrectly detected as being available
 181 # regardless of what version of OS X you target because the symbol is available
 182 # in the .tbd file as a weak symbol.
 183 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 184 #
 185 # We cannot simply do cc.has_function with -Wl,-no_weak_imports because the
 186 # check does its own prototype decl that doesn't trigger that compiler flag.
 187 #
 188 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 189 # actually available, so we can unconditionally disable it for older versions.
 190 disable_clock_gettime_src = '''#include <AvailabilityMacros.h>
 191 #include <TargetConditionals.h>
 192 #if defined(TARGET_OS_MAC)
 193 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 194 #    error "Not compiling for OS X 10.12 or later"
 195 #  endif
 196 #else
 197 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 198 #    error "Not compiling for iOS 10.0 or later"
 199 #  endif
 200 #endif
 201 '''
 202
 203 if cc.has_function('clock_gettime', prefix : '#include <time.h>')
 204   if host_machine.system() == 'darwin'
 205     if cc.compiles(disable_clock_gettime_src, name : 'target darwin/ios version has clock_gettime')
 206       cdata.set('HAVE_CLOCK_GETTIME', 1)
 207     endif
 208   else
 209     cdata.set('HAVE_CLOCK_GETTIME', 1)
 210   endif
 211 endif
 212
 213 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 214 # building with MSVC
 215 if cc.get_id() == 'msvc'
 216   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 217 else
 218   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 219 endif
 220
 221 # -------------------------------------------------------------------------------------
 222 # config.h things needed by libcheck (FIXME: move into the libcheck meson.build) (tpm)
 223 # -------------------------------------------------------------------------------------
 224 # FIXME: check if it is _getpid or getpid on windows (tpm)
 225 if cc.has_function('getpid', prefix : '#include <sys/types.h>\n#include <unistd.h>')
 226   cdata.set('HAVE_GETPID', 1)
 227 elif cc.has_function('_getpid', prefix : '#include <process.h>')
 228   cdata.set('HAVE__GETPID', 1)
 229 endif
 230 # FIXME: check for _strdup() but how/where and with what includes? (windows?) (tpm)
 231 if cc.has_function('strdup', prefix : '#include <string.h>')
 232   cdata.set('HAVE_DECL_STRDUP', 1)
 233 elif cc.has_function('_strdup', prefix : '#include <string.h>')
 234   cdata.set('HAVE__STRDUP', 1)
 235 endif
 236 if cc.has_function('mkstemp', prefix : '#include <stdlib.h>')
 237   cdata.set('HAVE_MKSTEMP', 1)
 238 endif
 239 if host_machine.system() != 'windows'
 240   cdata.set('HAVE_FORK', 1)
 241 else
 242   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 243   cdata.set('HAVE_FORK', 0)
 244 endif
 245 if cc.has_function('alarm', prefix : '#include <unistd.h>')
 246   cdata.set('HAVE_ALARM', 1)
 247 endif
 248 if cc.has_function('localtime_r', prefix : '#include <time.h>')
 249   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 250 endif
 251 if cc.has_function('strsignal', prefix : '#include <string.h>')
 252   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 253 endif
 254
 255 configure_file(input : 'config.h.meson',
 256   output : 'config.h',
 257   configuration : cdata)
 258
 259
 260 configinc = include_directories('.')
 261 libsinc = include_directories('libs')
 262 privinc = include_directories('gst')
 263
 264 # Find dependencies
 265 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
 266 gobject_dep = dependency('gobject-2.0')
 267 gmodule_dep = dependency('gmodule-2.0')
 268 if host_machine.system() == 'windows'
 269     gio_dep = dependency('gio-2.0')
 270 else
 271     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
 272 endif
 273
 274 mathlib = cc.find_library('m', required : false)
 275 rt_lib = cc.find_library('rt', required : false) # clock_gettime
 276
 277 # Platform deps; only ws2_32 for now
 278 platform_deps = []
 279 if host_machine.system() == 'windows'
 280   platform_deps = [cc.find_library('ws2_32')]
 281 endif
 282
 283 gir = find_program('g-ir-scanner', required : false)
 284 gnome = import('gnome')
 285
 286 # Fixme, not very elegant.
 287 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 288
 289 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**); gst_init(NULL,NULL);' ]
 290 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 291
 292 gst_c_args = ['-DHAVE_CONFIG_H']
 293 if libtype == 'static'
 294   gst_c_args += ['-DGST_STATIC_COMPILATION']
 295 endif
 296
 297 subdir('gst')
 298 subdir('libs')
 299 subdir('plugins')
 300 subdir('tools')
 301 subdir('pkgconfig')
 302 subdir('tests')
 303
 304 gtkdoc = find_program('gtkdoc-scan', required : false)
 305 if build_machine.system() != 'windows'
 306   if gtkdoc.found()
 307     subdir('docs')
 308   else
 309     message('Not building documentation as gtk-doc was not found')
 310   endif
 311 else
 312   message('Disabling gtk-doc while building on Windows')
 313 endif
 314 subdir('po')
 315
 316 python3 = find_program('python3')
 317 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')