m4/evas_check_engine.m4

   1
   2 dnl use: EVAS_CHECK_ENGINE_DEP_BUFFER(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   3
   4 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_BUFFER],
   5 [
   6
   7 have_dep="yes"
   8 evas_engine_[]$1[]_cflags=""
   9 evas_engine_[]$1[]_libs=""
  10
  11 AC_SUBST([evas_engine_$1_cflags])
  12 AC_SUBST([evas_engine_$1_libs])
  13
  14 if test "x${have_dep}" = "xyes" ; then
  15   m4_default([$4], [:])
  16 else
  17   m4_default([$5], [:])
  18 fi
  19
  20 ])
  21
  22 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_XLIB(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  23
  24 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_XLIB],
  25 [
  26
  27 have_dep="no"
  28 evas_engine_[]$1[]_cflags=""
  29 evas_engine_[]$1[]_libs=""
  30
  31 AC_PATH_X
  32 AC_PATH_XTRA
  33
  34 AC_CHECK_HEADER([X11/X.h], [have_dep="yes"])
  35
  36 if test "x${have_dep}" = "xyes" ; then
  37    AC_CHECK_LIB([X11], [XCreateImage], [have_dep="yes"], [have_dep="no"])
  38 fi
  39
  40 if test "x${have_dep}" = "xyes" ; then
  41    AC_CHECK_LIB([Xext], [XShmCreateImage], [have_dep="yes"], [have_dep="no"])
  42 fi
  43
  44 if test "x${have_dep}" = "xyes" ; then
  45    if test "x$2" = "xyes" ; then
  46       x_libs="${x_libs} -lX11 -lXext"
  47    else
  48       x_dir=${x_dir:-/usr/X11R6}
  49       x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
  50       x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
  51    fi
  52    evas_engine_[]$1[]_cflags="${x_cflags}"
  53    evas_engine_[]$1[]_libs="${x_libs}"
  54 fi
  55
  56 AC_SUBST([evas_engine_$1_cflags])
  57 AC_SUBST([evas_engine_$1_libs])
  58
  59 if test "x${have_dep}" = "xyes" ; then
  60   m4_default([$4], [:])
  61 else
  62   m4_default([$5], [:])
  63 fi
  64
  65 ])
  66
  67 dnl use: EVAS_CHECK_ENGINE_DEP_GL_XLIB(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
  68
  69 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_GL_XLIB],
  70 [
  71
  72 evas_engine_[]$1[]_cflags=""
  73 evas_engine_[]$1[]_libs=""
  74
  75 AC_PATH_X
  76 AC_PATH_XTRA
  77
  78 AC_CHECK_HEADER([GL/gl.h],
  79    [have_dep="yes"],
  80    [have_dep="no"],
  81    [
  82 #include <GL/gl.h>
  83 #include <GL/glext.h>
  84 #include <GL/glx.h>
  85 #include <X11/Xlib.h>
  86 #include <X11/Xatom.h>
  87 #include <X11/Xutil.h>
  88 #include <X11/extensions/Xrender.h>
  89 #include <X11/Xresource.h>
  90    ])
  91
  92 gl_pt_lib="";
  93 have_gl_pt="no"
  94 AC_CHECK_LIB([pthread], [pthread_create], [have_gl_pt="yes"], [have_gl_pt="no"])
  95 if test "x$have_gl_pt" = "xyes" ; then
  96    gl_pt_lib=" -lpthread"
  97 fi
  98
  99 if test "x${have_dep}" = "xyes" ; then
 100    AC_CHECK_LIB([X11], [XCreateColormap], [have_dep="yes"], [have_dep="no"])
 101 fi
 102
 103 if test "x${have_dep}" = "xyes" ; then
 104    AC_CHECK_LIB([Xrender], [XRenderCreatePicture], [have_dep="yes"], [have_dep="no"])
 105 fi
 106
 107 if test "x${have_dep}" = "xyes" ; then
 108    AC_CHECK_LIB([GL], [glXCreateContext], [have_dep="yes"], [have_dep="no"], -lX11 -lXext -lXrender -lm $gl_pt_lib)
 109 fi
 110
 111 if test "x$gl_flavor_gles" = "xyes" ; then
 112   have_dep=no
 113 fi
 114
 115 if test "x${have_dep}" = "xyes" ; then
 116    PKG_CHECK_MODULES([GL_EET], [eet >= 1.4.0], [have_dep="yes"], [have_dep="no"])
 117    if test "x${have_dep}" = "xyes" ; then
 118       if test "x$2" = "xyes" ; then
 119          x_libs="${x_libs} -lX11 -lXext -lXrender"
 120       else
 121          x_dir=${x_dir:-/usr/X11R6}
 122          x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 123          x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext -lXrender"
 124       fi
 125    evas_engine_[]$1[]_cflags="-I/usr/include ${x_cflags}"
 126    evas_engine_[]$1[]_libs="${x_libs} -lGL $gl_pt_lib"
 127    evas_engine_gl_common_libs="-lGL $gl_pt_lib"
 128    fi
 129 else
 130    if test "x$2" = "xyes" ; then
 131       x_libs="${x_libs} -lX11 -lXext -lXrender"
 132    else
 133       x_dir=${x_dir:-/usr/X11R6}
 134       x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 135       x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext -lXrender"
 136    fi
 137    AC_CHECK_HEADER([GLES2/gl2.h],
 138       [have_egl="yes"],
 139       [have_egl="no"],
 140       [
 141 #include <GLES2/gl2.h>
 142 #include <GLES2/gl2ext.h>
 143 #include <EGL/egl.h>
 144 #include <X11/Xlib.h>
 145 #include <X11/Xatom.h>
 146 #include <X11/Xutil.h>
 147 #include <X11/extensions/Xrender.h>
 148 #include <X11/Xresource.h>
 149       ])
 150    if test "x${have_egl}" = "xyes" ; then
 151       AC_CHECK_LIB(GLESv2, glTexImage2D, [have_glesv2="yes"], , -lEGL ${x_libs} -lm $gl_pt_lib)
 152       if test "x${have_glesv2}" = "xyes" ; then
 153          PKG_CHECK_MODULES([GL_EET], [eet >= 1.4.0], [have_dep="yes"], [have_dep="no"])
 154          if test "x${have_dep}" = "xyes" ; then
 155             evas_engine_[]$1[]_cflags="${x_cflags}"
 156             evas_engine_[]$1[]_libs="${x_libs} -lGLESv2 -lEGL -lm $gl_pt_lib"
 157             evas_engine_gl_common_libs="-lGLESv2 -lm $gl_pt_lib"
 158             have_dep="yes"
 159             gl_flavor_gles="no"
 160             AC_DEFINE(GLES_VARIETY_SGX, 1, [Imagination SGX GLES2 support])
 161             gles_variety_sgx="yes"
 162          fi
 163       fi
 164    fi
 165 fi
 166
 167 AC_SUBST([evas_engine_$1_cflags])
 168 AC_SUBST([evas_engine_$1_libs])
 169
 170
 171 if test "x${have_dep}" = "xyes" ; then
 172   m4_default([$4], [:])
 173 else
 174   m4_default([$5], [:])
 175 fi
 176
 177 ])
 178
 179 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_XCB(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 180
 181 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_XCB],
 182 [
 183
 184 requirement=""
 185 have_dep="no"
 186 evas_engine_[]$1[]_cflags=""
 187 evas_engine_[]$1[]_libs=""
 188
 189 PKG_CHECK_MODULES([XCB],
 190    [xcb xcb-shm xcb-image >= 0.2.1 pixman-1],
 191    [
 192     have_dep="yes"
 193     requirement="xcb xcb-shm xcb-image pixman-1"
 194     evas_engine_[]$1[]_cflags="${XCB_CFLAGS}"
 195     evas_engine_[]$1[]_libs="${XCB_LIBS}"
 196    ],[
 197     have_dep="no"
 198    ]
 199 )
 200
 201 AC_SUBST([evas_engine_$1_cflags])
 202 AC_SUBST([evas_engine_$1_libs])
 203
 204 if test "x$3" = "xstatic" ; then
 205    requirement_evas="${requirement} ${requirement_evas}"
 206 fi
 207
 208 if test "x${have_dep}" = "xyes" ; then
 209   m4_default([$4], [:])
 210 else
 211   m4_default([$5], [:])
 212 fi
 213
 214 ])
 215
 216
 217 dnl use: EVAS_CHECK_ENGINE_DEP_GL_XCB(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 218
 219 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_GL_XCB],
 220 [
 221
 222 evas_engine_[]$1[]_cflags=""
 223 evas_engine_[]$1[]_libs=""
 224
 225 AC_PATH_X
 226 AC_PATH_XTRA
 227
 228 AC_CHECK_HEADER([GL/gl.h],
 229    [have_dep="yes"],
 230    [have_dep="no"],
 231    [
 232 #include <GL/gl.h>
 233 #include <GL/glext.h>
 234 #include <GL/glx.h>
 235    ])
 236
 237 gl_pt_lib="";
 238 have_gl_pt="no"
 239 AC_CHECK_LIB([pthread], [pthread_create], [have_gl_pt="yes"], [have_gl_pt="no"])
 240 if test "x$have_gl_pt" = "xyes" ; then
 241    gl_pt_lib=" -lpthread"
 242 fi
 243
 244 if test "x${have_dep}" = "xyes" ; then
 245    AC_CHECK_LIB([X11], [XCreateColormap], [have_dep="yes"], [have_dep="no"])
 246 fi
 247
 248 if test "x${have_dep}" = "xyes" ; then
 249    AC_CHECK_LIB([Xrender], [XRenderCreatePicture], [have_dep="yes"], [have_dep="no"])
 250 fi
 251
 252 if test "x${have_dep}" = "xyes" ; then
 253    AC_CHECK_LIB([GL], [glXCreateContext], [have_dep="yes"], [have_dep="no"], -lX11 -lXext -lXrender -lm $gl_pt_lib)
 254 fi
 255
 256 PKG_CHECK_MODULES([XCB_GL],
 257    [x11-xcb xcb xcb-glx xcb-render xcb-renderutil],
 258    [
 259     have_dep="yes"
 260     requirement="x11-xcb xcb xcb-glx xcb-render xcb-renderutil"
 261     evas_engine_[]$1[]_cflags="${XCB_GL_CFLAGS}"
 262     evas_engine_[]$1[]_libs="${XCB_GL_LIBS}"
 263    ],[
 264     have_dep="no"
 265    ]
 266 )
 267
 268 if test "x$gl_flavor_gles" = "xyes" ; then
 269   have_dep=no
 270 fi
 271
 272 if test "x${have_dep}" = "xyes" ; then
 273    PKG_CHECK_MODULES([GL_EET], [eet >= 1.4.0], [have_dep="yes"], [have_dep="no"])
 274    if test "x${have_dep}" = "xyes" ; then
 275       if test "x$2" = "xyes" ; then
 276          x_libs="${x_libs} -lX11 -lXext -lXrender"
 277       else
 278          x_dir=${x_dir:-/usr/X11R6}
 279          x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 280          x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext -lXrender"
 281       fi
 282    evas_engine_[]$1[]_cflags="-I/usr/include ${XCB_GL_CFLAGS} ${x_cflags}"
 283    evas_engine_[]$1[]_libs="${XCB_GL_LIBS} ${x_libs} -lGL $gl_pt_lib"
 284    evas_engine_gl_common_libs="-lGL $gl_pt_lib"
 285    fi
 286 else
 287    if test "x$2" = "xyes" ; then
 288       x_libs="${x_libs} -lX11 -lXext -lXrender"
 289    else
 290       x_dir=${x_dir:-/usr/X11R6}
 291       x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 292       x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext -lXrender"
 293    fi
 294    AC_CHECK_HEADER([GLES2/gl2.h],
 295       [have_egl="yes"],
 296       [have_egl="no"],
 297       [
 298 #include <GLES2/gl2.h>
 299 #include <GLES2/gl2ext.h>
 300 #include <EGL/egl.h>
 301       ])
 302    if test "x${have_egl}" = "xyes" ; then
 303       AC_CHECK_LIB(GLESv2, glTexImage2D, [have_glesv2="yes"], , -lEGL ${x_libs} -lm $gl_pt_lib)
 304       if test "x${have_glesv2}" = "xyes" ; then
 305          PKG_CHECK_MODULES([GL_EET], [eet >= 1.4.0], [have_dep="yes"], [have_dep="no"])
 306          if test "x${have_dep}" = "xyes" ; then
 307             evas_engine_[]$1[]_cflags="${XCB_GL_CFLAGS} ${x_cflags}"
 308             evas_engine_[]$1[]_libs="${XCB_GL_LIBS} ${x_libs} -lGLESv2 -lEGL -lm $gl_pt_lib"
 309             evas_engine_gl_common_libs="-lGLESv2 -lm $gl_pt_lib"
 310             have_dep="yes"
 311             gl_flavor_gles="no"
 312             AC_DEFINE(GLES_VARIETY_SGX, 1, [Imagination SGX GLES2 support])
 313             gles_variety_sgx="yes"
 314          fi
 315       fi
 316    fi
 317 fi
 318
 319 AC_SUBST([evas_engine_$1_cflags])
 320 AC_SUBST([evas_engine_$1_libs])
 321
 322 if test "x${have_dep}" = "xyes" ; then
 323   m4_default([$4], [:])
 324 else
 325   m4_default([$5], [:])
 326 fi
 327
 328 ])
 329
 330
 331
 332
 333 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_GDI(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 334
 335 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_GDI],
 336 [
 337
 338 have_dep="no"
 339 evas_engine_[]$1[]_cflags=""
 340 evas_engine_[]$1[]_libs=""
 341
 342 AC_CHECK_HEADER([windows.h],
 343    [
 344     have_dep="yes"
 345     evas_engine_[]$1[]_libs="-lgdi32"
 346    ]
 347 )
 348
 349 AC_SUBST([evas_engine_$1_cflags])
 350 AC_SUBST([evas_engine_$1_libs])
 351
 352 if test "x${have_dep}" = "xyes" ; then
 353   m4_default([$4], [:])
 354 else
 355   m4_default([$5], [:])
 356 fi
 357
 358 ])
 359
 360 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_DDRAW(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 361
 362 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_DDRAW],
 363 [
 364
 365 have_dep="no"
 366 evas_engine_[]$1[]_cflags=""
 367 evas_engine_[]$1[]_libs=""
 368
 369 AC_CHECK_HEADER([ddraw.h],
 370    [
 371     have_dep="yes"
 372     evas_engine_[]$1[]_libs="-lddraw"
 373    ]
 374 )
 375
 376 AC_SUBST([evas_engine_$1_cflags])
 377 AC_SUBST([evas_engine_$1_libs])
 378
 379 if test "x${have_dep}" = "xyes" ; then
 380   m4_default([$4], [:])
 381 else
 382   m4_default([$5], [:])
 383 fi
 384
 385 ])
 386
 387 dnl use: EVAS_CHECK_ENGINE_DEP_DIRECT3D(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 388
 389 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_DIRECT3D],
 390 [
 391
 392 evas_engine_[]$1[]_cflags=""
 393 evas_engine_[]$1[]_libs=""
 394
 395 AC_CHECK_HEADERS([d3d9.h d3dx9.h],
 396    [
 397     have_dep="yes"
 398     evas_engine_[]$1[]_libs="-ld3d9 -ld3dx9 -lgdi32"
 399    ],
 400    [have_dep="no"; break]
 401 )
 402
 403 AC_SUBST([evas_engine_$1_cflags])
 404 AC_SUBST([evas_engine_$1_libs])
 405
 406 if test "x${have_dep}" = "xyes" ; then
 407   m4_default([$4], [:])
 408 else
 409   m4_default([$5], [:])
 410 fi
 411
 412 ])
 413
 414 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_SDL(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 415
 416 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_SDL],
 417 [
 418
 419 requirement=""
 420 have_dep="no"
 421 evas_engine_[]$1[]_cflags=""
 422 evas_engine_[]$1[]_libs=""
 423
 424 PKG_CHECK_MODULES([SDL],
 425    [sdl >= 1.2.0],
 426    [
 427     have_dep="yes"
 428     requirement="sdl"
 429     evas_engine_[]$1[]_cflags="${SDL_CFLAGS}"
 430     evas_engine_[]$1[]_libs="${SDL_LIBS}"
 431    ]
 432 )
 433
 434 AC_SUBST([evas_engine_$1_cflags])
 435 AC_SUBST([evas_engine_$1_libs])
 436
 437 if test "x$3" = "xstatic" ; then
 438    requirement_evas="${requirement} ${requirement_evas}"
 439 fi
 440
 441 if test "x${have_dep}" = "xyes" ; then
 442   m4_default([$4], [:])
 443 else
 444   m4_default([$5], [:])
 445 fi
 446
 447 ])
 448
 449
 450 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_SDL(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 451
 452 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_SDL],
 453 [
 454
 455 requirement=""
 456 have_dep="no"
 457 evas_engine_[]$1[]_cflags=""
 458 evas_engine_[]$1[]_libs=""
 459
 460 PKG_CHECK_MODULES([SDL],
 461    [sdl >= 1.2.0],
 462    [
 463     have_dep="yes"
 464     requirement="sdl"
 465     evas_engine_[]$1[]_cflags="${SDL_CFLAGS}"
 466     evas_engine_[]$1[]_libs="${SDL_LIBS}"
 467    ]
 468 )
 469
 470 AC_SUBST([evas_engine_$1_cflags])
 471 AC_SUBST([evas_engine_$1_libs])
 472
 473 if test "x$3" = "xstatic" ; then
 474    requirement_evas="${requirement} ${requirement_evas}"
 475 fi
 476
 477 if test "x${have_dep}" = "xyes" ; then
 478   m4_default([$4], [:])
 479 else
 480   m4_default([$5], [:])
 481 fi
 482
 483 ])
 484
 485 dnl use: EVAS_CHECK_ENGINE_DEP_GL_SDL(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 486
 487 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_GL_SDL],
 488 [
 489
 490 requirement=""
 491 have_dep="no"
 492 evas_engine_[]$1[]_cflags=""
 493 evas_engine_[]$1[]_libs=""
 494
 495 PKG_CHECK_MODULES([SDL],
 496    [sdl >= 1.2.0],
 497    [
 498     have_dep="yes"
 499     requirement="sdl"
 500     evas_engine_[]$1[]_cflags="${SDL_CFLAGS}"
 501     evas_engine_[]$1[]_libs="${SDL_LIBS}"
 502    ]
 503 )
 504
 505 gl_pt_lib="";
 506 have_gl_pt="no"
 507 AC_CHECK_LIB([pthread], [pthread_create], [have_gl_pt="yes"], [have_gl_pt="no"])
 508 if test "x$have_gl_pt" = "xyes" ; then
 509    gl_pt_lib=" -lpthread"
 510 fi
 511
 512 AC_CHECK_HEADER([GL/gl.h],
 513    [have_dep="yes"],
 514    [have_dep="no"],
 515    [
 516 #include <GL/gl.h>
 517 #include <GL/glext.h>
 518    ])
 519
 520 if test "x$gl_flavor_gles" = "xyes" ; then
 521   have_dep=no
 522 fi
 523
 524 if test "x${have_dep}" = "xyes" ; then
 525    evas_engine_[]$1[]_cflags="${SDL_CFLAGS}"
 526    evas_engine_[]$1[]_libs="${SDL_LIBS} -lGL -lm $gl_pt_lib"
 527    evas_engine_gl_common_libs="-lGL -lm $gl_pt_lib"
 528 else
 529    AC_CHECK_HEADER([SDL/SDL_opengles.h],
 530       [have_egl="yes"],
 531       [have_egl="no"],
 532       [
 533 #include <SDL/SDL_opengles.h>
 534 #include <EGL/egl.h>
 535       ])
 536    if test "x${have_egl}" = "xyes" ; then
 537       AC_CHECK_LIB(GLESv2, glTexImage2D, [have_glesv2="yes"], , -lEGL -lm $gl_pt_lib)
 538       if test "x${have_glesv2}" = "xyes" ; then
 539          evas_engine_[]$1[]_cflags="${SDL_CFLAGS}"
 540          evas_engine_[]$1[]_libs="${SDL_LIBS} -lGLESv2 -lEGL -lm $gl_pt_lib"
 541          evas_engine_gl_common_libs="-lGLESv2 -lm $gl_pt_lib"
 542          have_dep="yes"
 543          gl_flavor_gles="no"
 544          AC_DEFINE(GLES_VARIETY_SGX, 1, [Imagination SGX GLES2 support])
 545          gles_variety_sgx="yes"
 546       fi
 547    fi
 548 fi
 549
 550 AC_SUBST([evas_engine_$1_cflags])
 551 AC_SUBST([evas_engine_$1_libs])
 552
 553 if test "x$3" = "xstatic" ; then
 554    requirement_evas="${requirement} ${requirement_evas}"
 555 fi
 556
 557 if test "x${have_dep}" = "xyes" ; then
 558   m4_default([$4], [:])
 559 else
 560   m4_default([$5], [:])
 561 fi
 562
 563 ])
 564
 565 dnl use: EVAS_CHECK_ENGINE_DEP_FB(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 566
 567 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_FB],
 568 [
 569
 570 have_dep="no"
 571 evas_engine_[]$1[]_cflags=""
 572 evas_engine_[]$1[]_libs=""
 573
 574 AC_CHECK_HEADER([linux/fb.h], [have_dep="yes"])
 575
 576 AC_SUBST([evas_engine_$1_cflags])
 577 AC_SUBST([evas_engine_$1_libs])
 578
 579 if test "x${have_dep}" = "xyes" ; then
 580   m4_default([$4], [:])
 581 else
 582   m4_default([$5], [:])
 583 fi
 584
 585 ])
 586
 587 dnl use: EVAS_CHECK_ENGINE_DEP_DIRECTFB(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 588
 589 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_DIRECTFB],
 590 [
 591
 592 requirement=""
 593 have_dep="no"
 594 evas_engine_[]$1[]_cflags=""
 595 evas_engine_[]$1[]_libs=""
 596
 597 PKG_CHECK_MODULES([DIRECTFB],
 598    [directfb >= 0.9.16],
 599    [
 600     have_dep="yes"
 601     requirement="directfb"
 602     evas_engine_[]$1[]_cflags="${DIRECTFB_CFLAGS}"
 603     evas_engine_[]$1[]_libs="${DIRECTFB_LIBS}"
 604    ]
 605 )
 606
 607 AC_SUBST([evas_engine_$1_cflags])
 608 AC_SUBST([evas_engine_$1_libs])
 609
 610 if test "x$3" = "xstatic" ; then
 611    requirement_evas="${requirement} ${requirement_evas}"
 612 fi
 613
 614 if test "x${have_dep}" = "xyes" ; then
 615   m4_default([$4], [:])
 616 else
 617   m4_default([$5], [:])
 618 fi
 619
 620 ])
 621
 622 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_8_X11(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 623
 624 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_8_X11],
 625 [
 626
 627 have_dep="no"
 628 evas_engine_[]$1[]_cflags=""
 629 evas_engine_[]$1[]_libs=""
 630
 631 PKG_CHECK_MODULES([XCB],
 632    [xcb xcb-shm xcb-image >= 0.2.1 pixman-1],
 633    [
 634     have_dep="yes"
 635     requirement="xcb xcb-shm xcb-image pixman-1"
 636     evas_engine_[]$1[]_cflags="${XCB_CFLAGS}"
 637     evas_engine_[]$1[]_libs="${XCB_LIBS}"
 638    ],[
 639     have_dep="no"
 640    ]
 641 )
 642
 643 AC_SUBST([evas_engine_$1_cflags])
 644 AC_SUBST([evas_engine_$1_libs])
 645
 646 if test "x$3" = "xstatic" ; then
 647    requirement_evas="${requirement} ${requirement_evas}"
 648 fi
 649
 650 if test "x${have_dep}" = "xyes" ; then
 651   m4_default([$4], [:])
 652 else
 653   m4_default([$5], [:])
 654 fi
 655
 656 ])
 657
 658 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_X11(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 659 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_X11],
 660 [
 661
 662 have_dep="no"
 663 evas_engine_[]$1[]_cflags=""
 664 evas_engine_[]$1[]_libs=""
 665
 666 AC_PATH_X
 667 AC_PATH_XTRA
 668
 669 AC_CHECK_HEADER([X11/X.h], [have_dep="yes"])
 670
 671 if test "x${have_dep}" = "xyes" ; then
 672    AC_CHECK_LIB([X11], [XCreateImage], [have_dep="yes"], [have_dep="no"])
 673 fi
 674
 675 if test "x${have_dep}" = "xyes" ; then
 676    AC_CHECK_LIB([Xext], [XShmCreateImage], [have_dep="yes"], [have_dep="no"])
 677 fi
 678
 679 if test "x${have_dep}" = "xyes" ; then
 680    if test "x$2" = "xyes" ; then
 681       x_libs="${x_libs} -lX11 -lXext"
 682    else
 683       x_dir=${x_dir:-/usr/X11R6}
 684       x_cflags=${x_cflags:--I${x_includes:-$x_dir/include}}
 685       x_libs="${x_libs:--L${x_libraries:-$x_dir/lib}} -lX11 -lXext"
 686    fi
 687    evas_engine_[]$1[]_cflags="${x_cflags}"
 688    evas_engine_[]$1[]_libs="${x_libs}"
 689 fi
 690
 691 AC_SUBST([evas_engine_$1_cflags])
 692 AC_SUBST([evas_engine_$1_libs])
 693
 694 if test "x${have_dep}" = "xyes" ; then
 695   m4_default([$4], [:])
 696 else
 697   m4_default([$5], [:])
 698 fi
 699
 700 ])
 701
 702 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_DDRAW(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 703
 704 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_DDRAW],
 705 [
 706
 707 have_dep="no"
 708 evas_engine_[]$1[]_cflags=""
 709 evas_engine_[]$1[]_libs=""
 710
 711 AC_CHECK_HEADER([ddraw.h],
 712    [
 713     have_dep="yes"
 714     evas_engine_[]$1[]_libs="-lddraw -lgdi32"
 715    ]
 716 )
 717
 718 AC_SUBST([evas_engine_$1_cflags])
 719 AC_SUBST([evas_engine_$1_libs])
 720
 721 if test "x${have_dep}" = "xyes" ; then
 722   m4_default([$4], [:])
 723 else
 724   m4_default([$5], [:])
 725 fi
 726
 727 ])
 728
 729 dnl use: EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_WINCE(engine, simple, want_static[, ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
 730
 731 AC_DEFUN([EVAS_CHECK_ENGINE_DEP_SOFTWARE_16_WINCE],
 732 [
 733
 734 have_dep="yes"
 735 evas_engine_[]$1[]_cflags=""
 736 evas_engine_[]$1[]_libs=""
 737
 738 AC_SUBST([evas_engine_$1_cflags])
 739 AC_SUBST([evas_engine_$1_libs])
 740
 741 if test "x${have_dep}" = "xyes" ; then
 742   m4_default([$4], [:])
 743 else
 744   m4_default([$5], [:])
 745 fi
 746
 747 ])
 748
 749 dnl use: EVAS_CHECK_ENGINE(engine, want_engine, simple, description)
 750
 751
 752 AC_DEFUN([EVAS_CHECK_ENGINE],
 753 [
 754
 755 m4_pushdef([UP], m4_translit([$1], [-a-z], [_A-Z]))dnl
 756 m4_pushdef([DOWN], m4_translit([$1], [-A-Z], [_a-z]))dnl
 757
 758 want_engine="$2"
 759 want_static_engine="no"
 760 have_engine="no"
 761 have_evas_engine_[]DOWN="no"
 762
 763 AC_ARG_ENABLE([$1],
 764    [AC_HELP_STRING([--enable-$1], [enable $4 rendering backend])],
 765    [
 766     if test "x${enableval}" = "xyes" ; then
 767        want_engine="yes"
 768     else
 769        if test "x${enableval}" = "xstatic" ; then
 770           want_engine="static"
 771        else
 772           want_engine="no"
 773        fi
 774     fi
 775    ])
 776
 777 AC_MSG_CHECKING([whether to enable $4 rendering backend])
 778 AC_MSG_RESULT([${want_engine}])
 779
 780 if test "x${want_engine}" = "xyes" -o "x${want_engine}" = "xstatic" -o "x${want_engine}" = "xauto" ; then
 781    m4_default([EVAS_CHECK_ENGINE_DEP_]m4_defn([UP]))(DOWN, $3, ${want_engine}, [have_engine="yes"], [have_engine="no"])
 782 fi
 783
 784 if test "x${have_engine}" = "xno" -a "x${want_engine}" = "xyes" -a "x${use_strict}" = "xyes" ; then
 785    AC_MSG_ERROR([$4 dependencies not found (strict dependencies checking)])
 786 fi
 787
 788 AC_MSG_CHECKING([whether $4 rendering backend will be built])
 789 AC_MSG_RESULT([${have_engine}])
 790
 791 if test "x${have_engine}" = "xyes" ; then
 792    if test "x${want_engine}" = "xstatic" ; then
 793       have_evas_engine_[]DOWN="static"
 794       want_static_engine="yes"
 795    else
 796       have_evas_engine_[]DOWN="yes"
 797    fi
 798 fi
 799
 800 if test "x${have_engine}" = "xyes" ; then
 801    AC_DEFINE(BUILD_ENGINE_[]UP, [1], [$4 rendering backend])
 802 fi
 803
 804 AM_CONDITIONAL(BUILD_ENGINE_[]UP, [test "x${have_engine}" = "xyes"])
 805
 806 if test "x${want_static_engine}" = "xyes" ; then
 807    AC_DEFINE(EVAS_STATIC_BUILD_[]UP, [1], [Build $1 engine inside libevas])
 808    have_static_module="yes"
 809 fi
 810
 811 AM_CONDITIONAL(EVAS_STATIC_BUILD_[]UP, [test "x${want_static_engine}" = "xyes"])
 812
 813 m4_popdef([UP])
 814 m4_popdef([DOWN])
 815
 816 ])