meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', required : false)
  20 have_objc = add_languages('objc', required : false)
  21
  22 glib_req = '>= 2.40.0'
  23 orc_req = '>= 0.4.24'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27 soversion = 0
  28 # maintaining compatibility with the previous libtool versioning
  29 # current = minor * 100 + micro
  30 curversion = gst_version_minor * 100 + gst_version_micro
  31 libversion = '@0@.@1@.0'.format(soversion, curversion)
  32 osxversion = curversion + 1
  33
  34 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  35
  36 cc = meson.get_compiler('c')
  37 host_system = host_machine.system()
  38
  39 if cc.get_id() == 'msvc'
  40   # Ignore several spurious warnings for things gstreamer does very commonly
  41   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  42   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  43   # NOTE: Only add warnings here if you are sure they're spurious
  44   add_project_arguments(
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50       language : 'c')
  51   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  52   # are built with MinGW
  53   noseh_link_args = ['/SAFESEH:NO']
  54 else
  55   noseh_link_args = []
  56 endif
  57
  58 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  59   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  60 endif
  61
  62 # Symbol visibility
  63 if cc.has_argument('-fvisibility=hidden')
  64   add_project_arguments('-fvisibility=hidden', language: 'c')
  65 endif
  66
  67 # Disable strict aliasing
  68 if cc.has_argument('-fno-strict-aliasing')
  69   add_project_arguments('-fno-strict-aliasing', language: 'c')
  70 endif
  71
  72 # Define G_DISABLE_DEPRECATED for development versions
  73 if gst_version_is_dev
  74   message('Disabling deprecated GLib API')
  75   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  76 endif
  77
  78 cast_checks = get_option('gobject-cast-checks')
  79 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  80   message('Disabling GLib cast checks')
  81   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  82 endif
  83
  84 glib_asserts = get_option('glib-asserts')
  85 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  86   message('Disabling GLib asserts')
  87   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  88 endif
  89
  90 glib_checks = get_option('glib-checks')
  91 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  92   message('Disabling GLib checks')
  93   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  94 endif
  95
  96 core_conf = configuration_data()
  97 check_headers = [
  98   ['HAVE_DLFCN_H', 'dlfcn.h'],
  99   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 100   ['HAVE_INTTYPES_H', 'inttypes.h'],
 101   ['HAVE_MEMORY_H', 'memory.h'],
 102   ['HAVE_PROCESS_H', 'process.h'],
 103   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 104   ['HAVE_STDINT_H', 'stdint.h'],
 105   ['HAVE_STDLIB_H', 'stdlib.h'],
 106   ['HAVE_STRINGS_H', 'strings.h'],
 107   ['HAVE_STRING_H', 'string.h'],
 108   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 109   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 110   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 111   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 112   ['HAVE_UNISTD_H', 'unistd.h'],
 113   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 114   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 115   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 116 ]
 117 foreach h : check_headers
 118   if cc.has_header(h.get(1))
 119     core_conf.set(h.get(0), 1)
 120   endif
 121 endforeach
 122
 123 check_functions = [
 124   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 125   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 126   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 127   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 128   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 129 ]
 130
 131 libm = cc.find_library('m', required : false)
 132 foreach f : check_functions
 133   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 134     core_conf.set(f.get(0), 1)
 135   endif
 136 endforeach
 137
 138 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 139 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 140 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 141 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 142 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 143
 144 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 145 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 146 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 147 core_conf.set_quoted('VERSION', gst_version)
 148 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 149 core_conf.set_quoted('GST_API_VERSION', api_version)
 150 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 151 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 152
 153 install_plugins_helper = get_option('install_plugins_helper')
 154 if install_plugins_helper == ''
 155   install_plugins_helper = join_paths(get_option('prefix'),
 156                                       get_option('libexecdir'),
 157                                       'gst-install-plugins-helper')
 158 endif
 159 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 160
 161 warning_flags = [
 162   '-Wmissing-declarations',
 163   '-Wredundant-decls',
 164   '-Wundef',
 165   '-Wwrite-strings',
 166   '-Wformat',
 167   '-Wformat-nonliteral',
 168   '-Wformat-security',
 169   '-Winit-self',
 170   '-Wmissing-include-dirs',
 171   '-Waddress',
 172   '-Wno-multichar',
 173   '-Wvla',
 174   '-Wpointer-arith',
 175 ]
 176
 177 warning_c_flags = [
 178   '-Wmissing-prototypes',
 179   '-Wdeclaration-after-statement',
 180 ]
 181
 182 warning_cxx_flags = [
 183   '-Waggregate-return',
 184 ]
 185
 186 if have_cxx
 187   cxx = meson.get_compiler('cpp')
 188   foreach extra_arg : warning_cxx_flags
 189     if cxx.has_argument (extra_arg)
 190       add_project_arguments([extra_arg], language: 'cpp')
 191     endif
 192   endforeach
 193 endif
 194
 195 foreach extra_arg : warning_flags
 196   if cc.has_argument (extra_arg)
 197     add_project_arguments([extra_arg], language: 'c')
 198   endif
 199   if have_cxx and cxx.has_argument (extra_arg)
 200     add_project_arguments([extra_arg], language: 'cpp')
 201   endif
 202 endforeach
 203
 204 foreach extra_arg : warning_c_flags
 205   if cc.has_argument (extra_arg)
 206     add_project_arguments([extra_arg], language: 'c')
 207   endif
 208 endforeach
 209
 210 # GStreamer package name and origin url
 211 gst_package_name = get_option('package-name')
 212 if gst_package_name == ''
 213   if gst_version_nano == 0
 214     gst_package_name = 'GStreamer Base Plug-ins source release'
 215   elif gst_version_nano == 1
 216     gst_package_name = 'GStreamer Base Plug-ins git'
 217   else
 218     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 219   endif
 220 endif
 221 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 222 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 223
 224 # FIXME: These should be configure options
 225 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 226 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 227
 228 # Set whether the audioresampling method should be detected at runtime
 229 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 230
 231 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 232 if get_option('default_library') == 'static'
 233   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 234 endif
 235
 236 # X11 checks are for sys/ and tests/
 237 x11_dep = dependency('x11', required : get_option('x11'))
 238 # GLib checks are for the entire project
 239 # Almost everything that uses glib also uses gobject
 240 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 241              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 242 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 243 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 244 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : host_system != 'windows',
 245                          fallback: ['glib', 'libgiounix_dep'])
 246 gmodule_dep = dependency('gmodule-no-export-2.0',
 247                          fallback: ['glib', 'libgmodule_dep'])
 248
 249 # some of the examples can use gdk-pixbuf and GTK+3
 250 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 251 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 252 # TODO: https://github.com/mesonbuild/meson/issues/3941
 253 if not get_option('x11').disabled()
 254   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 255 else
 256   gtk_x11_dep = dependency('', required : false)
 257 endif
 258 # gtk+ quartz backend is only available on macOS
 259 if host_system == 'darwin'
 260   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 261 else
 262   gtk_quartz_dep = dependency('', required : false)
 263 endif
 264
 265 core_conf.set('HAVE_X', x11_dep.found())
 266 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 267
 268 if gio_dep.type_name() == 'pkgconfig'
 269     core_conf.set_quoted('GIO_MODULE_DIR',
 270         gio_dep.get_pkgconfig_variable('giomoduledir'))
 271     core_conf.set_quoted('GIO_LIBDIR',
 272         gio_dep.get_pkgconfig_variable('libdir'))
 273     core_conf.set_quoted('GIO_PREFIX',
 274         gio_dep.get_pkgconfig_variable('prefix'))
 275 else
 276     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 277       get_option('libdir'), 'gio/modules'))
 278     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 279       get_option('libdir')))
 280     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 281 endif
 282
 283 configinc = include_directories('.')
 284 libsinc = include_directories('gst-libs')
 285
 286 # To use the subproject make subprojects directory
 287 # and put gstreamer meson git there (symlinking is fine)
 288 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 289   fallback : ['gstreamer', 'gst_dep'])
 290 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 291   fallback : ['gstreamer', 'gst_base_dep'])
 292 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 293   fallback : ['gstreamer', 'gst_net_dep'])
 294 if host_system != 'windows'
 295   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 296     required : get_option('tests'),
 297     fallback : ['gstreamer', 'gst_check_dep'])
 298 endif
 299 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 300   fallback : ['gstreamer', 'gst_controller_dep'])
 301
 302 have_orcc = false
 303 orcc_args = []
 304 # Used by various libraries/elements that use Orc code
 305 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'))
 306 orcc = find_program('orcc', required : get_option('orc'))
 307 if orc_dep.found() and orcc.found()
 308   have_orcc = true
 309   orcc_args = [orcc, '--include', 'glib.h']
 310   core_conf.set('HAVE_ORC', 1)
 311 else
 312   message('Orc Compiler not found or disabled, will use backup C code')
 313   core_conf.set('DISABLE_ORC', 1)
 314 endif
 315
 316 # Used to build SSE* things in audio-resampler
 317 sse_args = '-msse'
 318 sse2_args = '-msse2'
 319 sse41_args = '-msse4.1'
 320
 321 have_sse = cc.has_argument(sse_args)
 322 have_sse2 = cc.has_argument(sse2_args)
 323 have_sse41 = cc.has_argument(sse41_args)
 324
 325 if gst_dep.type_name() == 'internal'
 326     gst_proj = subproject('gstreamer')
 327
 328     if not gst_proj.get_variable('gst_debug')
 329         message('GStreamer debug system is disabled')
 330         add_project_arguments('-Wno-unused', language: 'c')
 331     else
 332         message('GStreamer debug system is enabled')
 333     endif
 334 else
 335     # We can't check that in the case of subprojects as we won't
 336     # be able to build against an internal dependency (which is not built yet)
 337     if not cc.compiles('''
 338 #include <gst/gstconfig.h>
 339 #ifdef GST_DISABLE_GST_DEBUG
 340 #error "debugging disabled, make compiler fail"
 341 #endif''' , dependencies: gst_dep)
 342         message('GStreamer debug system is disabled')
 343         add_project_arguments('-Wno-unused', language: 'c')
 344     else
 345         message('GStreamer debug system is enabled')
 346     endif
 347 endif
 348
 349 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 350 gnome = import('gnome')
 351 build_gir = gir.found() and not meson.is_cross_build()
 352 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 353     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 354     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 355     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 356     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 357     'gst_init(NULL,NULL);' ]
 358
 359 pkgconfig = import('pkgconfig')
 360 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 361 if get_option('default_library') == 'shared'
 362   # If we don't build static plugins there is no need to generate pc files
 363   plugins_pkgconfig_install_dir = disabler()
 364 endif
 365
 366 subdir('gst-libs')
 367 subdir('gst')
 368 subdir('ext')
 369 subdir('sys')
 370 if not get_option('tools').disabled()
 371   subdir('tools')
 372 endif
 373 subdir('tests')
 374 subdir('pkgconfig')
 375
 376 # xgettext is optional (on Windows for instance)
 377 if find_program('xgettext', required : get_option('nls')).found()
 378   core_conf.set('ENABLE_NLS', 1)
 379   subdir('po')
 380 endif
 381
 382 if build_machine.system() == 'windows'
 383   message('Disabling gtk-doc while building on Windows')
 384 else
 385   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 386     subdir('docs')
 387   else
 388     message('Not building documentation as gtk-doc was not found')
 389   endif
 390 endif
 391
 392 # Use core_conf after all subdirs have set values
 393 configure_file(output : 'config.h', configuration : core_conf)
 394
 395 python3 = import('python3').find_python()
 396 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')