m4/minuso.m4

   1 ##                                                          -*- Autoconf -*-
   2 # Copyright (C) 1999-2012 Free Software Foundation, Inc.
   3 #
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # serial 6
   9
  10 # AM_PROG_CC_C_O
  11 # --------------
  12 # Like AC_PROG_CC_C_O, but changed for automake.
  13 AC_DEFUN([AM_PROG_CC_C_O],
  14 [AC_REQUIRE([AC_PROG_CC_C_O])dnl
  15 AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
  16 AC_REQUIRE_AUX_FILE([compile])dnl
  17 # FIXME: we rely on the cache variable name because
  18 # there is no other way.
  19 set dummy $CC
  20 am_cc=`echo $[2] | sed ['s/[^a-zA-Z0-9_]/_/g;s/^[0-9]/_/']`
  21 eval am_t=\$ac_cv_prog_cc_${am_cc}_c_o
  22 if test "$am_t" != yes; then
  23    # Losing compiler, so override with the script.
  24    # FIXME: It is wrong to rewrite CC.
  25    # But if we don't then we get into trouble of one sort or another.
  26    # A longer-term fix would be to have automake use am__CC in this case,
  27    # and then we could set am__CC="\$(top_srcdir)/compile \$(CC)"
  28    CC="$am_aux_dir/compile $CC"
  29 fi
  30 dnl Make sure AC_PROG_CC is never called again, or it will override our
  31 dnl setting of CC.
  32 m4_define([AC_PROG_CC],
  33           [m4_fatal([AC_PROG_CC cannot be called after AM_PROG_CC_C_O])])
  34 ])