m4/jm-macros.m4

   1 #serial 95   -*- autoconf -*-
   2
   3 dnl Misc type-related macros for coreutils.
   4
   5 # Copyright (C) 1998, 2000, 2001, 2002, 2003, 2004, 2005 Free Software
   6 # Foundation, Inc.
   7
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2, or (at your option)
  11 # any later version.
  12
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software Foundation,
  20 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  21
  22 # Written by Jim Meyering.
  23
  24 AC_DEFUN([gl_MACROS],
  25 [
  26   AC_PREREQ(2.58)
  27
  28   GNU_PACKAGE="GNU $PACKAGE"
  29   AC_DEFINE_UNQUOTED(GNU_PACKAGE, "$GNU_PACKAGE",
  30     [The concatenation of the strings `GNU ', and PACKAGE.])
  31   AC_SUBST(GNU_PACKAGE)
  32
  33   AM_MISSING_PROG(HELP2MAN, help2man)
  34   AC_SUBST(OPTIONAL_BIN_PROGS)
  35   AC_SUBST(MAN)
  36   AC_SUBST(DF_PROG)
  37
  38   dnl This macro actually runs replacement code.  See isc-posix.m4.
  39   AC_REQUIRE([AC_ISC_POSIX])dnl
  40
  41   gl_CHECK_ALL_TYPES
  42
  43   AC_REQUIRE([gl_HOST_OS])
  44   AC_REQUIRE([gl_ASSERT])
  45   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_DIRENT_D_TYPE])
  46   AC_REQUIRE([gl_CHECK_TYPE_STRUCT_DIRENT_D_INO])
  47   AC_REQUIRE([gl_CHECK_DECLS])
  48
  49   AC_REQUIRE([gl_PREREQ])
  50
  51   AC_REQUIRE([gl_FUNC_DIRFD])
  52   AC_REQUIRE([AC_FUNC_ACL])
  53   AC_REQUIRE([gl_FUNC_LCHOWN])
  54   AC_REQUIRE([gl_FUNC_RMDIR_NOTEMPTY])
  55   AC_REQUIRE([gl_FUNC_CHOWN])
  56   AC_REQUIRE([AC_FUNC_LSTAT])
  57   AC_REQUIRE([AC_FUNC_STRERROR_R])
  58   AC_REQUIRE([gl_FUNC_GROUP_MEMBER])
  59   AC_REQUIRE([gl_AFS])
  60   AC_REQUIRE([gl_AC_FUNC_LINK_FOLLOWS_SYMLINK])
  61   AC_REQUIRE([gl_FUNC_FPENDING])
  62
  63   # This is for od and stat, and any other program that
  64   # uses the PRI.MAX macros from inttypes.h.
  65   AC_REQUIRE([gt_INTTYPES_PRI])
  66   AC_REQUIRE([gl_ULLONG_MAX])
  67
  68   AC_REQUIRE([gl_FUNC_GETGROUPS])
  69
  70   AC_REQUIRE([AC_FUNC_FSEEKO])
  71   AC_REQUIRE([AC_FUNC_ALLOCA])
  72
  73   AC_CONFIG_LIBOBJ_DIR([lib])
  74   AC_FUNC_GETLOADAVG([lib])
  75
  76   AC_REQUIRE([gl_SYS_PROC_UPTIME])
  77   AC_REQUIRE([gl_FUNC_FTRUNCATE])
  78
  79   # raise is used by at least sort and ls.
  80   AC_REPLACE_FUNCS(raise)
  81
  82   # By default, argmatch should fail calling usage (1).
  83   AC_DEFINE(ARGMATCH_DIE, [usage (1)],
  84             [Define to the function xargmatch calls on failures.])
  85   AC_DEFINE(ARGMATCH_DIE_DECL, [extern void usage ()],
  86             [Define to the declaration of the xargmatch failure function.])
  87
  88   dnl Used to define SETVBUF in sys2.h.
  89   dnl This evokes the following warning from autoconf:
  90   dnl ...: warning: AC_TRY_RUN called without default to allow cross compiling
  91   AC_FUNC_SETVBUF_REVERSED
  92
  93   # used by sleep and shred
  94   AC_REQUIRE([gl_CLOCK_TIME])
  95   AC_CHECK_FUNCS_ONCE(gettimeofday)
  96   AC_FUNC_GETTIMEOFDAY_CLOBBER
  97   # used by shred
  98   AC_CHECK_FUNCS_ONCE(directio)
  99
 100   AC_REQUIRE([AC_FUNC_CLOSEDIR_VOID])
 101
 102   AC_CHECK_FUNCS_ONCE( \
 103     endgrent \
 104     endpwent \
 105     fchmod \
 106     fchown \
 107     ftruncate \
 108     hasmntopt \
 109     isascii \
 110     iswspace \
 111     lchown \
 112     listmntent \
 113     mempcpy \
 114     mkfifo \
 115     mbrlen \
 116     realpath \
 117     sethostname \
 118     siginterrupt \
 119     sysctl \
 120     sysinfo \
 121     tcgetpgrp \
 122     wcrtomb \
 123     tzset \
 124   )
 125
 126   AC_FUNC_STRTOD
 127
 128   AC_REQUIRE([cu_PREREQ_STAT_PROG])
 129
 130   # for dd.c and shred.c
 131   coreutils_saved_libs=$LIBS
 132     AC_SEARCH_LIBS([fdatasync], [rt posix4],
 133                    [test "$ac_cv_search_fdatasync" = "none required" ||
 134                     LIB_FDATASYNC=$ac_cv_search_fdatasync])
 135     AC_SUBST([LIB_FDATASYNC])
 136     AC_CHECK_FUNCS(fdatasync)
 137   LIBS=$coreutils_saved_libs
 138
 139   # See if linking `seq' requires -lm.
 140   # It does on nearly every system.  The single exception (so far) is
 141   # BeOS which has all the math functions in the normal runtime library
 142   # and doesn't have a separate math library.
 143
 144   AC_SUBST(SEQ_LIBM)
 145   ac_seq_body='
 146      static double x, y;
 147      x = floor (x);
 148      x = rint (x);
 149      x = modf (x, &y);'
 150   AC_TRY_LINK([#include <math.h>], $ac_seq_body, ,
 151     [ac_seq_save_LIBS="$LIBS"
 152      LIBS="$LIBS -lm"
 153      AC_TRY_LINK([#include <math.h>], $ac_seq_body, SEQ_LIBM=-lm)
 154      LIBS="$ac_seq_save_LIBS"
 155     ])
 156
 157   AC_REQUIRE([AM_LANGINFO_CODESET])
 158   AC_REQUIRE([gl_GLIBC21])
 159   AM_ICONV
 160   gl_FUNC_UNLINK_BUSY_TEXT
 161
 162   # These tests are for df.
 163   AC_REQUIRE([gl_FSUSAGE])
 164   AC_REQUIRE([gl_MOUNTLIST])
 165   if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 166     DF_PROG='df$(EXEEXT)'
 167   fi
 168   AC_REQUIRE([gl_AC_DOS])
 169   AC_REQUIRE([AC_FUNC_CANONICALIZE_FILE_NAME])
 170
 171   # If any of these functions don't exist (e.g. DJGPP 2.03),
 172   # use the corresponding stub.
 173   AC_CHECK_FUNC([fchdir], , [AC_LIBOBJ(fchdir-stub)])
 174
 175   AC_REQUIRE([gl_FUNC_FREE])
 176   AC_REQUIRE([gl_FUNC_CHDIR_LONG])
 177   AC_REQUIRE([gl_FUNC_XFTS])
 178   AC_REQUIRE([gl_ROOT_DEV_INO])
 179   AC_REQUIRE([gl_VERSION_ETC])
 180   AC_REQUIRE([gl_DIACRIT])
 181   AC_REQUIRE([gl_TYPE_SOCKLEN_T])
 182 ])
 183
 184 AC_DEFUN([gl_CHECK_ALL_HEADERS],
 185 [
 186   AC_CHECK_HEADERS_ONCE( \
 187     hurd.h \
 188     paths.h \
 189     priv.h \
 190     stropts.h \
 191     sys/ioctl.h \
 192     sys/param.h \
 193     sys/resource.h \
 194     sys/statvfs.h \
 195     sys/systeminfo.h \
 196     sys/time.h \
 197     sys/vfs.h \
 198     sys/wait.h \
 199     syslog.h \
 200     termios.h \
 201   )
 202   AC_CHECK_HEADERS(sys/mount.h sys/sysctl.h, [], [],
 203     [AC_INCLUDES_DEFAULT
 204      [#if HAVE_SYS_PARAM_H
 205        #include <sys/param.h>
 206       #endif]])
 207 ])
 208
 209 # This macro must be invoked before any tests that run the compiler.
 210 AC_DEFUN([gl_CHECK_ALL_TYPES],
 211 [
 212   dnl This test must come as early as possible after the compiler configuration
 213   dnl tests, because the choice of the file model can (in principle) affect
 214   dnl whether functions and headers are available, whether they work, etc.
 215   AC_REQUIRE([AC_SYS_LARGEFILE])
 216
 217   dnl This test must precede tests of compiler characteristics like
 218   dnl that for the inline keyword, since it may change the degree to
 219   dnl which the compiler supports such features.
 220   AC_REQUIRE([AM_C_PROTOTYPES])
 221
 222   dnl Checks for typedefs, structures, and compiler characteristics.
 223   AC_REQUIRE([AC_C_BIGENDIAN])
 224   AC_REQUIRE([AC_C_CONST])
 225   AC_REQUIRE([AC_C_VOLATILE])
 226   AC_REQUIRE([AC_C_INLINE])
 227   AC_REQUIRE([AC_C_LONG_DOUBLE])
 228
 229   AC_REQUIRE([gl_CHECK_ALL_HEADERS])
 230   AC_REQUIRE([AC_HEADER_DIRENT])
 231   AC_REQUIRE([AC_HEADER_STDC])
 232   AC_CHECK_MEMBERS(
 233     [struct stat.st_author,
 234      struct stat.st_blksize],,,
 235     [$ac_includes_default
 236 #include <sys/stat.h>
 237   ])
 238   AC_REQUIRE([AC_STRUCT_ST_BLOCKS])
 239
 240   AC_REQUIRE([AC_STRUCT_ST_DM_MODE])
 241
 242   AC_REQUIRE([AC_TYPE_GETGROUPS])
 243   AC_REQUIRE([AC_TYPE_MBSTATE_T])
 244   AC_REQUIRE([AC_TYPE_MODE_T])
 245   AC_REQUIRE([AC_TYPE_OFF_T])
 246   AC_REQUIRE([AC_TYPE_PID_T])
 247   AC_REQUIRE([AC_TYPE_SIZE_T])
 248   AC_REQUIRE([AC_TYPE_UID_T])
 249   AC_CHECK_TYPE(ino_t, unsigned long int)
 250
 251   gt_TYPE_SSIZE_T
 252
 253   dnl This relies on the fact that autoconf 2.14a's implementation of
 254   dnl AC_CHECK_TYPE checks includes unistd.h.
 255   AC_CHECK_TYPE(major_t, unsigned int)
 256   AC_CHECK_TYPE(minor_t, unsigned int)
 257
 258   AC_REQUIRE([gl_AC_TYPE_UINT32_T])
 259   AC_REQUIRE([gl_AC_TYPE_UINTMAX_T])
 260   AC_REQUIRE([gl_AC_TYPE_UINTPTR_T])
 261   AC_REQUIRE([gl_AC_TYPE_UNSIGNED_LONG_LONG])
 262
 263   AC_REQUIRE([AC_HEADER_MAJOR])
 264   AC_REQUIRE([AC_HEADER_DIRENT])
 265
 266 ])