mbr/mbr.S

   1 /* -----------------------------------------------------------------------
   2  *
   3  *   Copyright 2007-2008 H. Peter Anvin - All Rights Reserved
   4  *
   5  *   Permission is hereby granted, free of charge, to any person
   6  *   obtaining a copy of this software and associated documentation
   7  *   files (the "Software"), to deal in the Software without
   8  *   restriction, including without limitation the rights to use,
   9  *   copy, modify, merge, publish, distribute, sublicense, and/or
  10  *   sell copies of the Software, and to permit persons to whom
  11  *   the Software is furnished to do so, subject to the following
  12  *   conditions:
  13  *
  14  *   The above copyright notice and this permission notice shall
  15  *   be included in all copies or substantial portions of the Software.
  16  *
  17  *   THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18  *   EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  19  *   OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20  *   NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  21  *   HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  22  *   WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  23  *   FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  24  *   OTHER DEALINGS IN THE SOFTWARE.
  25  *
  26  * ----------------------------------------------------------------------- */
  27
  28         .code16
  29         .text
  30
  31         .globl  bootsec
  32 stack           = 0x7c00
  33 driveno         = (stack-6)
  34 sectors         = (stack-8)
  35 secpercyl       = (stack-12)
  36
  37 BIOS_page = 0x462
  38
  39         /* gas/ld has issues with doing this as absolute addresses... */
  40         .section ".bootsec", "a", @nobits
  41         .globl  bootsec
  42 bootsec:
  43         .space  512
  44
  45         .text
  46         .globl  _start
  47 _start:
  48         cli
  49         xorw    %ax, %ax
  50         movw    %ax, %ds
  51         movw    %ax, %ss
  52         movw    $stack, %sp
  53         movw    %sp, %si
  54         pushw   %es             /* es:di -> $PnP header */
  55         pushw   %di
  56         pushw   %dx             /* dl -> drive number */
  57         movw    %ax, %es
  58         sti
  59         cld
  60
  61         /* Copy down to 0:0x600 */
  62         movw    $_start, %di
  63         movw    $(512/2), %cx
  64         rep; movsw
  65
  66         ljmpw   $0, $next
  67
  68 next:
  69         /* Check to see if we have EBIOS */
  70         pushw   %dx             /* drive number */
  71         movw    $0x4100, %ax
  72         movw    $0x55aa, %bx
  73         xorw    %cx, %cx
  74         xorb    %dh, %dh
  75         stc
  76         int     $0x13
  77         jc      1f
  78         cmpw    $0xaa55, %bx
  79         jne     1f
  80         shrw    %cx             /* Bit 0 = fixed disk subset */
  81         jnc     1f
  82
  83         /* We have EBIOS; patch in the following code at
  84            read_sector_cbios: movb $0x42, %ah ;  jmp read_common */
  85         movl    $0xeb42b4+((read_common-read_sector_cbios-4) << 24), \
  86                 (read_sector_cbios)
  87
  88 1:
  89         popw    %dx
  90
  91         /* Get (C)HS geometry */
  92         movb    $0x08, %ah
  93         int     $0x13
  94         andw    $0x3f, %cx      /* Sector count */
  95         pushw   %cx             /* Save sectors on the stack */
  96         movzbw  %dh, %ax        /* dh = max head */
  97         incw    %ax             /* From 0-based max to count */
  98         mulw    %cx             /* Heads*sectors -> sectors per cylinder */
  99
 100         /* Save sectors/cylinder on the stack */
 101         pushw   %dx             /* High word */
 102         pushw   %ax             /* Low word */
 103
 104         xorl    %eax, %eax      /* Base */
 105         cdq                     /* Root (%edx <- 0) */
 106         call    scan_partition_table
 107
 108         /* If we get here, we have no OS */
 109 missing_os:
 110         call    error
 111         .ascii  "Missing operating system.\r\n"
 112         .byte   0
 113
 114 /*
 115  * read_sector: read a single sector pointed to by %eax to 0x7c00.
 116  * CF is set on error.  All registers saved.
 117  */
 118 read_sector:
 119         pushal
 120         xorl    %edx, %edx
 121         movw    $bootsec, %bx
 122         pushl   %edx    /* MSW of LBA */
 123         pushl   %eax    /* LSW of LBA */
 124         pushw   %es     /* Buffer segment */
 125         pushw   %bx     /* Buffer offset */
 126         pushw   $1      /* Sector count */
 127         pushw   $16     /* Size of packet */
 128         movw    %sp, %si
 129
 130         /* This chunk is skipped if we have ebios */
 131         /* Do not clobber %eax before this chunk! */
 132         /* This also relies on %bx and %edx as set up above. */
 133 read_sector_cbios:
 134         divl    (secpercyl)
 135         shlb    $6, %ah
 136         movb    %ah, %cl
 137         movb    %al, %ch
 138         xchgw   %dx, %ax
 139         divb    (sectors)
 140         movb    %al, %dh
 141         orb     %ah, %cl
 142         incw    %cx     /* Sectors are 1-based */
 143         movw    $0x0201, %ax
 144
 145 read_common:
 146         movb    (driveno), %dl
 147         int     $0x13
 148         addw    $16, %sp        /* Drop DAPA */
 149         popal
 150         ret
 151
 152 /*
 153  * read_partition_table:
 154  *      Read a partition table (pointed to by %eax), and copy
 155  *      the partition table into the ptab buffer.
 156  *
 157  *      Clobbers %si, %di, and %cx, other registers preserved.
 158  *      %cx = 0 on exit.
 159  *
 160  *      On error, CF is set and ptab is overwritten with junk.
 161  */
 162 ptab    = _start+446
 163
 164 read_partition_table:
 165         call    read_sector
 166         movw    $bootsec+446, %si
 167         movw    $ptab, %di
 168         movw    $(16*4/2), %cx
 169         rep ; movsw
 170         ret
 171
 172 /*
 173  * scan_partition_table:
 174  *      Scan a partition table currently loaded in the partition table
 175  *      area.  Preserve all registers.
 176  *
 177  *      On entry:
 178  *        %eax - base (location of this partition table)
 179  *        %edx - root (offset from MBR, or 0 for MBR)
 180  *
 181  *      These get pushed into stack slots:
 182  *        28(%bp) - %eax - base
 183  *        20(%bp) - %edx - root
 184  */
 185
 186 scan_partition_table:
 187         pushal
 188         movw    %sp, %bp
 189
 190         /* Search for active partitions */
 191         movw    $ptab, %bx
 192         movw    $4, %cx
 193         xorw    %ax, %ax
 194         push    %bx
 195         push    %cx
 196 5:
 197         testb   $0x80, (%bx)
 198         jz      6f
 199         incw    %ax
 200         movw    %bx, %si
 201 6:
 202         addw    $16, %bx
 203         loopw   5b
 204
 205         decw    %ax             /* Number of active partitions found */
 206         jz      boot
 207         jns     too_many_active
 208
 209         /* No active partitions found, look for extended partitions */
 210         popw    %cx             /* %cx <- 4    */
 211         popw    %bx             /* %bx <- ptab */
 212 7:
 213         movb    4(%bx), %al
 214         cmpb    $0x0f, %al      /* 0x0f = Win9x extended */
 215         je      8f
 216         andb    $~0x80, %al     /* 0x85 = Linux extended */
 217         cmpb    $0x05, %al      /* 0x05 = MS-DOS extended */
 218         jne     9f
 219
 220         /* It is an extended partition.  Read the extended partition and
 221            try to scan it.  If the scan returns, re-load the current
 222            partition table and resume scan. */
 223 8:
 224         movl    8(%bx), %eax            /* Partition table offset */
 225         movl    20(%bp), %edx           /* "Root" */
 226         addl    %edx, %eax              /* Compute location of new ptab */
 227         andl    %edx, %edx              /* Is this the MBR? */
 228         jnz     10f
 229         movl    %eax, %edx              /* Offset -> root if this was MBR */
 230 10:
 231         call    read_partition_table
 232         jc      11f
 233         call    scan_partition_table
 234 11:
 235         /* This returned, so we need to reload the current partition table */
 236         movl    28(%bp), %eax           /* "Base" */
 237         call    read_partition_table
 238
 239         /* fall through */
 240 9:
 241         /* Not an extended partition */
 242         addw    $16, %bx
 243         loopw   7b
 244
 245         /* Nothing found, return */
 246         popal
 247         ret
 248
 249 too_many_active:
 250         call    error
 251         .ascii  "Multiple active partitions.\r\n"
 252         .byte   0
 253
 254 /*
 255  * boot: invoke the actual bootstrap. (%si) points to the partition
 256  *       table entry, and 28(%bp) has the partition table base.
 257  */
 258 boot:
 259         movl    8(%si), %eax
 260         addl    28(%bp), %eax
 261         movl    %eax, 8(%si)    /* Adjust in-memory partition table entry */
 262         call    read_sector
 263         jc      disk_error
 264         cmpw    $0xaa55, (bootsec+510)
 265         jne     missing_os              /* Not a valid boot sector */
 266         movw    $driveno, %sp   /* driveno == bootsec-6 */
 267         popw    %dx             /* dl -> drive number */
 268         popw    %di             /* es:di -> $PnP vector */
 269         popw    %es
 270         cli
 271         jmpw    *%sp            /* %sp == bootsec */
 272
 273 disk_error:
 274         call    error
 275         .ascii  "Operating system load error.\r\n"
 276         .byte   0
 277
 278 /*
 279  * Print error messages.  This is invoked with "call", with the
 280  * error message at the return address.
 281  */
 282 error:
 283         popw    %si
 284 2:
 285         lodsb
 286         andb    %al, %al
 287         jz      3f
 288         movb    $0x0e, %ah
 289         movb    (BIOS_page), %bh
 290         movb    $0x07, %bl
 291         int     $0x10
 292         jmp     2b
 293 3:
 294         int     $0x18           /* Boot failure */
 295 die:
 296         hlt
 297         jmp     die