m4/vala.m4

   1 # Autoconf support for the Vala compiler
   2
   3 # Copyright (C) 2008-2012 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # Check whether the Vala compiler exists in $PATH. If it is found, the
  10 # variable VALAC is set. Optionally a minimum release number of the
  11 # compiler can be requested.
  12 #
  13 # AM_PROG_VALAC([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  14 # --------------------------------------------------------------------------
  15 AC_DEFUN([AM_PROG_VALAC],
  16 [AC_PATH_PROG([VALAC], [valac], [])
  17  AS_IF([test -z "$VALAC"],
  18    [m4_default([$3],
  19      [AC_MSG_WARN([no vala compiler found])
  20       AC_MSG_WARN([you will not be able to compile vala source files])])],
  21    [AS_IF([test -n "$1"],
  22       [AC_MSG_CHECKING([whether $VALAC is at least version $1])
  23        am__vala_version=`$VALAC --version | sed 's/Vala  *//'`
  24        AS_VERSION_COMPARE([$1], ["$am__vala_version"],
  25          [AC_MSG_RESULT([yes])],
  26          [AC_MSG_RESULT([yes])],
  27          [AC_MSG_RESULT([no])
  28           VALAC=:])])
  29     if test x"$VALAC" = x":"; then
  30       m4_default([$3], [AC_MSG_ERROR([no proper vala compiler found], [77])])
  31     else
  32       m4_default([$2], [:])
  33     fi])])