m4/python.m4

   1 ## ------------------------                                 -*- Autoconf -*-
   2 ## Python file handling
   3 ## From Andrew Dalke
   4 ## Updated by James Henstridge
   5 ## ------------------------
   6 # Copyright (C) 1999-2012 Free Software Foundation, Inc.
   7 #
   8 # This file is free software; the Free Software Foundation
   9 # gives unlimited permission to copy and/or distribute it,
  10 # with or without modifications, as long as this notice is preserved.
  11
  12 # serial 9
  13
  14 # AM_PATH_PYTHON([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  15 # ---------------------------------------------------------------------------
  16 # Adds support for distributing Python modules and packages.  To
  17 # install modules, copy them to $(pythondir), using the python_PYTHON
  18 # automake variable.  To install a package with the same name as the
  19 # automake package, install to $(pkgpythondir), or use the
  20 # pkgpython_PYTHON automake variable.
  21 #
  22 # The variables $(pyexecdir) and $(pkgpyexecdir) are provided as
  23 # locations to install python extension modules (shared libraries).
  24 # Another macro is required to find the appropriate flags to compile
  25 # extension modules.
  26 #
  27 # If your package is configured with a different prefix to python,
  28 # users will have to add the install directory to the PYTHONPATH
  29 # environment variable, or create a .pth file (see the python
  30 # documentation for details).
  31 #
  32 # If the MINIMUM-VERSION argument is passed, AM_PATH_PYTHON will
  33 # cause an error if the version of python installed on the system
  34 # doesn't meet the requirement.  MINIMUM-VERSION should consist of
  35 # numbers and dots only.
  36 AC_DEFUN([AM_PATH_PYTHON],
  37  [
  38   dnl Find a Python interpreter.  Python versions prior to 2.0 are not
  39   dnl supported. (2.0 was released on October 16, 2000).
  40   m4_define_default([_AM_PYTHON_INTERPRETER_LIST],
  41 [python python2 python3 python3.2 python3.1 python3.0 python2.7 dnl
  42  python2.6 python2.5 python2.4 python2.3 python2.2 python2.1 python2.0])
  43
  44   AC_ARG_VAR([PYTHON], [the Python interpreter])
  45
  46   m4_if([$1],[],[
  47     dnl No version check is needed.
  48     # Find any Python interpreter.
  49     if test -z "$PYTHON"; then
  50       AC_PATH_PROGS([PYTHON], _AM_PYTHON_INTERPRETER_LIST, :)
  51     fi
  52     am_display_PYTHON=python
  53   ], [
  54     dnl A version check is needed.
  55     if test -n "$PYTHON"; then
  56       # If the user set $PYTHON, use it and don't search something else.
  57       AC_MSG_CHECKING([whether $PYTHON version is >= $1])
  58       AM_PYTHON_CHECK_VERSION([$PYTHON], [$1],
  59                               [AC_MSG_RESULT([yes])],
  60                               [AC_MSG_RESULT([no])
  61                                AC_MSG_ERROR([Python interpreter is too old])])
  62       am_display_PYTHON=$PYTHON
  63     else
  64       # Otherwise, try each interpreter until we find one that satisfies
  65       # VERSION.
  66       AC_CACHE_CHECK([for a Python interpreter with version >= $1],
  67         [am_cv_pathless_PYTHON],[
  68         for am_cv_pathless_PYTHON in _AM_PYTHON_INTERPRETER_LIST none; do
  69           test "$am_cv_pathless_PYTHON" = none && break
  70           AM_PYTHON_CHECK_VERSION([$am_cv_pathless_PYTHON], [$1], [break])
  71         done])
  72       # Set $PYTHON to the absolute path of $am_cv_pathless_PYTHON.
  73       if test "$am_cv_pathless_PYTHON" = none; then
  74         PYTHON=:
  75       else
  76         AC_PATH_PROG([PYTHON], [$am_cv_pathless_PYTHON])
  77       fi
  78       am_display_PYTHON=$am_cv_pathless_PYTHON
  79     fi
  80   ])
  81
  82   if test "$PYTHON" = :; then
  83   dnl Run any user-specified action, or abort.
  84     m4_default([$3], [AC_MSG_ERROR([no suitable Python interpreter found])])
  85   else
  86
  87   dnl Query Python for its version number.  Getting [:3] seems to be
  88   dnl the best way to do this; it's what "site.py" does in the standard
  89   dnl library.
  90
  91   AC_CACHE_CHECK([for $am_display_PYTHON version], [am_cv_python_version],
  92     [am_cv_python_version=`$PYTHON -c "import sys; sys.stdout.write(sys.version[[:3]])"`])
  93   AC_SUBST([PYTHON_VERSION], [$am_cv_python_version])
  94
  95   dnl Use the values of $prefix and $exec_prefix for the corresponding
  96   dnl values of PYTHON_PREFIX and PYTHON_EXEC_PREFIX.  These are made
  97   dnl distinct variables so they can be overridden if need be.  However,
  98   dnl general consensus is that you shouldn't need this ability.
  99
 100   AC_SUBST([PYTHON_PREFIX], ['${prefix}'])
 101   AC_SUBST([PYTHON_EXEC_PREFIX], ['${exec_prefix}'])
 102
 103   dnl At times (like when building shared libraries) you may want
 104   dnl to know which OS platform Python thinks this is.
 105
 106   AC_CACHE_CHECK([for $am_display_PYTHON platform], [am_cv_python_platform],
 107     [am_cv_python_platform=`$PYTHON -c "import sys; sys.stdout.write(sys.platform)"`])
 108   AC_SUBST([PYTHON_PLATFORM], [$am_cv_python_platform])
 109
 110
 111   dnl Set up 4 directories:
 112
 113   dnl pythondir -- where to install python scripts.  This is the
 114   dnl   site-packages directory, not the python standard library
 115   dnl   directory like in previous automake betas.  This behavior
 116   dnl   is more consistent with lispdir.m4 for example.
 117   dnl Query distutils for this directory.
 118   AC_CACHE_CHECK([for $am_display_PYTHON script directory],
 119     [am_cv_python_pythondir],
 120     [if test "x$prefix" = xNONE
 121      then
 122        am_py_prefix=$ac_default_prefix
 123      else
 124        am_py_prefix=$prefix
 125      fi
 126      am_cv_python_pythondir=`$PYTHON -c "import sys; from distutils import sysconfig; sys.stdout.write(sysconfig.get_python_lib(0,0,prefix='$am_py_prefix'))" 2>/dev/null`
 127      case $am_cv_python_pythondir in
 128      $am_py_prefix*)
 129        am__strip_prefix=`echo "$am_py_prefix" | sed 's|.|.|g'`
 130        am_cv_python_pythondir=`echo "$am_cv_python_pythondir" | sed "s,^$am__strip_prefix,$PYTHON_PREFIX,"`
 131        ;;
 132      *)
 133        case $am_py_prefix in
 134          /usr|/System*) ;;
 135          *)
 136           am_cv_python_pythondir=$PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages
 137           ;;
 138        esac
 139        ;;
 140      esac
 141     ])
 142   AC_SUBST([pythondir], [$am_cv_python_pythondir])
 143
 144   dnl pkgpythondir -- $PACKAGE directory under pythondir.  Was
 145   dnl   PYTHON_SITE_PACKAGE in previous betas, but this naming is
 146   dnl   more consistent with the rest of automake.
 147
 148   AC_SUBST([pkgpythondir], [\${pythondir}/$PACKAGE])
 149
 150   dnl pyexecdir -- directory for installing python extension modules
 151   dnl   (shared libraries)
 152   dnl Query distutils for this directory.
 153   AC_CACHE_CHECK([for $am_display_PYTHON extension module directory],
 154     [am_cv_python_pyexecdir],
 155     [if test "x$exec_prefix" = xNONE
 156      then
 157        am_py_exec_prefix=$am_py_prefix
 158      else
 159        am_py_exec_prefix=$exec_prefix
 160      fi
 161      am_cv_python_pyexecdir=`$PYTHON -c "import sys; from distutils import sysconfig; sys.stdout.write(sysconfig.get_python_lib(1,0,prefix='$am_py_exec_prefix'))" 2>/dev/null`
 162      case $am_cv_python_pyexecdir in
 163      $am_py_exec_prefix*)
 164        am__strip_prefix=`echo "$am_py_exec_prefix" | sed 's|.|.|g'`
 165        am_cv_python_pyexecdir=`echo "$am_cv_python_pyexecdir" | sed "s,^$am__strip_prefix,$PYTHON_EXEC_PREFIX,"`
 166        ;;
 167      *)
 168        case $am_py_exec_prefix in
 169          /usr|/System*) ;;
 170          *)
 171            am_cv_python_pyexecdir=$PYTHON_EXEC_PREFIX/lib/python$PYTHON_VERSION/site-packages
 172            ;;
 173        esac
 174        ;;
 175      esac
 176     ])
 177   AC_SUBST([pyexecdir], [$am_cv_python_pyexecdir])
 178
 179   dnl pkgpyexecdir -- $(pyexecdir)/$(PACKAGE)
 180
 181   AC_SUBST([pkgpyexecdir], [\${pyexecdir}/$PACKAGE])
 182
 183   dnl Run any user-specified action.
 184   $2
 185   fi
 186
 187 ])
 188
 189
 190 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 191 # ---------------------------------------------------------------------------
 192 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 193 # Run ACTION-IF-FALSE otherwise.
 194 # This test uses sys.hexversion instead of the string equivalent (first
 195 # word of sys.version), in order to cope with versions such as 2.2c1.
 196 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 197 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 198  [prog="import sys
 199 # split strings by '.' and convert to numeric.  Append some zeros
 200 # because we need at least 4 digits for the hex conversion.
 201 # map returns an iterator in Python 3.0 and a list in 2.x
 202 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 203 minverhex = 0
 204 # xrange is not present in Python 3.0 and range returns an iterator
 205 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 206 sys.exit(sys.hexversion < minverhex)"
 207   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])