m4/evas_scaler.m4

   1 dnl Copyright (C) 2009 Vincent Torri <vtorri at univ-evry dot fr>
   2 dnl That code is public domain and can be freely used or copied.
   3
   4 dnl Macro that enables scaler support is wanted.
   5
   6 dnl Usage: EVAS_CHECK_SCALER(scaler, description [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
   7 dnl The parameter 'scaler' is the type of scaler.
   8 dnl The parameter 'description' is the description of the scaler.
   9 dnl Defines BUILD_[TYPEOFSCALER]
  10
  11 AC_DEFUN([EVAS_CHECK_SCALER],
  12 [
  13 m4_pushdef([UP], m4_translit([$1], [-a-z], [_A-Z]))dnl
  14 m4_pushdef([DOWN], m4_translit([$1], [-A-Z], [_a-z]))dnl
  15
  16 AC_ARG_ENABLE([$1],
  17    AC_HELP_STRING([--disable-$1], [disable $2 code @<:@default=enabled@:>@]),
  18    [
  19     if test "x${enableval}" = "xyes" ; then
  20        _efl_enable_scaler_option_[]DOWN="yes"
  21     else
  22        _efl_enable_scaler_option_[]DOWN="no"
  23     fi
  24    ],
  25    [_efl_enable_scaler_option_[]DOWN="yes"])
  26
  27 AC_MSG_CHECKING(whether to build $2)
  28 AC_MSG_RESULT([${_efl_enable_scaler_option_[]DOWN}])
  29
  30 if test "x${_efl_enable_scaler_option_[]DOWN}" = "xyes" ; then
  31    AC_DEFINE([BUILD_]UP[], [1], [define to 1 if you have the $2 support])
  32 fi
  33
  34 if test "x${_efl_enable_scaler_option_[]DOWN}" = "xyes" ; then
  35    m4_default([$3], [:])
  36 else
  37    m4_default([$4], [:])
  38 fi
  39
  40 m4_popdef([UP])
  41 m4_popdef([DOWN])
  42 ])
  43
  44 dnl End of evas_scaler.m4