m4macros/gsettings.m4

   1 dnl GLIB_GSETTINGS
   2 dnl Defines GSETTINGS_SCHEMAS_INSTALL which controls whether
   3 dnl the schema should be compiled
   4 dnl
   5
   6 AC_DEFUN([GLIB_GSETTINGS],
   7 [
   8   m4_pattern_allow([AM_V_GEN])
   9   AC_ARG_ENABLE(schemas-compile,
  10                 AC_HELP_STRING([--disable-schemas-compile],
  11                                [Disable regeneration of gschemas.compiled on install]),
  12                 [case ${enableval} in
  13                   yes) GSETTINGS_DISABLE_SCHEMAS_COMPILE=""  ;;
  14                   no)  GSETTINGS_DISABLE_SCHEMAS_COMPILE="1" ;;
  15                   *) AC_MSG_ERROR([bad value ${enableval} for --enable-schemas-compile]) ;;
  16                  esac])
  17   AC_SUBST([GSETTINGS_DISABLE_SCHEMAS_COMPILE])
  18   PKG_PROG_PKG_CONFIG([0.16])
  19   AC_SUBST(gsettingsschemadir, [${datadir}/glib-2.0/schemas])
  20   if test x$cross_compiling != xyes; then
  21     GLIB_COMPILE_SCHEMAS=`$PKG_CONFIG --variable glib_compile_schemas gio-2.0`
  22   else
  23     AC_PATH_TOOL(GLIB_COMPILE_SCHEMAS, glib-compile-schemas)
  24   fi
  25   AC_SUBST(GLIB_COMPILE_SCHEMAS)
  26   if test "x$GLIB_COMPILE_SCHEMAS" = "x"; then
  27     AC_MSG_ERROR([glib-compile-schemas not found.])
  28   fi
  29
  30   GSETTINGS_RULES='
  31 .PHONY : uninstall-gsettings-schemas install-gsettings-schemas clean-gsettings-schemas
  32
  33 mostlyclean-am: clean-gsettings-schemas
  34
  35 %.gschema.valid: %.gschema.xml
  36         $(AM_V_GEN) if test -f "$^"; then d=; else d="$(srcdir)/"; fi; $(GLIB_COMPILE_SCHEMAS) --dry-run --schema-file=$${d}$^ && touch [$]@
  37
  38 all-am: $(gsettings_SCHEMAS:.xml=.valid)
  39 uninstall-am: uninstall-gsettings-schemas
  40 install-data-am: install-gsettings-schemas
  41
  42 .SECONDARY: $(gsettings_SCHEMAS)
  43
  44 gsettings__base_list = \
  45   sed "$$!N;$$!N;$$!N;$$!N;$$!N;$$!N;$$!N;s/\n/ /g" | \
  46   sed "$$!N;$$!N;$$!N;$$!N;s/\n/ /g"
  47
  48 install-gsettings-schemas: $(gsettings_SCHEMAS:.xml=.valid)
  49         @$(NORMAL_INSTALL)
  50         test -z "$(gsettingsschemadir)" || $(MKDIR_P) "$(DESTDIR)$(gsettingsschemadir)"
  51         @list='\''$(gsettings_SCHEMAS)'\''; test -n "$(gsettingsschemadir)" || list=; \
  52         for p in $$list; do \
  53           if test -f "$$p"; then d=; else d="$(srcdir)/"; fi; \
  54           echo "$$d$$p"; \
  55         done | $(gsettings__base_list) | \
  56         while read files; do \
  57           echo " $(INSTALL_DATA) $$files '\''$(DESTDIR)$(gsettingsschemadir)'\''"; \
  58           $(INSTALL_DATA) $$files "$(DESTDIR)$(gsettingsschemadir)" || exit $$?; \
  59         done
  60         test -n "$(GSETTINGS_DISABLE_SCHEMAS_COMPILE)$(DESTDIR)" || $(GLIB_COMPILE_SCHEMAS) $(gsettingsschemadir)
  61
  62 uninstall-gsettings-schemas:
  63         @$(NORMAL_UNINSTALL)
  64         @list='\''$(gsettings_SCHEMAS)'\''; test -n "$(gsettingsschemadir)" || list=; \
  65         files=`for p in $$list; do echo $$p; done | sed -e '\''s|^.*/||'\''`; \
  66         test -n "$$files" || exit 0; \
  67         echo " ( cd '\''$(DESTDIR)$(gsettingsschemadir)'\'' && rm -f" $$files ")"; \
  68         cd "$(DESTDIR)$(gsettingsschemadir)" && rm -f $$files
  69         test -n "$(GSETTINGS_DISABLE_SCHEMAS_COMPILE)$(DESTDIR)" || $(GLIB_COMPILE_SCHEMAS) --uninstall $(gsettingsschemadir)
  70
  71 clean-gsettings-schemas:
  72         rm -f $(gsettings_SCHEMAS:.xml=.valid)
  73
  74 '
  75   _GSETTINGS_SUBST(GSETTINGS_RULES)
  76 ])
  77
  78 dnl _GSETTINGS_SUBST(VARIABLE)
  79 dnl Abstract macro to do either _AM_SUBST_NOTMAKE or AC_SUBST
  80 AC_DEFUN([_GSETTINGS_SUBST],
  81 [
  82 AC_SUBST([$1])
  83 m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([$1])])
  84 ]
  85 )