meson.build

   1 project('gstreamer', 'c', 'cpp',
   2   version : '1.11.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 prefix = get_option('prefix')
  25 libtype = get_option('library_format')
  26
  27 libexecdir = get_option('libexecdir')
  28 helpers_install_dir = libexecdir + '/gstreamer-1.0/'
  29
  30 cc = meson.get_compiler('c')
  31
  32 # Ignore several spurious warnings for things gstreamer does very commonly
  33 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  34 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  35 # NOTE: Only add warnings here if you are sure they're spurious
  36 if cc.get_id() == 'msvc'
  37   add_project_arguments(
  38       '/wd4018', # implicit signed/unsigned conversion
  39       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  40       '/wd4244', # lossy type conversion (e.g. double -> int)
  41       '/wd4305', # truncating type conversion (e.g. double -> float)
  42       language : 'c')
  43 endif
  44
  45 cdata = configuration_data()
  46 cdata.set('GST_VERSION_MAJOR', gst_version_major)
  47 cdata.set('GST_VERSION_MINOR', gst_version_minor)
  48 cdata.set('GST_VERSION_MICRO', gst_version_micro)
  49 cdata.set('GST_VERSION_NANO', gst_version_nano)
  50 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  51 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  52 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  53 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  54 cdata.set('GST_API_VERSION', '"1.0"')
  55 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  56 cdata.set('GST_LICENSE', '"LGPL"')
  57 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  58 cdata.set('GST_PACKAGE_NAME', '"GStreamer source release"')
  59 cdata.set('PACKAGE', '"gstreamer"')
  60 cdata.set('PACKAGE_NAME', '"GStreamer"')
  61 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  62 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  64 cdata.set('PACKAGE_URL', '""')
  65 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  66 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  67 cdata.set('VERSION', '"@0@"'.format(gst_version))
  68 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  69 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  70 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  71 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  72
  73 if gst_version_nano > 0
  74     # Have GST_ERROR message printed when running from git
  75     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  76 else
  77     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  78 endif
  79
  80 # These are only needed/used by the ABI tests
  81 host_defines = [
  82   [ 'x86', 'HAVE_CPU_I386' ],
  83   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  84   [ 'arm', 'HAVE_CPU_ARM' ],
  85   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
  86   [ 'mips', 'HAVE_CPU_MIPS' ],
  87   [ 'powerpc', 'HAVE_CPU_PPC' ],
  88   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
  89   [ 'alpha', 'HAVE_CPU_ALPHA' ],
  90   [ 'sparc', 'HAVE_CPU_SPARC' ],
  91   [ 'ia64', 'HAVE_CPU_IA64' ],
  92   [ 'hppa', 'HAVE_CPU_HPPA' ],
  93   [ 'm68k', 'HAVE_CPU_M68K' ],
  94   [ 's390', 'HAVE_CPU_S390' ],
  95 ]
  96 foreach h : host_defines
  97   if h.get(0) == host_machine.cpu()
  98     cdata.set(h.get(1), 1)
  99   endif
 100 endforeach
 101 # FIXME: should really be called HOST_CPU or such
 102 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 103
 104 check_headers = [
 105   'dlfcn.h',
 106   'inttypes.h',
 107   'memory.h',
 108   'poll.h',
 109   'stdint.h',
 110   'stdio_ext.h',
 111   'strings.h',
 112   'string.h',
 113   'sys/param.h',
 114   'sys/poll.h',
 115   'sys/prctl.h',
 116   'sys/socket.h',
 117   'sys/stat.h',
 118   'sys/times.h',
 119   'sys/time.h',
 120   'sys/types.h',
 121   'sys/utsname.h',
 122   'sys/wait.h',
 123   'ucontext.h',
 124   'unistd.h',
 125   'valgrind/valgrind.h',
 126   'sys/resource.h',
 127 ]
 128
 129 if host_machine.system() == 'windows'
 130   check_headers += ['winsock2.h']
 131 endif
 132
 133 foreach h : check_headers
 134   if cc.has_header(h)
 135     define = 'HAVE_' + h.underscorify().to_upper()
 136     cdata.set(define, 1)
 137   endif
 138 endforeach
 139
 140 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 141   cdata.set('HAVE_TM_GMTOFF', 1)
 142 endif
 143
 144 check_functions = [
 145   'gmtime_r',
 146   'sigaction',
 147   'getrusage',
 148   'fseeko',
 149   'ftello',
 150   'poll',
 151   'pselect',
 152   'getpagesize',
 153   'clock_gettime',
 154   # These are needed by libcheck
 155   'getline',
 156   'mkstemp',
 157   'alarm',
 158   'gettimeofday',
 159 ]
 160
 161 foreach f : check_functions
 162   if cc.has_function(f)
 163     define = 'HAVE_' + f.underscorify().to_upper()
 164     cdata.set(define, 1)
 165   endif
 166 endforeach
 167
 168 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 169   cdata.set('HAVE_LOCALTIME_R', 1)
 170   # Needed by libcheck
 171   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 172 endif
 173
 174 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 175 # building with MSVC
 176 if cc.get_id() == 'msvc'
 177   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 178 else
 179   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 180 endif
 181
 182 # -------------------------------------------------------------------------------------
 183 # config.h things needed by libcheck
 184 # -------------------------------------------------------------------------------------
 185 if cc.has_function('getpid', prefix : '#include <sys/types.h>\n#include <unistd.h>')
 186   cdata.set('HAVE_GETPID', 1)
 187 elif cc.has_function('_getpid', prefix : '#include <process.h>')
 188   cdata.set('HAVE__GETPID', 1) # Windows (MSVC)
 189 endif
 190 if cc.has_function('strdup', prefix : '#include <string.h>')
 191   cdata.set('HAVE_DECL_STRDUP', 1)
 192 elif cc.has_function('_strdup', prefix : '#include <string.h>')
 193   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 194 endif
 195 if host_machine.system() != 'windows'
 196   cdata.set('HAVE_FORK', 1)
 197 else
 198   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 199   cdata.set('HAVE_FORK', 0)
 200 endif
 201 if cc.has_function('strsignal', prefix : '#include <string.h>')
 202   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 203 endif
 204 # Check for availability of types
 205 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 206   cdata.set('clockid_t', 'int')
 207 endif
 208 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 209   cdata.set('timer_t', 'int')
 210 endif
 211 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 212                       prefix : '#include <time.h>')
 213   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 214 endif
 215 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 216                       prefix : '#include <time.h>')
 217   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 218 endif
 219
 220 # Platform deps; only ws2_32 and execinfo for now
 221 platform_deps = []
 222 if host_machine.system() == 'windows'
 223   platform_deps = [cc.find_library('ws2_32')]
 224 endif
 225
 226 unwind_dep = dependency('libunwind', required : false)
 227 dw_dep = dependency('libdw', required: false)
 228 if unwind_dep.found()
 229   cdata.set('HAVE_UNWIND', 1)
 230   if dw_dep.found()
 231     cdata.set('HAVE_DW', 1)
 232   else
 233     message('Support for backtraces is partial only.')
 234   endif
 235 else
 236   if cc.has_function('backtrace')
 237     cdata.set('HAVE_BACKTRACE', 1)
 238   else
 239       message('NO backtraces support.')
 240   endif
 241 endif
 242
 243 if cc.has_header('execinfo.h')
 244   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 245     cdata.set('HAVE_BACKTRACE', 1)
 246   else
 247     execinfo_dep = cc.find_library('execinfo', required : false)
 248     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 249       cdata.set('HAVE_BACKTRACE', 1)
 250       platform_deps += execinfo_dep
 251     endif
 252   endif
 253 endif
 254
 255 disable_gst_debug = get_option('disable_gst_debug')
 256 if get_option('disable_gst_debug')
 257     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
 258   add_project_arguments(['-Wno-unused'], language: 'c')
 259 endif
 260
 261 configure_file(input : 'config.h.meson',
 262   output : 'config.h',
 263   configuration : cdata)
 264
 265
 266 configinc = include_directories('.')
 267 libsinc = include_directories('libs')
 268 privinc = include_directories('gst')
 269
 270 # Find dependencies
 271 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
 272 gobject_dep = dependency('gobject-2.0')
 273 gmodule_dep = dependency('gmodule-2.0')
 274 if host_machine.system() == 'windows'
 275     gio_dep = dependency('gio-2.0')
 276 else
 277     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
 278 endif
 279
 280 mathlib = cc.find_library('m', required : false)
 281 # Needed for timer_create/settime/delete
 282 # Also provides clock_gettime in glibc < 2.17
 283 rt_lib = cc.find_library('rt', required : false)
 284
 285 gir = find_program('g-ir-scanner', required : false)
 286 gnome = import('gnome')
 287
 288 # Fixme, not very elegant.
 289 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 290
 291 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 292     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 293     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 294     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 295     'gst_init(NULL,NULL);' ]
 296 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 297
 298 gst_c_args = ['-DHAVE_CONFIG_H']
 299 if libtype == 'static'
 300   gst_c_args += ['-DGST_STATIC_COMPILATION']
 301 endif
 302
 303 # Used in gst/parse/meson.build and below
 304 py3 = find_program('python3', required : false)
 305 if not py3.found()
 306   # Maybe 'python' is Python 3
 307   py3 = find_program('python')
 308 endif
 309
 310 subdir('gst')
 311 subdir('libs')
 312 subdir('plugins')
 313 subdir('tools')
 314 subdir('pkgconfig')
 315 subdir('tests')
 316 subdir('po')
 317
 318 if build_machine.system() == 'windows'
 319   message('Disabling gtk-doc while building on Windows')
 320 elif get_option('disable_gtkdoc')
 321   message('gtk-doc is disabled via options')
 322 else
 323   if find_program('gtkdoc-scan', required : false).found()
 324     subdir('docs')
 325   else
 326     message('Not building documentation as gtk-doc was not found')
 327   endif
 328 endif
 329
 330 run_command(py3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')