m4/openat.m4

   1 #serial 15
   2 # See if we need to use our replacement for Solaris' openat et al functions.
   3
   4 dnl Copyright (C) 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Jim Meyering.
  10
  11 AC_DEFUN([gl_FUNC_OPENAT],
  12 [
  13   AC_LIBOBJ([openat-die])
  14   AC_LIBOBJ([openat-proc])
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16   AC_CHECK_FUNCS_ONCE([lchmod])
  17   AC_CHECK_FUNCS_ONCE([fdopendir])
  18   AC_REPLACE_FUNCS([fchmodat mkdirat openat])
  19   case $ac_cv_func_openat+$ac_cv_func_lstat_dereferences_slashed_symlink in
  20   yes+yes) ;;
  21   yes+*) AC_LIBOBJ([fstatat]);;
  22   *)
  23     AC_DEFINE([__OPENAT_PREFIX], [[rpl_]],
  24       [Define to rpl_ if the openat replacement function should be used.])
  25     gl_PREREQ_OPENAT;;
  26   esac
  27   gl_FUNC_FCHOWNAT
  28 ])
  29
  30 # gl_FUNC_FCHOWNAT_DEREF_BUG([ACTION-IF-BUGGY[, ACTION-IF-NOT_BUGGY]])
  31 AC_DEFUN([gl_FUNC_FCHOWNAT_DEREF_BUG],
  32 [
  33   AC_CACHE_CHECK([whether fchownat works with AT_SYMLINK_NOFOLLOW],
  34     gl_cv_func_fchownat_nofollow_works,
  35     [
  36      gl_dangle=conftest.dangle
  37      # Remove any remnants of a previous test.
  38      rm -f $gl_dangle
  39      # Arrange for deletion of the temporary file this test creates.
  40      ac_clean_files="$ac_clean_files $gl_dangle"
  41      AC_RUN_IFELSE(
  42        [AC_LANG_SOURCE(
  43           [[
  44 #include <fcntl.h>
  45 #include <unistd.h>
  46 #include <stdlib.h>
  47 #include <errno.h>
  48 #include <sys/types.h>
  49 int
  50 main ()
  51 {
  52   return (fchownat (AT_FDCWD, "$gl_dangle", -1, getgid (),
  53                     AT_SYMLINK_NOFOLLOW) != 0
  54           && errno == ENOENT);
  55 }
  56           ]])],
  57     [gl_cv_func_fchownat_nofollow_works=yes],
  58     [gl_cv_func_fchownat_nofollow_works=no],
  59     [gl_cv_func_fchownat_nofollow_works=no],
  60     )
  61   ])
  62   AS_IF([test $gl_cv_func_fchownat_nofollow_works = no], [$1], [$2])
  63 ])
  64
  65 # If we have the fchownat function, and it has the bug (in glibc-2.4)
  66 # that it dereferences symlinks even with AT_SYMLINK_NOFOLLOW, then
  67 # use the replacement function.
  68 # Also use the replacement function if fchownat is simply not available.
  69 AC_DEFUN([gl_FUNC_FCHOWNAT],
  70 [
  71   # Assume we'll use the replacement function.
  72   # The only case in which we won't is when we have fchownat, and it works.
  73   use_replacement_fchownat=yes
  74
  75   AC_CHECK_FUNC([fchownat], [have_fchownat=yes], [have_fchownat=no])
  76   if test $have_fchownat = yes; then
  77     gl_FUNC_FCHOWNAT_DEREF_BUG([have_fchownat_bug=yes])
  78     if test $have_fchownat_bug = no; then
  79       use_replacement_fchownat=no
  80     fi
  81   fi
  82
  83   if test $use_replacement_fchownat = yes; then
  84     AC_LIBOBJ(fchownat)
  85     AC_DEFINE(fchownat, rpl_fchownat,
  86       [Define to rpl_fchownat if the replacement function should be used.])
  87   fi
  88 ])
  89
  90 AC_DEFUN([gl_PREREQ_OPENAT],
  91 [
  92   :
  93 ])