m4/mktime.m4

   1 # serial 36
   2 dnl Copyright (C) 2002-2003, 2005-2007, 2009-2021 Free Software Foundation,
   3 dnl Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Jim Meyering.
   9
  10 AC_DEFUN([gl_TIME_T_IS_SIGNED],
  11 [
  12   AC_CACHE_CHECK([whether time_t is signed],
  13     [gl_cv_time_t_is_signed],
  14     [AC_COMPILE_IFELSE(
  15        [AC_LANG_PROGRAM([[#include <time.h>
  16                           char time_t_signed[(time_t) -1 < 0 ? 1 : -1];]])],
  17        [gl_cv_time_t_is_signed=yes],
  18        [gl_cv_time_t_is_signed=no])])
  19   if test $gl_cv_time_t_is_signed = yes; then
  20     AC_DEFINE([TIME_T_IS_SIGNED], [1], [Define to 1 if time_t is signed.])
  21   fi
  22 ])
  23
  24 dnl Test whether mktime works. Set gl_cv_func_working_mktime.
  25 AC_DEFUN([gl_FUNC_MKTIME_WORKS],
  26 [
  27   AC_REQUIRE([gl_TIME_T_IS_SIGNED])
  28   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  29
  30   dnl We don't use AC_FUNC_MKTIME any more, because it is no longer maintained
  31   dnl in Autoconf and because it invokes AC_LIBOBJ.
  32   AC_CHECK_HEADERS_ONCE([unistd.h])
  33   AC_CHECK_DECLS_ONCE([alarm])
  34   AC_REQUIRE([gl_MULTIARCH])
  35   AC_CACHE_CHECK([for working mktime], [gl_cv_func_working_mktime],
  36     [if test $APPLE_UNIVERSAL_BUILD = 1; then
  37        # A universal build on Apple Mac OS X platforms.
  38        # The test result would be 'yes' in 32-bit mode and 'no' in 64-bit mode.
  39        # But we need a configuration result that is valid in both modes.
  40        gl_cv_func_working_mktime="guessing no"
  41      else
  42        AC_RUN_IFELSE(
  43          [AC_LANG_SOURCE(
  44 [[/* Test program from Paul Eggert and Tony Leneis.  */
  45 #include <limits.h>
  46 #include <stdlib.h>
  47 #include <time.h>
  48
  49 #ifdef HAVE_UNISTD_H
  50 # include <unistd.h>
  51 #endif
  52
  53 #if HAVE_DECL_ALARM
  54 # include <signal.h>
  55 #endif
  56
  57 ]GL_MDA_DEFINES[
  58
  59 #ifndef TIME_T_IS_SIGNED
  60 # define TIME_T_IS_SIGNED 0
  61 #endif
  62
  63 static time_t time_t_max;
  64 static time_t time_t_min;
  65
  66 /* Values we'll use to set the TZ environment variable.  */
  67 static char *tz_strings[] = {
  68   (char *) 0, "TZ=GMT0", "TZ=JST-9",
  69   "TZ=EST+3EDT+2,M10.1.0/00:00:00,M2.3.0/00:00:00"
  70 };
  71 #define N_STRINGS (sizeof (tz_strings) / sizeof (tz_strings[0]))
  72
  73 /* Return 0 if mktime fails to convert a date in the spring-forward gap.
  74    Based on a problem report from Andreas Jaeger.  */
  75 static int
  76 spring_forward_gap ()
  77 {
  78   /* glibc (up to about 1998-10-07) failed this test. */
  79   struct tm tm;
  80
  81   /* Use the portable POSIX.1 specification "TZ=PST8PDT,M4.1.0,M10.5.0"
  82      instead of "TZ=America/Vancouver" in order to detect the bug even
  83      on systems that don't support the Olson extension, or don't have the
  84      full zoneinfo tables installed.  */
  85   putenv ("TZ=PST8PDT,M4.1.0,M10.5.0");
  86
  87   tm.tm_year = 98;
  88   tm.tm_mon = 3;
  89   tm.tm_mday = 5;
  90   tm.tm_hour = 2;
  91   tm.tm_min = 0;
  92   tm.tm_sec = 0;
  93   tm.tm_isdst = -1;
  94   return mktime (&tm) != (time_t) -1;
  95 }
  96
  97 static int
  98 mktime_test1 (time_t now)
  99 {
 100   struct tm *lt;
 101   return ! (lt = localtime (&now)) || mktime (lt) == now;
 102 }
 103
 104 static int
 105 mktime_test (time_t now)
 106 {
 107   return (mktime_test1 (now)
 108           && mktime_test1 ((time_t) (time_t_max - now))
 109           && mktime_test1 ((time_t) (time_t_min + now)));
 110 }
 111
 112 static int
 113 irix_6_4_bug ()
 114 {
 115   /* Based on code from Ariel Faigon.  */
 116   struct tm tm;
 117   tm.tm_year = 96;
 118   tm.tm_mon = 3;
 119   tm.tm_mday = 0;
 120   tm.tm_hour = 0;
 121   tm.tm_min = 0;
 122   tm.tm_sec = 0;
 123   tm.tm_isdst = -1;
 124   mktime (&tm);
 125   return tm.tm_mon == 2 && tm.tm_mday == 31;
 126 }
 127
 128 static int
 129 bigtime_test (int j)
 130 {
 131   struct tm tm;
 132   time_t now;
 133   tm.tm_year = tm.tm_mon = tm.tm_mday = tm.tm_hour = tm.tm_min = tm.tm_sec = j;
 134   now = mktime (&tm);
 135   if (now != (time_t) -1)
 136     {
 137       struct tm *lt = localtime (&now);
 138       if (! (lt
 139              && lt->tm_year == tm.tm_year
 140              && lt->tm_mon == tm.tm_mon
 141              && lt->tm_mday == tm.tm_mday
 142              && lt->tm_hour == tm.tm_hour
 143              && lt->tm_min == tm.tm_min
 144              && lt->tm_sec == tm.tm_sec
 145              && lt->tm_yday == tm.tm_yday
 146              && lt->tm_wday == tm.tm_wday
 147              && ((lt->tm_isdst < 0 ? -1 : 0 < lt->tm_isdst)
 148                   == (tm.tm_isdst < 0 ? -1 : 0 < tm.tm_isdst))))
 149         return 0;
 150     }
 151   return 1;
 152 }
 153
 154 static int
 155 year_2050_test ()
 156 {
 157   /* The correct answer for 2050-02-01 00:00:00 in Pacific time,
 158      ignoring leap seconds.  */
 159   unsigned long int answer = 2527315200UL;
 160
 161   struct tm tm;
 162   time_t t;
 163   tm.tm_year = 2050 - 1900;
 164   tm.tm_mon = 2 - 1;
 165   tm.tm_mday = 1;
 166   tm.tm_hour = tm.tm_min = tm.tm_sec = 0;
 167   tm.tm_isdst = -1;
 168
 169   /* Use the portable POSIX.1 specification "TZ=PST8PDT,M4.1.0,M10.5.0"
 170      instead of "TZ=America/Vancouver" in order to detect the bug even
 171      on systems that don't support the Olson extension, or don't have the
 172      full zoneinfo tables installed.  */
 173   putenv ("TZ=PST8PDT,M4.1.0,M10.5.0");
 174
 175   t = mktime (&tm);
 176
 177   /* Check that the result is either a failure, or close enough
 178      to the correct answer that we can assume the discrepancy is
 179      due to leap seconds.  */
 180   return (t == (time_t) -1
 181           || (0 < t && answer - 120 <= t && t <= answer + 120));
 182 }
 183
 184 int
 185 main ()
 186 {
 187   int result = 0;
 188   time_t t, delta;
 189   int i, j;
 190   int time_t_signed_magnitude = (time_t) ~ (time_t) 0 < (time_t) -1;
 191
 192 #if HAVE_DECL_ALARM
 193   /* This test makes some buggy mktime implementations loop.
 194      Give up after 60 seconds; a mktime slower than that
 195      isn't worth using anyway.  */
 196   signal (SIGALRM, SIG_DFL);
 197   alarm (60);
 198 #endif
 199
 200   time_t_max = (! TIME_T_IS_SIGNED
 201                 ? (time_t) -1
 202                 : ((((time_t) 1 << (sizeof (time_t) * CHAR_BIT - 2)) - 1)
 203                    * 2 + 1));
 204   time_t_min = (! TIME_T_IS_SIGNED
 205                 ? (time_t) 0
 206                 : time_t_signed_magnitude
 207                 ? ~ (time_t) 0
 208                 : ~ time_t_max);
 209
 210   delta = time_t_max / 997; /* a suitable prime number */
 211   for (i = 0; i < N_STRINGS; i++)
 212     {
 213       if (tz_strings[i])
 214         putenv (tz_strings[i]);
 215
 216       for (t = 0; t <= time_t_max - delta && (result & 1) == 0; t += delta)
 217         if (! mktime_test (t))
 218           result |= 1;
 219       if ((result & 2) == 0
 220           && ! (mktime_test ((time_t) 1)
 221                 && mktime_test ((time_t) (60 * 60))
 222                 && mktime_test ((time_t) (60 * 60 * 24))))
 223         result |= 2;
 224
 225       for (j = 1; (result & 4) == 0; j <<= 1)
 226         {
 227           if (! bigtime_test (j))
 228             result |= 4;
 229           if (INT_MAX / 2 < j)
 230             break;
 231         }
 232       if ((result & 8) == 0 && ! bigtime_test (INT_MAX))
 233         result |= 8;
 234     }
 235   if (! irix_6_4_bug ())
 236     result |= 16;
 237   if (! spring_forward_gap ())
 238     result |= 32;
 239   if (! year_2050_test ())
 240     result |= 64;
 241   return result;
 242 }]])],
 243          [gl_cv_func_working_mktime=yes],
 244          [gl_cv_func_working_mktime=no],
 245          [case "$host_os" in
 246                     # Guess no on native Windows.
 247             mingw*) gl_cv_func_working_mktime="guessing no" ;;
 248             *)      gl_cv_func_working_mktime="$gl_cross_guess_normal" ;;
 249           esac
 250          ])
 251      fi
 252     ])
 253 ])
 254
 255 dnl Main macro of module 'mktime'.
 256 AC_DEFUN([gl_FUNC_MKTIME],
 257 [
 258   AC_REQUIRE([gl_TIME_H_DEFAULTS])
 259   AC_REQUIRE([AC_CANONICAL_HOST])
 260   AC_REQUIRE([gl_FUNC_MKTIME_WORKS])
 261
 262   REPLACE_MKTIME=0
 263   if test "$gl_cv_func_working_mktime" != yes; then
 264     REPLACE_MKTIME=1
 265     AC_DEFINE([NEED_MKTIME_WORKING], [1],
 266       [Define if the compilation of mktime.c should define 'mktime'
 267        with the algorithmic workarounds.])
 268   fi
 269   case "$host_os" in
 270     mingw*)
 271       REPLACE_MKTIME=1
 272       AC_DEFINE([NEED_MKTIME_WINDOWS], [1],
 273         [Define if the compilation of mktime.c should define 'mktime'
 274          with the native Windows TZ workaround.])
 275       ;;
 276   esac
 277 ])
 278
 279 dnl Main macro of module 'mktime-internal'.
 280 AC_DEFUN([gl_FUNC_MKTIME_INTERNAL], [
 281   AC_REQUIRE([gl_FUNC_MKTIME_WORKS])
 282
 283   WANT_MKTIME_INTERNAL=0
 284   dnl BeOS has __mktime_internal in libc, but other platforms don't.
 285   AC_CHECK_FUNC([__mktime_internal],
 286     [AC_DEFINE([mktime_internal], [__mktime_internal],
 287        [Define to the real name of the mktime_internal function.])
 288     ],
 289     [dnl mktime works but it doesn't export __mktime_internal,
 290      dnl so we need to substitute our own mktime implementation.
 291      WANT_MKTIME_INTERNAL=1
 292      AC_DEFINE([NEED_MKTIME_INTERNAL], [1],
 293        [Define if the compilation of mktime.c should define 'mktime_internal'.])
 294     ])
 295 ])
 296
 297 # Prerequisites of lib/mktime.c.
 298 AC_DEFUN([gl_PREREQ_MKTIME], [:])