meson.build

   1 project('gstreamer', 'c', 'cpp',
   2   version : '1.11.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 prefix = get_option('prefix')
  25 libtype = get_option('library_format')
  26
  27 libexecdir = get_option('libexecdir')
  28 helpers_install_dir = libexecdir + '/gstreamer-1.0/'
  29
  30 cc = meson.get_compiler('c')
  31
  32 # Ignore several spurious warnings for things gstreamer does very commonly
  33 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  34 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  35 # NOTE: Only add warnings here if you are sure they're spurious
  36 if cc.get_id() == 'msvc'
  37   add_project_arguments(
  38       '/wd4018', # implicit signed/unsigned conversion
  39       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  40       '/wd4244', # lossy type conversion (e.g. double -> int)
  41       '/wd4305', # truncating type conversion (e.g. double -> float)
  42       language : 'c')
  43 endif
  44
  45 cdata = configuration_data()
  46 cdata.set('GST_VERSION_MAJOR', gst_version_major)
  47 cdata.set('GST_VERSION_MINOR', gst_version_minor)
  48 cdata.set('GST_VERSION_MICRO', gst_version_micro)
  49 cdata.set('GST_VERSION_NANO', gst_version_nano)
  50 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  51 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  52 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  53 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  54 cdata.set('GST_API_VERSION', '"1.0"')
  55 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  56 cdata.set('GST_LICENSE', '"LGPL"')
  57 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  58 cdata.set('GST_PACKAGE_NAME', '"GStreamer source release"')
  59 cdata.set('PACKAGE', '"gstreamer"')
  60 cdata.set('PACKAGE_NAME', '"GStreamer"')
  61 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  62 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  64 cdata.set('PACKAGE_URL', '""')
  65 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  66 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  67 cdata.set('VERSION', '"@0@"'.format(gst_version))
  68 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  69 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  70 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  71 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  72
  73 if gst_version_nano > 0
  74     # Have GST_ERROR message printed when running from git
  75     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  76 else
  77     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  78 endif
  79
  80 # These are only needed/used by the ABI tests
  81 host_defines = [
  82   [ 'x86', 'HAVE_CPU_I386' ],
  83   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  84   [ 'arm', 'HAVE_CPU_ARM' ],
  85   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
  86   [ 'mips', 'HAVE_CPU_MIPS' ],
  87   [ 'powerpc', 'HAVE_CPU_PPC' ],
  88   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
  89   [ 'alpha', 'HAVE_CPU_ALPHA' ],
  90   [ 'sparc', 'HAVE_CPU_SPARC' ],
  91   [ 'ia64', 'HAVE_CPU_IA64' ],
  92   [ 'hppa', 'HAVE_CPU_HPPA' ],
  93   [ 'm68k', 'HAVE_CPU_M68K' ],
  94   [ 's390', 'HAVE_CPU_S390' ],
  95 ]
  96 foreach h : host_defines
  97   if h.get(0) == host_machine.cpu()
  98     cdata.set(h.get(1), 1)
  99   endif
 100 endforeach
 101 # FIXME: should really be called HOST_CPU or such
 102 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 103
 104 check_headers = [['dlfcn.h','HAVE_DLFCN_H'],
 105   ['inttypes.h', 'HAVE_INTTYPES_H'],
 106   ['memory.h', 'HAVE_MEMORY_H'],
 107   ['poll.h', 'HAVE_POLL_H'],
 108   ['stdint.h', 'HAVE_STDINT_H'],
 109   ['stdio_ext.h', 'HAVE_STDIO_EXT_H'],
 110   ['strings.h', 'HAVE_STRINGS_H'],
 111   ['string.h', 'HAVE_STRING_H'],
 112   ['sys/param.h', 'HAVE_SYS_PARAM_H'],
 113   ['sys/poll.h', 'HAVE_SYS_POLL_H'],
 114   ['sys/prctl.h', 'HAVE_SYS_PRCTL_H'],
 115   ['sys/socket.h', 'HAVE_SYS_SOCKET_H'],
 116   ['sys/stat.h', 'HAVE_SYS_STAT_H'],
 117   ['sys/times.h', 'HAVE_SYS_TIMES_H'],
 118   ['sys/time.h', 'HAVE_SYS_TIME_H'],
 119   ['sys/types.h', 'HAVE_SYS_TYPES_H'],
 120   ['sys/utsname.h', 'HAVE_SYS_UTSNAME_H'],
 121   ['sys/wait.h', 'HAVE_SYS_WAIT_H'],
 122   ['ucontext.h', 'HAVE_UCONTEXT_H'],
 123   ['unistd.h', 'HAVE_UNISTD_H'],
 124   ['valgrind/valgrind.h', 'HAVE_VALGRIND_VALGRIND_H'],
 125   ['sys/resource.h', 'HAVE_SYS_RESOURCE_H'],
 126 ]
 127
 128 if host_machine.system() == 'windows'
 129   check_headers += [ ['winsock2.h', 'HAVE_WINSOCK2_H'] ]
 130 endif
 131
 132 foreach h : check_headers
 133   if cc.has_header(h.get(0))
 134     cdata.set(h.get(1), 1)
 135   endif
 136 endforeach
 137
 138 gmtoff_src = '''#include <time.h>
 139 int main(void) {
 140   struct tm t;
 141   t.tm_gmtoff = 0;
 142   return 0;
 143 }
 144 '''
 145
 146 if cc.compiles(gmtoff_src, name : 'tm_gmtoff from time.h')
 147   cdata.set('HAVE_TM_GMTOFF', 1)
 148 endif
 149
 150 if cc.has_function('gmtime_r', prefix : '#include<time.h>')
 151   cdata.set('HAVE_GMTIME_R', 1)
 152 endif
 153 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 154   cdata.set('HAVE_LOCALTIME_R', 1)
 155   # Needed by libcheck
 156   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 157 endif
 158 if cc.has_function('sigaction', prefix : '#include<signal.h>')
 159   cdata.set('HAVE_SIGACTION', 1)
 160 endif
 161 have_getrusage = cc.has_function('getrusage', prefix : '#include <sys/time.h>\n#include <sys/resource.h>')
 162 if have_getrusage
 163   cdata.set('HAVE_GETRUSAGE', 1)
 164 endif
 165
 166 if cc.has_function('fseeko', prefix : '#include<stdio.h>')
 167   cdata.set('HAVE_FSEEKO', 1)
 168 endif
 169 if cc.has_function('ftello', prefix : '#include<stdio.h>')
 170   cdata.set('HAVE_FTELLO', 1)
 171 endif
 172 if cc.has_function('fsetpos', prefix : '#include<stdio.h>')
 173   cdata.set('HAVE_FSETPOS', 1)
 174 endif
 175 if cc.has_function('fgetpos', prefix : '#include<stdio.h>')
 176   cdata.set('HAVE_FGETPOS', 1)
 177 endif
 178 if cc.has_function('poll', prefix : '#include<poll.h>')
 179   cdata.set('HAVE_POLL', 1)
 180 endif
 181 if cc.has_function('pselect', prefix : '#include<sys/select.h>')
 182   cdata.set('HAVE_PSELECT', 1)
 183 endif
 184 cdata.set('HAVE_MMAP', 1)
 185
 186 if cc.has_function('posix_memalign', prefix : '#include<stdlib.h>')
 187   cdata.set('HAVE_POSIX_MEMALIGN', 1)
 188 endif
 189 if cc.has_function('getpagesize', prefix : '#include<unistd.h>')
 190   cdata.set('HAVE_GETPAGESIZE', 1)
 191 endif
 192
 193 # With XCode 8, clock_gettime will be incorrectly detected as being available
 194 # regardless of what version of OS X you target because the symbol is available
 195 # in the .tbd file as a weak symbol.
 196 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 197 #
 198 # We cannot simply do cc.has_function with -Wl,-no_weak_imports because the
 199 # check does its own prototype decl that doesn't trigger that compiler flag.
 200 #
 201 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 202 # actually available, so we can unconditionally disable it for older versions.
 203 disable_clock_gettime_src = '''#include <AvailabilityMacros.h>
 204 #include <TargetConditionals.h>
 205 #if defined(TARGET_OS_MAC)
 206 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 207 #    error "Not compiling for OS X 10.12 or later"
 208 #  endif
 209 #else
 210 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 211 #    error "Not compiling for iOS 10.0 or later"
 212 #  endif
 213 #endif
 214 '''
 215
 216 if cc.has_function('clock_gettime', prefix : '#include <time.h>')
 217   if host_machine.system() == 'darwin'
 218     if cc.compiles(disable_clock_gettime_src, name : 'target darwin/ios version has clock_gettime')
 219       cdata.set('HAVE_CLOCK_GETTIME', 1)
 220     endif
 221   else
 222     cdata.set('HAVE_CLOCK_GETTIME', 1)
 223   endif
 224 endif
 225
 226 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 227 # building with MSVC
 228 if cc.get_id() == 'msvc'
 229   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 230 else
 231   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 232 endif
 233
 234 # -------------------------------------------------------------------------------------
 235 # config.h things needed by libcheck
 236 # -------------------------------------------------------------------------------------
 237 if cc.has_function('getpid', prefix : '#include <sys/types.h>\n#include <unistd.h>')
 238   cdata.set('HAVE_GETPID', 1)
 239 elif cc.has_function('_getpid', prefix : '#include <process.h>')
 240   cdata.set('HAVE__GETPID', 1) # Windows (MSVC)
 241 endif
 242 if cc.has_function('strdup', prefix : '#include <string.h>')
 243   cdata.set('HAVE_DECL_STRDUP', 1)
 244 elif cc.has_function('_strdup', prefix : '#include <string.h>')
 245   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 246 endif
 247 if cc.has_function('getline', prefix : '#include <stdio.h>')
 248   cdata.set('HAVE_GETLINE', 1)
 249 endif
 250 if cc.has_function('mkstemp', prefix : '#include <stdlib.h>')
 251   cdata.set('HAVE_MKSTEMP', 1)
 252 endif
 253 if host_machine.system() != 'windows'
 254   cdata.set('HAVE_FORK', 1)
 255 else
 256   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 257   cdata.set('HAVE_FORK', 0)
 258 endif
 259 if cc.has_function('alarm', prefix : '#include <unistd.h>')
 260   cdata.set('HAVE_ALARM', 1)
 261 endif
 262 if cc.has_function('gettimeofday', prefix : '#include <sys/time.h>')
 263   cdata.set('HAVE_GETTIMEOFDAY', 1)
 264 endif
 265 if cc.has_function('strsignal', prefix : '#include <string.h>')
 266   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 267 endif
 268 # Check for availability of types
 269 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 270   cdata.set('clockid_t', 'int')
 271 endif
 272 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 273   cdata.set('timer_t', 'int')
 274 endif
 275 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 276                       prefix : '#include <time.h>')
 277   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 278 endif
 279 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 280                       prefix : '#include <time.h>')
 281   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 282 endif
 283
 284 # Platform deps; only ws2_32 and execinfo for now
 285 platform_deps = []
 286 if host_machine.system() == 'windows'
 287   platform_deps = [cc.find_library('ws2_32')]
 288 endif
 289
 290 unwind_dep = dependency('libunwind', required : false)
 291 dw_dep = dependency('libdw', required: false)
 292 if unwind_dep.found()
 293   cdata.set('HAVE_UNWIND', 1)
 294   if dw_dep.found()
 295     cdata.set('HAVE_DW', 1)
 296   else
 297     message('Support for backtraces is partial only.')
 298   endif
 299 else
 300   if cc.has_function('backtrace')
 301     cdata.set('HAVE_BACKTRACE', 1)
 302   else
 303       message('NO backtraces support.')
 304   endif
 305 endif
 306
 307 if cc.has_header('execinfo.h')
 308   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 309     cdata.set('HAVE_BACKTRACE', 1)
 310   else
 311     execinfo_dep = cc.find_library('execinfo', required : false)
 312     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 313       cdata.set('HAVE_BACKTRACE', 1)
 314       platform_deps += execinfo_dep
 315     endif
 316   endif
 317 endif
 318
 319 disable_gst_debug = get_option('disable_gst_debug')
 320 if get_option('disable_gst_debug')
 321     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
 322   add_project_arguments(['-Wno-unused'], language: 'c')
 323 endif
 324
 325 configure_file(input : 'config.h.meson',
 326   output : 'config.h',
 327   configuration : cdata)
 328
 329
 330 configinc = include_directories('.')
 331 libsinc = include_directories('libs')
 332 privinc = include_directories('gst')
 333
 334 # Find dependencies
 335 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
 336 gobject_dep = dependency('gobject-2.0')
 337 gmodule_dep = dependency('gmodule-2.0')
 338 if host_machine.system() == 'windows'
 339     gio_dep = dependency('gio-2.0')
 340 else
 341     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
 342 endif
 343
 344 mathlib = cc.find_library('m', required : false)
 345 # Needed for timer_create/settime/delete
 346 # Also provides clock_gettime in glibc < 2.17
 347 rt_lib = cc.find_library('rt', required : false)
 348
 349 gir = find_program('g-ir-scanner', required : false)
 350 gnome = import('gnome')
 351
 352 # Fixme, not very elegant.
 353 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 354
 355 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 356     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 357     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 358     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 359     'gst_init(NULL,NULL);' ]
 360 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 361
 362 gst_c_args = ['-DHAVE_CONFIG_H']
 363 if libtype == 'static'
 364   gst_c_args += ['-DGST_STATIC_COMPILATION']
 365 endif
 366
 367 subdir('gst')
 368 subdir('libs')
 369 subdir('plugins')
 370 subdir('tools')
 371 subdir('pkgconfig')
 372 subdir('tests')
 373 subdir('po')
 374
 375 if build_machine.system() == 'windows'
 376   message('Disabling gtk-doc while building on Windows')
 377 elif get_option('disable_gtkdoc')
 378   message('gtk-doc is disabled via options')
 379 else
 380   if find_program('gtkdoc-scan', required : false).found()
 381     subdir('docs')
 382   else
 383     message('Not building documentation as gtk-doc was not found')
 384   endif
 385 endif
 386
 387 python3 = find_program('python3')
 388 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')