meson.build

   1 project(
   2     'libxkbcommon',
   3     'c',
   4     version: '1.6.0',
   5     default_options: [
   6         'c_std=c11',
   7         'warning_level=2',
   8         'b_lundef=true',
   9     ],
  10     meson_version : '>= 0.52.0',
  11 )
  12 pkgconfig = import('pkgconfig')
  13 cc = meson.get_compiler('c')
  14
  15 dir_libexec = get_option('prefix')/get_option('libexecdir')/'xkbcommon'
  16
  17 # Compiler flags.
  18 cflags = [
  19     '-fno-strict-aliasing',
  20     '-Wno-unused-parameter',
  21     '-Wno-missing-field-initializers',
  22     '-Wpointer-arith',
  23     '-Wmissing-declarations',
  24     '-Wformat=2',
  25     '-Wstrict-prototypes',
  26     '-Wmissing-prototypes',
  27     '-Wnested-externs',
  28     '-Wbad-function-cast',
  29     '-Wshadow',
  30     '-Wlogical-op',
  31     '-Wdate-time',
  32     '-Wwrite-strings',
  33     '-Wno-documentation-deprecated-sync',
  34 ]
  35 add_project_arguments(cc.get_supported_arguments(cflags), language: 'c')
  36
  37
  38 # The XKB config root.
  39 XKBCONFIGROOT = get_option('xkb-config-root')
  40 if XKBCONFIGROOT == ''
  41     xkeyboard_config_dep = dependency('xkeyboard-config', required: false)
  42     if xkeyboard_config_dep.found()
  43         XKBCONFIGROOT = xkeyboard_config_dep.get_variable(pkgconfig: 'xkb_base')
  44     else
  45         XKBCONFIGROOT = get_option('prefix')/get_option('datadir')/'X11'/'xkb'
  46   endif
  47 endif
  48
  49 XKBCONFIGEXTRAPATH = get_option('xkb-config-extra-path')
  50 if XKBCONFIGEXTRAPATH == ''
  51     XKBCONFIGEXTRAPATH = get_option('prefix')/get_option('sysconfdir')/'xkb'
  52 endif
  53
  54 # The X locale directory for compose.
  55 XLOCALEDIR = get_option('x-locale-root')
  56 if XLOCALEDIR == ''
  57     XLOCALEDIR = get_option('prefix')/get_option('datadir')/'X11'/'locale'
  58 endif
  59
  60
  61 # config.h.
  62 configh_data = configuration_data()
  63 configh_data.set('EXIT_INVALID_USAGE', '2')
  64 configh_data.set_quoted('LIBXKBCOMMON_VERSION', meson.project_version())
  65 configh_data.set_quoted('LIBXKBCOMMON_TOOL_PATH', dir_libexec)
  66 # Like AC_USE_SYSTEM_EXTENSIONS, what #define to use to get extensions
  67 # beyond the base POSIX function set.
  68 if host_machine.system() == 'sunos'
  69   system_extensions = '__EXTENSIONS__'
  70 else
  71   system_extensions = '_GNU_SOURCE'
  72 endif
  73 configh_data.set(system_extensions, 1)
  74 system_ext_define = '#define ' + system_extensions
  75 configh_data.set_quoted('DFLT_XKB_CONFIG_ROOT', XKBCONFIGROOT)
  76 configh_data.set_quoted('DFLT_XKB_CONFIG_EXTRA_PATH', XKBCONFIGEXTRAPATH)
  77 configh_data.set_quoted('XLOCALEDIR', XLOCALEDIR)
  78 configh_data.set_quoted('DEFAULT_XKB_RULES', get_option('default-rules'))
  79 configh_data.set_quoted('DEFAULT_XKB_MODEL', get_option('default-model'))
  80 configh_data.set_quoted('DEFAULT_XKB_LAYOUT', get_option('default-layout'))
  81 if get_option('default-variant') != ''
  82     configh_data.set_quoted('DEFAULT_XKB_VARIANT', get_option('default-variant'))
  83 else
  84     configh_data.set('DEFAULT_XKB_VARIANT', 'NULL')
  85 endif
  86 if get_option('default-options') != ''
  87     configh_data.set_quoted('DEFAULT_XKB_OPTIONS', get_option('default-options'))
  88 else
  89     configh_data.set('DEFAULT_XKB_OPTIONS', 'NULL')
  90 endif
  91 if cc.has_header('unistd.h')
  92     configh_data.set('HAVE_UNISTD_H', 1)
  93 endif
  94 if cc.links('int main(){if(__builtin_expect(1<0,0)){}}', name: '__builtin_expect')
  95     configh_data.set('HAVE___BUILTIN_EXPECT', 1)
  96 endif
  97 if cc.has_header_symbol('unistd.h', 'eaccess', prefix: system_ext_define)
  98     configh_data.set('HAVE_EACCESS', 1)
  99 endif
 100 if cc.has_header_symbol('unistd.h', 'euidaccess', prefix: system_ext_define)
 101     configh_data.set('HAVE_EUIDACCESS', 1)
 102 endif
 103 if cc.has_header_symbol('sys/mman.h', 'mmap')
 104     configh_data.set('HAVE_MMAP', 1)
 105 endif
 106 if cc.has_header_symbol('stdlib.h', 'mkostemp', prefix: system_ext_define)
 107     configh_data.set('HAVE_MKOSTEMP', 1)
 108 endif
 109 if cc.has_header_symbol('fcntl.h', 'posix_fallocate', prefix: system_ext_define)
 110     configh_data.set('HAVE_POSIX_FALLOCATE', 1)
 111 endif
 112 if cc.has_header_symbol('string.h', 'strndup', prefix: system_ext_define)
 113     configh_data.set('HAVE_STRNDUP', 1)
 114 endif
 115 if cc.has_header_symbol('stdio.h', 'asprintf', prefix: system_ext_define)
 116     configh_data.set('HAVE_ASPRINTF', 1)
 117 elif cc.has_header_symbol('stdio.h', 'vasprintf', prefix: system_ext_define)
 118     configh_data.set('HAVE_VASPRINTF', 1)
 119 endif
 120 if cc.has_header_symbol('stdlib.h', 'secure_getenv', prefix: system_ext_define)
 121     configh_data.set('HAVE_SECURE_GETENV', 1)
 122 elif cc.has_header_symbol('stdlib.h', '__secure_getenv', prefix: system_ext_define)
 123     configh_data.set('HAVE___SECURE_GETENV', 1)
 124 else
 125     message('C library does not support secure_getenv, using getenv instead')
 126 endif
 127 if not cc.has_header_symbol('limits.h', 'PATH_MAX', prefix: system_ext_define)
 128     if host_machine.system() == 'windows'
 129         # see https://docs.microsoft.com/en-us/windows/win32/fileio/naming-a-file#maximum-path-length-limitation
 130         configh_data.set('PATH_MAX', 260)
 131     else
 132         configh_data.set('PATH_MAX', 4096)
 133     endif
 134 endif
 135
 136 # Silence some security & deprecation warnings on MSVC
 137 # for some unix/C functions we use.
 138 # https://docs.microsoft.com/en-us/cpp/error-messages/compiler-warnings/compiler-warning-level-3-c4996?view=vs-2019
 139 configh_data.set('_CRT_SECURE_NO_WARNINGS', 1)
 140 configh_data.set('_CRT_NONSTDC_NO_WARNINGS', 1)
 141 configh_data.set('_CRT_NONSTDC_NO_DEPRECATE', 1)
 142 # Reduce unnecessary includes on MSVC.
 143 configh_data.set('WIN32_LEAN_AND_MEAN', 1)
 144
 145 # Supports -Wl,--version-script?
 146 have_version_script = cc.links(
 147     'int main(){}',
 148     args: '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon.map',
 149     name: '-Wl,--version-script',
 150 )
 151
 152 map_to_def = find_program('scripts/map-to-def')
 153
 154 # libxkbcommon.
 155 # Note: we use some yacc extensions, which work with either GNU bison
 156 # (preferred) or byacc (with backtracking enabled).
 157 bison = find_program('bison', 'win_bison', required: false, version: '>= 2.3a')
 158 if bison.found()
 159     yacc = bison
 160     yacc_gen = generator(
 161         bison,
 162         output: ['@BASENAME@.c', '@BASENAME@.h'],
 163         arguments: ['--defines=@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 164     )
 165 else
 166     byacc = find_program('byacc', required: false)
 167     if byacc.found()
 168         yacc = byacc
 169         yacc_gen = generator(
 170             byacc,
 171             output: ['@BASENAME@.c', '@BASENAME@.h'],
 172             arguments: ['-H', '@OUTPUT1@', '-o', '@OUTPUT0@', '-p', '_xkbcommon_', '@INPUT@'],
 173         )
 174     else
 175         error('Could not find a compatible YACC program (bison or byacc)')
 176     endif
 177 endif
 178 libxkbcommon_sources = [
 179     'src/compose/parser.c',
 180     'src/compose/parser.h',
 181     'src/compose/paths.c',
 182     'src/compose/paths.h',
 183     'src/compose/state.c',
 184     'src/compose/table.c',
 185     'src/compose/table.h',
 186     'src/xkbcomp/action.c',
 187     'src/xkbcomp/action.h',
 188     'src/xkbcomp/ast.h',
 189     'src/xkbcomp/ast-build.c',
 190     'src/xkbcomp/ast-build.h',
 191     'src/xkbcomp/compat.c',
 192     'src/xkbcomp/expr.c',
 193     'src/xkbcomp/expr.h',
 194     'src/xkbcomp/include.c',
 195     'src/xkbcomp/include.h',
 196     'src/xkbcomp/keycodes.c',
 197     'src/xkbcomp/keymap.c',
 198     'src/xkbcomp/keymap-dump.c',
 199     'src/xkbcomp/keywords.c',
 200     yacc_gen.process('src/xkbcomp/parser.y'),
 201     'src/xkbcomp/parser-priv.h',
 202     'src/xkbcomp/rules.c',
 203     'src/xkbcomp/rules.h',
 204     'src/xkbcomp/scanner.c',
 205     'src/xkbcomp/symbols.c',
 206     'src/xkbcomp/types.c',
 207     'src/xkbcomp/vmod.c',
 208     'src/xkbcomp/vmod.h',
 209     'src/xkbcomp/xkbcomp.c',
 210     'src/xkbcomp/xkbcomp-priv.h',
 211     'src/atom.c',
 212     'src/atom.h',
 213     'src/context.c',
 214     'src/context.h',
 215     'src/context-priv.c',
 216     'src/darray.h',
 217     'src/keysym.c',
 218     'src/keysym.h',
 219     'src/keysym-utf.c',
 220     'src/ks_tables.h',
 221     'src/keymap.c',
 222     'src/keymap.h',
 223     'src/keymap-priv.c',
 224     'src/messages-codes.h',
 225     'src/scanner-utils.h',
 226     'src/state.c',
 227     'src/text.c',
 228     'src/text.h',
 229     'src/utf8.c',
 230     'src/utf8.h',
 231     'src/utils.c',
 232     'src/utils.h',
 233 ]
 234 libxkbcommon_link_args = []
 235 libxkbcommon_link_deps = []
 236 if have_version_script
 237     libxkbcommon_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon.map'
 238     libxkbcommon_link_deps += 'xkbcommon.map'
 239 elif cc.get_argument_syntax() == 'msvc'
 240     libxkbcommon_def = custom_target('xkbcommon.def',
 241         command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 242         input: 'xkbcommon.map',
 243         output: 'kxbcommon.def',
 244     )
 245     libxkbcommon_link_deps += libxkbcommon_def
 246     libxkbcommon_link_args += '/DEF:' + libxkbcommon_def.full_path()
 247 endif
 248
 249 libxkbcommon = library(
 250     'xkbcommon',
 251     'include/xkbcommon/xkbcommon.h',
 252     libxkbcommon_sources,
 253     link_args: libxkbcommon_link_args,
 254     link_depends: libxkbcommon_link_deps,
 255     gnu_symbol_visibility: 'hidden',
 256     version: '0.0.0',
 257     install: true,
 258     include_directories: include_directories('src', 'include'),
 259 )
 260 install_headers(
 261     'include/xkbcommon/xkbcommon.h',
 262     'include/xkbcommon/xkbcommon-compat.h',
 263     'include/xkbcommon/xkbcommon-compose.h',
 264     'include/xkbcommon/xkbcommon-keysyms.h',
 265     'include/xkbcommon/xkbcommon-names.h',
 266     subdir: 'xkbcommon',
 267 )
 268
 269 dep_libxkbcommon = declare_dependency(
 270     link_with: libxkbcommon,
 271     include_directories: include_directories('include'),
 272 )
 273 if meson.version().version_compare('>= 0.54.0')
 274     meson.override_dependency('xkbcommon', dep_libxkbcommon)
 275 endif
 276 pkgconfig.generate(
 277     libxkbcommon,
 278     name: 'xkbcommon',
 279     filebase: 'xkbcommon',
 280     version: meson.project_version(),
 281     description: 'XKB API common to servers and clients',
 282 )
 283
 284
 285 # libxkbcommon-x11.
 286 if get_option('enable-x11')
 287     xcb_dep = dependency('xcb', version: '>=1.10', required: false)
 288     xcb_xkb_dep = dependency('xcb-xkb', version: '>=1.10', required: false)
 289     if not xcb_dep.found() or not xcb_xkb_dep.found()
 290         error('''X11 support requires xcb-xkb >= 1.10 which was not found.
 291 You can disable X11 support with -Denable-x11=false.''')
 292     endif
 293
 294     libxkbcommon_x11_sources = [
 295         'src/x11/keymap.c',
 296         'src/x11/state.c',
 297         'src/x11/util.c',
 298         'src/x11/x11-priv.h',
 299         'src/context.h',
 300         'src/context-priv.c',
 301         'src/keymap.h',
 302         'src/keymap-priv.c',
 303         'src/atom.h',
 304         'src/atom.c',
 305     ]
 306     libxkbcommon_x11_link_args = []
 307     libxkbcommon_x11_link_deps = []
 308     if have_version_script
 309         libxkbcommon_x11_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbcommon-x11.map'
 310         libxkbcommon_x11_link_deps += 'xkbcommon-x11.map'
 311     elif cc.get_argument_syntax() == 'msvc'
 312         libxkbcommon_x11_def = custom_target('xkbcommon-x11.def',
 313             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 314             input: 'xkbcommon-x11.map',
 315             output: 'xkbcommon-x11.def',
 316         )
 317         libxkbcommon_x11_link_deps += libxkbcommon_x11_def
 318         libxkbcommon_x11_link_args += '/DEF:' + libxkbcommon_x11_def.full_path()
 319     endif
 320     libxkbcommon_x11 = library(
 321         'xkbcommon-x11',
 322         'include/xkbcommon/xkbcommon-x11.h',
 323         libxkbcommon_x11_sources,
 324         link_args: libxkbcommon_x11_link_args,
 325         link_depends: libxkbcommon_x11_link_deps,
 326         gnu_symbol_visibility: 'hidden',
 327         version: '0.0.0',
 328         install: true,
 329         include_directories: include_directories('src', 'include'),
 330         link_with: libxkbcommon,
 331         dependencies: [
 332             xcb_dep,
 333             xcb_xkb_dep,
 334         ],
 335     )
 336     install_headers(
 337         'include/xkbcommon/xkbcommon-x11.h',
 338         subdir: 'xkbcommon',
 339     )
 340     dep_libxkbcommon_x11 = declare_dependency(
 341         link_with: libxkbcommon_x11,
 342         include_directories: include_directories('include'),
 343     )
 344     if meson.version().version_compare('>= 0.54.0')
 345         meson.override_dependency('xkbcommon-x11', dep_libxkbcommon_x11)
 346     endif
 347     pkgconfig.generate(
 348         libxkbcommon_x11,
 349         name: 'xkbcommon-x11',
 350         filebase: 'xkbcommon-x11',
 351         version: meson.project_version(),
 352         description: 'XKB API common to servers and clients - X11 support',
 353         requires: ['xkbcommon'],
 354         requires_private: ['xcb>=1.10', 'xcb-xkb>=1.10'],
 355     )
 356 endif
 357
 358 # libxkbregistry
 359 if get_option('enable-xkbregistry')
 360     dep_libxml = dependency('libxml-2.0')
 361     deps_libxkbregistry = [dep_libxml]
 362     libxkbregistry_sources = [
 363         'src/registry.c',
 364         'src/utils.h',
 365         'src/utils.c',
 366         'src/util-list.h',
 367         'src/util-list.c',
 368     ]
 369     libxkbregistry_link_args = []
 370     libxkbregistry_link_deps = []
 371     if have_version_script
 372         libxkbregistry_link_args += '-Wl,--version-script=' + meson.current_source_dir()/'xkbregistry.map'
 373         libxkbregistry_link_deps += 'xkbregistry.map'
 374     elif cc.get_argument_syntax() == 'msvc'
 375         libxkbregistry_def = custom_target('xkbregistry.def',
 376             command: [map_to_def, '@INPUT@', '@OUTPUT@'],
 377             input: 'xkbregistry.map',
 378             output: 'xkbregistry.def',
 379         )
 380         libxkbregistry_link_deps += libxkbregistry_def
 381         libxkbregistry_link_args += '/DEF:' + libxkbregistry_def.full_path()
 382     endif
 383     libxkbregistry = library(
 384         'xkbregistry',
 385         'include/xkbcommon/xkbregistry.h',
 386         libxkbregistry_sources,
 387         link_args: libxkbregistry_link_args,
 388         link_depends: libxkbregistry_link_deps,
 389         gnu_symbol_visibility: 'hidden',
 390         dependencies: deps_libxkbregistry,
 391         version: '0.0.0',
 392         install: true,
 393         include_directories: include_directories('src', 'include'),
 394     )
 395     install_headers(
 396         'include/xkbcommon/xkbregistry.h',
 397         subdir: 'xkbcommon',
 398     )
 399     pkgconfig.generate(
 400         libxkbregistry,
 401         name: 'xkbregistry',
 402         filebase: 'xkbregistry',
 403         version: meson.project_version(),
 404         description: 'XKB API to query available rules, models, layouts, variants and options',
 405     )
 406
 407     dep_libxkbregistry = declare_dependency(
 408         link_with: libxkbregistry,
 409         include_directories: include_directories('include'),
 410     )
 411     if meson.version().version_compare('>= 0.54.0')
 412         meson.override_dependency('xkbregistry', dep_libxkbregistry)
 413     endif
 414 endif
 415
 416 man_pages = []
 417
 418 # Tools
 419 #build_tools = get_option('enable-tools') and cc.has_header_symbol('getopt.h', 'getopt_long', prefix: '#define _GNU_SOURCE')
 420 build_tools = false
 421 if build_tools
 422     # Common resources
 423     libxkbcommon_tools_internal_sources = [
 424         'tools/tools-common.h',
 425         'tools/tools-common.c',
 426     ]
 427     libxkbcommon_tools_internal = static_library(
 428         'tools-internal',
 429         libxkbcommon_tools_internal_sources,
 430         dependencies: dep_libxkbcommon,
 431     )
 432     tools_dep = declare_dependency(
 433         include_directories: [include_directories('tools', 'include')],
 434         link_with: libxkbcommon_tools_internal,
 435         dependencies: dep_libxkbcommon,
 436     )
 437
 438     # Tool: xkbcli
 439     executable('xkbcli', 'tools/xkbcli.c',
 440                dependencies: tools_dep, install: true)
 441     install_man('tools/xkbcli.1')
 442
 443     if get_option('enable-bash-completion')
 444         bash_completion_path = get_option('bash-completion-path')
 445         if bash_completion_path == ''
 446             bash_completion = dependency('bash-completion', required: false)
 447             if bash_completion.found()
 448                 bash_completion_path = bash_completion.get_variable(pkgconfig: 'completionsdir')
 449             else
 450                 bash_completion_path = get_option('datadir') / 'bash-completion/completions'
 451             endif
 452         endif
 453         install_data('tools/xkbcli-bash-completion.sh',
 454                      rename: 'xkbcli',
 455                      install_dir: bash_completion_path)
 456     endif
 457
 458     # Tool: compile-keymap
 459     xkbcli_compile_keymap = executable('xkbcli-compile-keymap',
 460                                        'tools/compile-keymap.c',
 461                                        dependencies: tools_dep,
 462                                        install: true,
 463                                        install_dir: dir_libexec)
 464     install_man('tools/xkbcli-compile-keymap.1')
 465     # The same tool again, but with access to some private APIs.
 466     executable('compile-keymap',
 467                'tools/compile-keymap.c',
 468                libxkbcommon_sources,
 469                dependencies: [tools_dep],
 470                c_args: ['-DENABLE_PRIVATE_APIS'],
 471                include_directories: [include_directories('src', 'include')],
 472                install: false)
 473
 474     # Tool: compose
 475     executable('compose',
 476                'tools/compose.c',
 477                dependencies: tools_dep,
 478                include_directories: [include_directories('src', 'include')],
 479                install: false)
 480     configh_data.set10('HAVE_XKBCLI_COMPILE_KEYMAP', true)
 481
 482     # Tool: how-to-type
 483     executable('xkbcli-how-to-type',
 484                'tools/how-to-type.c',
 485                dependencies: tools_dep,
 486                install: true,
 487                install_dir: dir_libexec)
 488     install_man('tools/xkbcli-how-to-type.1')
 489     configh_data.set10('HAVE_XKBCLI_HOW_TO_TYPE', true)
 490
 491     # Tool: interactive-evdev
 492     if cc.has_header('linux/input.h')
 493         executable('xkbcli-interactive-evdev',
 494                    'tools/interactive-evdev.c',
 495                    dependencies: tools_dep,
 496                    install: true,
 497                    install_dir: dir_libexec)
 498         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_EVDEV', true)
 499         install_man('tools/xkbcli-interactive-evdev.1')
 500         # The same tool again, but with access to some private APIs.
 501         executable('interactive-evdev',
 502                 'tools/interactive-evdev.c',
 503                 libxkbcommon_sources,
 504                 libxkbcommon_tools_internal_sources,
 505                 dependencies: [tools_dep],
 506                 c_args: ['-DENABLE_PRIVATE_APIS'],
 507                 include_directories: [include_directories('src', 'include')],
 508                 install: false)
 509     endif
 510
 511     # Tool: interactive-x11
 512     if get_option('enable-x11')
 513         x11_tools_dep = declare_dependency(
 514             link_with: libxkbcommon_x11,
 515             dependencies: [
 516                 tools_dep,
 517                 xcb_dep,
 518                 xcb_xkb_dep,
 519             ],
 520         )
 521         executable('xkbcli-interactive-x11',
 522                    'tools/interactive-x11.c',
 523                    dependencies: x11_tools_dep,
 524                    install: true,
 525                    install_dir: dir_libexec)
 526         install_man('tools/xkbcli-interactive-x11.1')
 527         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_X11', true)
 528     endif
 529
 530     # Tool: interactive-wayland
 531     if get_option('enable-wayland')
 532         wayland_client_dep = dependency('wayland-client', version: '>=1.2.0', required: false)
 533         wayland_protocols_dep = dependency('wayland-protocols', version: '>=1.12', required: false)
 534         wayland_scanner_dep = dependency('wayland-scanner', required: false, native: true)
 535         if not wayland_client_dep.found() or not wayland_protocols_dep.found() or not wayland_scanner_dep.found()
 536             error('''The Wayland xkbcli programs require wayland-client >= 1.2.0, wayland-protocols >= 1.7 which were not found.
 537 You can disable the Wayland xkbcli programs with -Denable-wayland=false.''')
 538         endif
 539
 540         wayland_scanner = find_program(wayland_scanner_dep.get_variable(pkgconfig: 'wayland_scanner'))
 541         wayland_scanner_code_gen = generator(
 542             wayland_scanner,
 543             output: '@BASENAME@-protocol.c',
 544             arguments: ['private-code', '@INPUT@', '@OUTPUT@'],
 545         )
 546         wayland_scanner_client_header_gen = generator(
 547             wayland_scanner,
 548             output: '@BASENAME@-client-protocol.h',
 549             arguments: ['client-header', '@INPUT@', '@OUTPUT@'],
 550         )
 551         wayland_protocols_datadir = wayland_protocols_dep.get_variable(pkgconfig: 'pkgdatadir')
 552         xdg_shell_xml = wayland_protocols_datadir/'stable/xdg-shell/xdg-shell.xml'
 553         xdg_shell_sources = [
 554             wayland_scanner_code_gen.process(xdg_shell_xml),
 555             wayland_scanner_client_header_gen.process(xdg_shell_xml),
 556         ]
 557         executable('xkbcli-interactive-wayland',
 558                    'tools/interactive-wayland.c',
 559                    xdg_shell_sources,
 560                    dependencies: [tools_dep, wayland_client_dep],
 561                    install: true,
 562                    install_dir: dir_libexec)
 563         install_man('tools/xkbcli-interactive-wayland.1')
 564         configh_data.set10('HAVE_XKBCLI_INTERACTIVE_WAYLAND', true)
 565     endif
 566
 567     # Tool: list
 568     if get_option('enable-xkbregistry')
 569         configh_data.set10('HAVE_XKBCLI_LIST', true)
 570         executable('xkbcli-list',
 571                    'tools/registry-list.c',
 572                    dependencies: dep_libxkbregistry,
 573                    install: true,
 574                    install_dir: dir_libexec)
 575         install_man('tools/xkbcli-list.1')
 576     endif
 577
 578     # Tool: check-messages
 579     executable('xkb-check-messages',
 580                'tools/check-messages.c',
 581                'tools/messages.c',
 582                'tools/messages.h',
 583                'src/messages-codes.h',
 584                dependencies: [tools_dep],
 585                include_directories: [include_directories('src', 'include', 'tools')],
 586                install: false)
 587 endif
 588
 589
 590 # xkeyboard-config "verifier"
 591 xkct_config = configuration_data()
 592 xkct_config.set('MESON_BUILD_ROOT', meson.current_build_dir())
 593 xkct_config.set('XKB_CONFIG_ROOT', XKBCONFIGROOT)
 594 configure_file(input: 'test/xkeyboard-config-test.py.in',
 595                output: 'xkeyboard-config-test',
 596                configuration: xkct_config)
 597
 598 # Tests
 599 test_env = environment()
 600 test_env.set('XKB_LOG_LEVEL', 'debug')
 601 test_env.set('XKB_LOG_VERBOSITY', '10')
 602 test_env.set('top_srcdir', meson.current_source_dir())
 603 test_env.set('top_builddir', meson.current_build_dir())
 604 test_env.set('HAVE_XKBCLI_INTERACTIVE_EVDEV', configh_data.get('HAVE_XKBCLI_INTERACTIVE_EVDEV', 0).to_string())
 605 test_env.set('HAVE_XKBCLI_INTERACTIVE_WAYLAND', configh_data.get('HAVE_XKBCLI_INTERACTIVE_WAYLAND', 0).to_string())
 606 test_env.set('HAVE_XKBCLI_INTERACTIVE_X11', configh_data.get('HAVE_XKBCLI_INTERACTIVE_X11', 0).to_string())
 607 test_env.set('HAVE_XKBCLI_LIST', configh_data.get('HAVE_XKBCLI_LIST', 0).to_string())
 608
 609 test_configh_data = configuration_data()
 610 test_configh_data.set_quoted('TEST_XKB_CONFIG_ROOT', meson.current_source_dir()/'test'/'data')
 611 configure_file(output: 'test-config.h', configuration: test_configh_data)
 612
 613 # Some tests need to use unexported symbols, so we link them against
 614 # an internal copy of libxkbcommon with all symbols exposed.
 615 libxkbcommon_test_internal = static_library(
 616     'xkbcommon-test-internal',
 617     'test/common.c',
 618     'test/test.h',
 619     'test/evdev-scancodes.h',
 620     'bench/bench.c',
 621     'bench/bench.h',
 622     libxkbcommon_sources,
 623     include_directories: include_directories('src', 'include'),
 624 )
 625 test_dep = declare_dependency(
 626     include_directories: include_directories('src', 'include'),
 627     link_with: libxkbcommon_test_internal,
 628 )
 629 if get_option('enable-x11')
 630     libxkbcommon_x11_test_internal = static_library(
 631         'xkbcommon-x11-internal',
 632         libxkbcommon_x11_sources,
 633         'test/xvfb-wrapper.c',
 634         'test/xvfb-wrapper.h',
 635         include_directories: include_directories('src', 'include'),
 636         link_with: libxkbcommon_test_internal,
 637         dependencies: [
 638             xcb_dep,
 639             xcb_xkb_dep,
 640         ],
 641     )
 642     x11_test_dep = declare_dependency(
 643         link_with: libxkbcommon_x11_test_internal,
 644         dependencies: [
 645             test_dep,
 646             xcb_dep,
 647             xcb_xkb_dep,
 648         ],
 649     )
 650 endif
 651 test(
 652     'keysym',
 653     executable('test-keysym', 'test/keysym.c', dependencies: test_dep),
 654     env: test_env,
 655 )
 656 test(
 657     'keymap',
 658     executable('test-keymap', 'test/keymap.c', dependencies: test_dep),
 659     env: test_env,
 660 )
 661 test(
 662     'filecomp',
 663     executable('test-filecomp', 'test/filecomp.c', dependencies: test_dep),
 664     env: test_env,
 665 )
 666 test(
 667     'context',
 668     executable('test-context', 'test/context.c', dependencies: test_dep),
 669     env: test_env,
 670 )
 671 test(
 672     'rules-file',
 673     executable('test-rules-file', 'test/rules-file.c', dependencies: test_dep),
 674     env: test_env,
 675 )
 676 test(
 677     'rules-file-includes',
 678     executable('test-rules-file-includes', 'test/rules-file-includes.c', dependencies: test_dep),
 679     env: test_env,
 680 )
 681 test(
 682     'stringcomp',
 683     executable('test-stringcomp', 'test/stringcomp.c', dependencies: test_dep),
 684     env: test_env,
 685 )
 686 test(
 687     'buffercomp',
 688     executable('test-buffercomp', 'test/buffercomp.c', dependencies: test_dep),
 689     env: test_env,
 690 )
 691 test(
 692     'log',
 693     executable('test-log', 'test/log.c', dependencies: test_dep),
 694     env: test_env,
 695 )
 696 test(
 697     'atom',
 698     executable('test-atom', 'test/atom.c', dependencies: test_dep),
 699     env: test_env,
 700 )
 701 test(
 702     'utf8',
 703     executable('test-utf8', 'test/utf8.c', dependencies: test_dep),
 704     env: test_env,
 705 )
 706 test(
 707     'state',
 708     executable('test-state', 'test/state.c', dependencies: test_dep),
 709     env: test_env,
 710 )
 711 test(
 712     'keyseq',
 713     executable('test-keyseq', 'test/keyseq.c', dependencies: test_dep),
 714     env: test_env,
 715 )
 716 test(
 717     'rulescomp',
 718     executable('test-rulescomp', 'test/rulescomp.c', dependencies: test_dep),
 719     env: test_env,
 720 )
 721 test(
 722     'compose',
 723     executable('test-compose', 'test/compose.c', dependencies: test_dep),
 724     env: test_env,
 725 )
 726 test(
 727     'utils',
 728     executable('test-utils', 'test/utils.c', dependencies: test_dep),
 729     env: test_env,
 730 )
 731 test(
 732     'symbols-leak-test',
 733     find_program('test/symbols-leak-test.py'),
 734     env: test_env,
 735     suite: ['python-tests'],
 736 )
 737 test(
 738     'modifiers',
 739     executable('test-modifiers', 'test/modifiers.c', dependencies: test_dep),
 740     env: test_env,
 741 )
 742 test(
 743     'messages',
 744     executable(
 745         'test-messages',
 746         'test/messages.c',
 747         'tools/messages.c',
 748         'tools/messages.h',
 749         include_directories: include_directories('src', 'include', 'tools'),
 750         dependencies: test_dep),
 751     env: test_env,
 752 )
 753 if get_option('enable-x11')
 754     test(
 755         'x11',
 756         executable('test-x11', 'test/x11.c', dependencies: x11_test_dep),
 757         env: test_env,
 758     )
 759     test(
 760         'x11comp',
 761         executable('test-x11comp', 'test/x11comp.c', dependencies: x11_test_dep),
 762         env: test_env,
 763     )
 764 endif
 765 if get_option('enable-xkbregistry')
 766     test(
 767         'registry',
 768         executable('test-registry', 'test/registry.c',
 769                    include_directories: include_directories('src'),
 770                    dependencies: [dep_libxkbregistry, test_dep]),
 771         env: test_env,
 772     )
 773 endif
 774 if build_tools
 775     test('tool-option-parsing',
 776          find_program('test/tool-option-parsing.py'),
 777          env: test_env,
 778          suite: ['python-tests'])
 779
 780     # A set of keysyms to test for. Add one or two symbols to this array
 781     # whenever the xorgproto gets updated to make sure we resolve them.
 782     keysyms_to_test = [
 783         'XF86Macro23',
 784     ]
 785
 786     env = environment()
 787     env.set('XKB_CONFIG_ROOT', meson.current_source_dir()/'test'/'data')
 788     foreach keysym: keysyms_to_test
 789         test('keysym-test-@0@'.format(keysym),
 790              find_program('test/test-keysym.py'),
 791              env: env,
 792              args: [keysym, '--tool', xkbcli_compile_keymap],
 793              suite: ['python-tests'])
 794     endforeach
 795 endif
 796
 797 valgrind = find_program('valgrind', required: false)
 798 if valgrind.found()
 799     add_test_setup('valgrind',
 800         exe_wrapper: [valgrind,
 801                        '--leak-check=full',
 802                        '--track-origins=yes',
 803                        '--gen-suppressions=all',
 804                        '--error-exitcode=99'],
 805         timeout_multiplier : 10)
 806 else
 807     message('valgrind not found, disabling valgrind test setup')
 808 endif
 809
 810
 811 # Fuzzing target programs.
 812 executable('fuzz-keymap', 'fuzz/keymap/target.c', dependencies: test_dep)
 813 executable('fuzz-compose', 'fuzz/compose/target.c', dependencies: test_dep)
 814
 815
 816 # Benchmarks.
 817 bench_env = environment()
 818 bench_env.set('top_srcdir', meson.current_source_dir())
 819 benchmark(
 820     'key-proc',
 821     executable('bench-key-proc', 'bench/key-proc.c', dependencies: test_dep),
 822     env: bench_env,
 823 )
 824 benchmark(
 825     'rules',
 826     executable('bench-rules', 'bench/rules.c', dependencies: test_dep),
 827     env: bench_env,
 828 )
 829 benchmark(
 830     'rulescomp',
 831     executable('bench-rulescomp', 'bench/rulescomp.c', dependencies: test_dep),
 832     env: bench_env,
 833 )
 834 benchmark(
 835     'compose',
 836     executable('bench-compose', 'bench/compose.c', dependencies: test_dep),
 837     env: bench_env,
 838 )
 839 benchmark(
 840     'compose-traversal',
 841     executable('bench-compose-traversal', 'bench/compose-traversal.c', dependencies: test_dep),
 842     env: bench_env,
 843 )
 844 benchmark(
 845     'atom',
 846     executable('bench-atom', 'bench/atom.c', dependencies: test_dep),
 847     env: bench_env,
 848 )
 849 if get_option('enable-x11')
 850   benchmark(
 851       'x11',
 852       executable('bench-x11', 'bench/x11.c', dependencies: x11_test_dep),
 853       env: bench_env,
 854   )
 855 endif
 856
 857
 858 # Documentation.
 859 if get_option('enable-docs')
 860     doxygen = find_program('doxygen', required: false)
 861     if not doxygen.found()
 862         error('''Documentation requires doxygen which was not found.
 863 You can disable the documentation with -Denable-docs=false.''')
 864     endif
 865     doxygen_wrapper = find_program('scripts/doxygen-wrapper')
 866
 867     doxygen_input = [
 868         'README.md',
 869         'doc/diagrams/xkb-configuration.dot',
 870         'doc/doxygen-extra.css',
 871         'doc/introduction-to-xkb.md',
 872         'doc/quick-guide.md',
 873         'doc/compatibility.md',
 874         'doc/user-configuration.md',
 875         'doc/rules-format.md',
 876         'doc/keymap-format-text-v1.md',
 877         'doc/message-registry.md',
 878         'include/xkbcommon/xkbcommon.h',
 879         'include/xkbcommon/xkbcommon-compose.h',
 880         'include/xkbcommon/xkbcommon-keysyms.h',
 881         'include/xkbcommon/xkbcommon-names.h',
 882         'include/xkbcommon/xkbcommon-x11.h',
 883         'include/xkbcommon/xkbregistry.h',
 884     ]
 885     doxygen_data = configuration_data()
 886     doxygen_data.set('PACKAGE_NAME', meson.project_name())
 887     doxygen_data.set('PACKAGE_VERSION', meson.project_version())
 888     doxygen_data.set('INPUT', ' '.join(doxygen_input))
 889     doxygen_data.set('OUTPUT_DIRECTORY', meson.current_build_dir())
 890     doxyfile = configure_file(
 891         input: 'doc/Doxyfile.in',
 892         output: 'Doxyfile',
 893         configuration: doxygen_data,
 894     )
 895     # TODO: Meson should provide this.
 896     docdir = get_option('datadir')/'doc'/meson.project_name()
 897     doc_gen = custom_target(
 898         'doc',
 899         input: [doxyfile] + doxygen_input,
 900         output: 'html',
 901         command: [
 902             doxygen_wrapper,
 903             doxygen,
 904             meson.current_build_dir()/'Doxyfile',
 905             meson.current_source_dir(),
 906         ],
 907         install: true,
 908         install_dir: docdir,
 909         build_by_default: true,
 910     )
 911     if get_option('enable-cool-uris')
 912         ensure_stable_urls = find_program('scripts'/'ensure-stable-doc-urls.py')
 913         custom_target(
 914             'doc-cool-uris',
 915             input: [doc_gen, 'doc'/'cool-uris.yaml'],
 916             output: 'html-xtra',
 917             command: [
 918                 ensure_stable_urls,
 919                 'generate-redirections',
 920                 meson.current_source_dir()/'doc'/'cool-uris.yaml',
 921                 meson.current_build_dir()/'html'
 922             ],
 923             install: false,
 924             build_by_default: true,
 925         )
 926     endif
 927 endif
 928
 929 configure_file(output: 'config.h', configuration: configh_data)
 930
 931
 932 # Stable variables for projects using xkbcommon as a subproject.
 933 # These variables should not be renamed.
 934 libxkbcommon_dep = dep_libxkbcommon
 935 if get_option('enable-x11')
 936   libxkbcommon_x11_dep = dep_libxkbcommon_x11
 937 endif
 938 if get_option('enable-xkbregistry')
 939   libxkbregistry_dep = dep_libxkbregistry
 940 endif
 941
 942 if meson.version().version_compare('>=0.62.0')
 943     summary({
 944       'backend': meson.backend(),
 945       'buildtype': get_option('buildtype'),
 946       'c_args': get_option('c_args'),
 947       'c_link_args': get_option('c_link_args'),
 948       'yacc': yacc.full_path() + ' ' + yacc.version(),
 949     }, section: 'Compiler')
 950     summary({
 951       'prefix': get_option('prefix'),
 952       'bindir': get_option('bindir'),
 953       'libdir': get_option('libdir'),
 954       'datadir': get_option('datadir'),
 955       'xkb-config-root': XKBCONFIGROOT,
 956       'xkb-config-extra-path': XKBCONFIGEXTRAPATH,
 957       'xlocaledir': XLOCALEDIR,
 958     }, section: 'Directories')
 959     summary({
 960       'docs': get_option('enable-docs'),
 961       'tools': get_option('enable-tools'),
 962       'wayland': get_option('enable-wayland'),
 963       'x11': get_option('enable-x11'),
 964     }, section: 'Features')
 965     summary({
 966       'layout': get_option('default-layout'),
 967       'model': get_option('default-model'),
 968       'options': get_option('default-options'),
 969       'rules': get_option('default-rules'),
 970       'variant': get_option('default-variant'),
 971     }, section: 'Defaults')
 972 endif