meson.build

   1 project('at-spi2-atk', 'c',
   2         version: '2.34.1',
   3         license: 'LGPLv2.1+',
   4         default_options: [
   5           'buildtype=debugoptimized',
   6           'warning_level=1',
   7           'c_std=c99',
   8         ],
   9         meson_version : '>= 0.40.1')
  10
  11 atk_bridge_soversion = 0
  12 atk_bridge_libversion = '0.0.0'
  13
  14 cc = meson.get_compiler('c')
  15 host_system = host_machine.system()
  16
  17 # XXX: for strcasecmp(); should use g_ascii_strcasecmp()
  18 add_project_arguments([ '-D_DEFAULT_SOURCE', ], language: 'c')
  19
  20 # We are using deprecated API; don't warn if we're building stable
  21 # releases, to avoid making the build logs less readable. We keep
  22 # the warnings during development cycles, to remind us we should
  23 # port away from deprecated API
  24 if meson.project_version().split('.').get(1).to_int().is_even()
  25   add_project_arguments([ '-DATK_DISABLE_DEPRECATION_WARNINGS' ], language: 'c')
  26 endif
  27
  28 # XXX: Unused
  29 at_spi_conf = configuration_data()
  30 at_spi_conf.set('GETTEXT_PACKAGE', meson.project_name())
  31 configure_file(output: 'config.h',
  32                configuration: at_spi_conf)
  33
  34 root_inc = include_directories('.')
  35
  36 # Dependencies
  37 libdbus_req_version = '>= 1.5'
  38 glib_req_version = '>= 2.32.0'
  39 gobject_req_version = '>= 2.0.0'
  40 gmodule_req_version = '>= 2.0.0'
  41 atk_req_version = '>= 2.33.3'
  42 atspi_req_version = '>= 2.33.2'
  43 libxml_req_version = '>= 2.9.1'
  44
  45 libdbus_dep = dependency('dbus-1', version: libdbus_req_version)
  46 glib_dep = dependency('glib-2.0', version: glib_req_version)
  47 gobject_dep = dependency('gobject-2.0', version: gobject_req_version)
  48 gmodule_dep = dependency('gmodule-2.0', version: gmodule_req_version)
  49 atk_dep = dependency('atk', version: atk_req_version)
  50 atspi_dep = dependency('atspi-2', version: atspi_req_version)
  51 libxml_dep = dependency('libxml-2.0', version: libxml_req_version, required: false)
  52
  53 if get_option('disable_p2p')
  54   p2p_cflags = [ '-DDISABLE_P2P' ]
  55 else
  56   p2p_cflags = []
  57 endif
  58
  59 install_data('at-spi2-atk.desktop',
  60              install_dir: join_paths(get_option('libdir'), 'gnome-settings-daemon-3.0', 'gtk-modules'))
  61
  62 subdir('droute')
  63 subdir('atk-adaptor')
  64 subdir('tests')