m4/evas_dither.m4

   1 dnl Copyright (C) 2009 Vincent Torri <vtorri at univ-evry dot fr>
   2 dnl That code is public domain and can be freely used or copied.
   3
   4 dnl Macro that enables dithering support is wanted.
   5
   6 dnl Usage: EVAS_CHECK_DITHER(dither, description [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
   7 dnl The parameter 'dither' is the type of dithering.
   8 dnl The parameter 'description' is the description of the dithering.
   9 dnl Defines BUILD_[TYPEOFDITHERING]
  10
  11 AC_DEFUN([EVAS_CHECK_DITHER],
  12 [
  13 m4_pushdef([UP], m4_translit([$1], [-a-z], [_A-Z]))dnl
  14 m4_pushdef([DOWN], m4_translit([$1], [-A-Z], [_a-z]))dnl
  15
  16 AC_ARG_ENABLE([$1],
  17    AC_HELP_STRING([--enable-$1], [enable $2 @<:@default=disabled@:>@]),
  18    [
  19     if test "x${enableval}" = "xyes" ; then
  20        _efl_enable_dither_option_[]DOWN="yes"
  21     else
  22        _efl_enable_dither_option_[]DOWN="no"
  23     fi
  24    ],
  25    [_efl_enable_dither_option_[]DOWN="no"])
  26
  27 AC_MSG_CHECKING(whether to build $2)
  28 AC_MSG_RESULT([${_efl_enable_dither_option_[]DOWN}])
  29
  30 if test "x${_efl_enable_dither_option_[]DOWN}" = "xyes" ; then
  31    AC_DEFINE([BUILD_]UP[], [1], [define to 1 if you have the $2 support])
  32 fi
  33
  34 if test "x${_efl_enable_dither_option_[]DOWN}" = "xyes" ; then
  35    m4_default([$3], [:])
  36 else
  37    m4_default([$4], [:])
  38 fi
  39
  40 m4_popdef([UP])
  41 m4_popdef([DOWN])
  42 ])
  43
  44 dnl End of evas_dither.m4