meson.build

   1 project('gst-plugins-good', 'c', 'cpp',
   2   version : '1.11.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22
  23 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  24
  25 cc = meson.get_compiler('c')
  26
  27 if cc.get_id() == 'msvc'
  28   # Ignore several spurious warnings for things gstreamer does very commonly
  29   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31   # NOTE: Only add warnings here if you are sure they're spurious
  32   add_project_arguments(
  33       '/wd4018', # implicit signed/unsigned conversion
  34       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  35       '/wd4244', # lossy type conversion (e.g. double -> int)
  36       '/wd4305', # truncating type conversion (e.g. double -> float)
  37       language : 'c')
  38   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  39   # are built with MinGW
  40   noseh_link_args = ['/SAFESEH:NO']
  41 else
  42   noseh_link_args = []
  43 endif
  44
  45 cdata = configuration_data()
  46
  47 check_headers = [
  48   ['HAVE_DLFCN_H', 'dlfcn.h'],
  49   ['HAVE_FCNTL_H', 'fcntl.h'],
  50   ['HAVE_INTTYPES_H', 'inttypes.h'],
  51   ['HAVE_MEMORY_H', 'memory.h'],
  52   ['HAVE_PROCESS_H', 'process.h'],
  53   ['HAVE_STDINT_H', 'stdint.h'],
  54   ['HAVE_STDLIB_H', 'stdlib.h'],
  55   ['HAVE_STRINGS_H', 'strings.h'],
  56   ['HAVE_STRING_H', 'string.h'],
  57   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
  58   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  59   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  60   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  61   ['HAVE_SYS_TIME_H', 'sys/time.h'],
  62   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  63   ['HAVE_UNISTD_H', 'unistd.h'],
  64 ]
  65
  66 foreach h : check_headers
  67   if cc.has_header(h.get(1))
  68     cdata.set(h.get(0), 1)
  69   endif
  70 endforeach
  71
  72 check_functions = [
  73   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
  74   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
  75   ['HAVE_COSH', 'cosh', '#include<math.h>'],
  76 # check token HAVE_CPU_ALPHA
  77 # check token HAVE_CPU_ARM
  78 # check token HAVE_CPU_CRIS
  79 # check token HAVE_CPU_CRISV32
  80 # check token HAVE_CPU_HPPA
  81 # check token HAVE_CPU_I386
  82 # check token HAVE_CPU_IA64
  83 # check token HAVE_CPU_M68K
  84 # check token HAVE_CPU_MIPS
  85 # check token HAVE_CPU_PPC
  86 # check token HAVE_CPU_PPC64
  87 # check token HAVE_CPU_S390
  88 # check token HAVE_CPU_SPARC
  89 # check token HAVE_CPU_X86_64
  90   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  91 # check token HAVE_DIRECTSOUND
  92 # check token HAVE_EXPERIMENTAL
  93 # check token HAVE_EXTERNAL
  94 # check token HAVE_FPCLASS
  95 # check token HAVE_GCC_ASM
  96   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
  97 # check token HAVE_GETTEXT
  98 # check token HAVE_GST_V4L2
  99 # check token HAVE_IOS
 100   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 101 # check token HAVE_LIBV4L2
 102   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 103 # check token HAVE_OSS
 104 # check token HAVE_OSS4
 105 # check token HAVE_OSS_INCLUDE_IN_MACHINE
 106 # check token HAVE_OSS_INCLUDE_IN_ROOT
 107 # check token HAVE_OSS_INCLUDE_IN_SYS
 108 # check token HAVE_OSX_AUDIO
 109 # check token HAVE_OSX_VIDEO
 110 # check token HAVE_RDTSC
 111   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 112 # check token HAVE_SUNAUDIO
 113 # check token HAVE_WAVEFORM
 114 ]
 115
 116 foreach f : check_functions
 117   if cc.has_function(f.get(1), prefix : f.get(2))
 118     cdata.set(f.get(0), 1)
 119   endif
 120 endforeach
 121
 122 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 123 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 124 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 125 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 126 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 127
 128 # Here be fixmes.
 129 # FIXME: check if this is correct
 130 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 131 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 132 cdata.set('VERSION', '"@0@"'.format(gst_version))
 133 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 134 cdata.set('GST_LICENSE', '"LGPL"')
 135 cdata.set('PACKAGE', '"gst-plugins-good"')
 136 cdata.set('GETTEXT_PACKAGE', '"gst-plugins-good-1.0"')
 137 cdata.set('PACKAGE_NAME', '"GStreamer Good Plug-ins"')
 138 cdata.set('GST_PACKAGE_NAME', '"GStreamer Good Plug-ins"')
 139 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"') # FIXME: make configurable
 140
 141 # Mandatory GST deps
 142 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 143   fallback : ['gstreamer', 'gst_dep'])
 144 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 145   fallback : ['gstreamer', 'gst_base_dep'])
 146 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 147   fallback : ['gstreamer', 'gst_net_dep'])
 148 if host_machine.system() != 'windows'
 149   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 150     fallback : ['gstreamer', 'gst_check_dep'])
 151 endif
 152 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 153   fallback : ['gstreamer', 'gst_controller_dep'])
 154
 155 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 156     fallback : ['gst-plugins-base', 'pbutils_dep'])
 157 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 158     fallback : ['gst-plugins-base', 'allocators_dep'])
 159 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 160     fallback : ['gst-plugins-base', 'app_dep'])
 161 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 162     fallback : ['gst-plugins-base', 'audio_dep'])
 163 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 164     fallback : ['gst-plugins-base', 'fft_dep'])
 165 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 166     fallback : ['gst-plugins-base', 'riff_dep'])
 167 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 168     fallback : ['gst-plugins-base', 'rtp_dep'])
 169 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 170     fallback : ['gst-plugins-base', 'rtsp_dep'])
 171 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 172     fallback : ['gst-plugins-base', 'sdp_dep'])
 173 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 174     fallback : ['gst-plugins-base', 'tag_dep'])
 175 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 176     fallback : ['gst-plugins-base', 'video_dep'])
 177
 178 libm = cc.find_library('m', required : false)
 179 zlib_dep = dependency('zlib')
 180 bz2lib = cc.find_library('bz2', required : false)
 181 gio_dep = dependency('gio-2.0', version : glib_req)
 182 glib_deps = [dependency('glib-2.0', version : glib_req),
 183              dependency('gobject-2.0', version : glib_req)]
 184
 185 cdata.set('HAVE_ZLIB', 1)
 186 if bz2lib.found()
 187   cdata.set('HAVE_BZ2', 1)
 188 endif
 189
 190 # Check all of the things.
 191 # TODO: None of these are actually used yet because
 192 # the build files haven't been written
 193 deps = [
 194   ['gtk_dep','gtk+-3.0', '', ''],
 195   ['gtkx_dep','gtk+-x11-3.0', '', ''],
 196   ['caca_dep','caca', '', ''],
 197   ['libraw1394_dep','libraw1394', '>=2.0.0', ''],
 198   ['libiec61883_dep','libiec61883', '>=1.0.0', ''],
 199 ]
 200
 201 foreach d : deps
 202   varname = d[0]
 203   depname = d[1]
 204   version = d[2]
 205   confhname = d[3]
 206   if version == ''
 207     curdep = dependency(depname, required : false)
 208   else
 209     curdep = dependency(depname, required : false, version : version)
 210   endif
 211   set_variable(varname, curdep)
 212   if curdep.found() and confhname != ''
 213     cdata.set(confhname, 1)
 214   endif
 215 endforeach
 216
 217 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 218 configinc = include_directories('.')
 219 libsinc = include_directories('gst-libs')
 220
 221 have_orcc = false
 222 orcc_args = []
 223 if get_option('use_orc') != 'no'
 224   need_orc = get_option('use_orc') == 'yes'
 225   # Used by various libraries/elements that use Orc code
 226   orc_dep = dependency('orc-0.4', version : '>= 0.4.17', required : need_orc)
 227   orcc = find_program('orcc', required : need_orc)
 228   if orc_dep.found() and orcc.found()
 229     have_orcc = true
 230     orcc_args = [orcc, '--include', 'glib.h']
 231     cdata.set('HAVE_ORC', 1)
 232   else
 233     message('Orc Compiler not found, will use backup C code')
 234     cdata.set('DISABLE_ORC', 1)
 235   endif
 236 else
 237   cdata.set('DISABLE_ORC', 1)
 238 endif
 239
 240 subdir('gst')
 241 subdir('sys')
 242 subdir('ext')
 243 subdir('tests')
 244 subdir('po')
 245
 246 configure_file(input : 'config.h.meson',
 247   output : 'config.h',
 248   configuration : cdata)
 249
 250 python3 = find_program('python3')
 251 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')