meson.build

   1 project(
   2     'libxkbcommon',
   3     'c',
   4     version: '1.0.1',
   5     default_options: [
   6         'c_std=c99',
   7         'warning_level=2',
   8         'b_lundef=true',
   9     ],
  10     meson_version : '>= 0.49.0',
  11 )
  12 pkgconfig = import('pkgconfig')
  13 cc = meson.get_compiler('c')
  14
  15 dir_libexec = get_option('prefix')/get_option('libexecdir')/'xkbcommon'
  16
  17 # Compiler flags.
  18 cflags = [
  19     '-fno-strict-aliasing',
  20     '-fsanitize-undefined-trap-on-error',
  21     '-Wno-unused-parameter',
  22     '-Wno-missing-field-initializers',
  23     '-Wpointer-arith',
  24     '-Wmissing-declarations',
  25     '-Wformat=2',
  26     '-Wstrict-prototypes',
  27     '-Wmissing-prototypes',
  28     '-Wnested-externs',
  29     '-Wbad-function-cast',
  30     '-Wshadow',
  31     '-Wlogical-op',
  32     '-Wdate-time',
  33     '-Wwrite-strings',
  34     '-Wno-documentation-deprecated-sync',
  35 ]
  36 add_project_arguments(cc.get_supported_arguments(cflags), language: 'c')
  37
  38
  39 # The XKB config root.
  40 XKBCONFIGROOT = get_option('xkb-config-root')
  41 if XKBCONFIGROOT == ''
  42     xkeyboard_config_dep = dependency('xkeyboard-config', required: false)
  43     if xkeyboard_config_dep.found()
  44         XKBCONFIGROOT = xkeyboard_config_dep.get_pkgconfig_variable('xkb_base')
  45     else
  46         XKBCONFIGROOT = get_option('prefix')/get_option('datadir')/'X11'/'xkb'
  47   endif
  48 endif
  49
  50 XKBCONFIGEXTRAPATH = get_option('xkb-config-extra-path')
  51 if XKBCONFIGEXTRAPATH == ''
  52     XKBCONFIGEXTRAPATH = join_paths(get_option('prefix'), get_option('sysconfdir'), 'xkb')
  53 endif
  54
  55 # The X locale directory for compose.
  56 XLOCALEDIR = get_option('x-locale-root')
  57 if XLOCALEDIR == ''
  58     XLOCALEDIR = get_option('prefix')/get_option('datadir')/'X11'/'locale'
  59 endif
  60
  61
  62 # config.h.
  63 configh_data = configuration_data()
  64 configh_data.set('EXIT_INVALID_USAGE', '2')
  65 configh_data.set_quoted('LIBXKBCOMMON_VERSION', meson.project_version())
  66 configh_data.set_quoted('LIBXKBCOMMON_TOOL_PATH', dir_libexec)
  67 # Like AC_USE_SYSTEM_EXTENSIONS, what #define to use to get extensions
  68 # beyond the base POSIX function set.
  69 if host_machine.system() == 'sunos'
  70   system_extensions = '__EXTENSIONS__'
  71 else
  72   system_extensions = '_GNU_SOURCE'
  73 endif
  74 configh_data.set(system_extensions, 1)
  75 system_ext_define = '#define ' + system_extensions
  76 configh_data.set_quoted('DFLT_XKB_CONFIG_ROOT', XKBCONFIGROOT)
  77 configh_data.set_quoted('DFLT_XKB_CONFIG_EXTRA_PATH', XKBCONFIGEXTRAPATH)
  78 configh_data.set_quoted('XLOCALEDIR', XLOCALEDIR)
  79 configh_data.set_quoted('DEFAULT_XKB_RULES', get_option('default-rules'))
  80 configh_data.set_quoted('DEFAULT_XKB_MODEL', get_option('default-model'))
  81 configh_data.set_quoted('DEFAULT_XKB_LAYOUT', get_option('default-layout'))
  82 if get_option('default-variant') != ''
  83     configh_data.set_quoted('DEFAULT_XKB_VARIANT', get_option('default-variant'))
  84 else
  85     configh_data.set('DEFAULT_XKB_VARIANT', 'NULL')
  86 endif
  87 if get_option('default-options') != ''
  88     configh_data.set_quoted('DEFAULT_XKB_OPTIONS', get_option('default-options'))
  89 else
  90     configh_data.set('DEFAULT_XKB_OPTIONS', 'NULL')
  91 endif
  92 if cc.has_header('unistd.h')
  93     configh_data.set('HAVE_UNISTD_H', 1)
  94 endif
  95 if cc.links('int main(){if(__builtin_expect(1<0,0)){}}', name: '__builtin_expect')
  96     configh_data.set('HAVE___BUILTIN_EXPECT', 1)
  97 endif
  98 if cc.has_header_symbol('unistd.h', 'eaccess', prefix: system_ext_define)
  99     configh_data.set('HAVE_EACCESS', 1)
 100 endif
 101 if cc.has_header_symbol('unistd.h', 'euidaccess', prefix: system_ext_define)
 102     configh_data.set('HAVE_EUIDACCESS', 1)
 103 endif
 104 if cc.has_header_symbol('sys/mman.h', 'mmap')
 105     configh_data.set('HAVE_MMAP', 1)
 106 endif
 107 if cc.has_header_symbol('stdlib.h', 'mkostemp', prefix: system_ext_define)
 108     configh_data.set('HAVE_MKOSTEMP', 1)
 109 endif
 110 if cc.has_header_symbol('fcntl.h', 'posix_fallocate', prefix: system_ext_define)
 111     configh_data.set('HAVE_POSIX_FALLOCATE', 1)
 112 endif
 113 if cc.has_header_symbol('string.h', 'strndup', prefix: system_ext_define)
 114     configh_data.set('HAVE_STRNDUP', 1)
 115 endif
 116 if cc.has_header_symbol('stdio.h', 'asprintf', prefix: system_ext_define)
 117     configh_data.set('HAVE_ASPRINTF', 1)
 118 elif cc.has_header_symbol('stdio.h', 'vasprintf', prefix: system_ext_define)
 119     configh_data.set('HAVE_VASPRINTF', 1)
 120 endif
 121 if cc.has_header_symbol('stdlib.h', 'secure_getenv', prefix: system_ext_define)
 122     configh_data.set('HAVE_SECURE_GETENV', 1)
 123 elif cc.has_header_symbol('stdlib.h', '__secure_getenv', prefix: system_ext_define)
 124     configh_data.set('HAVE___SECURE_GETENV', 1)
 125 else
 126     message('C library does not support secure_getenv, using getenv instead')
 127 endif
 128 have_getopt_long = cc.has_header_symbol('getopt.h', 'getopt_long',
 129                                         prefix: '#define _GNU_SOURCE')
 130 if not cc.has_header_symbol('limits.h', 'PATH_MAX', prefix: system_ext_define)
 131     if host_machine.system() == 'windows'
 132         # see https://docs.microsoft.com/en-us/windows/win32/fileio/naming-a-file#maximum-path-length-limitation
 133         configh_data.set('PATH_MAX', 260)
 134     else
 135         configh_data.set('PATH_MAX', 4096)
 136     endif
 137 endif
 138
 139 # Silence some security & deprecation warnings on MSVC
 140 # for some unix/C functions we use.
 141 # https://docs.microsoft.com/en-us/cpp/error-messages/compiler-warnings/compiler-warning-level-3-c4996?view=vs-2019
 142 configh_data.set('_CRT_SECURE_NO_WARNINGS', 1)
 143 configh_data.set('_CRT_NONSTDC_NO_WARNINGS', 1)
 144 configh_data.set('_CRT_NONSTDC_NO_DEPRECATE', 1)
 145 # Reduce unnecessary includes on MSVC.
 146 configh_data.set('WIN32_LEAN_AND_MEAN', 1)
 147
 148 # Supports -Wl,--version-script?
 149 have_version_script = cc.links(
 150     'int main(){}',
 151     args: '-Wl,--version-script=' + meson.source_root()/'xkbcommon.map',
 152     name: '-Wl,--version-script',
 153 )
 154
 155
 156 # libxkbcommon.
 157 # Note: we use some yacc extensions, which work with either GNU bison
 158 # (preferred) or byacc (with backtracking enabled).
 159 bison = find_program('bison', 'win_bison', required: false)
 160 if bison.found()
 161     yacc_gen = generator(
 162         bison,
 163         output: ['@BASENAME@.c', '@BASENAME@.h'],
 164         arguments: ['--defines=@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 165     )
 166 else
 167     byacc = find_program('byacc', required: false)
 168     if byacc.found()
 169         yacc_gen = generator(
 170             byacc,
 171             output: ['@BASENAME@.c', '@BASENAME@.h'],
 172             arguments: ['-H', '@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 173         )
 174     else
 175         error('Could not find a compatible YACC program (bison or byacc)')
 176     endif
 177 endif
 178 libxkbcommon_sources = [
 179     'src/compose/parser.c',
 180     'src/compose/parser.h',
 181     'src/compose/paths.c',
 182     'src/compose/paths.h',
 183     'src/compose/state.c',
 184     'src/compose/table.c',
 185     'src/compose/table.h',
 186     'src/xkbcomp/action.c',
 187     'src/xkbcomp/action.h',
 188     'src/xkbcomp/ast.h',
 189     'src/xkbcomp/ast-build.c',
 190     'src/xkbcomp/ast-build.h',
 191     'src/xkbcomp/compat.c',
 192     'src/xkbcomp/expr.c',
 193     'src/xkbcomp/expr.h',
 194     'src/xkbcomp/include.c',
 195     'src/xkbcomp/include.h',
 196     'src/xkbcomp/keycodes.c',
 197     'src/xkbcomp/keymap.c',
 198     'src/xkbcomp/keymap-dump.c',
 199     'src/xkbcomp/keywords.c',
 200     yacc_gen.process('src/xkbcomp/parser.y'),
 201     'src/xkbcomp/parser-priv.h',
 202     'src/xkbcomp/rules.c',
 203     'src/xkbcomp/rules.h',
 204     'src/xkbcomp/scanner.c',
 205     'src/xkbcomp/symbols.c',
 206     'src/xkbcomp/types.c',
 207     'src/xkbcomp/vmod.c',
 208     'src/xkbcomp/vmod.h',
 209     'src/xkbcomp/xkbcomp.c',
 210     'src/xkbcomp/xkbcomp-priv.h',
 211     'src/atom.c',
 212     'src/atom.h',
 213     'src/context.c',
 214     'src/context.h',
 215     'src/context-priv.c',
 216     'src/darray.h',
 217     'src/keysym.c',
 218     'src/keysym.h',
 219     'src/keysym-utf.c',
 220     'src/ks_tables.h',
 221     'src/keymap.c',
 222     'src/keymap.h',
 223     'src/keymap-priv.c',
 224     'src/scanner-utils.h',
 225     'src/state.c',
 226     'src/text.c',
 227     'src/text.h',
 228     'src/utf8.c',
 229     'src/utf8.h',
 230     'src/utils.c',
 231     'src/utils.h',
 232 ]
 233 libxkbcommon_link_args = []
 234 if have_version_script
 235     libxkbcommon_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbcommon.map'
 236 endif
 237 libxkbcommon = library(
 238     'xkbcommon',
 239     'xkbcommon/xkbcommon.h',
 240     libxkbcommon_sources,
 241     link_args: libxkbcommon_link_args,
 242     link_depends: 'xkbcommon.map',
 243     gnu_symbol_visibility: 'hidden',
 244     version: '0.0.0',
 245     install: true,
 246     include_directories: include_directories('src'),
 247 )
 248 install_headers(
 249     'xkbcommon/xkbcommon.h',
 250     'xkbcommon/xkbcommon-compat.h',
 251     'xkbcommon/xkbcommon-compose.h',
 252     'xkbcommon/xkbcommon-keysyms.h',
 253     'xkbcommon/xkbcommon-names.h',
 254     subdir: 'xkbcommon',
 255 )
 256 libxkbcommon_dep = declare_dependency(
 257     link_with: libxkbcommon,
 258 )
 259 pkgconfig.generate(
 260     libxkbcommon,
 261     name: 'xkbcommon',
 262     filebase: 'xkbcommon',
 263     version: meson.project_version(),
 264     description: 'XKB API common to servers and clients',
 265 )
 266
 267
 268 # libxkbcommon-x11.
 269 if get_option('enable-x11')
 270     xcb_dep = dependency('xcb', version: '>=1.10', required: false)
 271     xcb_xkb_dep = dependency('xcb-xkb', version: '>=1.10', required: false)
 272     if not xcb_dep.found() or not xcb_xkb_dep.found()
 273         error('''X11 support requires xcb-xkb >= 1.10 which was not found.
 274 You can disable X11 support with -Denable-x11=false.''')
 275     endif
 276
 277     libxkbcommon_x11_sources = [
 278         'src/x11/keymap.c',
 279         'src/x11/state.c',
 280         'src/x11/util.c',
 281         'src/x11/x11-priv.h',
 282         'src/context.h',
 283         'src/context-priv.c',
 284         'src/keymap.h',
 285         'src/keymap-priv.c',
 286         'src/atom.h',
 287         'src/atom.c',
 288     ]
 289     libxkbcommon_x11_link_args = []
 290     if have_version_script
 291         libxkbcommon_x11_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbcommon-x11.map'
 292     endif
 293     libxkbcommon_x11 = library(
 294         'xkbcommon-x11',
 295         'xkbcommon/xkbcommon-x11.h',
 296         libxkbcommon_x11_sources,
 297         link_args: libxkbcommon_x11_link_args,
 298         link_depends: 'xkbcommon-x11.map',
 299         gnu_symbol_visibility: 'hidden',
 300         version: '0.0.0',
 301         install: true,
 302         include_directories: include_directories('src'),
 303         link_with: libxkbcommon,
 304         dependencies: [
 305             xcb_dep,
 306             xcb_xkb_dep,
 307         ],
 308     )
 309     install_headers(
 310         'xkbcommon/xkbcommon-x11.h',
 311         subdir: 'xkbcommon',
 312     )
 313     libxkbcommon_x11_dep = declare_dependency(
 314         link_with: libxkbcommon_x11,
 315     )
 316     pkgconfig.generate(
 317         libxkbcommon_x11,
 318         name: 'xkbcommon-x11',
 319         filebase: 'xkbcommon-x11',
 320         version: meson.project_version(),
 321         description: 'XKB API common to servers and clients - X11 support',
 322         requires: ['xkbcommon'],
 323         requires_private: ['xcb>=1.10', 'xcb-xkb>=1.10'],
 324     )
 325 endif
 326
 327 # libxkbregistry
 328 if get_option('enable-xkbregistry')
 329     dep_libxml = dependency('libxml-2.0')
 330     deps_libxkbregistry = [dep_libxml]
 331     libxkbregistry_sources = [
 332         'src/registry.c',
 333         'src/utils.h',
 334         'src/utils.c',
 335         'src/util-list.h',
 336         'src/util-list.c',
 337     ]
 338     libxkbregistry_link_args = []
 339     if have_version_script
 340         libxkbregistry_link_args += '-Wl,--version-script=' + meson.source_root()/'xkbregistry.map'
 341     endif
 342     libxkbregistry = library(
 343         'xkbregistry',
 344         'xkbcommon/xkbregistry.h',
 345         libxkbregistry_sources,
 346         link_args: libxkbregistry_link_args,
 347         link_depends: 'xkbregistry.map',
 348         gnu_symbol_visibility: 'hidden',
 349         dependencies: deps_libxkbregistry,
 350         version: '0.0.0',
 351         install: true,
 352         include_directories: include_directories('src'),
 353     )
 354     install_headers(
 355         'xkbcommon/xkbregistry.h',
 356         subdir: 'xkbcommon',
 357     )
 358     pkgconfig.generate(
 359         libxkbregistry,
 360         name: 'xkbregistry',
 361         filebase: 'xkbregistry',
 362         version: meson.project_version(),
 363         description: 'XKB API to query available rules, models, layouts, variants and options',
 364     )
 365
 366     dep_libxkbregistry = declare_dependency(
 367                                 include_directories: include_directories('xkbcommon'),
 368                                 link_with: libxkbregistry
 369                                 )
 370 endif
 371
 372 man_pages = []
 373
 374 # Tools
 375 build_tools = have_getopt_long
 376 if build_tools
 377     libxkbcommon_tools_internal = static_library(
 378         'tools-internal',
 379         'tools/tools-common.h',
 380         'tools/tools-common.c',
 381         dependencies: libxkbcommon_dep,
 382     )
 383     tools_dep = declare_dependency(
 384         include_directories: [include_directories('tools')],
 385         link_with: libxkbcommon_tools_internal,
 386     )
 387
 388     executable('xkbcli', 'tools/xkbcli.c',
 389                dependencies: tools_dep, install: true)
 390     install_man('tools/xkbcli.1')
 391
 392     executable('xkbcli-compile-keymap',
 393                'tools/compile-keymap.c',
 394                dependencies: tools_dep,
 395                install: true,
 396                install_dir: dir_libexec)
 397     install_man('tools/xkbcli-compile-keymap.1')
 398     # The same tool again, but with access to some private APIs.
 399     executable('compile-keymap',
 400                'tools/compile-keymap.c',
 401                libxkbcommon_sources,
 402                dependencies: [tools_dep],
 403                c_args: ['-DENABLE_PRIVATE_APIS'],
 404                include_directories: [include_directories('src')],
 405                install: false)
 406     configh_data.set10('HAVE_XKBCLI_COMPILE_KEYMAP', true)
 407     executable('xkbcli-how-to-type',
 408                'tools/how-to-type.c',
 409                dependencies: tools_dep,
 410                install: true,
 411                install_dir: dir_libexec)
 412     install_man('tools/xkbcli-how-to-type.1')
 413     configh_data.set10('HAVE_XKBCLI_HOW_TO_TYPE', true)
 414     if cc.has_header('linux/input.h')
 415         executable('xkbcli-interactive-evdev',
 416                    'tools/interactive-evdev.c',
 417                    dependencies: tools_dep,
 418                    install: true,
 419                    install_dir: dir_libexec)
 420         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_EVDEV', true)
 421         install_man('tools/xkbcli-interactive-evdev.1')
 422     endif
 423     if get_option('enable-x11')
 424         x11_tools_dep = declare_dependency(
 425             link_with: libxkbcommon_x11,
 426             dependencies: [
 427                 tools_dep,
 428                 xcb_dep,
 429                 xcb_xkb_dep,
 430             ],
 431         )
 432         executable('xkbcli-interactive-x11',
 433                    'tools/interactive-x11.c',
 434                    dependencies: x11_tools_dep,
 435                    install: true,
 436                    install_dir: dir_libexec)
 437         install_man('tools/xkbcli-interactive-x11.1')
 438         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_X11', true)
 439     endif
 440     if get_option('enable-wayland')
 441         wayland_client_dep = dependency('wayland-client', version: '>=1.2.0', required: false)
 442         wayland_protocols_dep = dependency('wayland-protocols', version: '>=1.12', required: false)
 443         wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
 444         if not wayland_client_dep.found() or not wayland_protocols_dep.found() or not wayland_scanner_dep.found()
 445             error('''The Wayland xkbcli programs require wayland-client >= 1.2.0, wayland-protocols >= 1.7 which were not found.
 446 You can disable the Wayland xkbcli programs with -Denable-wayland=false.''')
 447         endif
 448
 449         wayland_scanner = find_program(wayland_scanner_dep.get_pkgconfig_variable('wayland_scanner'))
 450         wayland_scanner_code_gen = generator(
 451             wayland_scanner,
 452             output: '@BASENAME@-protocol.c',
 453             arguments: ['code', '@INPUT@', '@OUTPUT@'],
 454         )
 455         wayland_scanner_client_header_gen = generator(
 456             wayland_scanner,
 457             output: '@BASENAME@-client-protocol.h',
 458             arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
 459         )
 460         wayland_protocols_datadir = wayland_protocols_dep.get_pkgconfig_variable('pkgdatadir')
 461         xdg_shell_xml = wayland_protocols_datadir/'stable/xdg-shell/xdg-shell.xml'
 462         xdg_shell_sources = [
 463             wayland_scanner_code_gen.process(xdg_shell_xml),
 464             wayland_scanner_client_header_gen.process(xdg_shell_xml),
 465         ]
 466         executable('xkbcli-interactive-wayland',
 467                    'tools/interactive-wayland.c',
 468                    xdg_shell_sources,
 469                    dependencies: [tools_dep, wayland_client_dep],
 470                    install: true,
 471                    install_dir: dir_libexec)
 472         install_man('tools/xkbcli-interactive-wayland.1')
 473         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_WAYLAND', true)
 474     endif
 475
 476     if get_option('enable-xkbregistry')
 477         configh_data.set10('HAVE_XKBCLI_LIST', true)
 478         executable('xkbcli-list',
 479                    'tools/registry-list.c',
 480                    dependencies: dep_libxkbregistry,
 481                    install: true,
 482                    install_dir: dir_libexec)
 483         install_man('tools/xkbcli-list.1')
 484     endif
 485 endif
 486
 487
 488 # xkeyboard-config "verifier"
 489 xkct_config = configuration_data()
 490 xkct_config.set('MESON_BUILD_ROOT', meson.build_root())
 491 xkct_config.set('XKB_CONFIG_ROOT', XKBCONFIGROOT)
 492 configure_file(input: 'test/xkeyboard-config-test.py.in',
 493                output: 'xkeyboard-config-test',
 494                configuration: xkct_config)
 495
 496 # Tests
 497 test_env = environment()
 498 test_env.set('XKB_LOG_LEVEL', 'debug')
 499 test_env.set('XKB_LOG_VERBOSITY', '10')
 500 test_env.set('top_srcdir', meson.source_root())
 501 test_env.set('top_builddir', meson.build_root())
 502 test_env.set('HAVE_XKBCLI_INTERACTIVE_EVDEV', configh_data.get('HAVE_XKBCLI_INTERACTIVE_EVDEV', 0).to_string())
 503 test_env.set('HAVE_XKBCLI_INTERACTIVE_WAYLAND', configh_data.get('HAVE_XKBCLI_INTERACTIVE_WAYLAND', 0).to_string())
 504 test_env.set('HAVE_XKBCLI_INTERACTIVE_X11', configh_data.get('HAVE_XKBCLI_INTERACTIVE_X11', 0).to_string())
 505 test_env.set('HAVE_XKBCLI_LIST', configh_data.get('HAVE_XKBCLI_LIST', 0).to_string())
 506
 507 test_configh_data = configuration_data()
 508 test_configh_data.set_quoted('TEST_XKB_CONFIG_ROOT', meson.source_root()/'test'/'data')
 509 configure_file(output: 'test-config.h', configuration: test_configh_data)
 510
 511 # Some tests need to use unexported symbols, so we link them against
 512 # an internal copy of libxkbcommon with all symbols exposed.
 513 libxkbcommon_test_internal = static_library(
 514     'xkbcommon-test-internal',
 515     'test/common.c',
 516     'test/test.h',
 517     'test/evdev-scancodes.h',
 518     libxkbcommon_sources,
 519     include_directories: include_directories('src'),
 520 )
 521 test_dep = declare_dependency(
 522     include_directories: include_directories('src'),
 523     link_with: libxkbcommon_test_internal,
 524 )
 525 if get_option('enable-x11')
 526     libxkbcommon_x11_internal = static_library(
 527         'xkbcommon-x11-internal',
 528         libxkbcommon_x11_sources,
 529         include_directories: include_directories('src'),
 530         link_with: libxkbcommon_test_internal,
 531         dependencies: [
 532             xcb_dep,
 533             xcb_xkb_dep,
 534         ],
 535     )
 536     x11_test_dep = declare_dependency(
 537         link_with: libxkbcommon_x11_internal,
 538         dependencies: [
 539             test_dep,
 540             xcb_dep,
 541             xcb_xkb_dep,
 542         ],
 543     )
 544 endif
 545 test(
 546     'keysym',
 547     executable('test-keysym', 'test/keysym.c', dependencies: test_dep),
 548     env: test_env,
 549 )
 550 test(
 551     'keymap',
 552     executable('test-keymap', 'test/keymap.c', dependencies: test_dep),
 553     env: test_env,
 554 )
 555 test(
 556     'filecomp',
 557     executable('test-filecomp', 'test/filecomp.c', dependencies: test_dep),
 558     env: test_env,
 559 )
 560 # TODO: This test currently uses some functions that don't exist on Windows.
 561 if cc.get_id() != 'msvc'
 562   test(
 563       'context',
 564       executable('test-context', 'test/context.c', dependencies: test_dep),
 565       env: test_env,
 566   )
 567 endif
 568 test(
 569     'rules-file',
 570     executable('test-rules-file', 'test/rules-file.c', dependencies: test_dep),
 571     env: test_env,
 572 )
 573 test(
 574     'rules-file-includes',
 575     executable('test-rules-file-includes', 'test/rules-file-includes.c', dependencies: test_dep),
 576     env: test_env,
 577 )
 578 test(
 579     'stringcomp',
 580     executable('test-stringcomp', 'test/stringcomp.c', dependencies: test_dep),
 581     env: test_env,
 582 )
 583 test(
 584     'buffercomp',
 585     executable('test-buffercomp', 'test/buffercomp.c', dependencies: test_dep),
 586     env: test_env,
 587 )
 588 test(
 589     'log',
 590     executable('test-log', 'test/log.c', dependencies: test_dep),
 591     env: test_env,
 592 )
 593 test(
 594     'atom',
 595     executable('test-atom', 'test/atom.c', dependencies: test_dep),
 596     env: test_env,
 597 )
 598 test(
 599     'utf8',
 600     executable('test-utf8', 'test/utf8.c', dependencies: test_dep),
 601     env: test_env,
 602 )
 603 test(
 604     'state',
 605     executable('test-state', 'test/state.c', dependencies: test_dep),
 606     env: test_env,
 607 )
 608 test(
 609     'keyseq',
 610     executable('test-keyseq', 'test/keyseq.c', dependencies: test_dep),
 611     env: test_env,
 612 )
 613 test(
 614     'rulescomp',
 615     executable('test-rulescomp', 'test/rulescomp.c', dependencies: test_dep),
 616     env: test_env,
 617 )
 618 test(
 619     'compose',
 620     executable('test-compose', 'test/compose.c', dependencies: test_dep),
 621     env: test_env,
 622 )
 623 test(
 624     'utils',
 625     executable('test-utils', 'test/utils.c', dependencies: test_dep),
 626     env: test_env,
 627 )
 628 test(
 629     'symbols-leak-test',
 630     find_program('test/symbols-leak-test.py'),
 631     env: test_env,
 632     suite: ['python-tests'],
 633 )
 634 if get_option('enable-x11')
 635     test(
 636         'x11',
 637         executable('test-x11', 'test/x11.c', dependencies: x11_test_dep),
 638         env: test_env,
 639     )
 640     # test/x11comp is meant to be run, but it is (temporarily?) disabled.
 641     # See: https://github.com/xkbcommon/libxkbcommon/issues/30
 642     executable('test-x11comp', 'test/x11comp.c', dependencies: x11_test_dep)
 643 endif
 644 if get_option('enable-xkbregistry')
 645     test(
 646         'registry',
 647         executable('test-registry', 'test/registry.c',
 648                    include_directories: include_directories('src'),
 649                    dependencies: dep_libxkbregistry),
 650         env: test_env,
 651     )
 652 endif
 653 if build_tools
 654     test('tool-option-parsing',
 655          find_program('test/tool-option-parsing.py'),
 656          env: test_env,
 657          suite: ['python-tests'])
 658 endif
 659
 660 valgrind = find_program('valgrind', required: false)
 661 if valgrind.found()
 662     add_test_setup('valgrind',
 663         exe_wrapper: [valgrind,
 664                        '--leak-check=full',
 665                        '--track-origins=yes',
 666                        '--gen-suppressions=all',
 667                        '--error-exitcode=99'],
 668         timeout_multiplier : 10)
 669 else
 670     message('valgrind not found, disabling valgrind test setup')
 671 endif
 672
 673
 674 # Fuzzing target programs.
 675 executable('fuzz-keymap', 'fuzz/keymap/target.c', dependencies: test_dep)
 676 executable('fuzz-compose', 'fuzz/compose/target.c', dependencies: test_dep)
 677
 678
 679 # Benchmarks.
 680 libxkbcommon_bench_internal = static_library(
 681     'xkbcommon-bench-internal',
 682     'bench/bench.c',
 683     'bench/bench.h',
 684     link_with: libxkbcommon_test_internal,
 685 )
 686 bench_dep = declare_dependency(
 687     include_directories: include_directories('src'),
 688     link_with: libxkbcommon_bench_internal,
 689 )
 690 bench_env = environment()
 691 bench_env.set('top_srcdir', meson.source_root())
 692 benchmark(
 693     'key-proc',
 694     executable('bench-key-proc', 'bench/key-proc.c', dependencies: bench_dep),
 695     env: bench_env,
 696 )
 697 benchmark(
 698     'rules',
 699     executable('bench-rules', 'bench/rules.c', dependencies: bench_dep),
 700     env: bench_env,
 701 )
 702 benchmark(
 703     'rulescomp',
 704     executable('bench-rulescomp', 'bench/rulescomp.c', dependencies: bench_dep),
 705     env: bench_env,
 706 )
 707 benchmark(
 708     'compose',
 709     executable('bench-compose', 'bench/compose.c', dependencies: bench_dep),
 710     env: bench_env,
 711 )
 712
 713
 714 # Documentation.
 715 if get_option('enable-docs')
 716     doxygen = find_program('doxygen', required: false)
 717     if not doxygen.found()
 718         error('''Documentation requires doxygen which was not found.
 719 You can disable the documentation with -Denable-docs=false.''')
 720     endif
 721     doxygen_wrapper = find_program('scripts/doxygen-wrapper')
 722
 723     doxygen_input = [
 724         'README.md',
 725         'doc/doxygen-extra.css',
 726         'doc/quick-guide.md',
 727         'doc/compat.md',
 728         'doc/user-configuration.md',
 729         'doc/rules-format.md',
 730         'xkbcommon/xkbcommon.h',
 731         'xkbcommon/xkbcommon-names.h',
 732         'xkbcommon/xkbcommon-x11.h',
 733         'xkbcommon/xkbcommon-compose.h',
 734         'xkbcommon/xkbregistry.h',
 735     ]
 736     doxygen_data = configuration_data()
 737     doxygen_data.set('PACKAGE_NAME', meson.project_name())
 738     doxygen_data.set('PACKAGE_VERSION', meson.project_version())
 739     doxygen_data.set('INPUT', ' '.join(doxygen_input))
 740     doxygen_data.set('OUTPUT_DIRECTORY', meson.build_root())
 741     doxyfile = configure_file(
 742         input: 'doc/Doxyfile.in',
 743         output: 'Doxyfile',
 744         configuration: doxygen_data,
 745     )
 746     # TODO: Meson should provide this.
 747     docdir = get_option('datadir')/'doc'/meson.project_name()
 748     custom_target(
 749         'doc',
 750         input: [doxyfile] + doxygen_input,
 751         output: 'html',
 752         command: [doxygen_wrapper, doxygen.path(), meson.build_root()/'Doxyfile', meson.source_root()],
 753         install: true,
 754         install_dir: docdir,
 755         build_by_default: true,
 756     )
 757 endif
 758
 759 configure_file(output: 'config.h', configuration: configh_data)