m4/init.m4

   1 # Do all the work for Automake.  This macro actually does too much --
   2 # some checks are only needed if your package does certain things.
   3 # But this isn't really a big deal.
   4
   5 # serial 1
   6
   7 dnl Usage:
   8 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
   9
  10 AC_DEFUN(AM_INIT_AUTOMAKE,
  11 [AC_REQUIRE([AC_PROG_INSTALL])
  12 dnl We require 2.13 because we rely on SHELL being computed by configure.
  13 AC_PREREQ([2.13])
  14 PACKAGE=[$1]
  15 AC_SUBST(PACKAGE)
  16 VERSION=[$2]
  17 AC_SUBST(VERSION)
  18 dnl test to see if srcdir already configured
  19 if test "`CDPATH=: && cd $srcdir && pwd`" != "`pwd`" &&
  20    test -f $srcdir/config.status; then
  21   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
  22 fi
  23 ifelse([$3],,
  24 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
  25 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
  26 AC_REQUIRE([AM_SANITY_CHECK])
  27 AC_REQUIRE([AC_ARG_PROGRAM])
  28 AM_MISSING_PROG(ACLOCAL, aclocal)
  29 AM_MISSING_PROG(AUTOCONF, autoconf)
  30 AM_MISSING_PROG(AUTOMAKE, automake)
  31 AM_MISSING_PROG(AUTOHEADER, autoheader)
  32 AM_MISSING_PROG(MAKEINFO, makeinfo)
  33 AM_MISSING_PROG(AMTAR, tar)
  34 AM_MISSING_INSTALL_SH(install_sh)
  35 dnl We need awk for the "check" target.  The system "awk" is bad on
  36 dnl some platforms.
  37 AC_REQUIRE([AC_PROG_AWK])
  38 AC_REQUIRE([AC_PROG_MAKE_SET])
  39 AC_REQUIRE([AM_DEP_TRACK])
  40 AC_REQUIRE([AM_SET_DEPDIR])
  41 ifdef([AC_PROVIDE_AC_PROG_CC], [AM_DEPENDENCIES(CC)], [
  42    define([AC_PROG_CC], defn([AC_PROG_CC])[AM_DEPENDENCIES(CC)])])
  43 ifdef([AC_PROVIDE_AC_PROG_CXX], [AM_DEPENDENCIES(CXX)], [
  44    define([AC_PROG_CXX], defn([AC_PROG_CXX])[AM_DEPENDENCIES(CXX)])])
  45 ])