meson.build

   1 project('gstreamer', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.40.1',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('library_format')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48   # FIXME: Add FATAL_WARNINGS from configure.ac
  49 endif
  50
  51 cdata = configuration_data()
  52 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  53 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  54 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  55 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  56 cdata.set('GST_API_VERSION', '"1.0"')
  57 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  58 cdata.set('GST_LICENSE', '"LGPL"')
  59 cdata.set('PACKAGE', '"gstreamer"')
  60 cdata.set('PACKAGE_NAME', '"GStreamer"')
  61 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  62 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  64 cdata.set('PACKAGE_URL', '""')
  65 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  66 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  67 cdata.set('VERSION', '"@0@"'.format(gst_version))
  68 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  69 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  70 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  71 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  72
  73 if gst_version_nano > 0
  74     # Have GST_ERROR message printed when running from git
  75     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  76 else
  77     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  78 endif
  79
  80 # GStreamer package name and origin url
  81 gst_package_name = get_option('with-package-name')
  82 if gst_package_name == ''
  83   if gst_version_nano == 0
  84     gst_package_name = 'GStreamer source release'
  85   elif gst_version_nano == 1
  86     gst_package_name = 'GStreamer git'
  87   else
  88     gst_package_name = 'GStreamer prerelease'
  89   endif
  90 endif
  91 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  92 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  93
  94 # These are only needed/used by the ABI tests
  95 host_defines = [
  96   [ 'x86', 'HAVE_CPU_I386' ],
  97   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  98   [ 'arm', 'HAVE_CPU_ARM' ],
  99   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 100   [ 'mips', 'HAVE_CPU_MIPS' ],
 101   [ 'powerpc', 'HAVE_CPU_PPC' ],
 102   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 103   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 104   [ 'sparc', 'HAVE_CPU_SPARC' ],
 105   [ 'ia64', 'HAVE_CPU_IA64' ],
 106   [ 'hppa', 'HAVE_CPU_HPPA' ],
 107   [ 'm68k', 'HAVE_CPU_M68K' ],
 108   [ 's390', 'HAVE_CPU_S390' ],
 109 ]
 110 foreach h : host_defines
 111   if h.get(0) == host_machine.cpu()
 112     cdata.set(h.get(1), 1)
 113   endif
 114 endforeach
 115 # FIXME: should really be called HOST_CPU or such
 116 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 117
 118 check_headers = [
 119   'dlfcn.h',
 120   'inttypes.h',
 121   'memory.h',
 122   'poll.h',
 123   'stdint.h',
 124   'stdio_ext.h',
 125   'strings.h',
 126   'string.h',
 127   'sys/param.h',
 128   'sys/poll.h',
 129   'sys/prctl.h',
 130   'sys/socket.h',
 131   'sys/stat.h',
 132   'sys/times.h',
 133   'sys/time.h',
 134   'sys/types.h',
 135   'sys/utsname.h',
 136   'sys/wait.h',
 137   'ucontext.h',
 138   'unistd.h',
 139   'valgrind/valgrind.h',
 140   'sys/resource.h',
 141 ]
 142
 143 if host_machine.system() == 'windows'
 144   check_headers += ['winsock2.h']
 145 endif
 146
 147 foreach h : check_headers
 148   if cc.has_header(h)
 149     define = 'HAVE_' + h.underscorify().to_upper()
 150     cdata.set(define, 1)
 151   endif
 152 endforeach
 153
 154 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 155   cdata.set('HAVE_TM_GMTOFF', 1)
 156 endif
 157
 158 check_functions = [
 159   'gmtime_r',
 160   'sigaction',
 161   'getrusage',
 162   'fseeko',
 163   'ftello',
 164   'poll',
 165   'pselect',
 166   'getpagesize',
 167   'clock_gettime',
 168   # These are needed by libcheck
 169   'getline',
 170   'mkstemp',
 171   'alarm',
 172   'gettimeofday',
 173 ]
 174
 175 foreach f : check_functions
 176   if cc.has_function(f)
 177     define = 'HAVE_' + f.underscorify().to_upper()
 178     cdata.set(define, 1)
 179   endif
 180 endforeach
 181
 182 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 183   cdata.set('HAVE_LOCALTIME_R', 1)
 184   # Needed by libcheck
 185   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 186 endif
 187
 188 if cc.links('''#include <pthread.h>
 189                int main() {
 190                  pthread_setname_np("example"); return 0;
 191                }''', name : 'pthread_setname_np(const char*)')
 192   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 193 endif
 194
 195 # Check for posix timers and the monotonic clock
 196 time_prefix = '#include <time.h>\n'
 197 if cdata.has('HAVE_UNISTD_H')
 198   time_prefix += '#include <unistd.h>'
 199 endif
 200
 201 posix_timers_src = time_prefix + '''
 202 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 203 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 204 #endif
 205 '''
 206 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
 207   cdata.set('HAVE_POSIX_TIMERS', 1)
 208 endif
 209
 210 monotonic_clock_src = time_prefix + '''
 211 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 212 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 213 #endif
 214 '''
 215 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
 216   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 217 endif
 218
 219 # Check for __uint128_t (gcc) by checking for 128-bit division
 220 uint128_t_src = '''int main() {
 221 static __uint128_t v1 = 100;
 222 static __uint128_t v2 = 10;
 223 static __uint128_t u;
 224 u = v1 / v2;
 225 }'''
 226 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 227   cdata.set('HAVE_UINT128_T', 1)
 228 endif
 229
 230 # All supported platforms have long long now
 231 cdata.set('HAVE_LONG_LONG', 1)
 232
 233 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 234 # building with MSVC
 235 if cc.get_id() == 'msvc'
 236   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 237 else
 238   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 239 endif
 240
 241 # -------------------------------------------------------------------------------------
 242 # config.h things needed by libcheck
 243 # -------------------------------------------------------------------------------------
 244 if cc.has_function('getpid')
 245   cdata.set('HAVE_GETPID', 1)
 246 elif host_system == 'windows' and cc.has_function('_getpid')
 247   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 248   cdata.set('HAVE__GETPID', 1)
 249 endif
 250 if cc.has_function('strdup')
 251   cdata.set('HAVE_DECL_STRDUP', 1)
 252 elif host_system == 'windows' and cc.has_function('_strdup')
 253   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 254 endif
 255 if host_machine.system() != 'windows'
 256   cdata.set('HAVE_FORK', 1)
 257 else
 258   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 259   cdata.set('HAVE_FORK', 0)
 260 endif
 261 if cc.has_function('strsignal')
 262   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 263 endif
 264 # Check for availability of types
 265 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 266   cdata.set('clockid_t', 'int')
 267 endif
 268 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 269   cdata.set('timer_t', 'int')
 270 endif
 271 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 272                       prefix : '#include <time.h>')
 273   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 274 endif
 275 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 276                       prefix : '#include <time.h>')
 277   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 278 endif
 279
 280 # Platform deps; only ws2_32 and execinfo for now
 281 platform_deps = []
 282 if host_machine.system() == 'windows'
 283   platform_deps = [cc.find_library('ws2_32')]
 284 endif
 285
 286 backtrace_deps = []
 287 if not get_option('disable_libunwind')
 288   unwind_dep = dependency('libunwind', required : false)
 289   dw_dep = dependency('libdw', required: false)
 290   backtrace_deps = [unwind_dep, dw_dep]
 291   if unwind_dep.found()
 292     cdata.set('HAVE_UNWIND', 1)
 293     if dw_dep.found()
 294       cdata.set('HAVE_DW', 1)
 295     else
 296       message('Support for backtraces is partial only.')
 297     endif
 298   else
 299     if cc.has_function('backtrace')
 300       cdata.set('HAVE_BACKTRACE', 1)
 301     else
 302         message('NO backtraces support.')
 303     endif
 304   endif
 305 endif
 306
 307 if cc.has_header('execinfo.h')
 308   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 309     cdata.set('HAVE_BACKTRACE', 1)
 310   else
 311     execinfo_dep = cc.find_library('execinfo', required : false)
 312     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 313       cdata.set('HAVE_BACKTRACE', 1)
 314       platform_deps += execinfo_dep
 315     endif
 316   endif
 317 endif
 318
 319 disable_gst_debug = get_option('disable_gst_debug')
 320 if get_option('disable_gst_debug')
 321     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
 322   add_project_arguments(['-Wno-unused'], language: 'c')
 323 endif
 324
 325 # Used by the gstutils test
 326 gmp_dep = cc.find_library('gmp', required : false)
 327 cdata.set('HAVE_GMP', gmp_dep.found())
 328 gsl_dep = cc.find_library('gsl', required : false)
 329 gslcblas_dep = cc.find_library('gslcblas', required : false)
 330 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 331 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 332
 333 # Used by gstinfo.c
 334 dl_dep = cc.find_library('dl', required : false)
 335 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 336
 337
 338 configinc = include_directories('.')
 339 libsinc = include_directories('libs')
 340 privinc = include_directories('gst')
 341
 342 # Find dependencies
 343 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 344   fallback: ['glib', 'libglib_dep'])
 345 gobject_dep = dependency('gobject-2.0',
 346   fallback: ['glib', 'libgobject_dep'])
 347 gmodule_dep = dependency('gmodule-2.0',
 348   fallback: ['glib', 'libgmodule_dep'])
 349 if host_machine.system() == 'windows'
 350     gio_dep = dependency('gio-2.0',
 351         fallback: ['glib', 'libgio_dep'])
 352 else
 353     gio_dep = [dependency('gio-2.0',
 354                   fallback: ['glib', 'libgio_dep']),
 355                dependency('gio-unix-2.0',
 356                   fallback: ['glib', 'libgio_dep'])]
 357 endif
 358
 359 mathlib = cc.find_library('m', required : false)
 360 # Needed for timer_create/settime/delete
 361 # Also provides clock_gettime in glibc < 2.17
 362 rt_lib = cc.find_library('rt', required : false)
 363
 364 gir = find_program('g-ir-scanner', required : false)
 365 gnome = import('gnome')
 366
 367 # Fixme, not very elegant.
 368 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 369
 370 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 371     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 372     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 373     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 374     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 375     'gst_init(NULL,NULL);' ]
 376 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 377
 378 # Used by the *_mkenum.py helper scripts
 379 glib_mkenums = find_program('glib-mkenums')
 380
 381 gst_c_args = ['-DHAVE_CONFIG_H']
 382 if libtype == 'static'
 383   gst_c_args += ['-DGST_STATIC_COMPILATION']
 384 endif
 385
 386 # Used in gst/parse/meson.build and below
 387 py3 = find_program('python3', required : false)
 388 if not py3.found()
 389   # Maybe 'python' is Python 3
 390   py3 = find_program('python')
 391 endif
 392
 393 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 394
 395 bashcomp_found = bashcomp_dep.found()
 396 bash_completions_dir = ''
 397 bash_helpers_dir = ''
 398
 399 if bashcomp_found
 400   # get_pkgconfig_variable() won't let us set the prefix
 401   pkgconfig = find_program('pkg-config')
 402
 403   runcmd = run_command(pkgconfig,
 404       '--define-variable=prefix="."',
 405       '--variable=completionsdir',
 406       'bash-completion')
 407
 408   if (runcmd.returncode() == 0)
 409     bash_completions_dir = runcmd.stdout().strip()
 410   else
 411     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 412     bashcomp_found = false
 413   endif
 414
 415   runcmd = run_command(pkgconfig,
 416       '--define-variable=prefix="."',
 417       '--variable=helpersdir',
 418       'bash-completion')
 419
 420   if (runcmd.returncode() == 0)
 421     bash_helpers_dir = runcmd.stdout().strip()
 422   else
 423     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 424     bashcomp_found = false
 425   endif
 426 endif
 427
 428 subdir('gst')
 429 subdir('libs')
 430 subdir('plugins')
 431 subdir('tools')
 432 subdir('pkgconfig')
 433 subdir('tests')
 434 subdir('po')
 435 subdir('data')
 436
 437 configure_file(output : 'config.h', configuration : cdata)
 438
 439 if build_machine.system() == 'windows'
 440   message('Disabling gtk-doc while building on Windows')
 441 elif get_option('disable_gtkdoc')
 442   message('gtk-doc is disabled via options')
 443 else
 444   if find_program('gtkdoc-scan', required : false).found()
 445     subdir('docs')
 446   else
 447     message('Not building documentation as gtk-doc was not found')
 448   endif
 449 endif
 450
 451 run_command(py3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 452
 453 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))