meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 prefix = get_option('prefix')
  27
  28 libexecdir = get_option('libexecdir')
  29 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  30
  31 cc = meson.get_compiler('c')
  32
  33 # Ignore several spurious warnings for things gstreamer does very commonly
  34 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  35 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  36 # NOTE: Only add warnings here if you are sure they're spurious
  37 if cc.get_id() == 'msvc'
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       language : 'c')
  44 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  45   # FIXME: Add an option for this if people ask for it
  46   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  47 endif
  48
  49 # Symbol visibility
  50 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  51 if have_visibility_hidden
  52   add_project_arguments('-fvisibility=hidden', language: 'c')
  53 endif
  54
  55 # Disable strict aliasing
  56 if cc.has_argument('-fno-strict-aliasing')
  57   add_project_arguments('-fno-strict-aliasing', language: 'c')
  58 endif
  59
  60 cdata = configuration_data()
  61 cdata.set_quoted('GST_API_VERSION', apiversion)
  62 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  63 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  64 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  65 cdata.set_quoted('GST_API_VERSION', '1.0')
  66 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  67 cdata.set_quoted('GST_LICENSE', 'LGPL')
  68 cdata.set_quoted('PACKAGE', 'gstreamer')
  69 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  70 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  71 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  72 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  73 cdata.set_quoted('PACKAGE_URL', '')
  74 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  75 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  76 cdata.set_quoted('VERSION', gst_version)
  77 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  78 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  79 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  80 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  81 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  82   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  83
  84 if host_system == 'darwin'
  85   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
  86 endif
  87
  88 if gst_version_nano > 0
  89     # Have GST_ERROR message printed when running from git
  90     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  91 else
  92     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  93 endif
  94
  95 # GStreamer package name and origin url
  96 gst_package_name = get_option('package-name')
  97 if gst_package_name == ''
  98   if gst_version_nano == 0
  99     gst_package_name = 'GStreamer source release'
 100   elif gst_version_nano == 1
 101     gst_package_name = 'GStreamer git'
 102   else
 103     gst_package_name = 'GStreamer prerelease'
 104   endif
 105 endif
 106 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 107 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 108
 109 # These are only needed/used by the ABI tests
 110 host_defines = [
 111   [ 'x86', 'HAVE_CPU_I386' ],
 112   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 113   [ 'arm', 'HAVE_CPU_ARM' ],
 114   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 115   [ 'mips', 'HAVE_CPU_MIPS' ],
 116   [ 'powerpc', 'HAVE_CPU_PPC' ],
 117   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 118   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 119   [ 'sparc', 'HAVE_CPU_SPARC' ],
 120   [ 'ia64', 'HAVE_CPU_IA64' ],
 121   [ 'hppa', 'HAVE_CPU_HPPA' ],
 122   [ 'm68k', 'HAVE_CPU_M68K' ],
 123   [ 's390', 'HAVE_CPU_S390' ],
 124 ]
 125 foreach h : host_defines
 126   if h.get(0) == host_machine.cpu()
 127     cdata.set(h.get(1), 1)
 128   endif
 129 endforeach
 130 # FIXME: should really be called HOST_CPU or such
 131 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 132
 133 check_headers = [
 134   'dlfcn.h',
 135   'inttypes.h',
 136   'memory.h',
 137   'poll.h',
 138   'stdint.h',
 139   'stdio_ext.h',
 140   'strings.h',
 141   'string.h',
 142   'sys/param.h',
 143   'sys/poll.h',
 144   'sys/prctl.h',
 145   'sys/socket.h',
 146   'sys/stat.h',
 147   'sys/times.h',
 148   'sys/time.h',
 149   'sys/types.h',
 150   'sys/utsname.h',
 151   'sys/wait.h',
 152   'ucontext.h',
 153   'unistd.h',
 154   'valgrind/valgrind.h',
 155   'sys/resource.h',
 156 ]
 157
 158 if host_system == 'windows'
 159   check_headers += ['winsock2.h']
 160 endif
 161
 162 foreach h : check_headers
 163   if cc.has_header(h)
 164     define = 'HAVE_' + h.underscorify().to_upper()
 165     cdata.set(define, 1)
 166   endif
 167 endforeach
 168
 169 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 170   cdata.set('HAVE_TM_GMTOFF', 1)
 171 endif
 172
 173 check_functions = [
 174   'gmtime_r',
 175   'sigaction',
 176   'getrusage',
 177   'fseeko',
 178   'ftello',
 179   'poll',
 180   'ppoll',
 181   'pselect',
 182   'getpagesize',
 183   'clock_gettime',
 184   # These are needed by libcheck
 185   'getline',
 186   'mkstemp',
 187   'alarm',
 188   'gettimeofday',
 189 ]
 190
 191 foreach f : check_functions
 192   if cc.has_function(f)
 193     define = 'HAVE_' + f.underscorify().to_upper()
 194     cdata.set(define, 1)
 195   endif
 196 endforeach
 197
 198 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 199   cdata.set('HAVE_LOCALTIME_R', 1)
 200   # Needed by libcheck
 201   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 202 endif
 203
 204 if cc.links('''#include <pthread.h>
 205                int main() {
 206                  pthread_setname_np("example"); return 0;
 207                }''', name : 'pthread_setname_np(const char*)')
 208   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 209 endif
 210
 211 # Check for posix timers and the monotonic clock
 212 time_prefix = '#include <time.h>\n'
 213 if cdata.has('HAVE_UNISTD_H')
 214   time_prefix += '#include <unistd.h>'
 215 endif
 216
 217 posix_timers_src = time_prefix + '''
 218 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 219 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 220 #endif
 221 '''
 222 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 223   cdata.set('HAVE_POSIX_TIMERS', 1)
 224 endif
 225
 226 monotonic_clock_src = time_prefix + '''
 227 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 228 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 229 #endif
 230 '''
 231 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 232   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 233 endif
 234
 235 # Check for __uint128_t (gcc) by checking for 128-bit division
 236 uint128_t_src = '''int main() {
 237 static __uint128_t v1 = 100;
 238 static __uint128_t v2 = 10;
 239 static __uint128_t u;
 240 u = v1 / v2;
 241 }'''
 242 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 243   cdata.set('HAVE_UINT128_T', 1)
 244 endif
 245
 246 # All supported platforms have long long now
 247 cdata.set('HAVE_LONG_LONG', 1)
 248
 249 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 250 # building with MSVC
 251 if cc.get_id() == 'msvc'
 252   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 253 else
 254   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 255 endif
 256
 257 # -------------------------------------------------------------------------------------
 258 # config.h things needed by libcheck
 259 # -------------------------------------------------------------------------------------
 260 if cc.has_function('getpid')
 261   cdata.set('HAVE_GETPID', 1)
 262 elif host_system == 'windows' and cc.has_function('_getpid')
 263   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 264   cdata.set('HAVE__GETPID', 1)
 265 endif
 266 if cc.has_function('strdup')
 267   cdata.set('HAVE_DECL_STRDUP', 1)
 268 elif host_system == 'windows' and cc.has_function('_strdup')
 269   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 270 endif
 271 if host_system != 'windows'
 272   cdata.set('HAVE_FORK', 1)
 273 else
 274   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 275   cdata.set('HAVE_FORK', 0)
 276 endif
 277 if cc.has_function('strsignal')
 278   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 279 endif
 280 # Check for availability of types
 281 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 282   cdata.set('clockid_t', 'int')
 283 endif
 284 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 285   cdata.set('timer_t', 'int')
 286 endif
 287 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 288                       prefix : '#include <time.h>')
 289   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 290 endif
 291 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 292                       prefix : '#include <time.h>')
 293   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 294 endif
 295
 296 # Platform deps; only ws2_32 and execinfo for now
 297 platform_deps = []
 298 if host_system == 'windows'
 299   platform_deps = [cc.find_library('ws2_32')]
 300 endif
 301
 302 backtrace_deps = []
 303 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 304 dw_dep = dependency('libdw', required: get_option('libunwind'))
 305 backtrace_deps = [unwind_dep, dw_dep]
 306 if unwind_dep.found()
 307   cdata.set('HAVE_UNWIND', 1)
 308   if dw_dep.found()
 309     cdata.set('HAVE_DW', 1)
 310   else
 311     message('Support for backtraces is partial only.')
 312   endif
 313 else
 314   if cc.has_function('backtrace')
 315     cdata.set('HAVE_BACKTRACE', 1)
 316   else
 317       message('NO backtraces support.')
 318   endif
 319 endif
 320
 321 if cc.has_header('execinfo.h')
 322   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 323     cdata.set('HAVE_BACKTRACE', 1)
 324   else
 325     execinfo_dep = cc.find_library('execinfo', required : false)
 326     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 327       cdata.set('HAVE_BACKTRACE', 1)
 328       platform_deps += execinfo_dep
 329     endif
 330   endif
 331 endif
 332
 333 gst_debug = get_option('gst_debug')
 334 if not gst_debug
 335   add_project_arguments(['-Wno-unused'], language: 'c')
 336 endif
 337
 338 warning_flags = [
 339   '-Wmissing-declarations',
 340   '-Wmissing-prototypes',
 341   '-Wredundant-decls',
 342   '-Wundef',
 343   '-Wwrite-strings',
 344   '-Wformat',
 345   '-Wformat-nonliteral',
 346   '-Wformat-security',
 347   '-Wold-style-definition',
 348   '-Winit-self',
 349   '-Wmissing-include-dirs',
 350   '-Waddress',
 351   '-Waggregate-return',
 352   '-Wno-multichar',
 353   '-Wnested-externs',
 354   '-Wdeclaration-after-statement',
 355   '-Wvla',
 356   '-Wpointer-arith',
 357 ]
 358
 359 foreach extra_arg : warning_flags
 360   if cc.has_argument (extra_arg)
 361     add_project_arguments([extra_arg], language: 'c')
 362   endif
 363 endforeach
 364
 365 # Used by the gstutils test
 366 gmp_dep = cc.find_library('gmp', required : false)
 367 cdata.set('HAVE_GMP', gmp_dep.found())
 368 gsl_dep = cc.find_library('gsl', required : false)
 369 gslcblas_dep = cc.find_library('gslcblas', required : false)
 370 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 371 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 372
 373 # Used by gstinfo.c
 374 dl_dep = cc.find_library('dl', required : false)
 375 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 376 cdata.set10('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 377 cdata.set('USE_POISONING', get_option('poisoning'))
 378
 379 configinc = include_directories('.')
 380 libsinc = include_directories('libs')
 381 privinc = include_directories('gst')
 382
 383 # Find dependencies
 384 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 385   fallback: ['glib', 'libglib_dep'])
 386 gobject_dep = dependency('gobject-2.0',
 387   fallback: ['glib', 'libgobject_dep'])
 388 gmodule_dep = dependency('gmodule-2.0',
 389   fallback: ['glib', 'libgmodule_dep'])
 390 if host_system == 'windows'
 391     gio_dep = dependency('gio-2.0',
 392         fallback: ['glib', 'libgio_dep'])
 393 else
 394     gio_dep = [dependency('gio-2.0',
 395                   fallback: ['glib', 'libgio_dep']),
 396                dependency('gio-unix-2.0',
 397                   fallback: ['glib', 'libgio_dep'])]
 398 endif
 399
 400 mathlib = cc.find_library('m', required : false)
 401 # Needed for timer_create/settime/delete
 402 # Also provides clock_gettime in glibc < 2.17
 403 rt_lib = cc.find_library('rt', required : false)
 404
 405 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 406 gnome = import('gnome')
 407
 408 build_gir = gir.found() and not meson.is_cross_build()
 409
 410 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 411     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 412     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 413     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 414     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 415     'gst_init(NULL,NULL);' ]
 416
 417 gst_c_args = ['-DHAVE_CONFIG_H']
 418
 419 # FIXME: This is only needed on windows and probably breaks when
 420 # default_library = 'both'. We should add this flag to static_c_args instead
 421 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 422 if get_option('default_library') == 'static'
 423   gst_c_args += ['-DGST_STATIC_COMPILATION']
 424 endif
 425
 426 # Used in gst/parse/meson.build and below
 427 python3 = import('python3').find_python()
 428
 429 bashcomp_option = get_option('bash-completion')
 430 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 431 bash_completions_dir = ''
 432 bash_helpers_dir = ''
 433
 434 bashcomp_found = false
 435 if bashcomp_dep.found()
 436   bashcomp_found = true
 437   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 438   if bash_completions_dir == ''
 439     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 440     if bashcomp_option.enabled()
 441       error(msg)
 442     else
 443       message(msg)
 444     endif
 445     bashcomp_found = false
 446   endif
 447
 448   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 449   if bash_helpers_dir == ''
 450     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 451     if bashcomp_option.enabled()
 452       error(msg)
 453     else
 454       message(msg)
 455     endif
 456     bashcomp_found = false
 457   endif
 458 endif
 459
 460 subdir('gst')
 461 subdir('libs')
 462 subdir('plugins')
 463 subdir('tools')
 464 subdir('pkgconfig')
 465 subdir('tests')
 466 subdir('data')
 467
 468 # xgettext is optional (on Windows for instance)
 469 if find_program('xgettext', required : get_option('nls')).found()
 470   cdata.set('ENABLE_NLS', 1)
 471   subdir('po')
 472 endif
 473
 474 configure_file(output : 'config.h', configuration : cdata)
 475
 476 if build_machine.system() == 'windows'
 477   message('Disabling gtk-doc while building on Windows')
 478 else
 479   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 480     subdir('docs')
 481   else
 482     message('Not building documentation as gtk-doc was not found')
 483   endif
 484 endif
 485
 486 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 487
 488 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))