m4macros/gsettings.m4

   1 dnl GLIB_GSETTINGS
   2 dnl Defines GSETTINGS_SCHEMAS_INSTALL which controls whether
   3 dnl the schema should be compiled
   4 dnl
   5
   6 AC_DEFUN([GLIB_GSETTINGS],
   7 [
   8   AC_ARG_ENABLE(schemas-install,
   9         AC_HELP_STRING([--disable-schemas-install],
  10                        [Disable installation of GSettings schemas]),
  11      [case ${enableval} in
  12        yes|no) ;;
  13        *) AC_MSG_ERROR([bad value ${enableval} for --enable-schemas-install]) ;;
  14       esac])
  15   AM_CONDITIONAL([GSETTINGS_SCHEMAS_INSTALL], [test "$enable_schemas_install" != no])
  16
  17   PKG_PROG_PKG_CONFIG([0.16])
  18
  19   AC_SUBST(gsettingsschemadir, [${datadir}/glib-2.0/schemas])
  20   AC_SUBST(GLIB_COMPILE_SCHEMAS, `$PKG_CONFIG --variable glib_compile_schemas gio-2.0`)
  21   if test "x$GLIB_COMPILE_SCHEMAS" = "x"; then
  22     AC_MSG_ERROR([glib-compile-schemas not found.])
  23   fi
  24
  25   GSETTINGS_CHECK_RULE='
  26 .PHONY : check-gsettings-schema
  27
  28 check-gsettings-schema: gsettings_schema_validate_stamp
  29 MOSTLYCLEANFILES += gsettings_schema_validate_stamp
  30 gsettings_schema_validate_stamp: *.gschema.xml
  31         $(GLIB_COMPILE_SCHEMAS) --dry-run $(addprefix --schema-file=,$?)
  32         touch [$]@
  33
  34 all: check-gsettings-schema
  35 '
  36
  37   _GSETTINGS_SUBST(GSETTINGS_CHECK_RULE)
  38 ])
  39
  40 dnl _GSETTINGS_SUBST(VARIABLE)
  41 dnl Abstract macro to do either _AM_SUBST_NOTMAKE or AC_SUBST
  42 AC_DEFUN([_GSETTINGS_SUBST],
  43 [
  44 AC_SUBST([$1])
  45 m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([$1])])
  46 ]
  47 )