m4/man-bdb.m4

   1 # man-bdb.m4 serial 4
   2 dnl MAN_CHECK_BDB(WITH-DB, HEADERS, LIBS, [ACTION-IF-FOUND])
   3 dnl Helper to check Berkeley DB linkage when particular header files and
   4 dnl libraries are included. ACTION-IF-FOUND may contain $head and $lib.
   5 dnl Contributed by Duncan Simpson <dps@io.stargate.co.uk> and hacked into a
   6 dnl macro by Colin Watson.
   7
   8 AC_DEFUN([MAN_CHECK_BDB], [dnl
   9 man_bdb_requested=no
  10 for trydb in $1
  11 do
  12   if test "$db" = "$trydb"
  13   then
  14     man_bdb_requested=yes
  15   fi
  16 done
  17 if test "$db" = no || test "$man_bdb_requested" = yes
  18 then
  19   for head in $2
  20   do
  21     AC_CHECK_HEADERS([$head], [got=yes], [got=no])
  22     if test "$got" = "yes"
  23     then
  24       for lib in $3
  25       do
  26         AS_VAR_PUSHDEF([man_tr_bdb], [man_cv_bdb_header_${head}_lib_${lib}])dnl
  27         man_saved_LIBS="$LIBS"
  28         LIBS="$LIBS -l$lib"
  29         AC_CACHE_CHECK([for dbopen from <${head}> in -l${lib}], man_tr_bdb,
  30            [AC_TRY_LINK([#include <$head>], [dbopen("foo", 0, 0, 0, (void *) 0)],
  31                         [AS_VAR_SET([man_tr_bdb], [yes])],
  32                         [AS_VAR_SET([man_tr_bdb], [no])])
  33            ])
  34         AS_VAR_IF([man_tr_bdb], [yes],
  35                   [$4
  36                    AC_DEFINE_UNQUOTED([BDB_H], [<$head>],
  37                                       [Define if you have, and want to use, Berkeley database header files.])
  38                    AC_DEFINE_UNQUOTED([BTREE], [1],
  39                                       [Define if you have, and want to use, the Berkeley database library.])
  40                    AC_SUBST([DBTYPE], [btree])
  41                    DBLIBS="-l$lib"
  42                    db=yes],
  43                   [db=no])
  44         LIBS="$man_saved_LIBS"
  45         AS_VAR_POPDEF([man_tr_bdb])dnl
  46         test "$db" = "yes" && break
  47       done
  48     fi
  49     test "$db" = "yes" && break
  50   done
  51 fi[]dnl
  52 ])# MAN_CHECK_BDB