m4/tar.m4

   1 # Check how to create a tarball.                            -*- Autoconf -*-
   2
   3 # Copyright (C) 2004  Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  18 # 02111-1307, USA.
  19
  20 # serial 1
  21
  22
  23 # _AM_PROG_TAR(FORMAT)
  24 # --------------------
  25 # Check how to create a tarball in format FORMAT.
  26 # FORMAT should be one of `v7', `ustar', or `pax'.
  27 #
  28 # Substitute a variable $(am__tar) that is a command
  29 # writing to stdout a FORMAT-tarball containing the directory
  30 # $tardir.
  31 #     tardir=directory && $(am__tar) > result.tar
  32 #
  33 # Substitute a variable $(am__untar) that extract such
  34 # a tarball read from stdin.
  35 #     $(am__untar) < result.tar
  36 AC_DEFUN([_AM_PROG_TAR],
  37 [# Always define AMTAR for backward compatibility.
  38 AM_MISSING_PROG([AMTAR], [tar])
  39 m4_if([$1], [v7],
  40      [am__tar='${AMTAR} chof - "$$tardir"'; am__untar='${AMTAR} xf -'],
  41      [m4_case([$1], [ustar],, [pax],,
  42               [m4_fatal([Unknown tar format])])
  43 AC_MSG_CHECKING([how to create a $1 tar archive])
  44 # Loop over all known methods to create a tar archive until one works.
  45 for _am_tool in ${am_cv_prog_tar_$1-gnutar m4_if([$1], [ustar], [plaintar]) pax cpio none}
  46 do
  47   case $_am_tool in
  48   gnutar)
  49     for _am_tar in tar gnutar gtar;
  50     do
  51       AM_RUN_LOG([$_am_tar --version]) && break
  52     done
  53     am__tar="$_am_tar --format=m4_if([$1], [pax], [posix], [$1]) -chf - "'"$$tardir"'
  54     am__tar_="$_am_tar --format=m4_if([$1], [pax], [posix], [$1]) -chf - "'"$tardir"'
  55     am__untar="$_am_tar -xf -"
  56     ;;
  57   plaintar)
  58     # Must skip GNU tar: if it does not support --format= it doesn't create
  59     # ustar tarball either.
  60     (tar --version) >/dev/null 2>&1 && continue
  61     am__tar='tar chf - "$$tardir"'
  62     am__tar_='tar chf - "$tardir"'
  63     am__untar='tar xf -'
  64     ;;
  65   pax)
  66     am__tar='pax -L -x $1 -w "$$tardir"'
  67     am__tar_='pax -L -x $1 -w "$tardir"'
  68     am__untar='pax -r'
  69     ;;
  70   cpio)
  71     am__tar='find "$$tardir" -print | cpio -o -H $1 -L'
  72     am__tar_='find "$tardir" -print | cpio -o -H $1 -L'
  73     am__untar='cpio -i -H $1 -d'
  74     ;;
  75   none)
  76     am__tar=false
  77     am__tar_=false
  78     am__untar=false
  79     ;;
  80   esac
  81
  82   # If the value was cached, stop now.  We just wanted to have am__tar
  83   # and am__untar set.
  84   test -n "${am_cv_prog_tar_$1}" && break
  85
  86   # tar/untar a dummy directory, and stop if the command works
  87   rm -rf conftest.dir
  88   mkdir conftest.dir
  89   echo GrepMe > conftest.dir/file
  90   AM_RUN_LOG([tardir=conftest.dir && eval $am__tar_ >conftest.tar])
  91   rm -rf conftest.dir
  92   if test -s conftest.tar; then
  93     AM_RUN_LOG([$am__untar <conftest.tar])
  94     grep GrepMe conftest.dir/file >/dev/null 2>&1 && break
  95   fi
  96 done
  97 rm -rf conftest.dir
  98
  99 AC_CACHE_VAL([am_cv_prog_tar_$1], [am_cv_prog_tar_$1=$_am_tool])
 100 AC_MSG_RESULT([$am_cv_prog_tar_$1])])
 101 AC_SUBST([am__tar])
 102 AC_SUBST([am__untar])
 103 ]) # _AM_PROG_TAR