mbr/mbr.S

   1 /* -----------------------------------------------------------------------
   2  *
   3  *   Copyright 2007 H. Peter Anvin - All Rights Reserved
   4  *
   5  *   Permission is hereby granted, free of charge, to any person
   6  *   obtaining a copy of this software and associated documentation
   7  *   files (the "Software"), to deal in the Software without
   8  *   restriction, including without limitation the rights to use,
   9  *   copy, modify, merge, publish, distribute, sublicense, and/or
  10  *   sell copies of the Software, and to permit persons to whom
  11  *   the Software is furnished to do so, subject to the following
  12  *   conditions:
  13  *
  14  *   The above copyright notice and this permission notice shall
  15  *   be included in all copies or substantial portions of the Software.
  16  *
  17  *   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18  *   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  19  *   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20  *   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  21  *   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  22  *   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  23  *   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  24  *   OTHER DEALINGS IN THE SOFTWARE.
  25  *
  26  * ----------------------------------------------------------------------- */
  27
  28         .code16
  29         .text
  30
  31         .globl  bootsec
  32 stack           = 0x7c00
  33 driveno         = (stack-6)
  34 sectors         = (stack-8)
  35 secpercyl       = (stack-12)
  36
  37 BIOS_page = 0x462
  38
  39         /* gas/ld has issues with doing this as absolute addresses... */
  40         .section ".bootsec", "a", @nobits
  41         .globl  bootsec
  42 bootsec:
  43         .space  512
  44
  45         .text
  46         .globl  _start
  47 _start:
  48         cli
  49         xorw    %ax, %ax
  50         movw    %ax, %ds
  51         movw    %ax, %ss
  52         movw    $stack, %sp
  53         movw    %sp, %si
  54         pushw   %es             /* es:di -> $PnP header */
  55         pushw   %di
  56         pushw   %dx             /* dl -> drive number */
  57         movw    %ax, %es
  58         sti
  59         cld
  60
  61         /* Copy down to 0:0x600 */
  62         movw    $_start, %di
  63         movw    $(512/2), %cx
  64         rep; movsw
  65
  66         ljmpw   $0, $next
  67
  68 next:
  69         /* Check to see if we have EBIOS */
  70         pushw   %dx             /* drive number */
  71         movw    $0x4100, %ax
  72         movw    $0x55aa, %bx
  73         xorw    %cx, %cx
  74         xorb    %dh, %dh
  75         stc
  76         int     $0x13
  77         jc      1f
  78         cmpw    $0xaa55, %bx
  79         jne     1f
  80         shrw    %cx             /* Bit 0 = fixed disk subset */
  81         jnc     1f
  82
  83         /* We have EBIOS; patch in a jump to read_sector_ebios */
  84         movw    $0xeb+((read_sector_ebios-read_sector_cbios-2)<< 8), (read_sector_cbios)
  85
  86 1:
  87         popw    %dx
  88
  89         /* Get (C)HS geometry */
  90         movb    $0x08, %ah
  91         int     $0x13
  92         andw    $0x3f, %cx      /* Sector count */
  93         pushw   %cx             /* Save sectors on the stack */
  94         xorw    %ax, %ax
  95         pushw   %ax             /* High word of sectors/cylinder */
  96         movb    %dh, %al        /* dh = number of heads */
  97         incw    %ax             /* From 0-based to count */
  98         mulw    %cx             /* Heads*sectors -> sectors per cylinder */
  99         pushw   %ax             /* Save sectors/cylinder on the stack */
 100
 101         xorl    %eax, %eax      /* Base */
 102         cdq                     /* Root (%edx <- 0) */
 103         call    scan_partition_table
 104
 105         /* If we get here, we have no OS */
 106         jmp     missing_os
 107
 108 /*
 109  * read_sector: read a single sector pointed to by %eax to 0x7c00.
 110  * CF is set on error.  All registers saved.
 111  */
 112 read_sector:
 113         pushal
 114         movw    %sp, %si
 115         xorl    %edx, %edx
 116         movw    $bootsec, %bx
 117 read_sector_cbios:
 118         divl    (secpercyl)
 119         shlb    $6, %ah
 120         movb    %ah, %cl
 121         movb    %al, %ch
 122         xchgw   %dx, %ax
 123         divb    (sectors)
 124         movb    %al, %dh
 125         incb    %ah
 126         orb     %ah, %cl
 127         movw    $0x0201, %ax
 128         jmp     read_common
 129 read_sector_ebios:
 130         pushl   %edx    /* MSW of LBA */
 131         pushl   %eax    /* LSW of LBA */
 132         pushw   %es     /* Buffer segment */
 133         pushw   %bx     /* Buffer offset */
 134         pushw   $1      /* Sector count */
 135         pushw   $16     /* Size of packet */
 136         movb    $0x42, %ah
 137 read_common:
 138         movb    (driveno), %dl
 139         int     $0x13
 140         movw    %si, %sp
 141         popal
 142         ret
 143
 144 /*
 145  * read_partition_table:
 146  *      Read a partition table (pointed to by %eax), and copy
 147  *      the partition table into the ptab buffer.
 148  *      Clobbers %si, %di, and %cx, other registers preserved.
 149  */
 150 ptab    = _start+446
 151
 152 read_partition_table:
 153         call    read_sector
 154         jc      20f
 155         movw    $bootsec+446, %si
 156         movw    $ptab, %di
 157         movw    $(16*4/2), %cx
 158         rep ; movsw
 159 20:
 160         ret
 161
 162 /*
 163  * scan_partition_table:
 164  *      Scan a partition table currently loaded in the partition table
 165  *      area.  Preserve all registers.
 166  *
 167  *      On entry:
 168  *        %eax - base (location of this partition table)
 169  *        %edx - root (offset from MBR, or 0 for MBR)
 170  *
 171  *      These get pushed into stack slots:
 172  *        28(%bp) - %eax - base
 173  *        20(%bp) - %edx - root
 174  */
 175
 176 scan_partition_table:
 177         pushal
 178         movw    %sp, %bp
 179
 180         /* Search for active partitions */
 181         movw    $ptab, %bx
 182         movw    $4, %cx
 183         xorw    %ax, %ax
 184         push    %bx
 185         push    %cx
 186 5:
 187         testb   $0x80, (%bx)
 188         jz      6f
 189         incw    %ax
 190         movw    %bx, %si
 191 6:
 192         addw    $16, %bx
 193         loopw   5b
 194
 195         decw    %ax             /* Number of active partitions found */
 196         jz      boot
 197         jns     too_many_active
 198
 199         /* No active partitions found, look for extended partitions */
 200         popw    %bx             /* %bx <- ptab */
 201         popw    %cx             /* %cx <- 4    */
 202 7:
 203         movb    4(%bx), %al
 204         cmpb    $0x0f, %al      /* 0x0f = Win9x extended */
 205         je      8f
 206         andb    $~0x80, %al     /* 0x85 = Linux extended */
 207         cmpb    $0x05, %al      /* 0x05 = MS-DOS extended */
 208         jne     9f
 209
 210         /* It is an extended partition.  Read the extended partition and
 211            try to scan it.  If the scan returns, re-load the current
 212            partition table and resume scan. */
 213 8:
 214         movl    8(%bx), %eax            /* Partition table offset */
 215         movl    20(%bp), %edx           /* "Root" */
 216         addl    %edx, %eax              /* Compute location of new ptab */
 217         andl    %edx, %edx              /* Is this the MBR? */
 218         jnz     10f
 219         movl    %eax, %edx              /* Offset -> root if this was MBR */
 220 10:
 221         call    read_partition_table
 222         jc      11f
 223         call    scan_partition_table
 224 11:
 225         /* This returned, so we need to reload the current partition table */
 226         movl    28(%bp), %eax           /* "Base" */
 227         call    read_partition_table
 228
 229         /* fall through */
 230 9:
 231         /* Not an extended partition */
 232         addw    $16, %bx
 233         loopw   7b
 234
 235         /* Nothing found, return */
 236         popal
 237         ret
 238
 239 /*
 240  * boot: invoke the actual bootstrap. (%si) points to the partition
 241  *       table entry, and 28(%bp) has the partition table base.
 242  */
 243 boot:
 244         movl    8(%si), %eax
 245         addl    28(%bp), %eax
 246         movl    %eax, 8(%si)    /* Adjust in-memory partition table entry */
 247         call    read_sector
 248         jc      disk_error
 249         cmpw    $0xaa55, (bootsec+510)
 250         jne     missing_os              /* Not a valid boot sector */
 251         movw    $driveno, %sp
 252         popw    %dx             /* dl -> drive number */
 253         popw    %di             /* es:di -> $PnP vector */
 254         popw    %es
 255         cli
 256         jmp     bootsec
 257
 258 /*
 259  * error messages
 260  */
 261 missing_os:
 262         movw    $missing_os_msg, %si
 263         jmp     error
 264 disk_error:
 265         movw    $disk_error_msg, %si
 266         jmp     error
 267 too_many_active:
 268         movw    $too_many_active_msg, %si
 269         /* jmp error */
 270
 271 error:
 272 2:
 273         lodsb
 274         andb    %al, %al
 275         jz      3f
 276         movb    $0x0e, %ah
 277         movb    (BIOS_page), %bh
 278         movb    $0x07, %bl
 279         int     $0x10
 280         jmp     2b
 281 3:
 282         int     $0x18           /* Boot failure */
 283         jmp     .               /* Die */
 284
 285 missing_os_msg:
 286         .ascii  "Missing operating system."
 287         .byte   0
 288 disk_error_msg:
 289         .ascii  "Operating system load error."
 290         .byte   0
 291 too_many_active_msg:
 292         .ascii  "Multiple active partitions."
 293         .byte   0