meson.build

   1 project('libevdev', 'c',
   2         version: '1.9.0', # change autotools version too
   3         license: 'MIT/Expat',
   4         default_options: [ 'c_std=gnu99', 'warning_level=2' ],
   5         meson_version: '>= 0.47.0')
   6
   7 libevdev_version = meson.project_version().split('.')
   8
   9 dir_src         = join_paths(meson.source_root(), 'libevdev')
  10 dir_src_test    = join_paths(meson.source_root(), 'test')
  11
  12 # Include directories
  13 includes_include = include_directories('include')
  14
  15 # DO NOT MODIFY THIS
  16 # Use symbol versioning instead.
  17 libevdev_lt_c=5
  18 libevdev_lt_r=0
  19 libevdev_lt_a=3
  20
  21 # convert to soname
  22 libevdev_so_version = '@0@.@1@.@2@'.format((libevdev_lt_c - libevdev_lt_a),
  23                                            libevdev_lt_a, libevdev_lt_r)
  24
  25
  26 # Compiler setup
  27 cc = meson.get_compiler('c')
  28 cppflags = ['-Wno-unused-parameter', '-fvisibility=hidden']
  29 cflags = cppflags + ['-Wmissing-prototypes', '-Wstrict-prototypes']
  30 add_project_arguments(cflags, language: 'c')
  31 add_project_arguments(cppflags, language: 'cpp')
  32
  33 # config.h
  34 config_h = configuration_data()
  35 config_h.set('_GNU_SOURCE', '1')
  36
  37 # Dependencies
  38 pkgconfig = import('pkgconfig')
  39 dep_lm = cc.find_library('m')
  40
  41 # event-names.h
  42 input_h = join_paths(meson.source_root(), 'include', 'linux', 'input.h')
  43 input_event_codes_h = join_paths(meson.source_root(), 'include', 'linux', 'input-event-codes.h')
  44
  45 make_event_names = find_program('libevdev/make-event-names.py')
  46 event_names_h = configure_file(input: 'libevdev/libevdev.h',
  47                                output: 'event-names.h',
  48                                command: [make_event_names, input_h, input_event_codes_h],
  49                                capture: true)
  50
  51
  52 # libevdev.so
  53 install_headers('libevdev/libevdev.h',
  54                 'libevdev/libevdev-uinput.h',
  55                 subdir: 'libevdev-1.0/libevdev')
  56 src_libevdev = [
  57         event_names_h,
  58         'libevdev/libevdev.h',
  59         'libevdev/libevdev-int.h',
  60         'libevdev/libevdev-util.h',
  61         'libevdev/libevdev-uinput.c',
  62         'libevdev/libevdev-uinput.h',
  63         'libevdev/libevdev-uinput-int.h',
  64         'libevdev/libevdev.c',
  65         'libevdev/libevdev-names.c',
  66         'include/linux/input-event-codes.h',
  67         'include/linux/input.h',
  68         'include/linux/uinput.h'
  69 ]
  70
  71 mapfile = join_paths(dir_src, 'libevdev.sym')
  72 version_flag = '-Wl,--version-script,@0@'.format(mapfile)
  73 lib_libevdev = library('evdev',
  74         src_libevdev,
  75         include_directories: [includes_include],
  76         dependencies: [],
  77         version: libevdev_so_version,
  78         link_args: version_flag,
  79         link_depends: mapfile,
  80         install: true
  81 )
  82
  83 dep_libevdev = declare_dependency(link_with: lib_libevdev)
  84
  85 pkgconfig.generate(
  86         filebase: 'libevdev',
  87         name: 'libevdev',
  88         description: 'Handler library for evdev events',
  89         version: meson.project_version(),
  90         libraries: lib_libevdev,
  91         subdirs: 'libevdev-1.0',
  92 )
  93
  94 man_config = configuration_data()
  95 man_config.set('PACKAGE_VERSION', meson.project_version())
  96 manpage = configure_file(input: 'doc/libevdev.man.in',
  97                          output: 'libevdev.3',
  98                          configuration: man_config)
  99 install_man(manpage)
 100
 101
 102 # tools
 103 executable('libevdev-events',
 104            sources: ['tools/libevdev-events.c'],
 105            include_directories: [includes_include],
 106            dependencies: dep_libevdev,
 107            install: false)
 108 executable('touchpad-edge-detector',
 109            sources: ['tools/touchpad-edge-detector.c'],
 110            include_directories: [includes_include],
 111            dependencies: [dep_libevdev, dep_lm],
 112            install: true)
 113 executable('mouse-dpi-tool',
 114            sources: ['tools/mouse-dpi-tool.c'],
 115            include_directories: [includes_include],
 116            dependencies: dep_libevdev,
 117            install: true)
 118 executable('libevdev-tweak-device',
 119            sources: ['tools/libevdev-tweak-device.c'],
 120            include_directories: [includes_include],
 121            dependencies: dep_libevdev,
 122            install: true)
 123
 124
 125 # tests
 126 dep_check = dependency('check', version: '>= 0.9.9',
 127                        required: get_option('tests'))
 128 if dep_check.found()
 129         executable('test-link',
 130                    sources: ['test/test-link.c'],
 131                    include_directories: [includes_include],
 132                    dependencies: dep_libevdev,
 133                    install: false)
 134         executable('test-compile-pedantic',
 135                    sources: ['test/test-compile-pedantic.c'],
 136                    c_args: ['-pedantic', '-Werror', '-std=c89'],
 137                    include_directories: [includes_include],
 138                    dependencies: dep_libevdev,
 139                    install: false)
 140
 141         src_common = [
 142                 'test/test-common-uinput.c',
 143                 'test/test-common-uinput.h',
 144                 'test/test-common.c',
 145                 'test/test-common.h',
 146                 'test/test-main.c',
 147         ]
 148         test_event_codes = executable('test-event-codes',
 149                                       sources: src_common + [
 150                                         'test/test-event-codes.c',
 151                                         'test/test-event-names.c',
 152                                         'test/test-context.c',
 153                                       ],
 154                                       include_directories: [includes_include],
 155                                       dependencies: [dep_libevdev, dep_check],
 156                                       install: false)
 157         test('test-event-codes', test_event_codes, suite: 'library')
 158
 159         test_internals = executable('test-internals',
 160                                     sources: src_common + [
 161                                         'test/test-int-queue.c',
 162                                     ],
 163                                     include_directories: [includes_include],
 164                                     dependencies: [dep_libevdev, dep_check],
 165                                     install: false)
 166         test('test-internals', test_internals, suite: 'library')
 167
 168         test_uinput = executable('test-uinput',
 169                                  sources: src_common + [
 170                                         'test/test-uinput.c',
 171                                  ],
 172                                  include_directories: [includes_include],
 173                                  dependencies: [dep_libevdev, dep_check],
 174                                  install: false)
 175         test('test-uinput', test_uinput, suite: 'library')
 176
 177         test_libevdev = executable('test-libevdev',
 178                                    sources: src_common + [
 179                                         'test/test-libevdev-init.c',
 180                                         'test/test-libevdev-has-event.c',
 181                                         'test/test-libevdev-events.c',
 182                                    ],
 183                                    include_directories: [includes_include],
 184                                    dependencies: [dep_libevdev, dep_check],
 185                                    install: false)
 186         test('test-libevdev', test_libevdev, suite: 'library')
 187
 188         test_kernel = executable('test-kernel',
 189                                  sources: src_common + [
 190                                         'test/test-kernel.c',
 191                                  ],
 192                                  include_directories: [includes_include],
 193                                  dependencies: [dep_libevdev, dep_check],
 194                                  install: false)
 195         test('test-kernel', test_kernel, suite: 'kernel')
 196
 197
 198         valgrind = find_program('valgrind', required: false)
 199         if valgrind.found()
 200                 valgrind_env = environment()
 201                 valgrind_env.set('CK_TIMEOUT_MULTIPLIER', '10')
 202                 valgrind_env.set('CK_FORK', 'no')
 203                 valgrind_env.set('RUNNING_ON_VALGRIND', '1')
 204                 valgrind_suppressions_file = join_paths(dir_src_test, 'valgrind.suppressions')
 205                 add_test_setup('valgrind',
 206                                 exe_wrapper: [ valgrind,
 207                                                 '--leak-check=full',
 208                                                 '--gen-suppressions=all',
 209                                                 '--error-exitcode=3',
 210                                                 '--suppressions=' + valgrind_suppressions_file ],
 211                                 env:  valgrind_env,
 212                                 timeout_multiplier: 100)
 213         else
 214                 message('valgrind not found, disabling valgrind test suite')
 215         endif
 216
 217         test_static_link = find_program('test/test-static-symbols-leak.sh')
 218         test('static-symbols-leak', test_static_link,
 219              args: [meson.current_build_dir()],
 220              suite: 'static')
 221 endif
 222
 223 doxygen = find_program('doxygen', required: get_option('documentation'))
 224 if doxygen.found()
 225         doxygen = find_program('doxygen')
 226
 227         src_doxygen = files(
 228                 # source files
 229                 join_paths(dir_src, 'libevdev.h'),
 230                 join_paths(dir_src, 'libevdev-uinput.h'),
 231                 # style files
 232                 'doc/style/bootstrap.css',
 233                 'doc/style/customdoxygen.css',
 234                 'doc/style/doxy-boot.js',
 235                 'doc/style/dynsections.js',
 236                 'doc/style/footer.html',
 237                 'doc/style/header.html',
 238                 'doc/style/layout.xml',
 239                 'doc/style/libevdevdoxygen.css',
 240                 'doc/style/LICENSE',
 241                 'doc/style/README.md',
 242                 'doc/style/style.css',
 243         )
 244         doxyfiles = []
 245         foreach f: src_doxygen
 246                 df = configure_file(input: f,
 247                                     output: '@PLAINNAME@',
 248                                     copy: true)
 249                 doxyfiles += [df]
 250         endforeach
 251
 252         doc_config = configuration_data()
 253         doc_config.set('PACKAGE_NAME', meson.project_name())
 254         doc_config.set('PACKAGE_VERSION', meson.project_version())
 255         doc_config.set('builddir', meson.current_build_dir())
 256         doc_config.set('top_srcdir', meson.source_root())
 257         doc_config.set('srcdir', join_paths(meson.source_root(), 'doc'))
 258
 259         doxyfile = configure_file(input: 'doc/libevdev.doxygen.in',
 260                                   output: 'libevdev.doxygen',
 261                                   configuration: doc_config)
 262         custom_target('doxygen',
 263                       input: [doxyfiles, doxyfile] + src_doxygen,
 264                       output: ['.'],
 265                       command: [doxygen, doxyfile],
 266                       install: false,
 267                       build_by_default: true)
 268 endif
 269
 270 # Coverity breaks because it doesn't define _Float128 correctly, you'll end
 271 # up with a bunch of messages in the form:
 272 # "/usr/include/stdlib.h", line 133: error #20: identifier "_Float128" is
 273 #           undefined
 274 #   extern _Float128 strtof128 (const char *__restrict __nptr,
 275 #          ^
 276 # We don't use float128 ourselves, it gets pulled in from math.h or
 277 # something, so let's just define it as uint128 and move on.
 278 # Unfortunately we can't detect the coverity build at meson configure
 279 # time, we only know it fails at runtime. So make this an option instead, to
 280 # be removed when coverity fixes this again.
 281 if get_option('coverity')
 282         config_h.set('_Float128', '__uint128_t')
 283         config_h.set('_Float32', 'int')
 284         config_h.set('_Float32x', 'int')
 285         config_h.set('_Float64', 'long')
 286         config_h.set('_Float64x', 'long')
 287 endif
 288
 289 ############ output files ############
 290 configure_file(output: 'config.h', configuration: config_h)