m4/jm-macros.m4

   1 #serial 109   -*- autoconf -*-
   2
   3 dnl Misc type-related macros for coreutils.
   4
   5 # Copyright (C) 1998, 2000-2009 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # Written by Jim Meyering.
  21
  22 AC_DEFUN([coreutils_MACROS],
  23 [
  24   AM_MISSING_PROG(HELP2MAN, help2man)
  25   AC_SUBST([MAN])
  26
  27   dnl This macro actually runs replacement code.  See isc-posix.m4.
  28   AC_REQUIRE([AC_ISC_POSIX])dnl
  29
  30   gl_CHECK_ALL_TYPES
  31
  32   AC_REQUIRE([gl_CHECK_DECLS])
  33
  34   AC_REQUIRE([gl_PREREQ])
  35
  36   AC_REQUIRE([AC_FUNC_FSEEKO])
  37
  38   # By default, argmatch should fail calling usage (1).
  39   AC_DEFINE([ARGMATCH_DIE], [usage (1)],
  40             [Define to the function xargmatch calls on failures.])
  41   AC_DEFINE([ARGMATCH_DIE_DECL], [void usage (int _e)],
  42             [Define to the declaration of the xargmatch failure function.])
  43
  44   # used by ls
  45   AC_REQUIRE([gl_CLOCK_TIME])
  46   # used by shred
  47   AC_CHECK_FUNCS_ONCE([directio])
  48
  49   # Used by install.c.
  50   coreutils_saved_libs=$LIBS
  51     LIBS="$LIBS $LIB_SELINUX"
  52     AC_CHECK_FUNCS([matchpathcon_init_prefix], [],
  53     [
  54       case "$ac_cv_search_setfilecon:$ac_cv_header_selinux_selinux_h" in
  55         no:*) # SELinux disabled
  56           ;;
  57         *:no) # SELinux disabled
  58           ;;
  59         *)
  60         AC_MSG_WARN([SELinux enabled, but matchpathcon_init_prefix not found])
  61         AC_MSG_WARN([The install utility may run slowly])
  62       esac
  63     ])
  64   LIBS=$coreutils_saved_libs
  65
  66   # Used by sort.c.
  67   AC_CHECK_FUNCS_ONCE([nl_langinfo])
  68
  69   # Used by tail.c.
  70   AC_CHECK_FUNCS([inotify_init],
  71     [AC_DEFINE([HAVE_INOTIFY], [1],
  72      [Define to 1 if you have usable inotify support.])])
  73
  74   AC_CHECK_FUNCS_ONCE( \
  75     endgrent \
  76     endpwent \
  77     fchown \
  78     fchmod \
  79     ftruncate \
  80     iswspace \
  81     mkfifo \
  82     mbrlen \
  83     setgroups \
  84     sethostname \
  85     siginterrupt \
  86     sync \
  87     sysctl \
  88     sysinfo \
  89     tcgetpgrp \
  90   )
  91
  92   # for cp.c
  93   AC_CHECK_FUNCS_ONCE([utimensat])
  94
  95   # for remove.c
  96   AC_CHECK_FUNCS_ONCE([faccessat])
  97
  98   dnl This can't use AC_REQUIRE; I'm not quite sure why.
  99   cu_PREREQ_STAT_PROG
 100
 101   # for dd.c and shred.c
 102   coreutils_saved_libs=$LIBS
 103     AC_SEARCH_LIBS([fdatasync], [rt posix4],
 104                    [test "$ac_cv_search_fdatasync" = "none required" ||
 105                     LIB_FDATASYNC=$ac_cv_search_fdatasync])
 106     AC_SUBST([LIB_FDATASYNC])
 107     AC_CHECK_FUNCS([fdatasync])
 108   LIBS=$coreutils_saved_libs
 109
 110   # Check whether libcap is usable -- for ls --color support
 111   LIB_CAP=
 112   AC_ARG_ENABLE([libcap],
 113     AC_HELP_STRING([--disable-libcap], [disable libcap support]))
 114   if test "X$enable_libcap" != "Xno"; then
 115     AC_CHECK_LIB([cap], [cap_get_file],
 116       [AC_CHECK_HEADER([sys/capability.h],
 117         [LIB_CAP=-lcap
 118          AC_DEFINE([HAVE_CAP], [1], [libcap usability])]
 119       )])
 120     if test "X$LIB_CAP" = "X"; then
 121       if test "X$enable_libcap" = "Xyes"; then
 122         AC_MSG_ERROR([libcap library was not found or not usable])
 123       else
 124         AC_MSG_WARN([libcap library was not found or not usable, support for libcap will not be built])
 125       fi
 126     fi
 127   else
 128     AC_MSG_WARN([libcap support disabled by user])
 129   fi
 130   AC_SUBST([LIB_CAP])
 131
 132   # See if linking `seq' requires -lm.
 133   # It does on nearly every system.  The single exception (so far) is
 134   # BeOS which has all the math functions in the normal runtime library
 135   # and doesn't have a separate math library.
 136
 137   AC_SUBST([SEQ_LIBM])
 138   ac_seq_body='
 139      static double x, y;
 140      x = floor (x);
 141      x = rint (x);
 142      x = modf (x, &y);'
 143   AC_TRY_LINK([#include <math.h>], [$ac_seq_body], ,
 144     [ac_seq_save_LIBS="$LIBS"
 145      LIBS="$LIBS -lm"
 146      AC_TRY_LINK([#include <math.h>], [$ac_seq_body], [SEQ_LIBM=-lm])
 147      LIBS="$ac_seq_save_LIBS"
 148     ])
 149
 150   AC_REQUIRE([AM_LANGINFO_CODESET])
 151 ])
 152
 153 AC_DEFUN([gl_CHECK_ALL_HEADERS],
 154 [
 155   AC_CHECK_HEADERS_ONCE( \
 156     hurd.h \
 157     paths.h \
 158     priv.h \
 159     stropts.h \
 160     sys/ioctl.h \
 161     sys/param.h \
 162     sys/resource.h \
 163     sys/systeminfo.h \
 164     sys/time.h \
 165     sys/wait.h \
 166     syslog.h \
 167     termios.h \
 168   )
 169   AC_CHECK_HEADERS([sys/sysctl.h], [], [],
 170     [AC_INCLUDES_DEFAULT
 171      [#if HAVE_SYS_PARAM_H
 172        #include <sys/param.h>
 173       #endif]])
 174 ])
 175
 176 # This macro must be invoked before any tests that run the compiler.
 177 AC_DEFUN([gl_CHECK_ALL_TYPES],
 178 [
 179   dnl This test must come as early as possible after the compiler configuration
 180   dnl tests, because the choice of the file model can (in principle) affect
 181   dnl whether functions and headers are available, whether they work, etc.
 182   AC_REQUIRE([AC_SYS_LARGEFILE])
 183
 184   dnl This test must precede tests of compiler characteristics like
 185   dnl that for the inline keyword, since it may change the degree to
 186   dnl which the compiler supports such features.
 187   AC_REQUIRE([AM_C_PROTOTYPES])
 188
 189   dnl Checks for typedefs, structures, and compiler characteristics.
 190   AC_REQUIRE([gl_BIGENDIAN])
 191   AC_REQUIRE([AC_C_VOLATILE])
 192   AC_REQUIRE([AC_C_INLINE])
 193   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
 194
 195   AC_REQUIRE([gl_CHECK_ALL_HEADERS])
 196   AC_CHECK_MEMBERS(
 197     [struct stat.st_author],,,
 198     [$ac_includes_default
 199 #include <sys/stat.h>
 200   ])
 201   AC_REQUIRE([AC_STRUCT_ST_BLOCKS])
 202
 203   AC_REQUIRE([AC_TYPE_GETGROUPS])
 204   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 205   AC_REQUIRE([AC_TYPE_MODE_T])
 206   AC_REQUIRE([AC_TYPE_OFF_T])
 207   AC_REQUIRE([AC_TYPE_PID_T])
 208   AC_REQUIRE([AC_TYPE_SIZE_T])
 209   AC_REQUIRE([AC_TYPE_UID_T])
 210   AC_CHECK_TYPE([ino_t], [unsigned long int])
 211
 212   dnl This relies on the fact that Autoconf's implementation of
 213   dnl AC_CHECK_TYPE checks includes unistd.h.
 214   AC_CHECK_TYPE([major_t], [unsigned int])
 215   AC_CHECK_TYPE([minor_t], [unsigned int])
 216
 217   AC_REQUIRE([AC_HEADER_MAJOR])
 218 ])