meson.build

   1 project('gst-plugins-bad', 'c', 'cpp',
   2   version : '1.19.0.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 glib_req = '>= 2.56.0'
  20 orc_req = '>= 0.4.17'
  21 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  22
  23 api_version = '1.0'
  24 soversion = 0
  25 # maintaining compatibility with the previous libtool versioning
  26 # current = minor * 100 + micro
  27 curversion = gst_version_minor * 100 + gst_version_micro
  28 libversion = '@0@.@1@.0'.format(soversion, curversion)
  29 osxversion = curversion + 1
  30
  31 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  32 plugins = []
  33
  34 cc = meson.get_compiler('c')
  35 cxx = meson.get_compiler('cpp')
  36 host_system = host_machine.system()
  37
  38 if host_system in ['ios', 'darwin']
  39   have_objc = add_languages('objc', native: false)
  40   have_objcpp = add_languages('objcpp', native: false)
  41 else
  42   have_objc = false
  43   have_objcpp = false
  44 endif
  45
  46 cdata = configuration_data()
  47
  48 if cc.get_id() == 'msvc'
  49   # Ignore several spurious warnings for things gstreamer does very commonly
  50   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  51   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  52   # NOTE: Only add warnings here if you are sure they're spurious
  53   msvc_args = [
  54       '/wd4018', # implicit signed/unsigned conversion
  55       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  56       '/wd4244', # lossy type conversion (e.g. double -> int)
  57       '/wd4305', # truncating type conversion (e.g. double -> float)
  58       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  59   ]
  60   add_project_arguments(msvc_args, language : 'c')
  61   add_project_arguments(msvc_args, language : 'cpp')
  62   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  63   # are built with MinGW
  64   noseh_link_args = ['/SAFESEH:NO']
  65 else
  66   if cxx.has_argument('-Wno-non-virtual-dtor')
  67     add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  68   endif
  69
  70   noseh_link_args = []
  71 endif
  72
  73 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  74   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  75 endif
  76
  77 # Symbol visibility
  78 if cc.get_id() == 'msvc'
  79   export_define = '__declspec(dllexport) extern'
  80 elif cc.has_argument('-fvisibility=hidden')
  81   add_project_arguments('-fvisibility=hidden', language: 'c')
  82   add_project_arguments('-fvisibility=hidden', language: 'cpp')
  83   if have_objc
  84     add_project_arguments('-fvisibility=hidden', language: 'objc')
  85   endif
  86   export_define = 'extern __attribute__ ((visibility ("default")))'
  87 else
  88   export_define = 'extern'
  89 endif
  90
  91 # Passing this through the command line would be too messy
  92 cdata.set('GST_API_EXPORT', export_define)
  93
  94 # Disable strict aliasing
  95 if cc.has_argument('-fno-strict-aliasing')
  96   add_project_arguments('-fno-strict-aliasing', language: 'c')
  97 endif
  98 if cxx.has_argument('-fno-strict-aliasing')
  99   add_project_arguments('-fno-strict-aliasing', language: 'cpp')
 100 endif
 101
 102 # Define G_DISABLE_DEPRECATED for development versions
 103 if gst_version_is_dev
 104   message('Disabling deprecated GLib API')
 105   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 106 endif
 107
 108 cast_checks = get_option('gobject-cast-checks')
 109 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 110   message('Disabling GLib cast checks')
 111   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 112 endif
 113
 114 glib_asserts = get_option('glib-asserts')
 115 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 116   message('Disabling GLib asserts')
 117   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 118 endif
 119
 120 glib_checks = get_option('glib-checks')
 121 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 122   message('Disabling GLib checks')
 123   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 124 endif
 125
 126 check_headers = [
 127   ['HAVE_DLFCN_H', 'dlfcn.h'],
 128   ['HAVE_FCNTL_H', 'fcntl.h'],
 129   ['HAVE_INTTYPES_H', 'inttypes.h'],
 130   ['HAVE_MEMORY_H', 'memory.h'],
 131   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 132   ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
 133   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 134   ['HAVE_PTHREAD_H', 'pthread.h'],
 135   ['HAVE_STDINT_H', 'stdint.h'],
 136   ['HAVE_STDLIB_H', 'stdlib.h'],
 137   ['HAVE_STRINGS_H', 'strings.h'],
 138   ['HAVE_STRING_H', 'string.h'],
 139   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 140   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 141   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 142   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 143   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 144   ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
 145   ['HAVE_UNISTD_H', 'unistd.h'],
 146   ['HAVE_WINDOWS_H', 'windows.h'],
 147   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 148   ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
 149 ]
 150
 151 foreach h : check_headers
 152   if cc.has_header(h.get(1))
 153     cdata.set(h.get(0), 1)
 154   endif
 155 endforeach
 156
 157 check_functions = [
 158   ['HAVE_DCGETTEXT', 'dcgettext'],
 159   ['HAVE_GETPAGESIZE', 'getpagesize'],
 160   ['HAVE_GMTIME_R', 'gmtime_r'],
 161   ['HAVE_MEMFD_CREATE', 'memfd_create'],
 162   ['HAVE_MMAP', 'mmap'],
 163   ['HAVE_PIPE2', 'pipe2'],
 164   ['HAVE_GETRUSAGE', 'getrusage', '#include<sys/resource.h>'],
 165 ]
 166
 167 foreach f : check_functions
 168   prefix = ''
 169   if f.length() == 3
 170     prefix = f.get(2)
 171   endif
 172   if cc.has_function(f.get(1), prefix: prefix)
 173     cdata.set(f.get(0), 1)
 174   endif
 175 endforeach
 176
 177 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 178 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 179 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 180 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 181 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 182
 183 cdata.set_quoted('VERSION', gst_version)
 184 cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
 185 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 186 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gst-plugins-bad/issues/new')
 187 cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
 188 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
 189 cdata.set_quoted('GST_API_VERSION', api_version)
 190 cdata.set_quoted('GST_LICENSE', 'LGPL')
 191 cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
 192 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 193
 194 warning_flags = [
 195   '-Wmissing-declarations',
 196   '-Wredundant-decls',
 197   '-Wwrite-strings',
 198   '-Wformat',
 199   '-Wformat-security',
 200   '-Winit-self',
 201   '-Wmissing-include-dirs',
 202   '-Waddress',
 203   '-Wno-multichar',
 204   '-Wvla',
 205   '-Wpointer-arith',
 206 ]
 207
 208 warning_c_flags = [
 209   '-Wmissing-prototypes',
 210   '-Wdeclaration-after-statement',
 211   '-Wold-style-definition',
 212 ]
 213
 214 warning_cxx_flags = [
 215   '-Wformat-nonliteral',
 216 ]
 217
 218 foreach extra_arg : warning_c_flags
 219   if cc.has_argument (extra_arg)
 220     add_project_arguments([extra_arg], language: 'c')
 221   endif
 222 endforeach
 223
 224 foreach extra_arg : warning_cxx_flags
 225   if cxx.has_argument (extra_arg)
 226     add_project_arguments([extra_arg], language: 'cpp')
 227   endif
 228 endforeach
 229
 230 foreach extra_arg : warning_flags
 231   if cc.has_argument (extra_arg)
 232     add_project_arguments([extra_arg], language: 'c')
 233   endif
 234   if cxx.has_argument (extra_arg)
 235     add_project_arguments([extra_arg], language: 'cpp')
 236   endif
 237 endforeach
 238
 239 # GStreamer package name and origin url
 240 gst_package_name = get_option('package-name')
 241 if gst_package_name == ''
 242   if gst_version_nano == 0
 243     gst_package_name = 'GStreamer Bad Plug-ins source release'
 244   elif gst_version_nano == 1
 245     gst_package_name = 'GStreamer Bad Plug-ins git'
 246   else
 247     gst_package_name = 'GStreamer Bad Plug-ins prerelease'
 248   endif
 249 endif
 250 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 251 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 252
 253 # FIXME: This should be exposed as a configuration option
 254 if host_system == 'linux'
 255   cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
 256 elif ['darwin', 'ios'].contains(host_system)
 257   cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
 258   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 259   # Yes, we set this for iOS too. Same as Autotools.
 260   cdata.set('HAVE_OSX', 1)
 261 else
 262   cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
 263 endif
 264
 265 # Mandatory GST deps
 266 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 267   fallback : ['gstreamer', 'gst_dep'])
 268 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 269   fallback : ['gstreamer', 'gst_base_dep'])
 270 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 271   fallback : ['gstreamer', 'gst_net_dep'])
 272 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 273   fallback : ['gstreamer', 'gst_controller_dep'])
 274
 275 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 276     fallback : ['gst-plugins-base', 'pbutils_dep'])
 277 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 278     fallback : ['gst-plugins-base', 'allocators_dep'])
 279 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 280     fallback : ['gst-plugins-base', 'app_dep'])
 281 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 282     fallback : ['gst-plugins-base', 'audio_dep'])
 283 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 284     fallback : ['gst-plugins-base', 'fft_dep'])
 285 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 286     fallback : ['gst-plugins-base', 'riff_dep'])
 287 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 288     fallback : ['gst-plugins-base', 'rtp_dep'])
 289 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 290     fallback : ['gst-plugins-base', 'rtsp_dep'])
 291 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 292     fallback : ['gst-plugins-base', 'sdp_dep'])
 293 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 294     fallback : ['gst-plugins-base', 'tag_dep'])
 295 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 296     fallback : ['gst-plugins-base', 'video_dep'])
 297 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 298     required : get_option('tests'),
 299     fallback : ['gstreamer', 'gst_check_dep'])
 300
 301 # GStreamer OpenGL
 302 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 303     fallback : ['gst-plugins-base', 'gstgl_dep'], required: get_option('gl'))
 304 gstglproto_dep = dependency('gstreamer-gl-prototypes-1.0', version : gst_req,
 305     fallback : ['gst-plugins-base', 'gstglproto_dep'], required: get_option('gl'))
 306 gstglx11_dep = dependency('', required : false)
 307 gstglwayland_dep = dependency('', required : false)
 308 gstglegl_dep = dependency('', required : false)
 309
 310 if gstgl_dep.found()
 311   if gstgl_dep.type_name() == 'pkgconfig'
 312     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 313     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 314     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 315   else
 316     gstbase = subproject('gst-plugins-base')
 317     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 318     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 319     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 320   endif
 321
 322   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 323   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 324   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 325
 326   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 327     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 328   endforeach
 329
 330   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 331     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 332   endforeach
 333
 334   foreach api : ['gl', 'gles2']
 335     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 336   endforeach
 337
 338   # Behind specific checks because meson fails at optional dependencies with a
 339   # fallback to the same subproject.  On the first failure, meson will never
 340   # check the system again even if the fallback never existed.
 341   # Last checked with meson 0.54.3
 342   if gst_gl_have_window_x11
 343     gstglx11_dep = dependency('gstreamer-gl-x11-1.0', version : gst_req,
 344         fallback : ['gst-plugins-base', 'gstglx11_dep'], required: true)
 345   endif
 346   if gst_gl_have_window_wayland
 347     gstglwayland_dep = dependency('gstreamer-gl-wayland-1.0', version : gst_req,
 348         fallback : ['gst-plugins-base', 'gstglwayland_dep'], required: true)
 349   endif
 350   if gst_gl_have_platform_egl
 351     gstglegl_dep = dependency('gstreamer-gl-egl-1.0', version : gst_req,
 352         fallback : ['gst-plugins-base', 'gstglegl_dep'], required: true)
 353   endif
 354 endif
 355
 356 libm = cc.find_library('m', required : false)
 357 glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
 358 gmodule_dep = dependency('gmodule-2.0', fallback: ['glib', 'libgmodule_dep'])
 359 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 360 # gio-unix-2.0 is used by sys/bluez
 361
 362 # Optional dep of ext/gl and gst/librfb
 363 x11_dep = dependency('x11', required : get_option('x11'))
 364 if x11_dep.found()
 365   cdata.set('HAVE_X11', 1)
 366 endif
 367
 368 if host_machine.system() == 'windows'
 369   winsock2 = [cc.find_library('ws2_32')]
 370 else
 371   winsock2 = []
 372 endif
 373
 374 if ['darwin', 'ios'].contains(host_system)
 375   if not have_objc
 376     error('Building on MacOS/iOS/etc requires an ObjC compiler')
 377   endif
 378   if host_system == 'ios'
 379     cdata.set('HAVE_IOS', 1)
 380   endif
 381
 382   avfoundation_dep = dependency('AVFoundation', required : false)
 383   if avfoundation_dep.found()
 384       cdata.set('HAVE_AVFOUNDATION', 1)
 385   endif
 386
 387   videotoolbox_dep = dependency('VideoToolbox', required : false)
 388   if videotoolbox_dep.found()
 389       cdata.set('HAVE_VIDEOTOOLBOX', 1)
 390   endif
 391
 392 #  FIXME: framework.version() returns 'unknown'
 393 #  if videotoolbox_dep.version().version_compare('>=10.9.6')
 394 #    cdata.set('HAVE_VIDEOTOOLBOX_10_9_6', 1)
 395 #  endif
 396 endif
 397
 398 have_orcc = false
 399 orcc_args = []
 400 orc_targets = []
 401 # Used by various libraries/elements that use Orc code
 402 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 403     fallback : ['orc', 'orc_dep'])
 404 orcc = find_program('orcc', required : get_option('orc'))
 405 if orc_dep.found() and orcc.found()
 406   have_orcc = true
 407   orcc_args = [orcc, '--include', 'glib.h']
 408   cdata.set('HAVE_ORC', 1)
 409 else
 410   message('Orc Compiler not found or disabled, will use backup C code')
 411   cdata.set('DISABLE_ORC', 1)
 412 endif
 413 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 414
 415 gnustl_dep = declare_dependency()
 416 if host_system == 'android'
 417   gnustl_dep = dependency('gnustl', required : false)
 418 endif
 419
 420 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 421 if gst_dep.type_name() == 'internal'
 422   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 423 else
 424   # We can't check that in the case of subprojects as we won't
 425   # be able to build against an internal dependency (which is not built yet)
 426   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 427 endif
 428
 429 if gst_debug_disabled
 430   message('GStreamer debug system is disabled')
 431   if cc.has_argument('-Wno-unused')
 432     add_project_arguments('-Wno-unused', language: 'c')
 433   endif
 434   if cxx.has_argument ('-Wno-unused')
 435     add_project_arguments('-Wno-unused', language: 'cpp')
 436   endif
 437 else
 438   message('GStreamer debug system is enabled')
 439 endif
 440
 441 gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
 442 configinc = include_directories('.')
 443 libsinc = include_directories('gst-libs')
 444
 445 python3 = import('python').find_installation()
 446
 447 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 448 gnome = import('gnome')
 449 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 450 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 451     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 452     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 453     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 454     'gst_init(NULL,NULL);', '--quiet']
 455
 456 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 457
 458 pkgconfig = import('pkgconfig')
 459 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 460 if get_option('default_library') == 'shared'
 461   # If we don't build static plugins there is no need to generate pc files
 462   plugins_pkgconfig_install_dir = disabler()
 463 endif
 464
 465 pkgconfig_variables = ['exec_prefix=${prefix}',
 466     'toolsdir=${exec_prefix}/bin',
 467     'pluginsdir=${libdir}/gstreamer-1.0',
 468     'datarootdir=${prefix}/share',
 469     'datadir=${datarootdir}',
 470     'girdir=${datadir}/gir-1.0',
 471     'typelibdir=${libdir}/girepository-1.0']
 472
 473 pkgconfig_subdirs = ['gstreamer-1.0']
 474
 475 pkgconfig.generate(
 476   libraries : [gst_dep],
 477   variables : pkgconfig_variables,
 478   subdirs : pkgconfig_subdirs,
 479   name : 'gstreamer-plugins-bad-1.0',
 480   description : 'Streaming media framework, bad plugins libraries',
 481 )
 482
 483 subdir('gst-libs')
 484 subdir('gst')
 485 subdir('sys')
 486 subdir('ext')
 487 subdir('tests')
 488 subdir('data')
 489 subdir('tools')
 490
 491 if have_orcc
 492   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 493
 494   orc_update_targets = []
 495   foreach t : orc_targets
 496     orc_name = t.get('name')
 497     orc_file = t.get('orc-source')
 498     header = t.get('header')
 499     source = t.get('source')
 500     # alias_target() only works with build targets, so can't use run_target() here
 501     orc_update_targets += [
 502       custom_target('update-orc-@0@'.format(orc_name),
 503         input: [header, source],
 504         command: [update_orc_dist_files, orc_file, header, source],
 505         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 506     ]
 507   endforeach
 508
 509   if meson.version().version_compare('>= 0.52') and orc_update_targets.length() > 0
 510     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 511   endif
 512 endif
 513
 514 # xgettext is optional (on Windows for instance)
 515 if find_program('xgettext', required : get_option('nls')).found()
 516   cdata.set('ENABLE_NLS', 1)
 517   subdir('po')
 518 endif
 519
 520 subdir('scripts')
 521
 522 # Set release date
 523 if gst_version_nano == 0
 524   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 525   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-bad.doap'))
 526   if run_result.returncode() == 0
 527     release_date = run_result.stdout().strip()
 528     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 529     message('Package release date: ' + release_date)
 530   else
 531     # Error out if our release can't be found in the .doap file
 532     error(run_result.stderr())
 533   endif
 534 endif
 535
 536 configure_file(output : 'config.h', configuration : cdata)
 537
 538 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 539
 540 subdir('docs')
 541
 542 if meson.version().version_compare('>= 0.54')
 543   plugin_names = []
 544   foreach plugin: plugins
 545     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 546     split = plugin.name().split('gst')
 547     if split.length() == 2
 548       plugin_names += [split[1]]
 549     else
 550       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 551       plugin_names += [plugin.name()]
 552     endif
 553   endforeach
 554   summary({'Plugins':plugin_names}, list_sep: ', ')
 555 endif