meson.build

   1 project(
   2     'libxkbcommon',
   3     'c',
   4     version: '0.8.3',
   5     default_options: [
   6         'c_std=c99',
   7         'warning_level=2',
   8         'b_lundef=true',
   9     ],
  10     meson_version : '>= 0.41.0',
  11 )
  12 pkgconfig = import('pkgconfig')
  13 cc = meson.get_compiler('c')
  14
  15
  16 # Compiler flags.
  17 foreach cflag: [
  18     '-fvisibility=hidden',
  19     '-fno-strict-aliasing',
  20     '-fsanitize-undefined-trap-on-error',
  21     '-Wextra',
  22     '-Wno-unused-parameter',
  23     '-Wno-missing-field-initializers',
  24     '-Wpointer-arith',
  25     '-Wmissing-declarations',
  26     '-Wformat=2',
  27     '-Wstrict-prototypes',
  28     '-Wmissing-prototypes',
  29     '-Wnested-externs',
  30     '-Wbad-function-cast',
  31     '-Wshadow',
  32     '-Wlogical-op',
  33     '-Wdate-time',
  34     '-Wwrite-strings',
  35     '-Wno-documentation-deprecated-sync',
  36 ]
  37     if cc.has_argument(cflag)
  38         add_project_arguments(cflag, language: 'c')
  39     endif
  40 endforeach
  41
  42
  43 # The XKB config root.
  44 XKBCONFIGROOT = get_option('xkb-config-root')
  45 if XKBCONFIGROOT == ''
  46     xkeyboard_config_dep = dependency('xkeyboard-config', required: false)
  47     if xkeyboard_config_dep.found()
  48         XKBCONFIGROOT = xkeyboard_config_dep.get_pkgconfig_variable('xkb_base')
  49     else
  50         XKBCONFIGROOT = join_paths(get_option('prefix'), get_option('datadir'), 'X11', 'xkb')
  51   endif
  52 endif
  53
  54
  55 # The X locale directory for compose.
  56 XLOCALEDIR = get_option('x-locale-root')
  57 if XLOCALEDIR == ''
  58     XLOCALEDIR = join_paths(get_option('prefix'), get_option('datadir'), 'X11', 'locale')
  59 endif
  60
  61
  62 # config.h.
  63 configh_data = configuration_data()
  64 configh_data.set('_GNU_SOURCE', 1)
  65 configh_data.set_quoted('DFLT_XKB_CONFIG_ROOT', XKBCONFIGROOT)
  66 configh_data.set_quoted('XLOCALEDIR', XLOCALEDIR)
  67 configh_data.set_quoted('DEFAULT_XKB_RULES', get_option('default-rules'))
  68 configh_data.set_quoted('DEFAULT_XKB_MODEL', get_option('default-model'))
  69 configh_data.set_quoted('DEFAULT_XKB_LAYOUT', get_option('default-layout'))
  70 if get_option('default-variant') != ''
  71     configh_data.set_quoted('DEFAULT_XKB_VARIANT', get_option('default-variant'))
  72 endif
  73 if get_option('default-options') != ''
  74     configh_data.set_quoted('DEFAULT_XKB_OPTIONS', get_option('default-options'))
  75 endif
  76 if cc.links('int main(){if(__builtin_expect(1<0,0)){}}', name: '__builtin_expect')
  77     configh_data.set('HAVE___BUILTIN_EXPECT', 1)
  78 endif
  79 if cc.links('int main(){__builtin_popcount(1);}', name: '__builtin_popcount')
  80     configh_data.set('HAVE___BUILTIN_POPCOUNT', 1)
  81 endif
  82 if cc.has_header_symbol('unistd.h', 'eaccess', prefix: '#define _GNU_SOURCE')
  83     configh_data.set('HAVE_EACCESS', 1)
  84 endif
  85 if cc.has_header_symbol('unistd.h', 'euidaccess', prefix: '#define _GNU_SOURCE')
  86     configh_data.set('HAVE_EUIDACCESS', 1)
  87 endif
  88 if cc.has_header_symbol('sys/mman.h', 'mmap')
  89     configh_data.set('HAVE_MMAP', 1)
  90 endif
  91 if cc.has_header_symbol('stdlib.h', 'mkostemp', prefix: '#define _GNU_SOURCE')
  92     configh_data.set('HAVE_MKOSTEMP', 1)
  93 endif
  94 if cc.has_header_symbol('fcntl.h', 'posix_fallocate', prefix: '#define _GNU_SOURCE')
  95     configh_data.set('HAVE_POSIX_FALLOCATE', 1)
  96 endif
  97 if cc.has_header_symbol('stdlib.h', 'secure_getenv', prefix: '#define _GNU_SOURCE')
  98     configh_data.set('HAVE_SECURE_GETENV', 1)
  99 elif cc.has_header_symbol('stdlib.h', '__secure_getenv', prefix: '#define _GNU_SOURCE')
 100     configh_data.set('HAVE___SECURE_GETENV', 1)
 101 else
 102     message('C library does not support secure_getenv, using getenv instead')
 103 endif
 104 configure_file(output: 'config.h', configuration: configh_data)
 105 add_project_arguments('-include', 'config.h', language: 'c')
 106
 107
 108 # Supports -Wl,--version-script?
 109 have_version_script = cc.links(
 110     'int main(){}',
 111     args: '-Wl,--version-script=' + join_paths(meson.source_root(), 'xkbcommon.map'),
 112     name: '-Wl,--version-script',
 113 )
 114
 115
 116 # libxkbcommon.
 117 # Note: we use some yacc extensions, which work with either GNU bison
 118 # (preferred) or byacc. Other yacc's may or may not work.
 119 yacc = find_program('bison', 'byacc')
 120 yacc_gen = generator(
 121     yacc,
 122     output: ['@BASENAME@.c', '@BASENAME@.h'],
 123     arguments: ['@INPUT@', '--defines=@OUTPUT1@', '--output=@OUTPUT0@', '-p _xkbcommon_'],
 124 )
 125 libxkbcommon_sources = [
 126     'src/compose/parser.c',
 127     'src/compose/parser.h',
 128     'src/compose/paths.c',
 129     'src/compose/paths.h',
 130     'src/compose/state.c',
 131     'src/compose/table.c',
 132     'src/compose/table.h',
 133     'src/xkbcomp/action.c',
 134     'src/xkbcomp/action.h',
 135     'src/xkbcomp/ast.h',
 136     'src/xkbcomp/ast-build.c',
 137     'src/xkbcomp/ast-build.h',
 138     'src/xkbcomp/compat.c',
 139     'src/xkbcomp/expr.c',
 140     'src/xkbcomp/expr.h',
 141     'src/xkbcomp/include.c',
 142     'src/xkbcomp/include.h',
 143     'src/xkbcomp/keycodes.c',
 144     'src/xkbcomp/keymap.c',
 145     'src/xkbcomp/keymap-dump.c',
 146     'src/xkbcomp/keywords.c',
 147     yacc_gen.process('src/xkbcomp/parser.y'),
 148     'src/xkbcomp/parser-priv.h',
 149     'src/xkbcomp/rules.c',
 150     'src/xkbcomp/rules.h',
 151     'src/xkbcomp/scanner.c',
 152     'src/xkbcomp/symbols.c',
 153     'src/xkbcomp/types.c',
 154     'src/xkbcomp/vmod.c',
 155     'src/xkbcomp/vmod.h',
 156     'src/xkbcomp/xkbcomp.c',
 157     'src/xkbcomp/xkbcomp-priv.h',
 158     'src/atom.c',
 159     'src/atom.h',
 160     'src/context.c',
 161     'src/context.h',
 162     'src/context-priv.c',
 163     'src/darray.h',
 164     'src/keysym.c',
 165     'src/keysym.h',
 166     'src/keysym-utf.c',
 167     'src/ks_tables.h',
 168     'src/keymap.c',
 169     'src/keymap.h',
 170     'src/keymap-priv.c',
 171     'src/scanner-utils.h',
 172     'src/state.c',
 173     'src/text.c',
 174     'src/text.h',
 175     'src/utf8.c',
 176     'src/utf8.h',
 177     'src/utils.c',
 178     'src/utils.h',
 179 ]
 180 libxkbcommon_link_args = []
 181 if have_version_script
 182     libxkbcommon_link_args += '-Wl,--version-script=' + join_paths(meson.source_root(), 'xkbcommon.map')
 183 endif
 184 libxkbcommon = library(
 185     'xkbcommon',
 186     'xkbcommon/xkbcommon.h',
 187     libxkbcommon_sources,
 188     link_args: libxkbcommon_link_args,
 189     link_depends: 'xkbcommon.map',
 190     version: '0.0.0',
 191     install: true,
 192     include_directories: include_directories('src'),
 193 )
 194 install_headers(
 195     'xkbcommon/xkbcommon.h',
 196     'xkbcommon/xkbcommon-compat.h',
 197     'xkbcommon/xkbcommon-compose.h',
 198     'xkbcommon/xkbcommon-keysyms.h',
 199     'xkbcommon/xkbcommon-names.h',
 200     subdir: 'xkbcommon',
 201 )
 202 pkgconfig.generate(
 203     name: 'xkbcommon',
 204     filebase: 'xkbcommon',
 205     libraries: libxkbcommon,
 206     version: meson.project_version(),
 207     description: 'XKB API common to servers and clients',
 208 )
 209
 210
 211 # libxkbcommon-x11.
 212 if get_option('enable-x11')
 213     xcb_dep = dependency('xcb', version: '>=1.10', required: false)
 214     xcb_xkb_dep = dependency('xcb-xkb', version: '>=1.10', required: false)
 215     if not xcb_dep.found() or not xcb_xkb_dep.found()
 216         error('''X11 support requires xcb-xkb >= 1.10 which was not found.
 217 You can disable X11 support with -Denable-x11=false.''')
 218     endif
 219
 220     libxkbcommon_x11_internal = static_library(
 221         'xkbcommon-x11-internal',
 222         'src/x11/keymap.c',
 223         'src/x11/state.c',
 224         'src/x11/util.c',
 225         'src/x11/x11-priv.h',
 226         'src/context.h',
 227         'src/context-priv.c',
 228         'src/keymap.h',
 229         'src/keymap-priv.c',
 230         'src/atom.h',
 231         'src/atom.c',
 232         include_directories: include_directories('src'),
 233         link_with: libxkbcommon,
 234         dependencies: [
 235             xcb_dep,
 236             xcb_xkb_dep,
 237         ],
 238     )
 239     libxkbcommon_x11_link_args = []
 240     if have_version_script
 241         libxkbcommon_x11_link_args += '-Wl,--version-script=' + join_paths(meson.source_root(), 'xkbcommon-x11.map')
 242     endif
 243     libxkbcommon_x11 = library(
 244         'xkbcommon-x11',
 245         'xkbcommon/xkbcommon-x11.h',
 246         link_whole: libxkbcommon_x11_internal,
 247         link_args: libxkbcommon_x11_link_args,
 248         link_depends: 'xkbcommon-x11.map',
 249         version: '0.0.0',
 250         install: true,
 251     )
 252     install_headers(
 253         'xkbcommon/xkbcommon-x11.h',
 254         subdir: 'xkbcommon',
 255     )
 256     pkgconfig.generate(
 257         name: 'xkbcommon-x11',
 258         filebase: 'xkbcommon-x11',
 259         libraries: libxkbcommon_x11,
 260         version: meson.project_version(),
 261         description: 'XKB API common to servers and clients - X11 support',
 262         requires: ['xkbcommon'],
 263         requires_private: ['xcb>=1.10', 'xcb-xkb>=1.10'],
 264     )
 265 endif
 266
 267
 268 # Tests
 269 test_env = environment()
 270 test_env.set('XKB_LOG_LEVEL', 'debug')
 271 test_env.set('XKB_LOG_VERBOSITY', '10')
 272 test_env.set('top_srcdir', meson.source_root())
 273 test_env.set('MALLOC_PERTURB_', '15')
 274 test_env.set('MallocPreScribble', '1')
 275 test_env.set('MallocScribble', '1')
 276 # Some tests need to use unexported symbols, so we link them against
 277 # an internal copy of libxkbcommon with all symbols exposed.
 278 libxkbcommon_test_internal = static_library(
 279     'xkbcommon-test-internal',
 280     'test/common.c',
 281     'test/test.h',
 282     'test/evdev-scancodes.h',
 283     libxkbcommon_sources,
 284     include_directories: include_directories('src'),
 285 )
 286 test_dep = declare_dependency(
 287     include_directories: include_directories('src'),
 288     link_with: libxkbcommon_test_internal,
 289 )
 290 if get_option('enable-x11')
 291     x11_test_dep = declare_dependency(
 292         link_with: libxkbcommon_x11_internal,
 293         dependencies: [
 294             test_dep,
 295             xcb_dep,
 296             xcb_xkb_dep,
 297         ],
 298     )
 299 endif
 300 test(
 301     'keysym',
 302     executable('test-keysym', 'test/keysym.c', dependencies: test_dep),
 303     env: test_env,
 304 )
 305 test(
 306     'keymap',
 307     executable('test-keymap', 'test/keymap.c', dependencies: test_dep),
 308     env: test_env,
 309 )
 310 test(
 311     'filecomp',
 312     executable('test-filecomp', 'test/filecomp.c', dependencies: test_dep),
 313     env: test_env,
 314 )
 315 test(
 316     'context',
 317     executable('test-context', 'test/context.c', dependencies: test_dep),
 318     env: test_env,
 319 )
 320 test(
 321     'rules-file',
 322     executable('test-rules-file', 'test/rules-file.c', dependencies: test_dep),
 323     env: test_env,
 324 )
 325 test(
 326     'stringcomp',
 327     executable('test-stringcomp', 'test/stringcomp.c', dependencies: test_dep),
 328     env: test_env,
 329 )
 330 test(
 331     'buffercomp',
 332     executable('test-buffercomp', 'test/buffercomp.c', dependencies: test_dep),
 333     env: test_env,
 334 )
 335 test(
 336     'log',
 337     executable('test-log', 'test/log.c', dependencies: test_dep),
 338     env: test_env,
 339 )
 340 test(
 341     'atom',
 342     executable('test-atom', 'test/atom.c', dependencies: test_dep),
 343     env: test_env,
 344 )
 345 test(
 346     'utf8',
 347     executable('test-utf8', 'test/utf8.c', dependencies: test_dep),
 348     env: test_env,
 349 )
 350 test(
 351     'state',
 352     executable('test-state', 'test/state.c', dependencies: test_dep),
 353     env: test_env,
 354 )
 355 test(
 356     'keyseq',
 357     executable('test-keyseq', 'test/keyseq.c', dependencies: test_dep),
 358     env: test_env,
 359 )
 360 test(
 361     'rulescomp',
 362     executable('test-rulescomp', 'test/rulescomp.c', dependencies: test_dep),
 363     env: test_env,
 364 )
 365 test(
 366     'compose',
 367     executable('test-compose', 'test/compose.c', dependencies: test_dep),
 368     env: test_env,
 369 )
 370 test(
 371     'symbols-leak-test',
 372     find_program('test/symbols-leak-test.bash'),
 373     env: test_env,
 374 )
 375 if get_option('enable-x11')
 376     test(
 377         'x11',
 378         executable('test-x11', 'test/x11.c', dependencies: x11_test_dep),
 379         env: test_env,
 380     )
 381     # test/x11comp is meant to be run, but it is (temporarily?) disabled.
 382     # See: https://github.com/xkbcommon/libxkbcommon/issues/30
 383     executable('test-x11comp', 'test/x11comp.c', dependencies: x11_test_dep)
 384 endif
 385
 386
 387 # Fuzzing target programs.
 388 executable('fuzz-keymap', 'fuzz/keymap/target.c', dependencies: test_dep)
 389 executable('fuzz-compose', 'fuzz/compose/target.c', dependencies: test_dep)
 390
 391
 392 # Demo programs.
 393 executable('rmlvo-to-kccgst', 'test/rmlvo-to-kccgst.c', dependencies: test_dep)
 394 executable('rmlvo-to-keymap', 'test/rmlvo-to-keymap.c', dependencies: test_dep)
 395 executable('print-compiled-keymap', 'test/print-compiled-keymap.c', dependencies: test_dep)
 396 if cc.has_header('linux/input.h')
 397     executable('interactive-evdev', 'test/interactive-evdev.c', dependencies: test_dep)
 398 endif
 399 if get_option('enable-x11')
 400     executable('interactive-x11', 'test/interactive-x11.c', dependencies: x11_test_dep)
 401 endif
 402 if get_option('enable-wayland')
 403     wayland_client_dep = dependency('wayland-client', version: '>=1.2.0', required: false)
 404     wayland_protocols_dep = dependency('wayland-protocols', version: '>=1.7', required: false)
 405     wayland_scanner_dep = dependency('wayland-scanner', required: false)
 406     if not wayland_client_dep.found() or not wayland_protocols_dep.found() or not wayland_scanner_dep.found()
 407         error('''The Wayland demo programs require wayland-client >= 1.2.0, wayland-protocols >= 1.7 which were not found.
 408 You can disable the Wayland demo programs with -Denable-wayland=false.''')
 409     endif
 410
 411     wayland_scanner = find_program(wayland_scanner_dep.get_pkgconfig_variable('wayland_scanner'))
 412     wayland_scanner_code_gen = generator(
 413         wayland_scanner,
 414         output: '@BASENAME@-protocol.c',
 415         arguments: ['code', '@INPUT@', '@OUTPUT@'],
 416     )
 417     wayland_scanner_client_header_gen = generator(
 418         wayland_scanner,
 419         output: '@BASENAME@-client-protocol.h',
 420         arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
 421     )
 422     wayland_protocols_datadir = wayland_protocols_dep.get_pkgconfig_variable('pkgdatadir')
 423     xdg_shell_xml = join_paths(wayland_protocols_datadir, 'unstable/xdg-shell/xdg-shell-unstable-v6.xml')
 424     xdg_shell_sources = [
 425         wayland_scanner_code_gen.process(xdg_shell_xml),
 426         wayland_scanner_client_header_gen.process(xdg_shell_xml),
 427     ]
 428     executable('interactive-wayland', 'test/interactive-wayland.c', xdg_shell_sources, dependencies: [test_dep, wayland_client_dep])
 429 endif
 430
 431 # xkeyboard-config "verifier"
 432 xkct_config = configuration_data()
 433 xkct_config.set('MESON_BUILD_ROOT', meson.build_root())
 434 xkct_config.set('XKB_CONFIG_ROOT', XKBCONFIGROOT)
 435 configure_file(input: 'test/xkeyboard-config-test.py.in',
 436                output: 'xkeyboard-config-test',
 437                configuration: xkct_config,
 438                install: false)
 439
 440
 441 # Benchmarks.
 442 libxkbcommon_bench_internal = static_library(
 443     'xkbcommon-bench-internal',
 444     'bench/bench.c',
 445     'bench/bench.h',
 446     link_with: libxkbcommon_test_internal,
 447 )
 448 bench_dep = declare_dependency(
 449     include_directories: include_directories('src'),
 450     link_with: libxkbcommon_bench_internal,
 451 )
 452 bench_env = environment()
 453 bench_env.set('top_srcdir', meson.source_root())
 454 benchmark(
 455     'key-proc',
 456     executable('bench-key-proc', 'bench/key-proc.c', dependencies: bench_dep),
 457     env: bench_env,
 458 )
 459 benchmark(
 460     'rules',
 461     executable('bench-rules', 'bench/rules.c', dependencies: bench_dep),
 462     env: bench_env,
 463 )
 464 benchmark(
 465     'rulescomp',
 466     executable('bench-rulescomp', 'bench/rulescomp.c', dependencies: bench_dep),
 467     env: bench_env,
 468 )
 469 benchmark(
 470     'compose',
 471     executable('bench-compose', 'bench/compose.c', dependencies: bench_dep),
 472     env: bench_env,
 473 )
 474
 475
 476 # Documentation.
 477 if get_option('enable-docs')
 478     doxygen = find_program('doxygen', required: false)
 479     if not doxygen.found()
 480         error('''Documentation requires doxygen which was not found.
 481 You can disable the documentation with -Denable-docs=false.''')
 482     endif
 483     doxygen_wrapper = find_program('scripts/doxygen-wrapper')
 484
 485     doxygen_input = [
 486         'README.md',
 487         'doc/doxygen-extra.css',
 488         'doc/quick-guide.md',
 489         'doc/compat.md',
 490         'xkbcommon/xkbcommon.h',
 491         'xkbcommon/xkbcommon-names.h',
 492         'xkbcommon/xkbcommon-x11.h',
 493         'xkbcommon/xkbcommon-compose.h',
 494     ]
 495     doxygen_data = configuration_data()
 496     doxygen_data.set('PACKAGE_NAME', meson.project_name())
 497     doxygen_data.set('PACKAGE_VERSION', meson.project_version())
 498     doxygen_data.set('INPUT', ' '.join(doxygen_input))
 499     doxygen_data.set('OUTPUT_DIRECTORY', meson.build_root())
 500     doxyfile = configure_file(
 501         input: 'doc/Doxyfile.in',
 502         output: 'Doxyfile',
 503         configuration: doxygen_data,
 504     )
 505     # TODO: Meson should provide this.
 506     docdir = join_paths(get_option('datadir'), 'doc', meson.project_name())
 507     custom_target(
 508         'doc',
 509         input: [doxyfile] + doxygen_input,
 510         output: 'html',
 511         command: [doxygen_wrapper, doxygen.path(), join_paths(meson.build_root(), 'Doxyfile'), meson.source_root()],
 512         install: true,
 513         install_dir: docdir,
 514         build_by_default: true,
 515     )
 516 endif