m4/efl_doxygen.m4

   1 dnl Copyright (C) 2008 Vincent Torri <vtorri at univ-evry dot fr>
   2 dnl That code is public domain and can be freely used or copied.
   3
   4 dnl Macro that check if doxygen is available or not.
   5
   6 dnl EFL_CHECK_DOXYGEN([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
   7 dnl Test for the doxygen program
   8 dnl Defines efl_doxygen
   9 dnl Defines the automake conditionnal EFL_BUILD_DOC
  10 dnl
  11 AC_DEFUN([EFL_CHECK_DOXYGEN],
  12 [
  13
  14 dnl
  15 dnl Disable the build of the documentation
  16 dnl
  17 AC_ARG_ENABLE([doc],
  18    [AC_HELP_STRING(
  19        [--disable-doc],
  20        [Disable documentation build @<:@default=enabled@:>@])],
  21    [
  22     if test "x${enableval}" = "xyes" ; then
  23        efl_enable_doc="yes"
  24     else
  25        efl_enable_doc="no"
  26     fi
  27    ],
  28    [efl_enable_doc="yes"])
  29
  30 AC_MSG_CHECKING([whether to build documentation])
  31 AC_MSG_RESULT([${efl_enable_doc}])
  32
  33 if test "x${efl_enable_doc}" = "xyes" ; then
  34
  35 dnl
  36 dnl Specify the file name, without path
  37 dnl
  38
  39    efl_doxygen="doxygen"
  40
  41    AC_ARG_WITH([doxygen],
  42       [AC_HELP_STRING(
  43           [--with-doxygen=FILE],
  44           [doxygen program to use @<:@default=doxygen@:>@])],
  45 dnl
  46 dnl Check the given doxygen program.
  47 dnl
  48       [efl_doxygen=${withval}
  49        AC_CHECK_PROG([efl_have_doxygen],
  50           [${efl_doxygen}],
  51           [yes],
  52           [no])
  53        if test "x${efl_have_doxygen}" = "xno" ; then
  54           echo "WARNING:"
  55           echo "The doxygen program you specified:"
  56           echo "${efl_doxygen}"
  57           echo "was not found.  Please check the path and make sure "
  58           echo "the program exists and is executable."
  59           AC_MSG_WARN([no doxygen detected. Documentation will not be built])
  60        fi
  61       ],
  62       [AC_CHECK_PROG([efl_have_doxygen],
  63           [${efl_doxygen}],
  64           [yes],
  65           [no])
  66        if test "x${efl_have_doxygen}" = "xno" ; then
  67           echo "WARNING:"
  68           echo "The doxygen program was not found in your execute path."
  69           echo "You may have doxygen installed somewhere not covered by your path."
  70           echo ""
  71           echo "If this is the case make sure you have the packages installed, AND"
  72           echo "that the doxygen program is in your execute path (see your"
  73           echo "shell manual page on setting the \$PATH environment variable), OR"
  74           echo "alternatively, specify the program to use with --with-doxygen."
  75           AC_MSG_WARN([no doxygen detected. Documentation will not be built])
  76        fi
  77       ])
  78 fi
  79
  80 dnl
  81 dnl Substitution
  82 dnl
  83 AC_SUBST([efl_doxygen])
  84
  85 if ! test "x${efl_have_doxygen}" = "xyes" ; then
  86    efl_enable_doc="no"
  87 fi
  88
  89 AM_CONDITIONAL(EFL_BUILD_DOC, test "x${efl_enable_doc}" = "xyes")
  90
  91 if test "x${efl_enable_doc}" = "xyes" ; then
  92   m4_default([$1], [:])
  93 else
  94   m4_default([$2], [:])
  95 fi
  96
  97 ])
  98
  99 dnl End of doxygen.m4