m4/wcwidth.m4

   1 # wcwidth.m4 serial 27
   2 dnl Copyright (C) 2006-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_WCWIDTH],
   8 [
   9   AC_REQUIRE([gl_WCHAR_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11
  12   dnl Persuade glibc <wchar.h> to declare wcwidth().
  13   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  14
  15   AC_REQUIRE([gt_TYPE_WCHAR_T])
  16   AC_REQUIRE([gt_TYPE_WINT_T])
  17
  18   AC_CHECK_HEADERS_ONCE([wchar.h])
  19   AC_CHECK_FUNCS_ONCE([wcwidth])
  20
  21   AC_CHECK_DECLS([wcwidth], [], [], [[
  22 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  23 #include <string.h>
  24 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  25    <wchar.h>.
  26    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  27    before <wchar.h>.  */
  28 #include <stddef.h>
  29 #include <stdio.h>
  30 #include <time.h>
  31 #include <wchar.h>
  32 ]])
  33   if test $ac_cv_have_decl_wcwidth != yes; then
  34     HAVE_DECL_WCWIDTH=0
  35   fi
  36
  37   if test $ac_cv_func_wcwidth != yes; then
  38     AC_CACHE_CHECK([whether wcwidth is a macro],
  39       [gl_cv_func_wcwidth_macro],
  40       [AC_EGREP_CPP([wchar_header_defines_wcwidth], [
  41 #include <wchar.h>
  42 #ifdef wcwidth
  43  wchar_header_defines_wcwidth
  44 #endif],
  45          [gl_cv_func_wcwidth_macro=yes],
  46          [gl_cv_func_wcwidth_macro=no])
  47       ])
  48   fi
  49
  50   if test $ac_cv_func_wcwidth = yes || test $gl_cv_func_wcwidth_macro = yes; then
  51     HAVE_WCWIDTH=1
  52     dnl On Mac OS X 10.3, wcwidth(0x0301) (COMBINING ACUTE ACCENT) returns 1.
  53     dnl On OpenBSD 5.0, wcwidth(0x05B0) (HEBREW POINT SHEVA) returns 1.
  54     dnl On OSF/1 5.1, wcwidth(0x200B) (ZERO WIDTH SPACE) returns 1.
  55     dnl On OpenBSD 5.8, wcwidth(0xFF1A) (FULLWIDTH COLON) returns 0.
  56     dnl This leads to bugs in 'ls' (coreutils).
  57     AC_CACHE_CHECK([whether wcwidth works reasonably in UTF-8 locales],
  58       [gl_cv_func_wcwidth_works],
  59       [
  60         AC_RUN_IFELSE(
  61           [AC_LANG_SOURCE([[
  62 #include <locale.h>
  63 /* AIX 3.2.5 declares wcwidth in <string.h>. */
  64 #include <string.h>
  65 /* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
  66    <wchar.h>.
  67    BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
  68    before <wchar.h>.  */
  69 #include <stddef.h>
  70 #include <stdio.h>
  71 #include <time.h>
  72 #include <wchar.h>
  73 #if !HAVE_DECL_WCWIDTH
  74 extern
  75 # ifdef __cplusplus
  76 "C"
  77 # endif
  78 int wcwidth (int);
  79 #endif
  80 int main ()
  81 {
  82   int result = 0;
  83   if (setlocale (LC_ALL, "fr_FR.UTF-8") != NULL)
  84     {
  85       if (wcwidth (0x0301) > 0)
  86         result |= 1;
  87       if (wcwidth (0x05B0) > 0)
  88         result |= 2;
  89       if (wcwidth (0x200B) > 0)
  90         result |= 4;
  91       if (wcwidth (0xFF1A) == 0)
  92         result |= 8;
  93     }
  94   return result;
  95 }]])],
  96           [gl_cv_func_wcwidth_works=yes],
  97           [gl_cv_func_wcwidth_works=no],
  98           [
  99 changequote(,)dnl
 100            case "$host_os" in
 101                                         # Guess yes on glibc and AIX 7 systems.
 102              *-gnu* | gnu* | aix[7-9]*) gl_cv_func_wcwidth_works="guessing yes";;
 103              *)                         gl_cv_func_wcwidth_works="guessing no";;
 104            esac
 105 changequote([,])dnl
 106           ])
 107       ])
 108     case "$gl_cv_func_wcwidth_works" in
 109       *yes) ;;
 110       *no) REPLACE_WCWIDTH=1 ;;
 111     esac
 112   else
 113     HAVE_WCWIDTH=0
 114   fi
 115   dnl We don't substitute HAVE_WCWIDTH. We assume that if the system does not
 116   dnl have the wcwidth function, then it does not declare it.
 117 ])
 118
 119 # Prerequisites of lib/wcwidth.c.
 120 AC_DEFUN([gl_PREREQ_WCWIDTH], [
 121   AC_REQUIRE([AC_C_INLINE])
 122   :
 123 ])