m4/stl_hash.m4

   1 # We check two things: where the include file is for hash_map, and
   2 # what namespace hash_map lives in within that include file.  We
   3 # include AC_TRY_COMPILE for all the combinations we've seen in the
   4 # wild.  We define one of HAVE_HASH_MAP or HAVE_EXT_HASH_MAP depending
   5 # on location, and HASH_NAMESPACE to be the namespace hash_map is
   6 # defined in.
   7 #
   8 # Ideally we'd use AC_CACHE_CHECK, but that only lets us store one value
   9 # at a time, and we need to store two (filename and namespace).
  10 # prints messages itself, so we have to do the message-printing ourselves
  11 # via AC_MSG_CHECKING + AC_MSG_RESULT.  (TODO(csilvers): can we cache?)
  12
  13 AC_DEFUN([AC_CXX_STL_HASH],
  14   [AC_REQUIRE([AC_CXX_NAMESPACES])
  15    AC_MSG_CHECKING(the location of hash_map)
  16   AC_LANG_SAVE
  17    AC_LANG_CPLUSPLUS
  18    ac_cv_cxx_hash_map=""
  19    for location in ext/hash_map hash_map; do
  20      for namespace in __gnu_cxx "" std stdext; do
  21        if test -z "$ac_cv_cxx_hash_map"; then
  22          AC_TRY_COMPILE([#include <$location>],
  23                         [${namespace}::hash_map<int, int> t],
  24                         [ac_cv_cxx_hash_map="<$location>";
  25                          ac_cv_cxx_hash_namespace="$namespace";])
  26        fi
  27      done
  28    done
  29    ac_cv_cxx_hash_set=`echo "$ac_cv_cxx_hash_map" | sed s/map/set/`;
  30    if test -n "$ac_cv_cxx_hash_map"; then
  31       AC_DEFINE(HAVE_HASH_MAP, 1, [define if the compiler has hash_map])
  32       AC_DEFINE(HAVE_HASH_SET, 1, [define if the compiler has hash_set])
  33       AC_DEFINE_UNQUOTED(HASH_MAP_H,$ac_cv_cxx_hash_map,
  34                          [the location of <hash_map>])
  35       AC_DEFINE_UNQUOTED(HASH_SET_H,$ac_cv_cxx_hash_set,
  36                          [the location of <hash_set>])
  37       AC_DEFINE_UNQUOTED(HASH_NAMESPACE,$ac_cv_cxx_hash_namespace,
  38                          [the namespace of hash_map/hash_set])
  39       AC_MSG_RESULT([$ac_cv_cxx_hash_map])
  40    else
  41       AC_MSG_RESULT()
  42       AC_MSG_WARN([could not find an STL hash_map])
  43    fi
  44 ])