m4/init.m4

   1 # Do all the work for Automake.                             -*- Autoconf -*-
   2
   3 # Copyright (C) 1996-2012 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # serial 19
  10
  11 # This macro actually does too much.  Some checks are only needed if
  12 # your package does certain things.  But this isn't really a big deal.
  13
  14 # AM_INIT_AUTOMAKE(PACKAGE, VERSION, [NO-DEFINE])
  15 # AM_INIT_AUTOMAKE([OPTIONS])
  16 # -----------------------------------------------
  17 # The call with PACKAGE and VERSION arguments is the old style
  18 # call (pre autoconf-2.50), which is being phased out.  PACKAGE
  19 # and VERSION should now be passed to AC_INIT and removed from
  20 # the call to AM_INIT_AUTOMAKE.
  21 # We support both call styles for the transition.  After
  22 # the next Automake release, Autoconf can make the AC_INIT
  23 # arguments mandatory, and then we can depend on a new Autoconf
  24 # release and drop the old call support.
  25 AC_DEFUN([AM_INIT_AUTOMAKE],
  26 [AC_PREREQ([2.62])dnl
  27 dnl Autoconf wants to disallow AM_ names.  We explicitly allow
  28 dnl the ones we care about.
  29 m4_pattern_allow([^AM_[A-Z]+FLAGS$])dnl
  30 AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
  31 AC_REQUIRE([AC_PROG_INSTALL])dnl
  32 if test "`cd $srcdir && pwd`" != "`pwd`"; then
  33   # Use -I$(srcdir) only when $(srcdir) != ., so that make's output
  34   # is not polluted with repeated "-I."
  35   AC_SUBST([am__isrc], [' -I$(srcdir)'])_AM_SUBST_NOTMAKE([am__isrc])dnl
  36   # test to see if srcdir already configured
  37   if test -f $srcdir/config.status; then
  38     AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
  39   fi
  40 fi
  41
  42 # test whether we have cygpath
  43 if test -z "$CYGPATH_W"; then
  44   if (cygpath --version) >/dev/null 2>/dev/null; then
  45     CYGPATH_W='cygpath -w'
  46   else
  47     CYGPATH_W=echo
  48   fi
  49 fi
  50 AC_SUBST([CYGPATH_W])
  51
  52 # Define the identity of the package.
  53 dnl Distinguish between old-style and new-style calls.
  54 m4_ifval([$2],
  55 [m4_ifval([$3], [_AM_SET_OPTION([no-define])])dnl
  56  AC_SUBST([PACKAGE], [$1])dnl
  57  AC_SUBST([VERSION], [$2])],
  58 [_AM_SET_OPTIONS([$1])dnl
  59 dnl Diagnose old-style AC_INIT with new-style AM_AUTOMAKE_INIT.
  60 m4_if(
  61   m4_ifdef([AC_PACKAGE_NAME], [ok]):m4_ifdef([AC_PACKAGE_VERSION], [ok]),
  62   [ok:ok],,
  63   [m4_fatal([AC_INIT should be called with package and version arguments])])dnl
  64  AC_SUBST([PACKAGE], ['AC_PACKAGE_TARNAME'])dnl
  65  AC_SUBST([VERSION], ['AC_PACKAGE_VERSION'])])dnl
  66
  67 _AM_IF_OPTION([no-define],,
  68 [AC_DEFINE_UNQUOTED([PACKAGE], ["$PACKAGE"], [Name of package])
  69  AC_DEFINE_UNQUOTED([VERSION], ["$VERSION"], [Version number of package])])dnl
  70
  71 # Some tools Automake needs.
  72 AC_REQUIRE([AM_SANITY_CHECK])dnl
  73 AC_REQUIRE([AC_ARG_PROGRAM])dnl
  74 AM_MISSING_PROG([ACLOCAL], [aclocal-${am__api_version}])
  75 AM_MISSING_PROG([AUTOCONF], [autoconf])
  76 AM_MISSING_PROG([AUTOMAKE], [automake-${am__api_version}])
  77 AM_MISSING_PROG([AUTOHEADER], [autoheader])
  78 AM_MISSING_PROG([MAKEINFO], [makeinfo])
  79 AC_REQUIRE([AM_PROG_INSTALL_SH])dnl
  80 AC_REQUIRE([AM_PROG_INSTALL_STRIP])dnl
  81 AC_REQUIRE([AC_PROG_MKDIR_P])dnl
  82 # We need awk for the "check" target.  The system "awk" is bad on
  83 # some platforms.
  84 AC_REQUIRE([AC_PROG_AWK])dnl
  85 AC_REQUIRE([AC_PROG_MAKE_SET])dnl
  86 AC_REQUIRE([AM_SET_LEADING_DOT])dnl
  87 _AM_IF_OPTION([tar-ustar], [_AM_PROG_TAR([ustar])],
  88               [_AM_IF_OPTION([tar-pax], [_AM_PROG_TAR([pax])],
  89                              [_AM_PROG_TAR([v7])])])
  90 _AM_IF_OPTION([no-dependencies],,
  91 [AC_PROVIDE_IFELSE([AC_PROG_CC],
  92                   [_AM_DEPENDENCIES([CC])],
  93                   [m4_define([AC_PROG_CC],
  94                              m4_defn([AC_PROG_CC])[_AM_DEPENDENCIES([CC])])])dnl
  95 AC_PROVIDE_IFELSE([AC_PROG_CXX],
  96                   [_AM_DEPENDENCIES([CXX])],
  97                   [m4_define([AC_PROG_CXX],
  98                              m4_defn([AC_PROG_CXX])[_AM_DEPENDENCIES([CXX])])])dnl
  99 AC_PROVIDE_IFELSE([AC_PROG_OBJC],
 100                   [_AM_DEPENDENCIES([OBJC])],
 101                   [m4_define([AC_PROG_OBJC],
 102                              m4_defn([AC_PROG_OBJC])[_AM_DEPENDENCIES([OBJC])])])dnl
 103 dnl Support for Objective C++ was only introduced in Autoconf 2.65,
 104 dnl but we still cater to Autoconf 2.62.
 105 m4_ifdef([AC_PROG_OBJCXX],
 106 [AC_PROVIDE_IFELSE([AC_PROG_OBJCXX],
 107                   [_AM_DEPENDENCIES([OBJCXX])],
 108                   [m4_define([AC_PROG_OBJCXX],
 109                              m4_defn([AC_PROG_OBJCXX])[_AM_DEPENDENCIES([OBJCXX])])])])dnl
 110 ])
 111 _AM_IF_OPTION([silent-rules], [AC_REQUIRE([AM_SILENT_RULES])])dnl
 112 dnl The 'parallel-tests' driver may need to know about EXEEXT, so add the
 113 dnl 'am__EXEEXT' conditional if _AM_COMPILER_EXEEXT was seen.  This macro
 114 dnl is hooked onto _AC_COMPILER_EXEEXT early, see below.
 115 AC_CONFIG_COMMANDS_PRE(dnl
 116 [m4_provide_if([_AM_COMPILER_EXEEXT],
 117   [AM_CONDITIONAL([am__EXEEXT], [test -n "$EXEEXT"])])])dnl
 118 ])
 119
 120 dnl Hook into '_AC_COMPILER_EXEEXT' early to learn its expansion.  Do not
 121 dnl add the conditional right here, as _AC_COMPILER_EXEEXT may be further
 122 dnl mangled by Autoconf and run in a shell conditional statement.
 123 m4_define([_AC_COMPILER_EXEEXT],
 124 m4_defn([_AC_COMPILER_EXEEXT])[m4_provide([_AM_COMPILER_EXEEXT])])
 125
 126
 127 # When config.status generates a header, we must update the stamp-h file.
 128 # This file resides in the same directory as the config header
 129 # that is generated.  The stamp files are numbered to have different names.
 130
 131 # Autoconf calls _AC_AM_CONFIG_HEADER_HOOK (when defined) in the
 132 # loop where config.status creates the headers, so we can generate
 133 # our stamp files there.
 134 AC_DEFUN([_AC_AM_CONFIG_HEADER_HOOK],
 135 [# Compute $1's index in $config_headers.
 136 _am_arg=$1
 137 _am_stamp_count=1
 138 for _am_header in $config_headers :; do
 139   case $_am_header in
 140     $_am_arg | $_am_arg:* )
 141       break ;;
 142     * )
 143       _am_stamp_count=`expr $_am_stamp_count + 1` ;;
 144   esac
 145 done
 146 echo "timestamp for $_am_arg" >`AS_DIRNAME(["$_am_arg"])`/stamp-h[]$_am_stamp_count])