m4/make.m4

   1 # AM_MAKE_INCLUDE()
   2 # -----------------
   3 # Check to see how make treats includes.
   4 AC_DEFUN([AM_MAKE_INCLUDE],
   5 [am_make=${MAKE-make}
   6 cat > confinc << 'END'
   7 doit:
   8         @echo done
   9 END
  10 # If we don't find an include directive, just comment out the code.
  11 AC_MSG_CHECKING([for style of include used by $am_make])
  12 _am_include='#'
  13 _am_quote=
  14 _am_result=none
  15 # First try GNU make style include.
  16 echo "include confinc" > confmf
  17 if test "`$am_make -s -f confmf 2> /dev/null`" = "done"; then
  18    _am_include=include
  19    _am_quote=
  20    _am_result=GNU
  21 fi
  22 # Now try BSD make style include.
  23 if test "$_am_include" = "#"; then
  24    echo '.include "confinc"' > confmf
  25    if test "`$am_make -s -f confmf 2> /dev/null`" = "done"; then
  26       _am_include=.include
  27       _am_quote='"'
  28       _am_result=BSD
  29    fi
  30 fi
  31 AC_SUBST(_am_include)
  32 AC_SUBST(_am_quote)
  33 AC_MSG_RESULT($_am_result)
  34 rm -f confinc confmf
  35 ])