meson.build

   1 project('gstreamer', 'c',
   2   version : '1.19.0.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 datadir = join_paths(prefix, get_option('datadir'))
  32 libexecdir = get_option('libexecdir')
  33 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  34
  35 cc = meson.get_compiler('c')
  36
  37 cdata = configuration_data()
  38
  39 # Ignore several spurious warnings for things gstreamer does very commonly
  40 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  41 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  42 # NOTE: Only add warnings here if you are sure they're spurious
  43 if cc.get_id() == 'msvc'
  44   add_project_arguments(
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50       language : 'c')
  51 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  52   # FIXME: Add an option for this if people ask for it
  53   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  54 endif
  55
  56 # Symbol visibility
  57 have_visibility_hidden = false
  58 if cc.get_id() == 'msvc'
  59   export_define = '__declspec(dllexport) extern'
  60 elif cc.has_argument('-fvisibility=hidden')
  61   add_project_arguments('-fvisibility=hidden', language: 'c')
  62   export_define = 'extern __attribute__ ((visibility ("default")))'
  63   have_visibility_hidden = true
  64 else
  65   export_define = 'extern'
  66 endif
  67
  68 # Passing this through the command line would be too messy
  69 cdata.set('GST_API_EXPORT', export_define)
  70
  71 # Disable strict aliasing
  72 if cc.has_argument('-fno-strict-aliasing')
  73   add_project_arguments('-fno-strict-aliasing', language: 'c')
  74 endif
  75
  76 # Define G_DISABLE_DEPRECATED for development versions
  77 if gst_version_is_dev
  78   message('Disabling deprecated GLib API')
  79   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  80 endif
  81
  82 cast_checks = get_option('gobject-cast-checks')
  83 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  84   message('Disabling GLib cast checks')
  85   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  86 endif
  87
  88 glib_asserts = get_option('glib-asserts')
  89 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  90   message('Disabling GLib asserts')
  91   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  92 endif
  93
  94 glib_checks = get_option('glib-checks')
  95 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  96   message('Disabling GLib checks')
  97   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  98 endif
  99
 100 cdata.set_quoted('GST_API_VERSION', apiversion)
 101 cdata.set_quoted('GST_DATADIR', datadir)
 102 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 103 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 104 cdata.set_quoted('GST_API_VERSION', '1.0')
 105 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 106 cdata.set_quoted('GST_LICENSE', 'LGPL')
 107 cdata.set_quoted('PACKAGE', 'gstreamer')
 108 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 109 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 110 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 111 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 112 cdata.set_quoted('PACKAGE_URL', '')
 113 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 114 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 115 cdata.set_quoted('VERSION', gst_version)
 116 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 117 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 118 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 119   description: 'plugin directory path component, used to find plugins on relocatable builds on windows')
 120 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 121   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 122 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 123
 124 mem_align_opt = get_option('memory-alignment')
 125 if mem_align_opt == 'malloc'
 126   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 127 elif mem_align_opt == 'pagesize'
 128   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 129 else
 130   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 131 endif
 132
 133 if ['darwin', 'ios'].contains(host_system)
 134   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 135 endif
 136
 137 if gst_version_nano > 0
 138     # Have GST_ERROR message printed when running from git
 139     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 140 else
 141     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 142 endif
 143
 144 # GStreamer package name and origin url
 145 gst_package_name = get_option('package-name')
 146 if gst_package_name == ''
 147   if gst_version_nano == 0
 148     gst_package_name = 'GStreamer source release'
 149   elif gst_version_nano == 1
 150     gst_package_name = 'GStreamer git'
 151   else
 152     gst_package_name = 'GStreamer prerelease'
 153   endif
 154 endif
 155 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 156 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 157
 158 # These are only needed/used by the ABI tests
 159 host_defines = [
 160   [ 'x86', 'HAVE_CPU_I386' ],
 161   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 162   [ 'arm', 'HAVE_CPU_ARM' ],
 163   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 164   [ 'mips', 'HAVE_CPU_MIPS' ],
 165   [ 'powerpc', 'HAVE_CPU_PPC' ],
 166   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 167   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 168   [ 'sparc', 'HAVE_CPU_SPARC' ],
 169   [ 'ia64', 'HAVE_CPU_IA64' ],
 170   [ 'hppa', 'HAVE_CPU_HPPA' ],
 171   [ 'm68k', 'HAVE_CPU_M68K' ],
 172   [ 's390', 'HAVE_CPU_S390' ],
 173 ]
 174 foreach h : host_defines
 175   if h.get(0) == host_machine.cpu_family()
 176     cdata.set(h.get(1), 1)
 177   endif
 178 endforeach
 179 # FIXME: should really be called HOST_CPU or such
 180 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 181
 182 check_headers = [
 183   'dlfcn.h',
 184   'inttypes.h',
 185   'memory.h',
 186   'poll.h',
 187   'stdint.h',
 188   'stdio_ext.h',
 189   'strings.h',
 190   'string.h',
 191   'sys/param.h',
 192   'sys/poll.h',
 193   'sys/prctl.h',
 194   'sys/socket.h',
 195   'sys/stat.h',
 196   'sys/times.h',
 197   'sys/time.h',
 198   'sys/types.h',
 199   'sys/utsname.h',
 200   'sys/wait.h',
 201   'ucontext.h',
 202   'unistd.h',
 203   'sys/resource.h',
 204   'sys/uio.h',
 205 ]
 206
 207 if host_system == 'windows'
 208   check_headers += ['winsock2.h']
 209 endif
 210
 211 foreach h : check_headers
 212   if cc.has_header(h)
 213     define = 'HAVE_' + h.underscorify().to_upper()
 214     cdata.set(define, 1)
 215   endif
 216 endforeach
 217
 218 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 219   cdata.set('HAVE_TM_GMTOFF', 1)
 220 endif
 221
 222 check_functions = [
 223   'gmtime_r',
 224   'sigaction',
 225   'getrusage',
 226   'fseeko',
 227   'ftello',
 228   'poll',
 229   'ppoll',
 230   'pselect',
 231   'getpagesize',
 232   'clock_gettime',
 233   'strnlen',
 234   # These are needed by libcheck
 235   'getline',
 236   'mkstemp',
 237   'alarm',
 238   'gettimeofday',
 239 ]
 240
 241 foreach f : check_functions
 242   if cc.has_function(f)
 243     define = 'HAVE_' + f.underscorify().to_upper()
 244     cdata.set(define, 1)
 245   endif
 246 endforeach
 247
 248 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 249   cdata.set('HAVE_LOCALTIME_R', 1)
 250   # Needed by libcheck
 251   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 252 endif
 253
 254 if cc.links('''#include <pthread.h>
 255                int main() {
 256                  pthread_setname_np("example"); return 0;
 257                }''', name : 'pthread_setname_np(const char*)')
 258   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 259 endif
 260 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 261   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 262 endif
 263 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 264   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 265 endif
 266
 267 # Check for futex(2)
 268 if cc.links('''#include <linux/futex.h>
 269                #include <sys/syscall.h>
 270                #include <unistd.h>
 271                int main (int argc, char ** argv) {
 272                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 273                  return 0;
 274                }''', name : 'futex(2) system call')
 275   cdata.set('HAVE_FUTEX', 1)
 276 endif
 277
 278 # Check for posix timers and monotonic clock
 279 time_prefix = '#include <time.h>\n'
 280 if cdata.has('HAVE_UNISTD_H')
 281   time_prefix += '#include <unistd.h>'
 282 endif
 283
 284 posix_timers_src = time_prefix + '''
 285 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 286 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 287 #endif
 288 '''
 289 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 290   cdata.set('HAVE_POSIX_TIMERS', 1)
 291 endif
 292
 293 monotonic_clock_src = time_prefix + '''
 294 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 295 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 296 #endif
 297 '''
 298 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 299   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 300 endif
 301
 302 # Check for __uint128_t (gcc) by checking for 128-bit division
 303 uint128_t_src = '''int main() {
 304 static __uint128_t v1 = 100;
 305 static __uint128_t v2 = 10;
 306 static __uint128_t u;
 307 u = v1 / v2;
 308 }'''
 309 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 310   cdata.set('HAVE_UINT128_T', 1)
 311 endif
 312
 313 # All supported platforms have long long now
 314 cdata.set('HAVE_LONG_LONG', 1)
 315
 316 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 317 # building with MSVC
 318 if cc.get_id() == 'msvc'
 319   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 320 else
 321   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 322 endif
 323
 324 # -------------------------------------------------------------------------------------
 325 # config.h things needed by libcheck
 326 # -------------------------------------------------------------------------------------
 327 if cc.has_function('getpid')
 328   cdata.set('HAVE_GETPID', 1)
 329 elif host_system == 'windows' and cc.has_function('_getpid')
 330   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 331   cdata.set('HAVE__GETPID', 1)
 332 endif
 333 if cc.has_function('strdup')
 334   cdata.set('HAVE_DECL_STRDUP', 1)
 335 elif host_system == 'windows' and cc.has_function('_strdup')
 336   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 337 endif
 338 if host_system != 'windows'
 339   cdata.set('HAVE_FORK', 1)
 340 else
 341   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 342   cdata.set('HAVE_FORK', 0)
 343 endif
 344 if cc.has_function('strsignal')
 345   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 346 endif
 347 # Check for availability of types
 348 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 349   cdata.set('clockid_t', 'int')
 350 endif
 351 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 352   cdata.set('timer_t', 'int')
 353 endif
 354 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 355                       prefix : '#include <time.h>')
 356   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 357 endif
 358 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 359                       prefix : '#include <time.h>')
 360   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 361 endif
 362
 363 # Platform deps; only ws2_32 and execinfo for now
 364 platform_deps = []
 365 if host_system == 'windows'
 366   platform_deps = [cc.find_library('ws2_32')]
 367 endif
 368
 369 building_for_uwp = false
 370 if host_system == 'windows'
 371   # Check whether we're building for UWP apps
 372   code = '''
 373   #include <windows.h>
 374   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 375   #error "Not building for UWP"
 376   #endif'''
 377   if cc.compiles(code, name : 'building for UWP')
 378     building_for_uwp = true
 379   endif
 380 endif
 381
 382 backtrace_deps = []
 383 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 384 dw_dep = dependency('libdw', required: get_option('libdw'))
 385 dbghelp_option = get_option('dbghelp')
 386 if dbghelp_option.enabled() and building_for_uwp
 387   error('DbgHelp is not supported for UWP')
 388 endif
 389 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 390 backtrace_deps = [unwind_dep, dw_dep]
 391 backtrace_source_info = false
 392 backtrace_minimal = false
 393 # MSVC debug stack trace support
 394 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 395   cdata.set('HAVE_DBGHELP', 1)
 396   backtrace_source_info = true
 397 # DWARF stack trace support with libunwind and elf-utils
 398 elif unwind_dep.found()
 399   cdata.set('HAVE_UNWIND', 1)
 400   if dw_dep.found()
 401     cdata.set('HAVE_DW', 1)
 402     backtrace_source_info = true
 403   endif
 404   backtrace_minimal = true
 405 # Basic backtrace() stack trace support
 406 elif cc.has_function('backtrace')
 407   cdata.set('HAVE_BACKTRACE', 1)
 408   backtrace_minimal = true
 409 endif
 410 # Print messages about what was enabled
 411 if not backtrace_source_info
 412   if not backtrace_minimal
 413     message('NO support for stack traces.')
 414   else
 415     message('Minimal support for stack traces, no source info.')
 416   endif
 417 endif
 418
 419 if cc.has_header('execinfo.h')
 420   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 421     cdata.set('HAVE_BACKTRACE', 1)
 422   else
 423     execinfo_dep = cc.find_library('execinfo', required : false)
 424     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 425       cdata.set('HAVE_BACKTRACE', 1)
 426       platform_deps += execinfo_dep
 427     endif
 428   endif
 429 endif
 430
 431 gst_debug = get_option('gst_debug')
 432 if not gst_debug
 433   add_project_arguments(['-Wno-unused'], language: 'c')
 434 endif
 435
 436 warning_flags = [
 437   '-Wmissing-declarations',
 438   '-Wmissing-prototypes',
 439   '-Wredundant-decls',
 440   '-Wundef',
 441   '-Wwrite-strings',
 442   '-Wformat',
 443   '-Wformat-nonliteral',
 444   '-Wformat-security',
 445   '-Wold-style-definition',
 446   '-Winit-self',
 447   '-Wmissing-include-dirs',
 448   '-Waddress',
 449   '-Waggregate-return',
 450   '-Wno-multichar',
 451   '-Wdeclaration-after-statement',
 452   '-Wvla',
 453   '-Wpointer-arith',
 454 ]
 455
 456 foreach extra_arg : warning_flags
 457   if cc.has_argument (extra_arg)
 458     add_project_arguments([extra_arg], language: 'c')
 459   endif
 460 endforeach
 461
 462 # Used by the gstutils test
 463 gmp_dep = cc.find_library('gmp', required : false)
 464 cdata.set('HAVE_GMP', gmp_dep.found())
 465 gsl_dep = cc.find_library('gsl', required : false)
 466 gslcblas_dep = cc.find_library('gslcblas', required : false)
 467 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 468 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 469
 470 # Used by gstinfo.c
 471 dl_dep = cc.find_library('dl', required : false)
 472 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 473 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 474 cdata.set('USE_POISONING', get_option('poisoning'))
 475
 476 configinc = include_directories('.')
 477 libsinc = include_directories('libs')
 478 privinc = include_directories('gst')
 479
 480 # Find dependencies
 481 glib_dep = dependency('glib-2.0', version : '>=2.44.0',
 482   fallback: ['glib', 'libglib_dep'])
 483 gobject_dep = dependency('gobject-2.0',
 484   fallback: ['glib', 'libgobject_dep'])
 485 gmodule_dep = dependency('gmodule-2.0',
 486   fallback: ['glib', 'libgmodule_dep'])
 487 if host_system == 'windows'
 488     gio_dep = dependency('gio-2.0',
 489         fallback: ['glib', 'libgio_dep'])
 490 else
 491     gio_dep = [dependency('gio-2.0',
 492                   fallback: ['glib', 'libgio_dep']),
 493                dependency('gio-unix-2.0',
 494                   fallback: ['glib', 'libgio_dep'])]
 495 endif
 496
 497 mathlib = cc.find_library('m', required : false)
 498 # Needed for timer_create/settime/delete
 499 # Also provides clock_gettime in glibc < 2.17
 500 rt_lib = cc.find_library('rt', required : false)
 501
 502 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 503 gnome = import('gnome')
 504
 505 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 506
 507 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 508     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 509     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 510     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 511     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 512     'gst_init(NULL,NULL);', '--quiet']
 513
 514 gst_c_args = ['-DHAVE_CONFIG_H']
 515
 516 # FIXME: This is only needed on windows and probably breaks when
 517 # default_library = 'both'. We should add this flag to static_c_args instead
 518 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 519 if get_option('default_library') == 'static'
 520   gst_c_args += ['-DGST_STATIC_COMPILATION']
 521 endif
 522
 523 # Used in gst/parse/meson.build and below
 524 python3 = import('python').find_installation()
 525
 526 bashcomp_option = get_option('bash-completion')
 527 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 528 bash_completions_dir = ''
 529 bash_helpers_dir = ''
 530
 531 bashcomp_found = false
 532 if bashcomp_dep.found()
 533   bashcomp_found = true
 534   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 535   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: bashcomp_dir_override)
 536   if bash_completions_dir == ''
 537     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 538     if bashcomp_option.enabled()
 539       error(msg)
 540     else
 541       message(msg)
 542     endif
 543     bashcomp_found = false
 544   endif
 545
 546   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: bashcomp_dir_override)
 547   if bash_helpers_dir == ''
 548     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 549     if bashcomp_option.enabled()
 550       error(msg)
 551     else
 552       message(msg)
 553     endif
 554     bashcomp_found = false
 555   endif
 556 endif
 557
 558 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 559
 560 pkgconfig = import('pkgconfig')
 561 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 562 if get_option('default_library') == 'shared'
 563   # If we don't build static plugins there is no need to generate pc files
 564   plugins_pkgconfig_install_dir = disabler()
 565 endif
 566 pkgconfig_variables = ['exec_prefix=${prefix}',
 567     'toolsdir=${exec_prefix}/bin',
 568     'pluginsdir=${libdir}/gstreamer-1.0',
 569     'datarootdir=${prefix}/share',
 570     'datadir=${datarootdir}',
 571     'girdir=${datadir}/gir-1.0',
 572     'typelibdir=${libdir}/girepository-1.0',
 573     'libexecdir=${prefix}/libexec',
 574     'pluginscannerdir=${libexecdir}/gstreamer-1.0']
 575 pkgconfig_subdirs = ['gstreamer-1.0']
 576
 577 subdir('gst')
 578 subdir('libs')
 579 subdir('plugins')
 580 if not get_option('tools').disabled()
 581   subdir('tools')
 582 endif
 583 subdir('tests')
 584 subdir('data')
 585 subdir('docs')
 586
 587 # xgettext is optional (on Windows for instance)
 588 if find_program('xgettext', required : get_option('nls')).found()
 589   cdata.set('ENABLE_NLS', 1)
 590   subdir('po')
 591 endif
 592
 593 subdir('scripts')
 594
 595 # Set release date
 596 if gst_version_nano == 0
 597   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 598   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'))
 599   if run_result.returncode() == 0
 600     release_date = run_result.stdout().strip()
 601     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 602     message('Package release date: ' + release_date)
 603   else
 604     # Error out if our release can't be found in the .doap file
 605     error(run_result.stderr())
 606   endif
 607 endif
 608
 609 configure_file(output : 'config.h', configuration : cdata)
 610 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 611 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 612
 613 if meson.version().version_compare('>= 0.54')
 614   plugin_names = []
 615   foreach plugin: plugins
 616     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 617     split = plugin.name().split('gst')
 618     if split.length() == 2
 619       plugin_names += [split[1]]
 620     else
 621       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 622       plugin_names += [plugin.name()]
 623     endif
 624   endforeach
 625   summary({'Plugins':plugin_names}, list_sep: ', ')
 626 endif