meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 libexecdir = get_option('libexecdir')
  32 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  33
  34 cc = meson.get_compiler('c')
  35
  36 # Ignore several spurious warnings for things gstreamer does very commonly
  37 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39 # NOTE: Only add warnings here if you are sure they're spurious
  40 if cc.get_id() == 'msvc'
  41   add_project_arguments(
  42       '/wd4018', # implicit signed/unsigned conversion
  43       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  44       '/wd4244', # lossy type conversion (e.g. double -> int)
  45       '/wd4305', # truncating type conversion (e.g. double -> float)
  46       language : 'c')
  47 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  48   # FIXME: Add an option for this if people ask for it
  49   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  50 endif
  51
  52 # Symbol visibility
  53 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  54 if have_visibility_hidden
  55   add_project_arguments('-fvisibility=hidden', language: 'c')
  56 endif
  57
  58 # Disable strict aliasing
  59 if cc.has_argument('-fno-strict-aliasing')
  60   add_project_arguments('-fno-strict-aliasing', language: 'c')
  61 endif
  62
  63 # Define G_DISABLE_DEPRECATED for development versions
  64 if gst_version_is_dev
  65   message('Disabling deprecated GLib API')
  66   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  67 endif
  68
  69 cast_checks = get_option('gobject-cast-checks')
  70 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  71   message('Disabling GLib cast checks')
  72   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  73 endif
  74
  75 glib_asserts = get_option('glib-asserts')
  76 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  77   message('Disabling GLib asserts')
  78   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  79 endif
  80
  81 glib_checks = get_option('glib-checks')
  82 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  83   message('Disabling GLib checks')
  84   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  85 endif
  86
  87 cdata = configuration_data()
  88 cdata.set_quoted('GST_API_VERSION', apiversion)
  89 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  90 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  91 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  92 cdata.set_quoted('GST_API_VERSION', '1.0')
  93 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  94 cdata.set_quoted('GST_LICENSE', 'LGPL')
  95 cdata.set_quoted('PACKAGE', 'gstreamer')
  96 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  97 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  98 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  99 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 100 cdata.set_quoted('PACKAGE_URL', '')
 101 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 102 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 103 cdata.set_quoted('VERSION', gst_version)
 104 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 105 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 106 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 107   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 108 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 109
 110 mem_align_opt = get_option('memory-alignment')
 111 if mem_align_opt == 'malloc'
 112   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 113 elif mem_align_opt == 'pagesize'
 114   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 115 else
 116   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 117 endif
 118
 119 if ['darwin', 'ios'].contains(host_system)
 120   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 121 endif
 122
 123 if gst_version_nano > 0
 124     # Have GST_ERROR message printed when running from git
 125     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 126 else
 127     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 128 endif
 129
 130 # GStreamer package name and origin url
 131 gst_package_name = get_option('package-name')
 132 if gst_package_name == ''
 133   if gst_version_nano == 0
 134     gst_package_name = 'GStreamer source release'
 135   elif gst_version_nano == 1
 136     gst_package_name = 'GStreamer git'
 137   else
 138     gst_package_name = 'GStreamer prerelease'
 139   endif
 140 endif
 141 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 142 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 143
 144 # These are only needed/used by the ABI tests
 145 host_defines = [
 146   [ 'x86', 'HAVE_CPU_I386' ],
 147   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 148   [ 'arm', 'HAVE_CPU_ARM' ],
 149   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 150   [ 'mips', 'HAVE_CPU_MIPS' ],
 151   [ 'powerpc', 'HAVE_CPU_PPC' ],
 152   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 153   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 154   [ 'sparc', 'HAVE_CPU_SPARC' ],
 155   [ 'ia64', 'HAVE_CPU_IA64' ],
 156   [ 'hppa', 'HAVE_CPU_HPPA' ],
 157   [ 'm68k', 'HAVE_CPU_M68K' ],
 158   [ 's390', 'HAVE_CPU_S390' ],
 159 ]
 160 foreach h : host_defines
 161   if h.get(0) == host_machine.cpu()
 162     cdata.set(h.get(1), 1)
 163   endif
 164 endforeach
 165 # FIXME: should really be called HOST_CPU or such
 166 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 167
 168 check_headers = [
 169   'dlfcn.h',
 170   'inttypes.h',
 171   'memory.h',
 172   'poll.h',
 173   'stdint.h',
 174   'stdio_ext.h',
 175   'strings.h',
 176   'string.h',
 177   'sys/param.h',
 178   'sys/poll.h',
 179   'sys/prctl.h',
 180   'sys/socket.h',
 181   'sys/stat.h',
 182   'sys/times.h',
 183   'sys/time.h',
 184   'sys/types.h',
 185   'sys/utsname.h',
 186   'sys/wait.h',
 187   'ucontext.h',
 188   'unistd.h',
 189   'valgrind/valgrind.h',
 190   'sys/resource.h',
 191 ]
 192
 193 if host_system == 'windows'
 194   check_headers += ['winsock2.h']
 195 endif
 196
 197 foreach h : check_headers
 198   if cc.has_header(h)
 199     define = 'HAVE_' + h.underscorify().to_upper()
 200     cdata.set(define, 1)
 201   endif
 202 endforeach
 203
 204 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 205   cdata.set('HAVE_TM_GMTOFF', 1)
 206 endif
 207
 208 check_functions = [
 209   'gmtime_r',
 210   'sigaction',
 211   'getrusage',
 212   'fseeko',
 213   'ftello',
 214   'poll',
 215   'ppoll',
 216   'pselect',
 217   'getpagesize',
 218   'clock_gettime',
 219   # These are needed by libcheck
 220   'getline',
 221   'mkstemp',
 222   'alarm',
 223   'gettimeofday',
 224 ]
 225
 226 foreach f : check_functions
 227   if cc.has_function(f)
 228     define = 'HAVE_' + f.underscorify().to_upper()
 229     cdata.set(define, 1)
 230   endif
 231 endforeach
 232
 233 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 234   cdata.set('HAVE_LOCALTIME_R', 1)
 235   # Needed by libcheck
 236   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 237 endif
 238
 239 if cc.links('''#include <pthread.h>
 240                int main() {
 241                  pthread_setname_np("example"); return 0;
 242                }''', name : 'pthread_setname_np(const char*)')
 243   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 244 endif
 245
 246 # Check for posix timers and the monotonic clock
 247 time_prefix = '#include <time.h>\n'
 248 if cdata.has('HAVE_UNISTD_H')
 249   time_prefix += '#include <unistd.h>'
 250 endif
 251
 252 posix_timers_src = time_prefix + '''
 253 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 254 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 255 #endif
 256 '''
 257 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 258   cdata.set('HAVE_POSIX_TIMERS', 1)
 259 endif
 260
 261 monotonic_clock_src = time_prefix + '''
 262 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 263 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 264 #endif
 265 '''
 266 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 267   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 268 endif
 269
 270 # Check for __uint128_t (gcc) by checking for 128-bit division
 271 uint128_t_src = '''int main() {
 272 static __uint128_t v1 = 100;
 273 static __uint128_t v2 = 10;
 274 static __uint128_t u;
 275 u = v1 / v2;
 276 }'''
 277 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 278   cdata.set('HAVE_UINT128_T', 1)
 279 endif
 280
 281 # All supported platforms have long long now
 282 cdata.set('HAVE_LONG_LONG', 1)
 283
 284 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 285 # building with MSVC
 286 if cc.get_id() == 'msvc'
 287   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 288 else
 289   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 290 endif
 291
 292 # -------------------------------------------------------------------------------------
 293 # config.h things needed by libcheck
 294 # -------------------------------------------------------------------------------------
 295 if cc.has_function('getpid')
 296   cdata.set('HAVE_GETPID', 1)
 297 elif host_system == 'windows' and cc.has_function('_getpid')
 298   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 299   cdata.set('HAVE__GETPID', 1)
 300 endif
 301 if cc.has_function('strdup')
 302   cdata.set('HAVE_DECL_STRDUP', 1)
 303 elif host_system == 'windows' and cc.has_function('_strdup')
 304   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 305 endif
 306 if host_system != 'windows'
 307   cdata.set('HAVE_FORK', 1)
 308 else
 309   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 310   cdata.set('HAVE_FORK', 0)
 311 endif
 312 if cc.has_function('strsignal')
 313   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 314 endif
 315 # Check for availability of types
 316 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 317   cdata.set('clockid_t', 'int')
 318 endif
 319 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 320   cdata.set('timer_t', 'int')
 321 endif
 322 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 323                       prefix : '#include <time.h>')
 324   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 325 endif
 326 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 327                       prefix : '#include <time.h>')
 328   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 329 endif
 330
 331 # Platform deps; only ws2_32 and execinfo for now
 332 platform_deps = []
 333 if host_system == 'windows'
 334   platform_deps = [cc.find_library('ws2_32')]
 335 endif
 336
 337 backtrace_deps = []
 338 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 339 dw_dep = dependency('libdw', required: get_option('libunwind'))
 340 backtrace_deps = [unwind_dep, dw_dep]
 341 if unwind_dep.found()
 342   cdata.set('HAVE_UNWIND', 1)
 343   if dw_dep.found()
 344     cdata.set('HAVE_DW', 1)
 345   else
 346     message('Support for backtraces is partial only.')
 347   endif
 348 else
 349   if cc.has_function('backtrace')
 350     cdata.set('HAVE_BACKTRACE', 1)
 351   else
 352       message('NO backtraces support.')
 353   endif
 354 endif
 355
 356 if cc.has_header('execinfo.h')
 357   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 358     cdata.set('HAVE_BACKTRACE', 1)
 359   else
 360     execinfo_dep = cc.find_library('execinfo', required : false)
 361     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 362       cdata.set('HAVE_BACKTRACE', 1)
 363       platform_deps += execinfo_dep
 364     endif
 365   endif
 366 endif
 367
 368 gst_debug = get_option('gst_debug')
 369 if not gst_debug
 370   add_project_arguments(['-Wno-unused'], language: 'c')
 371 endif
 372
 373 warning_flags = [
 374   '-Wmissing-declarations',
 375   '-Wmissing-prototypes',
 376   '-Wredundant-decls',
 377   '-Wundef',
 378   '-Wwrite-strings',
 379   '-Wformat',
 380   '-Wformat-nonliteral',
 381   '-Wformat-security',
 382   '-Wold-style-definition',
 383   '-Winit-self',
 384   '-Wmissing-include-dirs',
 385   '-Waddress',
 386   '-Waggregate-return',
 387   '-Wno-multichar',
 388   '-Wnested-externs',
 389   '-Wdeclaration-after-statement',
 390   '-Wvla',
 391   '-Wpointer-arith',
 392 ]
 393
 394 foreach extra_arg : warning_flags
 395   if cc.has_argument (extra_arg)
 396     add_project_arguments([extra_arg], language: 'c')
 397   endif
 398 endforeach
 399
 400 # Used by the gstutils test
 401 gmp_dep = cc.find_library('gmp', required : false)
 402 cdata.set('HAVE_GMP', gmp_dep.found())
 403 gsl_dep = cc.find_library('gsl', required : false)
 404 gslcblas_dep = cc.find_library('gslcblas', required : false)
 405 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 406 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 407
 408 # Used by gstinfo.c
 409 dl_dep = cc.find_library('dl', required : false)
 410 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 411 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 412 cdata.set('USE_POISONING', get_option('poisoning'))
 413
 414 configinc = include_directories('.')
 415 libsinc = include_directories('libs')
 416 privinc = include_directories('gst')
 417
 418 # Find dependencies
 419 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 420   fallback: ['glib', 'libglib_dep'])
 421 gobject_dep = dependency('gobject-2.0',
 422   fallback: ['glib', 'libgobject_dep'])
 423 gmodule_dep = dependency('gmodule-2.0',
 424   fallback: ['glib', 'libgmodule_dep'])
 425 if host_system == 'windows'
 426     gio_dep = dependency('gio-2.0',
 427         fallback: ['glib', 'libgio_dep'])
 428 else
 429     gio_dep = [dependency('gio-2.0',
 430                   fallback: ['glib', 'libgio_dep']),
 431                dependency('gio-unix-2.0',
 432                   fallback: ['glib', 'libgio_dep'])]
 433 endif
 434
 435 mathlib = cc.find_library('m', required : false)
 436 # Needed for timer_create/settime/delete
 437 # Also provides clock_gettime in glibc < 2.17
 438 rt_lib = cc.find_library('rt', required : false)
 439
 440 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 441 gnome = import('gnome')
 442
 443 build_gir = gir.found() and not meson.is_cross_build()
 444
 445 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 446     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 447     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 448     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 449     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 450     'gst_init(NULL,NULL);' ]
 451
 452 gst_c_args = ['-DHAVE_CONFIG_H']
 453
 454 # FIXME: This is only needed on windows and probably breaks when
 455 # default_library = 'both'. We should add this flag to static_c_args instead
 456 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 457 if get_option('default_library') == 'static'
 458   gst_c_args += ['-DGST_STATIC_COMPILATION']
 459 endif
 460
 461 # Used in gst/parse/meson.build and below
 462 python3 = import('python3').find_python()
 463
 464 bashcomp_option = get_option('bash-completion')
 465 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 466 bash_completions_dir = ''
 467 bash_helpers_dir = ''
 468
 469 bashcomp_found = false
 470 if bashcomp_dep.found()
 471   bashcomp_found = true
 472   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 473   if bash_completions_dir == ''
 474     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 475     if bashcomp_option.enabled()
 476       error(msg)
 477     else
 478       message(msg)
 479     endif
 480     bashcomp_found = false
 481   endif
 482
 483   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 484   if bash_helpers_dir == ''
 485     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 486     if bashcomp_option.enabled()
 487       error(msg)
 488     else
 489       message(msg)
 490     endif
 491     bashcomp_found = false
 492   endif
 493 endif
 494
 495 subdir('gst')
 496 subdir('libs')
 497 subdir('plugins')
 498 if not get_option('tools').disabled()
 499   subdir('tools')
 500 endif
 501 subdir('pkgconfig')
 502 subdir('tests')
 503 subdir('data')
 504
 505 # xgettext is optional (on Windows for instance)
 506 if find_program('xgettext', required : get_option('nls')).found()
 507   cdata.set('ENABLE_NLS', 1)
 508   subdir('po')
 509 endif
 510
 511 configure_file(output : 'config.h', configuration : cdata)
 512
 513 if build_machine.system() == 'windows'
 514   message('Disabling gtk-doc while building on Windows')
 515 else
 516   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 517     subdir('docs')
 518   else
 519     message('Not building documentation as gtk-doc was not found')
 520   endif
 521 endif
 522
 523 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 524
 525 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))