m4/efl_check_libs.m4

   1 dnl Copyright (C) 2012 Vincent Torri <vincent dot torri at gmail dot com>
   2 dnl This code is public domain and can be freely used or copied.
   3
   4 dnl Macro that check dependencies libraries for the EFL:
   5
   6 dnl libjpeg
   7 dnl zlib
   8
   9 dnl _EFL_CHECK_LIB_LIBJPEG is for internal use
  10 dnl _EFL_CHECK_LIB_LIBJPEG(EFL, ACTION-IF-FOUND, ACTION-IF-NOT-FOUND)
  11
  12 AC_DEFUN([_EFL_CHECK_LIB_LIBJPEG],
  13 [
  14 m4_pushdef([UPEFL], m4_translit([$1], [-a-z], [_A-Z]))dnl
  15 m4_pushdef([DOWNEFL], m4_translit([$1], [-A-Z], [_a-z]))dnl
  16
  17 AC_CHECK_HEADER([jpeglib.h],
  18    [have_dep="yes"],
  19    [
  20     AC_MSG_ERROR(["Cannot find jpeglib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file"])
  21     have_dep="no"
  22    ])
  23
  24 if test "x${have_dep}" = "xyes" ; then
  25    AC_CHECK_LIB([jpeg], [jpeg_std_error],
  26       [
  27        have_dep="yes"
  28        requirements_libs_[]m4_defn([DOWNEFL])="${requirements_libs_[]m4_defn([DOWNEFL])} -ljpeg"
  29       ],
  30       [
  31        AC_MSG_ERROR("Cannot find libjpeg library. Make sure your LDFLAGS environment variable contains include lines for the location of this file")
  32        have_dep="no"
  33       ])
  34 fi
  35
  36 AS_IF([test "x${have_dep}" = "xyes"], [$2], [$3])
  37
  38 m4_popdef([DOWNEFL])
  39 m4_popdef([UPEFL])
  40 ])
  41
  42 dnl _EFL_CHECK_LIB_ZLIB is for internal use
  43 dnl _EFL_CHECK_LIB_ZLIB(EFL, ACTION-IF-FOUND, ACTION-IF-NOT-FOUND)
  44
  45 AC_DEFUN([_EFL_CHECK_LIB_ZLIB],
  46 [
  47 m4_pushdef([UPEFL], m4_translit([$1], [-a-z], [_A-Z]))dnl
  48 m4_pushdef([DOWNEFL], m4_translit([$1], [-A-Z], [_a-z]))dnl
  49
  50 PKG_CHECK_EXISTS([zlib],
  51    [
  52     _efl_have_lib="yes"
  53     requirements_pc_[]m4_defn([DOWNEFL])="${requirements_pc_[]m4_defn([DOWNEFL])} zlib"
  54    ],
  55    [
  56     _efl_have_lib="no"
  57    ])
  58
  59 if test "x${_efl_have_lib}" = "xno" ; then
  60    AC_CHECK_HEADER([zlib.h],
  61       [_efl_have_lib="yes"],
  62       [
  63        AC_MSG_ERROR(["Cannot find zlib.h. Make sure your CFLAGS environment variable contains include lines for the location of this file"])
  64        _efl_have_lib="no"
  65       ])
  66
  67    if test "x${_efl_have_lib}" = "xyes" ; then
  68       AC_CHECK_LIB([z], [zlibVersion],
  69          [
  70           _efl_have_lib="yes"
  71           requirements_libs_[]m4_defn([DOWNEFL])="${requirements_libs_[]m4_defn([DOWNEFL])} -lz"
  72          ],
  73          [
  74           AC_MSG_ERROR(["Cannot find libjpeg library. Make sure your LDFLAGS environment variable contains include lines for the location of this file"])
  75           _efl_have_lib="no"
  76          ])
  77    fi
  78 fi
  79
  80 AS_IF([test "x${_efl_have_lib}" = "xyes"], [$2], [$3])
  81
  82 m4_popdef([DOWNEFL])
  83 m4_popdef([UPEFL])
  84 ])
  85
  86 dnl Macro that checks for a library
  87 dnl
  88 dnl EFL_CHECK_LIB(EFL, LIBRARY)
  89 dnl AC_DEFINE : EFL_HAVE_LIBRARY (LIBRARY being replaced by its value)
  90
  91 AC_DEFUN([EFL_CHECK_LIB],
  92 [
  93 m4_pushdef([UP], m4_translit([$2], [-a-z], [_A-Z]))dnl
  94 m4_pushdef([DOWN], m4_translit([$2], [-A-Z], [_a-z]))dnl
  95
  96 m4_default([_EFL_CHECK_LIB_]m4_defn([UP]))($1, [have_lib="yes"], [have_lib="no"])
  97
  98 AC_MSG_CHECKING([for ]m4_defn([DOWN]))
  99 AC_MSG_RESULT([${have_lib}])
 100
 101 if test "x${have_lib}" = "xyes" ; then
 102    AC_DEFINE([HAVE_]m4_defn([UP]), [1], [Define to 1 if the `]m4_defn([DOWN])[' library is installed.])
 103 fi
 104
 105 efl_lib_[]m4_defn([DOWN])="${have_lib}"
 106
 107 m4_popdef([DOWN])
 108 m4_popdef([UP])
 109 ])
 110
 111 dnl Macro that iterates over a sequence of white separated libraries
 112 dnl and that calls EFL_CHECK_LIB() for each of these libraries
 113 dnl
 114 dnl EFL_CHECK_LIBS(EFL, LIBRARIES)
 115
 116 AC_DEFUN([EFL_CHECK_LIBS],
 117 [
 118 m4_foreach_w([lib], [$2], [EFL_CHECK_LIB($1, m4_defn([lib]))])
 119 ])