m4/python.m4

   1 ## ------------------------                                 -*- Autoconf -*-
   2 ## Python file handling
   3 ## From Andrew Dalke
   4 ## Updated by James Henstridge
   5 ## ------------------------
   6 # Copyright (C) 1999-2012 Free Software Foundation, Inc.
   7 #
   8 # This file is free software; the Free Software Foundation
   9 # gives unlimited permission to copy and/or distribute it,
  10 # with or without modifications, as long as this notice is preserved.
  11
  12
  13 # AM_PATH_PYTHON([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  14 # ---------------------------------------------------------------------------
  15 # Adds support for distributing Python modules and packages.  To
  16 # install modules, copy them to $(pythondir), using the python_PYTHON
  17 # automake variable.  To install a package with the same name as the
  18 # automake package, install to $(pkgpythondir), or use the
  19 # pkgpython_PYTHON automake variable.
  20 #
  21 # The variables $(pyexecdir) and $(pkgpyexecdir) are provided as
  22 # locations to install python extension modules (shared libraries).
  23 # Another macro is required to find the appropriate flags to compile
  24 # extension modules.
  25 #
  26 # If your package is configured with a different prefix to python,
  27 # users will have to add the install directory to the PYTHONPATH
  28 # environment variable, or create a .pth file (see the python
  29 # documentation for details).
  30 #
  31 # If the MINIMUM-VERSION argument is passed, AM_PATH_PYTHON will
  32 # cause an error if the version of python installed on the system
  33 # doesn't meet the requirement.  MINIMUM-VERSION should consist of
  34 # numbers and dots only.
  35 AC_DEFUN([AM_PATH_PYTHON],
  36  [
  37   dnl Find a Python interpreter.  Python versions prior to 2.0 are not
  38   dnl supported. (2.0 was released on October 16, 2000).
  39   m4_define_default([_AM_PYTHON_INTERPRETER_LIST],
  40 [python python2 python3 python3.2 python3.1 python3.0 python2.7 dnl
  41  python2.6 python2.5 python2.4 python2.3 python2.2 python2.1 python2.0])
  42
  43   AC_ARG_VAR([PYTHON], [the Python interpreter])
  44
  45   m4_if([$1],[],[
  46     dnl No version check is needed.
  47     # Find any Python interpreter.
  48     if test -z "$PYTHON"; then
  49       AC_PATH_PROGS([PYTHON], _AM_PYTHON_INTERPRETER_LIST, :)
  50     fi
  51     am_display_PYTHON=python
  52   ], [
  53     dnl A version check is needed.
  54     if test -n "$PYTHON"; then
  55       # If the user set $PYTHON, use it and don't search something else.
  56       AC_MSG_CHECKING([whether $PYTHON version is >= $1])
  57       AM_PYTHON_CHECK_VERSION([$PYTHON], [$1],
  58                               [AC_MSG_RESULT([yes])],
  59                               [AC_MSG_RESULT([no])
  60                                AC_MSG_ERROR([Python interpreter is too old])])
  61       am_display_PYTHON=$PYTHON
  62     else
  63       # Otherwise, try each interpreter until we find one that satisfies
  64       # VERSION.
  65       AC_CACHE_CHECK([for a Python interpreter with version >= $1],
  66         [am_cv_pathless_PYTHON],[
  67         for am_cv_pathless_PYTHON in _AM_PYTHON_INTERPRETER_LIST none; do
  68           test "$am_cv_pathless_PYTHON" = none && break
  69           AM_PYTHON_CHECK_VERSION([$am_cv_pathless_PYTHON], [$1], [break])
  70         done])
  71       # Set $PYTHON to the absolute path of $am_cv_pathless_PYTHON.
  72       if test "$am_cv_pathless_PYTHON" = none; then
  73         PYTHON=:
  74       else
  75         AC_PATH_PROG([PYTHON], [$am_cv_pathless_PYTHON])
  76       fi
  77       am_display_PYTHON=$am_cv_pathless_PYTHON
  78     fi
  79   ])
  80
  81   if test "$PYTHON" = :; then
  82   dnl Run any user-specified action, or abort.
  83     m4_default([$3], [AC_MSG_ERROR([no suitable Python interpreter found])])
  84   else
  85
  86   dnl Query Python for its version number.  Getting [:3] seems to be
  87   dnl the best way to do this; it's what "site.py" does in the standard
  88   dnl library.
  89
  90   AC_CACHE_CHECK([for $am_display_PYTHON version], [am_cv_python_version],
  91     [am_cv_python_version=`$PYTHON -c "import sys; sys.stdout.write(sys.version[[:3]])"`])
  92   AC_SUBST([PYTHON_VERSION], [$am_cv_python_version])
  93
  94   dnl Use the values of $prefix and $exec_prefix for the corresponding
  95   dnl values of PYTHON_PREFIX and PYTHON_EXEC_PREFIX.  These are made
  96   dnl distinct variables so they can be overridden if need be.  However,
  97   dnl general consensus is that you shouldn't need this ability.
  98
  99   AC_SUBST([PYTHON_PREFIX], ['${prefix}'])
 100   AC_SUBST([PYTHON_EXEC_PREFIX], ['${exec_prefix}'])
 101
 102   dnl At times (like when building shared libraries) you may want
 103   dnl to know which OS platform Python thinks this is.
 104
 105   AC_CACHE_CHECK([for $am_display_PYTHON platform], [am_cv_python_platform],
 106     [am_cv_python_platform=`$PYTHON -c "import sys; sys.stdout.write(sys.platform)"`])
 107   AC_SUBST([PYTHON_PLATFORM], [$am_cv_python_platform])
 108
 109
 110   dnl Set up 4 directories:
 111
 112   dnl pythondir -- where to install python scripts.  This is the
 113   dnl   site-packages directory, not the python standard library
 114   dnl   directory like in previous automake betas.  This behavior
 115   dnl   is more consistent with lispdir.m4 for example.
 116   dnl Query distutils for this directory.
 117   AC_CACHE_CHECK([for $am_display_PYTHON script directory],
 118     [am_cv_python_pythondir],
 119     [if test "x$prefix" = xNONE
 120      then
 121        am_py_prefix=$ac_default_prefix
 122      else
 123        am_py_prefix=$prefix
 124      fi
 125      am_cv_python_pythondir=`$PYTHON -c "import sys; from distutils import sysconfig; sys.stdout.write(sysconfig.get_python_lib(0,0,prefix='$am_py_prefix'))" 2>/dev/null`
 126      case $am_cv_python_pythondir in
 127      $am_py_prefix*)
 128        am__strip_prefix=`echo "$am_py_prefix" | sed 's|.|.|g'`
 129        am_cv_python_pythondir=`echo "$am_cv_python_pythondir" | sed "s,^$am__strip_prefix,$PYTHON_PREFIX,"`
 130        ;;
 131      *)
 132        case $am_py_prefix in
 133          /usr|/System*) ;;
 134          *)
 135           am_cv_python_pythondir=$PYTHON_PREFIX/lib/python$PYTHON_VERSION/site-packages
 136           ;;
 137        esac
 138        ;;
 139      esac
 140     ])
 141   AC_SUBST([pythondir], [$am_cv_python_pythondir])
 142
 143   dnl pkgpythondir -- $PACKAGE directory under pythondir.  Was
 144   dnl   PYTHON_SITE_PACKAGE in previous betas, but this naming is
 145   dnl   more consistent with the rest of automake.
 146
 147   AC_SUBST([pkgpythondir], [\${pythondir}/$PACKAGE])
 148
 149   dnl pyexecdir -- directory for installing python extension modules
 150   dnl   (shared libraries)
 151   dnl Query distutils for this directory.
 152   AC_CACHE_CHECK([for $am_display_PYTHON extension module directory],
 153     [am_cv_python_pyexecdir],
 154     [if test "x$exec_prefix" = xNONE
 155      then
 156        am_py_exec_prefix=$am_py_prefix
 157      else
 158        am_py_exec_prefix=$exec_prefix
 159      fi
 160      am_cv_python_pyexecdir=`$PYTHON -c "import sys; from distutils import sysconfig; sys.stdout.write(sysconfig.get_python_lib(1,0,prefix='$am_py_exec_prefix'))" 2>/dev/null`
 161      case $am_cv_python_pyexecdir in
 162      $am_py_exec_prefix*)
 163        am__strip_prefix=`echo "$am_py_exec_prefix" | sed 's|.|.|g'`
 164        am_cv_python_pyexecdir=`echo "$am_cv_python_pyexecdir" | sed "s,^$am__strip_prefix,$PYTHON_EXEC_PREFIX,"`
 165        ;;
 166      *)
 167        case $am_py_exec_prefix in
 168          /usr|/System*) ;;
 169          *)
 170            am_cv_python_pyexecdir=$PYTHON_EXEC_PREFIX/lib/python$PYTHON_VERSION/site-packages
 171            ;;
 172        esac
 173        ;;
 174      esac
 175     ])
 176   AC_SUBST([pyexecdir], [$am_cv_python_pyexecdir])
 177
 178   dnl pkgpyexecdir -- $(pyexecdir)/$(PACKAGE)
 179
 180   AC_SUBST([pkgpyexecdir], [\${pyexecdir}/$PACKAGE])
 181
 182   dnl Run any user-specified action.
 183   $2
 184   fi
 185
 186 ])
 187
 188
 189 # AM_PYTHON_CHECK_VERSION(PROG, VERSION, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
 190 # ---------------------------------------------------------------------------
 191 # Run ACTION-IF-TRUE if the Python interpreter PROG has version >= VERSION.
 192 # Run ACTION-IF-FALSE otherwise.
 193 # This test uses sys.hexversion instead of the string equivalent (first
 194 # word of sys.version), in order to cope with versions such as 2.2c1.
 195 # This supports Python 2.0 or higher. (2.0 was released on October 16, 2000).
 196 AC_DEFUN([AM_PYTHON_CHECK_VERSION],
 197  [prog="import sys
 198 # split strings by '.' and convert to numeric.  Append some zeros
 199 # because we need at least 4 digits for the hex conversion.
 200 # map returns an iterator in Python 3.0 and a list in 2.x
 201 minver = list(map(int, '$2'.split('.'))) + [[0, 0, 0]]
 202 minverhex = 0
 203 # xrange is not present in Python 3.0 and range returns an iterator
 204 for i in list(range(0, 4)): minverhex = (minverhex << 8) + minver[[i]]
 205 sys.exit(sys.hexversion < minverhex)"
 206   AS_IF([AM_RUN_LOG([$1 -c "$prog"])], [$3], [$4])])