m4/python.m4

   1 ## ------------------------                                 -*- Autoconf -*-
   2 ## Python file handling
   3 ## From Andrew Dalke
   4 ## Updated by James Henstridge
   5 ## ------------------------
   6 # Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2008, 2009,
   7 # 2011 Free Software Foundation, Inc.
   8 #
   9 # This file is free software; the Free Software Foundation
  10 # gives unlimited permission to copy and/or distribute it,
  11 # with or without modifications, as long as this notice is preserved.
  12
  13 # serial 1
  14
  15 # AM_PATH_PYTHON([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  16 # ---------------------------------------------------------------------------
  17 # Adds support for distributing Python modules and packages.  To
  18 # install modules, copy them to $(pythondir), using the python_PYTHON
  19 # automake variable.  To install a package with the same name as the
  20 # automake package, install to $(pkgpythondir), or use the
  21 # pkgpython_PYTHON automake variable.
  22 #
  23 # The variables $(pyexecdir) and $(pkgpyexecdir) are provided as
  24 # locations to install python extension modules (shared libraries).
  25 # Another macro is required to find the appropriate flags to compile
  26 # extension modules.
  27 #
  28 # If your package is configured with a different prefix to python,
  29 # users will have to add the install directory to the PYTHONPATH
  30 # environment variable, or create a .pth file (see the python
  31 # documentation for details).
  32 #
  33 # If the MINIMUM-VERSION argument is passed, AM_PATH_PYTHON will
  34 # cause an error if the version of python installed on the system
  35 # doesn't meet the requirement.  MINIMUM-VERSION should consist of
  36 # numbers and dots only.
  37 AC_DEFUN([AM_PATH_PYTHON],
  38  [
  39   dnl Find a Python interpreter.  Python versions prior to 2.0 are not
  40   dnl supported. (2.0 was released on October 16, 2000).
  41   m4_define_default([_AM_PYTHON_INTERPRETER_LIST],
  42 [python python2 python3 python3.2 python3.1 python3.0 python2.7 dnl
  43  python2.6 python2.5 python2.4 python2.3 python2.2 python2.1 python2.0])
  44
  45   AC_ARG_VAR([PYTHON], [the Python interpreter])
  46
  47   m4_if([$1],[],[
  48     dnl No version check is needed.
  49     # Find any Python interpreter.
  50     if test -z "$PYTHON"; then
  51       AC_PATH_PROGS([PYTHON], _AM_PYTHON_INTERPRETER_LIST, :)
  52     fi
  53     am_display_PYTHON=python
  54   ], [
  55     dnl A version check is needed.
  56     if test -n "$PYTHON"; then
  57       # If the user set $PYTHON, use it and don't search something else.
  58       AC_MSG_CHECKING([whether $PYTHON version >= $1])
  59       AM_PYTHON_CHECK_VERSION([$PYTHON], [$1],
  60                               [AC_MSG_RESULT(yes)],
  61                               [AC_MSG_ERROR(too old)])
  62       am_display_PYTHON=$PYTHON
  63     else
  64       # Otherwise, try each interpreter until we find one that satisfies
  65       # VERSION.
  66       AC_CACHE_CHECK([for a Python interpreter with version >= $1],
  67         [am_cv_pathless_PYTHON],[
  68         for am_cv_pathless_PYTHON in _AM_PYTHON_INTERPRETER_LIST none; do
  69           test "$am_cv_pathless_PYTHON" = none && break
  70           AM_PYTHON_CHECK_VERSION([$am_cv_pathless_PYTHON], [$1], [break])
  71         done])
  72       # Set $PYTHON to the absolute path of $am_cv_pathless_PYTHON.
  73       if test "$am_cv_pathless_PYTHON" = none; then
  74         PYTHON=:
  75       else
  76         AC_PATH_PROG([PYTHON], [$am_cv_pathless_PYTHON])
  77       fi
  78       am_display_PYTHON=$am_cv_pathless_PYTHON
  79     fi
  80   ])
  81
  82   if test "$PYTHON" = :; then
  83   dnl Run any user-specified action, or abort.
  84     m4_default([$3], [AC_MSG_ERROR([no suitable Python interpreter found])])
  85   else
  86
  87   dnl Query Python for its version number.  Getting [:3] seems to be
  88   dnl the best way to do this; it's what "site.py" does in the standard
  89   dnl library.
  90
  91   AC_CACHE_CHECK([for $am_display_PYTHON version], [am_cv_python_version],
  92     [am_cv_python_version=`$PYTHON -c "import sys; sys.stdout.write(sys.version[[:3]])"`])
  93   AC_SUBST([PYTHON_VERSION], [$am_cv_python_version])
  94
  95   dnl Use the values of $prefix and $exec_prefix for the corresponding
  96   dnl values of PYTHON_PREFIX and PYTHON_EXEC_PREFIX.  These are made
  97   dnl distinct variables so they can be overridden if need be.  However,
  98   dnl general consensus is that you shouldn't need this ability.
  99
 100   AC_SUBST([PYTHON_PREFIX], ['${prefix}'])
 101   AC_SUBST([PYTHON_EXEC_PREFIX], ['${exec_prefix}'])
 102
 103   dnl At times (like when building shared libraries) you may want
 104   dnl to know which OS platform Python thinks this is.
 105
 106   AC_CACHE_CHECK([for $am_display_PYTHON platform], [am_cv_python_platform],
 107     [am_cv_python_platform=`$PYTHON -c "import sys; sys.stdout.write(sys.platform)"`])
 108   AC_SUBST([PYTHON_PLATFORM], [$am_cv_python_platform])
 109
 110
 111   dnl Set up 4 directories:
 112
 113   dnl pythondir -- where to install python scripts.  This is the
 114   dnl   site-packages directory, not the python standard library
 115   dnl   directory like in previous automake betas.  This behavior
 116   dnl   is more consistent with lispdir.m4 for example.
 117   dnl Query distutils for this directory.  distutils does not exist in
 118   dnl Python 1.5, so we fall back to the hardcoded directory if it
 119   dnl doesn't work.
 120   AC_CACHE_CHECK([for $am_display_PYTHON script directory],
 121     [am_cv_python_pythondir],
 122     [if test "x$prefix" = xNONE
 123      then
 124        am_py_prefix=$ac_default_prefix
 125      else
 126        am_py_prefix=$prefix
 127      fi
 128      am_cv_python_pythondir=`$PYTHON -c "import sys; from distutils import sysconfig; sys.stdout.write(sysconfig.get_python_lib(0,0,prefix='$am_py_prefix'))" 2>/dev/null ||
 129      echo "$PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages"`
 130      case $am_cv_python_pythondir in
 131      $am_py_prefix*)
 132        am__strip_prefix=`echo "$am_py_prefix" | sed 's|.|.|g'`
 133        am_cv_python_pythondir=`echo "$am_cv_python_pythondir" | sed "s,^$am__strip_prefix,$PYTHON_PREFIX,"`
 134        ;;
 135      *)
 136        case $am_py_prefix in
 137          /usr|/System*) ;;
 138          *)
 139           am_cv_python_pythondir=$PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages
 140           ;;
 141        esac
 142        ;;
 143      esac
 144     ])
 145   AC_SUBST([pythondir], [$am_cv_python_pythondir])
 146
 147   dnl pkgpythondir -- $PACKAGE directory under pythondir.  Was
 148   dnl   PYTHON_SITE_PACKAGE in previous betas, but this naming is
 149   dnl   more consistent with the rest of automake.
 150
 151   AC_SUBST([pkgpythondir], [\${pythondir}/$PACKAGE])
 152
 153   dnl pyexecdir -- directory for installing python extension modules
 154   dnl   (shared libraries)
 155   dnl Query distutils for this directory.  distutils does not exist in
 156   dnl Python 1.5, so we fall back to the hardcoded directory if it
 157   dnl doesn't work.
 158   AC_CACHE_CHECK([for $am_display_PYTHON extension module directory],
 159     [am_cv_python_pyexecdir],
 160     [if test "x$exec_prefix" = xNONE
 161      then
 162        am_py_exec_prefix=$am_py_prefix
 163      else
 164        am_py_exec_prefix=$exec_prefix
 165      fi
 166      am_cv_python_pyexecdir=`$PYTHON -c "import sys; from distutils import sysconfig; sys.stdout.write(sysconfig.get_python_lib(1,0,prefix='$am_py_exec_prefix'))" 2>/dev/null ||
 167      echo "$PYTHON_EXEC_PREFIX/lib/python$PYTHON_VERSION/site-packages"`
 168      case $am_cv_python_pyexecdir in
 169      $am_py_exec_prefix*)
 170        am__strip_prefix=`echo "$am_py_exec_prefix" | sed 's|.|.|g'`
 171        am_cv_python_pyexecdir=`echo "$am_cv_python_pyexecdir" | sed "s,^$am__strip_prefix,$PYTHON_EXEC_PREFIX,"`
 172        ;;
 173      *)
 174        case $am_py_exec_prefix in
 175          /usr|/System*) ;;
 176          *)
 177            am_cv_python_pyexecdir=$PYTHON_EXEC_PREFIX/lib/python$PYTHON_VERSION/site-packages
 178            ;;
 179        esac
 180        ;;
 181      esac
 182     ])
 183   AC_SUBST([pyexecdir], [$am_cv_python_pyexecdir])
 184
 185   dnl pkgpyexecdir -- $(pyexecdir)/$(PACKAGE)
 186
 187   AC_SUBST([pkgpyexecdir], [\${pyexecdir}/$PACKAGE])
 188
 189   dnl Run any user-specified action.
 190   $2
 191   fi
 192
 193 ])
 194
 195
 196 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 197 # ---------------------------------------------------------------------------
 198 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 199 # Run ACTION-IF-FALSE otherwise.
 200 # This test uses sys.hexversion instead of the string equivalent (first
 201 # word of sys.version), in order to cope with versions such as 2.2c1.
 202 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 203 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 204  [prog="import sys
 205 # split strings by '.' and convert to numeric.  Append some zeros
 206 # because we need at least 4 digits for the hex conversion.
 207 # map returns an iterator in Python 3.0 and a list in 2.x
 208 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 209 minverhex = 0
 210 # xrange is not present in Python 3.0 and range returns an iterator
 211 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 212 sys.exit(sys.hexversion < minverhex)"
 213   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])